Cleanse the touch functions of the other evil
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / turrets / sv_turrets.qc
1 #ifdef SVQC
2 #include <server/autocvars.qh>
3
4 // Generic aiming
5 vector turret_aim_generic(entity this)
6 {
7
8         vector pre_pos, prep;
9         float distance, impact_time = 0, i, mintime;
10
11         turret_tag_fire_update(this);
12
13         if(this.aim_flags & TFL_AIM_SIMPLE)
14                 return real_origin(this.enemy);
15
16         mintime = max(this.attack_finished_single[0] - time,0) + sys_frametime;
17
18         // Baseline
19         pre_pos = real_origin(this.enemy);
20
21         // Lead?
22         if (this.aim_flags & TFL_AIM_LEAD)
23         {
24                 if (this.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
25                 {
26                         prep = pre_pos;
27
28                         distance = vlen(prep - this.tur_shotorg);
29                         impact_time = distance / this.shot_speed;
30
31                         prep = pre_pos + (this.enemy.velocity * (impact_time + mintime));
32
33                         if(this.aim_flags & TFL_AIM_ZPREDICT)
34                         if(!IS_ONGROUND(this.enemy))
35                         if(this.enemy.movetype == MOVETYPE_WALK || this.enemy.movetype == MOVETYPE_TOSS || this.enemy.movetype == MOVETYPE_BOUNCE)
36                         {
37                                 float vz;
38                                 prep_z = pre_pos_z;
39                                 vz = this.enemy.velocity_z;
40                                 for(i = 0; i < impact_time; i += sys_frametime)
41                                 {
42                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
43                                         prep_z = prep_z + vz * sys_frametime;
44                                 }
45                         }
46                         pre_pos = prep;
47                 }
48                 else
49                         pre_pos = pre_pos + this.enemy.velocity * mintime;
50         }
51
52         if(this.aim_flags & TFL_AIM_SPLASH)
53         {
54                 //tracebox(pre_pos + '0 0 32',this.enemy.mins,this.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
55                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
56                 if(trace_fraction != 1.0)
57                         pre_pos = trace_endpos;
58         }
59
60         return pre_pos;
61 }
62
63 float turret_targetscore_support(entity _turret,entity _target)
64 {
65         float score;            // Total score
66         float s_score = 0, d_score;
67
68         if (_turret.enemy == _target) s_score = 1;
69
70         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
71
72         score = (d_score * _turret.target_select_rangebias) +
73                         (s_score * _turret.target_select_samebias);
74
75         return score;
76 }
77
78 /*
79 * Generic bias aware score system.
80 */
81 float turret_targetscore_generic(entity _turret, entity _target)
82 {
83         float d_dist;      // Defendmode Distance
84         float score;            // Total score
85         float d_score;    // Distance score
86         float a_score;    // Angular score
87         float m_score = 0;  // missile score
88         float p_score = 0;  // player score
89         float ikr;                // ideal kill range
90
91         if (_turret.tur_defend)
92         {
93                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
94                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
95                 d_score = 1 - d_dist / _turret.target_range;
96         }
97         else
98         {
99                 // Make a normlized value base on the targets distance from our optimal killzone
100                 ikr = _turret.target_range_optimal;
101                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
102         }
103
104         a_score = 1 - tvt_thadf / _turret.aim_maxrotate;
105
106         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
107                 m_score = 1;
108
109         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
110                 p_score = 1;
111
112         d_score = max(d_score, 0);
113         a_score = max(a_score, 0);
114         m_score = max(m_score, 0);
115         p_score = max(p_score, 0);
116
117         score = (d_score * _turret.target_select_rangebias) +
118                         (a_score * _turret.target_select_anglebias) +
119                         (m_score * _turret.target_select_missilebias) +
120                         (p_score * _turret.target_select_playerbias);
121
122         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
123         {
124                 //dprint("Wtf?\n");
125                 score *= 0.001;
126         }
127
128 #ifdef TURRET_DEBUG
129         string sd,sa,sm,sp,ss;
130         string sdt,sat,smt,spt;
131
132         sd = ftos(d_score);
133         d_score *= _turret.target_select_rangebias;
134         sdt = ftos(d_score);
135
136         //sv = ftos(v_score);
137         //v_score *= _turret.target_select_samebias;
138         //svt = ftos(v_score);
139
140         sa = ftos(a_score);
141         a_score *= _turret.target_select_anglebias;
142         sat = ftos(a_score);
143
144         sm = ftos(m_score);
145         m_score *= _turret.target_select_missilebias;
146         smt = ftos(m_score);
147
148         sp = ftos(p_score);
149         p_score *= _turret.target_select_playerbias;
150         spt = ftos(p_score);
151
152
153         ss = ftos(score);
154         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
155         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
156         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
157         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
158         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
159         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
160
161 #endif
162
163         return score;
164 }
165
166 // Generic damage handling
167 void turret_hide(entity this)
168 {
169         this.effects   |= EF_NODRAW;
170         this.nextthink = time + this.respawntime - 0.2;
171         setthink(this, turret_respawn);
172 }
173
174 void turret_die(entity this)
175 {
176         this.deadflag             = DEAD_DEAD;
177         this.tur_head.deadflag = this.deadflag;
178
179 // Unsolidify and hide real parts
180         this.solid                       = SOLID_NOT;
181         this.tur_head.solid      = this.solid;
182
183         this.event_damage                 = func_null;
184         this.takedamage                  = DAMAGE_NO;
185
186         this.health                      = 0;
187
188 // Go boom
189         //RadiusDamage (this,this, min(this.ammo,50),min(this.ammo,50) * 0.25,250,NULL,min(this.ammo,50)*5,DEATH_TURRET,NULL);
190
191         Turret tur = get_turretinfo(this.m_id);
192         if(this.damage_flags & TFL_DMG_DEATH_NORESPAWN)
193         {
194                 tur.tr_death(tur, this);
195
196                 remove(this.tur_head);
197                 remove(this);
198         }
199         else
200         {
201                 // Setup respawn
202                 this.SendFlags    |= TNSF_STATUS;
203                 this.nextthink   = time + 0.2;
204                 setthink(this, turret_hide);
205
206                 tur.tr_death(tur, this);
207         }
208 }
209
210 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
211 {
212         // Enough already!
213         if(this.deadflag == DEAD_DEAD)
214                 return;
215
216         // Inactive turrets take no damage. (hm..)
217         if(!this.active)
218                 return;
219
220         if(SAME_TEAM(this, attacker))
221         {
222                 if(autocvar_g_friendlyfire)
223                         damage = damage * autocvar_g_friendlyfire;
224                 else
225                         return;
226         }
227
228         this.health -= damage;
229
230         // thorw head slightly off aim when hit?
231         if (this.damage_flags & TFL_DMG_HEADSHAKE)
232         {
233                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
234                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
235
236                 this.SendFlags  |= TNSF_ANG;
237         }
238
239         if (this.turret_flags & TUR_FLAG_MOVE)
240                 this.velocity = this.velocity + vforce;
241
242         if (this.health <= 0)
243         {
244                 this.event_damage                 = func_null;
245                 this.tur_head.event_damage = func_null;
246                 this.takedamage                  = DAMAGE_NO;
247                 this.nextthink = time;
248                 setthink(this, turret_die);
249         }
250
251         this.SendFlags  |= TNSF_STATUS;
252 }
253
254 void turret_think(entity this);
255 void turret_respawn(entity this)
256 {
257         // Make sure all parts belong to the same team since
258         // this function doubles as "teamchange" function.
259         this.tur_head.team      = this.team;
260         this.effects                       &= ~EF_NODRAW;
261         this.deadflag                           = DEAD_NO;
262         this.effects                            = EF_LOWPRECISION;
263         this.solid                                      = SOLID_BBOX;
264         this.takedamage                         = DAMAGE_AIM;
265         this.event_damage                       = turret_damage;
266         this.avelocity                          = '0 0 0';
267         this.tur_head.avelocity         = this.avelocity;
268         this.tur_head.angles            = this.idle_aim;
269         this.health                                     = this.max_health;
270         this.enemy                                      = NULL;
271         this.volly_counter                      = this.shot_volly;
272         this.ammo                                       = this.ammo_max;
273
274         this.nextthink = time + this.ticrate;
275         setthink(this, turret_think);
276
277         this.SendFlags = TNSF_FULL_UPDATE;
278
279         Turret tur = get_turretinfo(this.m_id);
280         tur.tr_setup(tur, this);
281 }
282
283
284 // Main functions
285 #define cvar_base "g_turrets_unit_"
286 .float clientframe;
287 void turrets_setframe(entity this, float _frame, float client_only)
288 {
289         if((client_only ? this.clientframe : this.frame ) != _frame)
290         {
291                 this.SendFlags |= TNSF_ANIM;
292                 this.anim_start_time = time;
293         }
294
295          if(client_only)
296                 this.clientframe = _frame;
297         else
298                 this.frame = _frame;
299
300 }
301
302 bool turret_send(entity this, entity to, float sf)
303 {
304
305         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
306         WriteByte(MSG_ENTITY, sf);
307         if(sf & TNSF_SETUP)
308         {
309                 WriteByte(MSG_ENTITY, this.m_id);
310
311                 WriteCoord(MSG_ENTITY, this.origin_x);
312                 WriteCoord(MSG_ENTITY, this.origin_y);
313                 WriteCoord(MSG_ENTITY, this.origin_z);
314
315                 WriteAngle(MSG_ENTITY, this.angles_x);
316                 WriteAngle(MSG_ENTITY, this.angles_y);
317         }
318
319         if(sf & TNSF_ANG)
320         {
321                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_x));
322                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_y));
323         }
324
325         if(sf & TNSF_AVEL)
326         {
327                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_x));
328                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_y));
329         }
330
331         if(sf & TNSF_MOVE)
332         {
333                 WriteShort(MSG_ENTITY, rint(this.origin_x));
334                 WriteShort(MSG_ENTITY, rint(this.origin_y));
335                 WriteShort(MSG_ENTITY, rint(this.origin_z));
336
337                 WriteShort(MSG_ENTITY, rint(this.velocity_x));
338                 WriteShort(MSG_ENTITY, rint(this.velocity_y));
339                 WriteShort(MSG_ENTITY, rint(this.velocity_z));
340
341                 WriteShort(MSG_ENTITY, rint(this.angles_y));
342         }
343
344         if(sf & TNSF_ANIM)
345         {
346                 WriteCoord(MSG_ENTITY, this.anim_start_time);
347                 WriteByte(MSG_ENTITY, this.frame);
348         }
349
350         if(sf & TNSF_STATUS)
351         {
352                 WriteByte(MSG_ENTITY, this.team);
353
354                 if(this.health <= 0)
355                         WriteByte(MSG_ENTITY, 0);
356                 else
357                         WriteByte(MSG_ENTITY, ceil((this.health / this.max_health) * 255));
358         }
359
360         return true;
361 }
362
363 void load_unit_settings(entity ent, bool is_reload)
364 {
365         string unitname = ent.netname;
366         string sbase;
367
368         if (ent == NULL)
369                 return;
370
371         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
372         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
373         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
374         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
375         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
376         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
377         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
378
379         sbase = strcat(cvar_base,unitname);
380         if (is_reload)
381         {
382                 ent.enemy = NULL;
383                 ent.tur_head.avelocity = '0 0 0';
384
385                 ent.tur_head.angles = '0 0 0';
386         }
387
388         ent.health       = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
389         ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
390
391         ent.shot_dmg             = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
392         ent.shot_refire   = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
393         ent.shot_radius   = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
394         ent.shot_speed          = cvar(strcat(sbase,"_shot_speed"));
395         ent.shot_spread   = cvar(strcat(sbase,"_shot_spread"));
396         ent.shot_force          = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
397         ent.shot_volly          = cvar(strcat(sbase,"_shot_volly"));
398         ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
399
400         ent.target_range                 = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
401         ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
402         ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
403         //ent.target_range_fire = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
404
405         ent.target_select_rangebias = cvar(strcat(sbase,"_target_select_rangebias"));
406         ent.target_select_samebias  = cvar(strcat(sbase,"_target_select_samebias"));
407         ent.target_select_anglebias = cvar(strcat(sbase,"_target_select_anglebias"));
408         ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
409         //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
410
411         ent.ammo_max     = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
412         ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
413
414         ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
415         ent.aim_speed   = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
416         ent.aim_maxrotate  = cvar(strcat(sbase,"_aim_maxrot"));
417         ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
418
419         ent.track_type          = cvar(strcat(sbase,"_track_type"));
420         ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
421         ent.track_accel_rotate  = cvar(strcat(sbase,"_track_accel_rot"));
422         ent.track_blendrate  = cvar(strcat(sbase,"_track_blendrate"));
423
424         if(is_reload) {
425                 Turret tur = get_turretinfo(ent.m_id);
426                 tur.tr_setup(tur, ent);
427         }
428 }
429
430 void turret_projectile_explode(entity this)
431 {
432
433         this.takedamage = DAMAGE_NO;
434         this.event_damage = func_null;
435 #ifdef TURRET_DEBUG
436         float d;
437         d = RadiusDamage (this, this.owner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, NULL);
438         this.owner.tur_debug_dmg_t_h = this.owner.tur_debug_dmg_t_h + d;
439         this.owner.tur_debug_dmg_t_f = this.owner.tur_debug_dmg_t_f + this.owner.shot_dmg;
440 #else
441         RadiusDamage (this, this.realowner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, NULL);
442 #endif
443         remove(this);
444 }
445
446 void turret_projectile_touch(entity this, entity toucher)
447 {
448         PROJECTILE_TOUCH(this, toucher);
449         turret_projectile_explode(this);
450 }
451
452 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
453 {
454         this.velocity  += vforce;
455         this.health     -= damage;
456         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
457         if(this.health <= 0)
458                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
459 }
460
461 entity turret_projectile(entity actor, Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
462 {
463     TC(Sound, _snd);
464         entity proj;
465
466         sound (actor, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
467         proj                             = spawn ();
468         setorigin(proj, actor.tur_shotorg);
469         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
470         proj.owner                = actor;
471         proj.realowner    = actor;
472         proj.bot_dodge    = true;
473         proj.bot_dodgerating = actor.shot_dmg;
474         setthink(proj, turret_projectile_explode);
475         settouch(proj, turret_projectile_touch);
476         proj.nextthink    = time + 9;
477         proj.movetype           = MOVETYPE_FLYMISSILE;
478         proj.velocity           = normalize(actor.tur_shotdir_updated + randomvec() * actor.shot_spread) * actor.shot_speed;
479         proj.flags                = FL_PROJECTILE;
480         proj.enemy                = actor.enemy;
481         proj.totalfrags  = _death;
482         PROJECTILE_MAKETRIGGER(proj);
483         if(_health)
484         {
485                 proj.health              = _health;
486                 proj.takedamage  = DAMAGE_YES;
487                 proj.event_damage  = turret_projectile_damage;
488         }
489         else
490                 proj.flags |= FL_NOTARGET;
491
492         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
493
494         return proj;
495 }
496
497 /**
498 ** updates enemy distances, predicted impact point/time
499 ** and updated aim<->predict impact distance.
500 **/
501 void turret_do_updates(entity t_turret)
502 {
503         vector enemy_pos = real_origin(t_turret.enemy);
504
505         turret_tag_fire_update(t_turret);
506
507         t_turret.tur_shotdir_updated = v_forward;
508         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
509         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
510
511         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
512         {
513                 oldpos = t_turret.enemy.origin;
514                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
515                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
516                 setorigin(t_turret.enemy, oldpos);
517
518                 if(trace_ent == t_turret.enemy)
519                         t_turret.tur_dist_impact_to_aimpos = 0;
520                 else
521                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
522         }
523         else*/
524                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
525
526         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
527         t_turret.tur_impactent                   = trace_ent;
528         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
529 }
530
531 /**
532 ** Handles head rotation according to
533 ** the units .track_type and .track_flags
534 **/
535 .float turret_framecounter;
536 void turret_track(entity this)
537 {
538         vector target_angle; // This is where we want to aim
539         vector move_angle;   // This is where we can aim
540         float f_tmp;
541         vector v1, v2;
542         v1 = this.tur_head.angles;
543         v2 = this.tur_head.avelocity;
544
545         if (this.track_flags == TFL_TRACK_NO)
546                 return;
547
548         if(!this.active)
549                 target_angle = this.idle_aim - ('1 0 0' * this.aim_maxpitch);
550         else if (this.enemy == NULL)
551         {
552                 if(time > this.lip)
553                         target_angle = this.idle_aim + this.angles;
554                 else
555                         target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
556         }
557         else
558         {
559                 target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
560         }
561
562         this.tur_head.angles_x = anglemods(this.tur_head.angles_x);
563         this.tur_head.angles_y = anglemods(this.tur_head.angles_y);
564
565         // Find the diffrence between where we currently aim and where we want to aim
566         //move_angle = target_angle - (this.angles + this.tur_head.angles);
567         //move_angle = shortangle_vxy(move_angle,(this.angles + this.tur_head.angles));
568
569         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(this.angles), AnglesTransform_FromAngles(target_angle))) - this.tur_head.angles;
570         move_angle = shortangle_vxy(move_angle, this.tur_head.angles);
571
572         switch(this.track_type)
573         {
574                 case TFL_TRACKTYPE_STEPMOTOR:
575                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
576                         if (this.track_flags & TFL_TRACK_PITCH)
577                         {
578                                 this.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
579                                 if(this.tur_head.angles_x > this.aim_maxpitch)
580                                         this.tur_head.angles_x = this.aim_maxpitch;
581
582                                 if(this.tur_head.angles_x  < -this.aim_maxpitch)
583                                         this.tur_head.angles_x = this.aim_maxpitch;
584                         }
585
586                         if (this.track_flags & TFL_TRACK_ROTATE)
587                         {
588                                 this.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
589                                 if(this.tur_head.angles_y > this.aim_maxrotate)
590                                         this.tur_head.angles_y = this.aim_maxrotate;
591
592                                 if(this.tur_head.angles_y  < -this.aim_maxrotate)
593                                         this.tur_head.angles_y = this.aim_maxrotate;
594                         }
595
596                         // CSQC
597                         this.SendFlags  |= TNSF_ANG;
598
599                         return;
600
601                 case TFL_TRACKTYPE_FLUIDINERTIA:
602                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
603                         move_angle_x = bound(-this.aim_speed, move_angle_x * this.track_accel_pitch * f_tmp, this.aim_speed);
604                         move_angle_y = bound(-this.aim_speed, move_angle_y * this.track_accel_rotate * f_tmp, this.aim_speed);
605                         move_angle = (this.tur_head.avelocity * this.track_blendrate) + (move_angle * (1 - this.track_blendrate));
606                         break;
607
608                 case TFL_TRACKTYPE_FLUIDPRECISE:
609
610                         move_angle_y = bound(-this.aim_speed, move_angle_y, this.aim_speed);
611                         move_angle_x = bound(-this.aim_speed, move_angle_x, this.aim_speed);
612
613                         break;
614         }
615
616         //  pitch
617         if (this.track_flags & TFL_TRACK_PITCH)
618         {
619                 this.tur_head.avelocity_x = move_angle_x;
620                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) > this.aim_maxpitch)
621                 {
622                         this.tur_head.avelocity_x = 0;
623                         this.tur_head.angles_x = this.aim_maxpitch;
624
625                         this.SendFlags  |= TNSF_ANG;
626                 }
627
628                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) < -this.aim_maxpitch)
629                 {
630                         this.tur_head.avelocity_x = 0;
631                         this.tur_head.angles_x = -this.aim_maxpitch;
632
633                         this.SendFlags  |= TNSF_ANG;
634                 }
635         }
636
637         //  rot
638         if (this.track_flags & TFL_TRACK_ROTATE)
639         {
640                 this.tur_head.avelocity_y = move_angle_y;
641
642                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) > this.aim_maxrotate)
643                 {
644                         this.tur_head.avelocity_y = 0;
645                         this.tur_head.angles_y = this.aim_maxrotate;
646
647                         this.SendFlags  |= TNSF_ANG;
648                 }
649
650                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) < -this.aim_maxrotate)
651                 {
652                         this.tur_head.avelocity_y = 0;
653                         this.tur_head.angles_y = -this.aim_maxrotate;
654
655                         this.SendFlags  |= TNSF_ANG;
656                 }
657         }
658
659         this.SendFlags  |= TNSF_AVEL;
660
661         // Force a angle update every 10'th frame
662         this.turret_framecounter += 1;
663         if(this.turret_framecounter >= 10)
664         {
665                 this.SendFlags |= TNSF_ANG;
666                 this.turret_framecounter = 0;
667         }
668 }
669
670 /*
671  + TFL_TARGETSELECT_NO
672  + TFL_TARGETSELECT_LOS
673  + TFL_TARGETSELECT_PLAYERS
674  + TFL_TARGETSELECT_MISSILES
675  - TFL_TARGETSELECT_TRIGGERTARGET
676  + TFL_TARGETSELECT_ANGLELIMITS
677  + TFL_TARGETSELECT_RANGELIMITS
678  + TFL_TARGETSELECT_TEAMCHECK
679  - TFL_TARGETSELECT_NOBUILTIN
680  + TFL_TARGETSELECT_OWNTEAM
681 */
682
683 /**
684 ** Evaluate a entity for target valitity based on validate_flags
685 ** NOTE: the caller must check takedamage before calling this, to inline this check.
686 **/
687 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
688 {
689         vector v_tmp;
690
691         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
692         //      return -0.5;
693
694         if(!e_target)
695                 return -2;
696
697         if(e_target.owner == e_turret)
698                 return -0.5;
699
700         if(!checkpvs(e_target.origin, e_turret))
701                 return -1;
702
703         if(e_target.alpha <= 0.3)
704                 return -1;
705
706         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
707                 return M_ARGV(3, float);
708
709         if (validate_flags & TFL_TARGETSELECT_NO)
710                 return -4;
711
712         // If only this was used more..
713         if (e_target.flags & FL_NOTARGET)
714                 return -5;
715
716         // Cant touch this
717         if(IS_VEHICLE(e_target))
718         {
719                 if (e_target.vehicle_health <= 0)
720                         return -6;
721         }
722         else if (e_target.health <= 0)
723                 return -6;
724         else if(STAT(FROZEN, e_target) > 0)
725                 return -6;
726
727         // player
728         if (IS_CLIENT(e_target))
729         {
730                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
731                         return -7;
732
733                 if (IS_DEAD(e_target))
734                         return -8;
735         }
736
737         // enemy turrets
738         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
739         if(e_target.owner.tur_head == e_target)
740         if(e_target.team != e_turret.team) // Dont break support units.
741                 return -9;
742
743         // Missile
744         if (e_target.flags & FL_PROJECTILE)
745         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
746                 return -10;
747
748         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
749         if(!(e_target.flags & FL_PROJECTILE))
750                 return -10.5;
751
752         // Team check
753         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
754         {
755                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
756                 {
757                         if (e_target.team != e_turret.team)
758                                 return -11;
759
760                         if (e_turret.team != e_target.owner.team)
761                                 return -12;
762                 }
763                 else
764                 {
765                         if (e_target.team == e_turret.team)
766                                 return -13;
767
768                         if (e_turret.team == e_target.owner.team)
769                                 return -14;
770                 }
771         }
772
773         // Range limits?
774         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
775         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
776         {
777                 if (tvt_dist < e_turret.target_range_min)
778                         return -15;
779
780                 if (tvt_dist > e_turret.target_range)
781                         return -16;
782         }
783
784         // Can we even aim this thing?
785         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
786         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
787         tvt_thadf = vlen(tvt_thadv);
788         tvt_tadf = vlen(tvt_tadv);
789
790         /*
791         if(validate_flags & TFL_TARGETSELECT_FOV)
792         {
793                 if(e_turret.target_select_fov < tvt_thadf)
794                         return -21;
795         }
796         */
797
798         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
799         {
800                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
801                         return -17;
802
803                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrotate)
804                         return -18;
805         }
806
807         // Line of sight?
808         if (validate_flags & TFL_TARGETSELECT_LOS)
809         {
810                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
811
812                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
813
814                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
815                         return -19;
816         }
817
818         if (e_target.classname == "grapplinghook")
819                 return -20;
820
821         /*
822         if (e_target.classname == "func_button")
823                 return -21;
824         */
825
826 #ifdef TURRET_DEBUG_TARGETSELECT
827         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
828 #endif
829
830         return 1;
831 }
832
833 entity turret_select_target(entity this)
834 {
835         entity e;               // target looper entity
836         float  score;   // target looper entity score
837         entity e_enemy;  // currently best scoreing target
838         float  m_score;  // currently best scoreing target's score
839
840         m_score = 0;
841         if(this.enemy && this.enemy.takedamage && turret_validate_target(this,this.enemy,this.target_validate_flags) > 0)
842         {
843                 e_enemy = this.enemy;
844                 m_score = this.turret_score_target(this,e_enemy) * this.target_select_samebias;
845         }
846         else
847                 e_enemy = this.enemy = NULL;
848
849         e = findradius(this.origin, this.target_range);
850
851         // Nothing to aim at?
852         if (!e)
853                 return NULL;
854
855         while (e)
856         {
857                 if(e.takedamage)
858                 {
859                         float f = turret_validate_target(this, e, this.target_select_flags);
860                         //dprint("F is: ", ftos(f), "\n");
861                         if ( f > 0)
862                         {
863                                 score = this.turret_score_target(this,e);
864                                 if ((score > m_score) && (score > 0))
865                                 {
866                                         e_enemy = e;
867                                         m_score = score;
868                                 }
869                         }
870                 }
871                 e = e.chain;
872         }
873
874         return e_enemy;
875 }
876
877
878 /*
879  + = implemented
880  - = not implemented
881
882  + TFL_FIRECHECK_NO
883  + TFL_FIRECHECK_WORLD
884  + TFL_FIRECHECK_DEAD
885  + TFL_FIRECHECK_DISTANCES
886  - TFL_FIRECHECK_LOS
887  + TFL_FIRECHECK_AIMDIST
888  + TFL_FIRECHECK_REALDIST
889  - TFL_FIRECHECK_ANGLEDIST
890  - TFL_FIRECHECK_TEAMCECK
891  + TFL_FIRECHECK_AFF
892  + TFL_FIRECHECK_AMMO_OWN
893  + TFL_FIRECHECK_AMMO_OTHER
894  + TFL_FIRECHECK_REFIRE
895 */
896
897 /**
898 ** Preforms pre-fire checks based on the uints firecheck_flags
899 **/
900 bool turret_firecheck(entity this)
901 {
902         // This one just dont care =)
903         if (this.firecheck_flags & TFL_FIRECHECK_NO)
904                 return true;
905
906         if (this.enemy == NULL)
907                 return false;
908
909         // Ready?
910         if (this.firecheck_flags & TFL_FIRECHECK_REFIRE)
911                 if (this.attack_finished_single[0] > time) return false;
912
913         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
914         if (this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
915                 if (this.volly_counter != this.shot_volly)
916                         if(this.ammo >= this.shot_dmg)
917                                 return true;
918
919         // Lack of zombies makes shooting dead things unnecessary :P
920         if (this.firecheck_flags & TFL_FIRECHECK_DEAD)
921                 if (IS_DEAD(this.enemy))
922                         return false;
923
924         // Own ammo?
925         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
926                 if (this.ammo < this.shot_dmg)
927                         return false;
928
929         // Other's ammo? (support-supply units)
930         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
931                 if (this.enemy.ammo >= this.enemy.ammo_max)
932                         return false;
933
934         // Target of opertunity?
935         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
936         {
937                 this.enemy = this.tur_impactent;
938                 return true;
939         }
940
941         if (this.firecheck_flags & TFL_FIRECHECK_DISTANCES)
942         {
943                 // To close?
944                 if (this.tur_dist_aimpos < this.target_range_min)
945                         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
946                                 return true; // Target of opertunity?
947                         else
948                                 return false;
949         }
950
951         // Try to avoid FF?
952         if (this.firecheck_flags & TFL_FIRECHECK_AFF)
953                 if (this.tur_impactent.team == this.team)
954                         return false;
955
956         // aim<->predicted impact
957         if (this.firecheck_flags & TFL_FIRECHECK_AIMDIST)
958                 if (this.tur_dist_impact_to_aimpos > this.aim_firetolerance_dist)
959                         return false;
960
961         // Volly status
962         if (this.shot_volly > 1)
963                 if (this.volly_counter == this.shot_volly)
964                         if (this.ammo < (this.shot_dmg * this.shot_volly))
965                                 return false;
966
967         /*if(this.firecheck_flags & TFL_FIRECHECK_VERIFIED)
968                 if(this.tur_impactent != this.enemy)
969                         return false;*/
970
971         return true;
972 }
973
974 bool turret_checkfire(entity this)
975 {
976         if(MUTATOR_CALLHOOK(Turret_CheckFire, this))
977                 return M_ARGV(1, bool);
978
979         return this.turret_firecheckfunc(this);
980 }
981
982 void turret_fire(entity this)
983 {
984         if (autocvar_g_turrets_nofire != 0)
985                 return;
986
987         if(MUTATOR_CALLHOOK(TurretFire, this))
988                 return;
989
990         Turret info = get_turretinfo(this.m_id);
991         info.tr_attack(info, this);
992
993         this.attack_finished_single[0] = time + this.shot_refire;
994         this.ammo -= this.shot_dmg;
995         this.volly_counter = this.volly_counter - 1;
996
997         if (this.volly_counter <= 0)
998         {
999                 this.volly_counter = this.shot_volly;
1000
1001                 if (this.shoot_flags & TFL_SHOOT_CLEARTARGET)
1002                         this.enemy = NULL;
1003
1004                 if (this.shot_volly > 1)
1005                         this.attack_finished_single[0] = time + this.shot_volly_refire;
1006         }
1007
1008 #ifdef TURRET_DEBUG
1009         if (this.enemy) paint_target3(this.tur_aimpos, 64, this.tur_debug_rvec, this.tur_impacttime + 0.25);
1010 #endif
1011 }
1012
1013 void turret_think(entity this)
1014 {
1015         this.nextthink = time + this.ticrate;
1016
1017         MUTATOR_CALLHOOK(TurretThink, this);
1018
1019 #ifdef TURRET_DEBUG
1020         if (this.tur_debug_tmr1 < time)
1021         {
1022                 if (this.enemy) paint_target (this.enemy,128,this.tur_debug_rvec,0.9);
1023                 paint_target(this,256,this.tur_debug_rvec,0.9);
1024                 this.tur_debug_tmr1 = time + 1;
1025         }
1026 #endif
1027
1028         // Handle ammo
1029         if (!(this.spawnflags & TSF_NO_AMMO_REGEN))
1030         if (this.ammo < this.ammo_max)
1031                 this.ammo = min(this.ammo + this.ammo_recharge, this.ammo_max);
1032
1033         // Inactive turrets needs to run the think loop,
1034         // So they can handle animation and wake up if need be.
1035         if(!this.active)
1036         {
1037                 turret_track(this);
1038                 return;
1039         }
1040
1041         // This is typicaly used for zaping every target in range
1042         // turret_fusionreactor uses this to recharge friendlys.
1043         if (this.shoot_flags & TFL_SHOOT_HITALLVALID)
1044         {
1045                 // Do a this.turret_fire for every valid target.
1046                 entity e = findradius(this.origin,this.target_range);
1047                 while (e)
1048                 {
1049                         if(e.takedamage)
1050                         {
1051                                 if (turret_validate_target(this,e,this.target_validate_flags))
1052                                 {
1053                                         this.enemy = e;
1054
1055                                         turret_do_updates(this);
1056
1057                                         if (turret_checkfire(this))
1058                                                 turret_fire(this);
1059                                 }
1060                         }
1061
1062                         e = e.chain;
1063                 }
1064                 this.enemy = NULL;
1065         }
1066         else if(this.shoot_flags & TFL_SHOOT_CUSTOM)
1067         {
1068                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1069
1070                 // Predict?
1071                 if(!(this.aim_flags & TFL_AIM_NO))
1072                         this.tur_aimpos = turret_aim_generic(this);
1073
1074                 // Turn & pitch?
1075                 if(!(this.track_flags & TFL_TRACK_NO))
1076                         turret_track(this);
1077
1078                 turret_do_updates(this);
1079
1080                 // Fire?
1081                 if (turret_checkfire(this))
1082                         turret_fire(this);
1083         }
1084         else
1085         {
1086                 // Special case for volly always. if it fired once it must compleate the volly.
1087                 if(this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1088                         if(this.volly_counter != this.shot_volly)
1089                         {
1090                                 // Predict or whatnot
1091                                 if(!(this.aim_flags & TFL_AIM_NO))
1092                                         this.tur_aimpos = turret_aim_generic(this);
1093
1094                                 // Turn & pitch
1095                                 if(!(this.track_flags & TFL_TRACK_NO))
1096                                         turret_track(this);
1097
1098                                 turret_do_updates(this);
1099
1100                                 // Fire!
1101                                 if (turret_checkfire(this))
1102                                         turret_fire(this);
1103
1104                                 Turret tur = get_turretinfo(this.m_id);
1105                                 tur.tr_think(tur, this);
1106
1107                                 return;
1108                         }
1109
1110                 // Check if we have a vailid enemy, and try to find one if we dont.
1111
1112                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1113                 float do_target_scan = 0;
1114                 if((this.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1115                         do_target_scan = 1;
1116
1117                 // Old target (if any) invalid?
1118                 if(this.target_validate_time < time)
1119                 if (turret_validate_target(this, this.enemy, this.target_validate_flags) <= 0)
1120                 {
1121                         this.enemy = NULL;
1122                         this.target_validate_time = time + 0.5;
1123                         do_target_scan = 1;
1124                 }
1125
1126                 // But never more often then g_turrets_targetscan_mindelay!
1127                 if (this.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1128                         do_target_scan = 0;
1129
1130                 if(do_target_scan)
1131                 {
1132                         this.enemy = turret_select_target(this);
1133                         this.target_select_time = time;
1134                 }
1135
1136                 // No target, just go to idle, do any custom stuff and bail.
1137                 if (this.enemy == NULL)
1138                 {
1139                         // Turn & pitch
1140                         if(!(this.track_flags & TFL_TRACK_NO))
1141                                 turret_track(this);
1142
1143                         Turret tur = get_turretinfo(this.m_id);
1144                         tur.tr_think(tur, this);
1145
1146                         // And bail.
1147                         return;
1148                 }
1149                 else
1150                         this.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1151
1152                 // Predict?
1153                 if(!(this.aim_flags & TFL_AIM_NO))
1154                         this.tur_aimpos = turret_aim_generic(this);
1155
1156                 // Turn & pitch?
1157                 if(!(this.track_flags & TFL_TRACK_NO))
1158                         turret_track(this);
1159
1160                 turret_do_updates(this);
1161
1162                 // Fire?
1163                 if (turret_checkfire(this))
1164                         turret_fire(this);
1165         }
1166
1167         Turret tur = get_turretinfo(this.m_id);
1168         tur.tr_think(tur, this);
1169 }
1170
1171 /*
1172         When .used a turret switch team to activator.team.
1173         If activator is NULL, the turret go inactive.
1174 */
1175 void turret_use(entity this, entity actor, entity trigger)
1176 {
1177         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname, "\n");
1178
1179         this.team = actor.team;
1180
1181         if(this.team == 0)
1182                 this.active = ACTIVE_NOT;
1183         else
1184                 this.active = ACTIVE_ACTIVE;
1185
1186 }
1187
1188 void turret_link(entity this)
1189 {
1190         Net_LinkEntity(this, true, 0, turret_send);
1191         setthink(this, turret_think);
1192         this.nextthink = time;
1193         this.tur_head.effects = EF_NODRAW;
1194 }
1195
1196 void turrets_manager_think(entity this)
1197 {
1198         this.nextthink = time + 1;
1199
1200         if (autocvar_g_turrets_reloadcvars == 1)
1201         {
1202                 FOREACH_ENTITY(IS_TURRET(it), {
1203                         load_unit_settings(it, true);
1204                         Turret tur = get_turretinfo(it.m_id);
1205                         tur.tr_think(tur, it);
1206                 });
1207                 cvar_set("g_turrets_reloadcvars", "0");
1208         }
1209 }
1210
1211 void turret_initparams(entity tur)
1212 {
1213         #define TRY(x) (x) ? (x)
1214         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1215         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1216         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1217         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1218         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1219         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1220         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1221         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1222         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1223         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), MAX_SHOT_DISTANCE);
1224         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), MAX_SHOT_DISTANCE);
1225         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), MAX_SHOT_DISTANCE);
1226         tur.aim_maxrotate               = bound(0,               (TRY(tur.aim_maxrotate)             :  90                                         ), 360);
1227         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1228         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1229         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), MAX_SHOT_DISTANCE);
1230         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1231         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1232         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1233         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1234         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1235         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1236         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1237         #undef TRY
1238 }
1239
1240 bool turret_initialize(entity this, Turret tur)
1241 {
1242         if(!autocvar_g_turrets)
1243                 return false;
1244
1245         if(tur.m_id == 0)
1246                 return false; // invalid turret
1247
1248         // if tur_head exists, we can assume this turret re-spawned
1249         if(!this.tur_head) {
1250                 tur.tr_precache(tur);
1251         }
1252
1253         entity e = find(NULL, classname, "turret_manager");
1254         if(!e)
1255         {
1256                 e = new(turret_manager);
1257                 setthink(e, turrets_manager_think);
1258                 e.nextthink = time + 2;
1259         }
1260
1261         if(!(this.spawnflags & TSF_SUSPENDED))
1262                 droptofloor(this);
1263
1264         this.netname = tur.netname;
1265         load_unit_settings(this, 0);
1266
1267         if(!this.team || !teamplay)             { this.team = MAX_SHOT_DISTANCE; }
1268         if(!this.ticrate)                               { this.ticrate = ((this.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1269         if(!this.health)                                { this.health = 1000; }
1270         if(!this.shot_refire)                   { this.shot_refire = 1; }
1271         if(!this.tur_shotorg)                   { this.tur_shotorg = '50 0 50'; }
1272         if(!this.turret_flags)                  { this.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1273         if(!this.damage_flags)                  { this.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1274         if(!this.aim_flags)                             { this.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1275         if(!this.track_type)                    { this.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1276         if(!this.track_flags)                   { this.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1277         if(!this.ammo_flags)                    { this.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1278         if(!this.target_select_flags)   { this.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1279         if(!this.firecheck_flags)               { this.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1280                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1281
1282         if(this.track_type != TFL_TRACKTYPE_STEPMOTOR)
1283         {
1284                 // Fluid / Ineria mode. Looks mutch nicer.
1285                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1286
1287                 this.aim_speed = bound(0.1, ((!this.aim_speed) ? 180 : this.aim_speed), 1000);
1288
1289                 if(!this.track_accel_pitch)             { this.track_accel_pitch = 0.5; }
1290                 if(!this.track_accel_rotate)    { this.track_accel_rotate = 0.5; }
1291                 if(!this.track_blendrate)               { this.track_blendrate = 0.35; }
1292         }
1293
1294         turret_initparams(this);
1295
1296         this.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1297
1298         if(this.turret_flags & TUR_FLAG_SPLASH)
1299                 this.aim_flags |= TFL_AIM_SPLASH;
1300
1301         if(this.turret_flags & TUR_FLAG_MISSILE)
1302                 this.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1303
1304         if(this.turret_flags & TUR_FLAG_PLAYER)
1305                 this.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1306
1307         if(this.spawnflags & TSL_NO_RESPAWN)
1308                 this.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1309
1310         if (this.turret_flags & TUR_FLAG_SUPPORT)
1311                 this.turret_score_target = turret_targetscore_support;
1312         else
1313                 this.turret_score_target = turret_targetscore_generic;
1314
1315         ++turret_count;
1316
1317         _setmodel(this, tur.model);
1318         setsize(this, tur.mins, tur.maxs);
1319
1320         this.m_id                                       = tur.m_id;
1321         this.classname                          = "turret_main";
1322         this.active                                     = ACTIVE_ACTIVE;
1323         this.effects                            = EF_NODRAW;
1324         this.netname                            = tur.turret_name;
1325         this.ticrate                            = bound(sys_frametime, this.ticrate, 60);
1326         this.max_health                         = this.health;
1327         this.target_validate_flags      = this.target_select_flags;
1328         this.ammo                                       = this.ammo_max;
1329         this.ammo_recharge                 *= this.ticrate;
1330         this.solid                                      = SOLID_BBOX;
1331         this.takedamage                         = DAMAGE_AIM;
1332         this.movetype                           = MOVETYPE_NOCLIP;
1333         this.view_ofs                           = '0 0 0';
1334         this.turret_firecheckfunc       = turret_firecheck;
1335         this.event_damage                       = turret_damage;
1336         this.use                                        = turret_use;
1337         this.bot_attack                         = true;
1338         this.nextthink                          = time + 1;
1339         this.nextthink                     += turret_count * sys_frametime;
1340
1341         this.tur_head = new(turret_head);
1342         _setmodel(this.tur_head, tur.head_model);
1343         setsize(this.tur_head, '0 0 0', '0 0 0');
1344         setorigin(this.tur_head, '0 0 0');
1345         setattachment(this.tur_head, this, "tag_head");
1346
1347         this.tur_head.netname           = this.tur_head.classname;
1348         this.tur_head.team                      = this.team;
1349         this.tur_head.owner                     = this;
1350         this.tur_head.takedamage        = DAMAGE_NO;
1351         this.tur_head.solid                     = SOLID_NOT;
1352         this.tur_head.movetype          = this.movetype;
1353
1354         if(!this.tur_defend)
1355         if(this.target != "")
1356         {
1357                 this.tur_defend = find(NULL, targetname, this.target);
1358                 if (this.tur_defend == NULL)
1359                 {
1360                         this.target = "";
1361                         LOG_TRACE("Turret has invalid defendpoint!\n");
1362                 }
1363         }
1364
1365         if (this.tur_defend)
1366                 this.idle_aim = this.tur_head.angles + angleofs(this.tur_head, this.tur_defend);
1367         else
1368                 this.idle_aim = '0 0 0';
1369
1370 #ifdef TURRET_DEBUG
1371         this.tur_debug_start = this.nextthink;
1372         while(vdist(this.tur_debug_rvec, <, 2))
1373                 this.tur_debug_rvec = randomvec() * 4;
1374
1375         this.tur_debug_rvec_x = fabs(this.tur_debug_rvec_x);
1376         this.tur_debug_rvec_y = fabs(this.tur_debug_rvec_y);
1377         this.tur_debug_rvec_z = fabs(this.tur_debug_rvec_z);
1378 #endif
1379
1380         turret_link(this);
1381         turret_respawn(this);
1382         turret_tag_fire_update(this);
1383
1384         tur.tr_setup(tur, this);
1385
1386         if(MUTATOR_CALLHOOK(TurretSpawn, this))
1387                 return false;
1388
1389         return true;
1390 }
1391 #endif