fb792b94bb926bdec1cd410746dd62fe94837471
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / triggers / trigger / swamp.qc
1 #if defined(CSQC)
2 #elif defined(MENUQC)
3 #elif defined(SVQC)
4     #include <lib/warpzone/util_server.qh>
5     #include <common/weapons/all.qh>
6     #include <server/defs.qh>
7     #include <common/deathtypes/all.qh>
8 #endif
9
10 /*
11 *               t_swamp.c
12 *               Adds spawnfunc_trigger_swamp and suppoart routines for xonotic 1.2.1+
13 *               Author tZork (Jakob MG)
14 *               jakob@games43.se
15 *               2005 11 29
16 */
17
18 .float swamp_interval;  //Hurt players in swamp with this interval
19 .float swamp_slowdown;  //Players in swamp get slowd down by this mutch 0-1 is slowdown 1-~ is speedup (!?)
20 .entity swampslug;
21
22 #ifdef SVQC
23 spawnfunc(trigger_swamp);
24 #endif
25 void swamp_touch(entity this);
26 void swampslug_think(entity this);
27
28
29 /*
30 * Uses a entity calld swampslug to handle players in the swamp
31 * It works like this: When the plyer enters teh swamp the spawnfunc_trigger_swamp
32 * attaches a new "swampslug" to the player. As long as the plyer is inside
33 * the swamp the swamp gives the slug new health. But the slug slowly kills itself
34 * so when the player goes outside the swamp, it dies and releases the player from the
35 * swamps curses (dmg/slowdown)
36 *
37 * I do it this way becuz there is no "untouch" event.
38 */
39 void swampslug_think(entity this)
40 {
41         //Slowly kill the slug
42         this.health = this.health - 1;
43
44         //Slug dead? then remove curses.
45         if(this.health <= 0)
46         {
47                 this.owner.in_swamp = 0;
48                 remove(this);
49                 //centerprint(this.owner,"Killing slug...\n");
50                 return;
51         }
52
53         // Slug still alive, so we are still in the swamp
54         // Or we have exited it very recently.
55         // Do the damage and renew the timer.
56 #ifdef SVQC
57         Damage (this.owner, this, this, this.dmg, DEATH_SWAMP.m_id, other.origin, '0 0 0');
58 #endif
59
60         this.nextthink = time + this.swamp_interval;
61 }
62
63 void swamp_touch(entity this)
64 {
65         // If whatever thats touching the swamp is not a player
66         // or if its a dead player, just dont care abt it.
67         if(!IS_PLAYER(other) || IS_DEAD(other))
68                 return;
69
70         EXACTTRIGGER_TOUCH;
71
72         // Chech if player alredy got a swampslug.
73         if(other.in_swamp != 1)
74         {
75                 // If not attach one.
76                 //centerprint(other,"Entering swamp!\n");
77                 other.swampslug = spawn();
78                 other.swampslug.health = 2;
79                 setthink(other.swampslug, swampslug_think);
80                 other.swampslug.nextthink = time;
81                 other.swampslug.owner = other;
82                 other.swampslug.dmg = this.dmg;
83                 other.swampslug.swamp_interval = this.swamp_interval;
84                 other.swamp_slowdown = this.swamp_slowdown;
85                 other.in_swamp = 1;
86                 return;
87         }
88
89         //other.in_swamp = 1;
90
91         //Revitalize players swampslug
92         other.swampslug.health = 2;
93 }
94
95 REGISTER_NET_LINKED(ENT_CLIENT_SWAMP)
96
97 #ifdef SVQC
98 float swamp_send(entity this, entity to, float sf)
99 {
100         WriteHeader(MSG_ENTITY, ENT_CLIENT_SWAMP);
101
102         WriteByte(MSG_ENTITY, this.dmg); // can probably get away with using a single byte here
103         WriteByte(MSG_ENTITY, this.swamp_slowdown);
104         WriteByte(MSG_ENTITY, this.swamp_interval);
105
106         trigger_common_write(this, false);
107
108         return true;
109 }
110
111 void swamp_link(entity this)
112 {
113         trigger_link(this, swamp_send);
114 }
115
116 /*QUAKED spawnfunc_trigger_swamp (.5 .5 .5) ?
117 Players gettin into the swamp will
118 get slowd down and damaged
119 */
120 spawnfunc(trigger_swamp)
121 {
122         // Init stuff
123         trigger_init(this);
124         settouch(this, swamp_touch);
125
126         // Setup default keys, if missing
127         if(this.dmg <= 0)
128                 this.dmg = 5;
129         if(this.swamp_interval <= 0)
130                 this.swamp_interval = 1;
131         if(this.swamp_slowdown <= 0)
132                 this.swamp_slowdown = 0.5;
133
134         swamp_link(this);
135 }
136
137 #elif defined(CSQC)
138
139 NET_HANDLE(ENT_CLIENT_SWAMP, bool isnew)
140 {
141         this.dmg = ReadByte();
142         this.swamp_slowdown = ReadByte();
143         this.swamp_interval = ReadByte();
144
145         trigger_common_read(this, false);
146
147         return = true;
148
149         this.classname = "trigger_swamp";
150         this.solid = SOLID_TRIGGER;
151         settouch(this, swamp_touch);
152         this.drawmask = MASK_NORMAL;
153         this.move_time = time;
154         this.entremove = trigger_remove_generic;
155 }
156 #endif