qcsrc/common/turrets/sv_turrets.qc

   1 #ifdef SVQC
   2 #include <server/autocvars.qh>
   3
   4 // Generic aiming
   5 vector turret_aim_generic()
   6 {SELFPARAM();
   7
   8         vector pre_pos, prep;
   9         float distance, impact_time = 0, i, mintime;
  10
  11         turret_tag_fire_update();
  12
  13         if(self.aim_flags & TFL_AIM_SIMPLE)
  14                 return real_origin(self.enemy);
  15
  16         mintime = max(self.attack_finished_single[0] - time,0) + sys_frametime;
  17
  18         // Baseline
  19         pre_pos = real_origin(self.enemy);
  20
  21         // Lead?
  22         if (self.aim_flags & TFL_AIM_LEAD)
  23         {
  24                 if (self.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  25                 {
  26                         prep = pre_pos;
  27
  28                         distance = vlen(prep - self.tur_shotorg);
  29                         impact_time = distance / self.shot_speed;
  30
  31                         prep = pre_pos + (self.enemy.velocity * (impact_time + mintime));
  32
  33                         if(self.aim_flags & TFL_AIM_ZPREDICT)
  34                         if(!IS_ONGROUND(self.enemy))
  35                         if(self.enemy.movetype == MOVETYPE_WALK || self.enemy.movetype == MOVETYPE_TOSS || self.enemy.movetype == MOVETYPE_BOUNCE)
  36                         {
  37                                 float vz;
  38                                 prep_z = pre_pos_z;
  39                                 vz = self.enemy.velocity_z;
  40                                 for(i = 0; i < impact_time; i += sys_frametime)
  41                                 {
  42                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  43                                         prep_z = prep_z + vz * sys_frametime;
  44                                 }
  45                         }
  46                         pre_pos = prep;
  47                 }
  48                 else
  49                         pre_pos = pre_pos + self.enemy.velocity * mintime;
  50         }
  51
  52         if(self.aim_flags & TFL_AIM_SPLASH)
  53         {
  54                 //tracebox(pre_pos + '0 0 32',self.enemy.mins,self.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,self.enemy);
  55                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,self.enemy);
  56                 if(trace_fraction != 1.0)
  57                         pre_pos = trace_endpos;
  58         }
  59
  60         return pre_pos;
  61 }
  62
  63 float turret_targetscore_support(entity _turret,entity _target)
  64 {
  65         float score;            // Total score
  66         float s_score = 0, d_score;
  67
  68         if (_turret.enemy == _target) s_score = 1;
  69
  70         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  71
  72         score = (d_score * _turret.target_select_rangebias) +
  73                         (s_score * _turret.target_select_samebias);
  74
  75         return score;
  76 }
  77
  78 /*
  79 * Generic bias aware score system.
  80 */
  81 float turret_targetscore_generic(entity _turret, entity _target)
  82 {
  83         float d_dist;      // Defendmode Distance
  84         float score;            // Total score
  85         float d_score;    // Distance score
  86         float a_score;    // Angular score
  87         float m_score = 0;  // missile score
  88         float p_score = 0;  // player score
  89         float ikr;                // ideal kill range
  90
  91         if (_turret.tur_defend)
  92         {
  93                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
  94                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
  95                 d_score = 1 - d_dist / _turret.target_range;
  96         }
  97         else
  98         {
  99                 // Make a normlized value base on the targets distance from our optimal killzone
 100                 ikr = _turret.target_range_optimal;
 101                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 102         }
 103
 104         a_score = 1 - tvt_thadf / _turret.aim_maxrotate;
 105
 106         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 107                 m_score = 1;
 108
 109         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 110                 p_score = 1;
 111
 112         d_score = max(d_score, 0);
 113         a_score = max(a_score, 0);
 114         m_score = max(m_score, 0);
 115         p_score = max(p_score, 0);
 116
 117         score = (d_score * _turret.target_select_rangebias) +
 118                         (a_score * _turret.target_select_anglebias) +
 119                         (m_score * _turret.target_select_missilebias) +
 120                         (p_score * _turret.target_select_playerbias);
 121
 122         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 123         {
 124                 //dprint("Wtf?\n");
 125                 score *= 0.001;
 126         }
 127
 128 #ifdef TURRET_DEBUG
 129         string sd,sa,sm,sp,ss;
 130         string sdt,sat,smt,spt;
 131
 132         sd = ftos(d_score);
 133         d_score *= _turret.target_select_rangebias;
 134         sdt = ftos(d_score);
 135
 136         //sv = ftos(v_score);
 137         //v_score *= _turret.target_select_samebias;
 138         //svt = ftos(v_score);
 139
 140         sa = ftos(a_score);
 141         a_score *= _turret.target_select_anglebias;
 142         sat = ftos(a_score);
 143
 144         sm = ftos(m_score);
 145         m_score *= _turret.target_select_missilebias;
 146         smt = ftos(m_score);
 147
 148         sp = ftos(p_score);
 149         p_score *= _turret.target_select_playerbias;
 150         spt = ftos(p_score);
 151
 152
 153         ss = ftos(score);
 154         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 155         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 156         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 157         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 158         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 159         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 160
 161 #endif
 162
 163         return score;
 164 }
 165
 166 // Generic damage handling
 167 void turret_hide(entity this)
 168 {
 169         self.effects   |= EF_NODRAW;
 170         self.nextthink = time + self.respawntime - 0.2;
 171         setthink(self, turret_respawn);
 172 }
 173
 174 void turret_die(entity this)
 175 {
 176         self.deadflag             = DEAD_DEAD;
 177         self.tur_head.deadflag = self.deadflag;
 178
 179 // Unsolidify and hide real parts
 180         self.solid                       = SOLID_NOT;
 181         self.tur_head.solid      = self.solid;
 182
 183         self.event_damage                 = func_null;
 184         self.takedamage                  = DAMAGE_NO;
 185
 186         self.health                      = 0;
 187
 188 // Go boom
 189         //RadiusDamage (self,self, min(self.ammo,50),min(self.ammo,50) * 0.25,250,world,min(self.ammo,50)*5,DEATH_TURRET,world);
 190
 191         Turret tur = get_turretinfo(self.m_id);
 192         if(self.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 193         {
 194                 tur.tr_death(tur, self);
 195
 196                 remove(self.tur_head);
 197                 remove(self);
 198         }
 199         else
 200         {
 201                 // Setup respawn
 202                 self.SendFlags    |= TNSF_STATUS;
 203                 self.nextthink   = time + 0.2;
 204                 setthink(self, turret_hide);
 205
 206                 tur.tr_death(tur, self);
 207         }
 208 }
 209
 210 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 211 {
 212         // Enough already!
 213         if(this.deadflag == DEAD_DEAD)
 214                 return;
 215
 216         // Inactive turrets take no damage. (hm..)
 217         if(!this.active)
 218                 return;
 219
 220         if(SAME_TEAM(this, attacker))
 221         {
 222                 if(autocvar_g_friendlyfire)
 223                         damage = damage * autocvar_g_friendlyfire;
 224                 else
 225                         return;
 226         }
 227
 228         this.health -= damage;
 229
 230         // thorw head slightly off aim when hit?
 231         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 232         {
 233                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 234                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 235
 236                 this.SendFlags  |= TNSF_ANG;
 237         }
 238
 239         if (this.turret_flags & TUR_FLAG_MOVE)
 240                 this.velocity = this.velocity + vforce;
 241
 242         if (this.health <= 0)
 243         {
 244                 this.event_damage                 = func_null;
 245                 this.tur_head.event_damage = func_null;
 246                 this.takedamage                  = DAMAGE_NO;
 247                 this.nextthink = time;
 248                 setthink(this, turret_die);
 249         }
 250
 251         this.SendFlags  |= TNSF_STATUS;
 252 }
 253
 254 void turret_think(entity this);
 255 void turret_respawn(entity this)
 256 {
 257         // Make sure all parts belong to the same team since
 258         // this function doubles as "teamchange" function.
 259         self.tur_head.team      = self.team;
 260         self.effects                       &= ~EF_NODRAW;
 261         self.deadflag                           = DEAD_NO;
 262         self.effects                            = EF_LOWPRECISION;
 263         self.solid                                      = SOLID_BBOX;
 264         self.takedamage                         = DAMAGE_AIM;
 265         self.event_damage                       = turret_damage;
 266         self.avelocity                          = '0 0 0';
 267         self.tur_head.avelocity         = self.avelocity;
 268         self.tur_head.angles            = self.idle_aim;
 269         self.health                                     = self.max_health;
 270         self.enemy                                      = world;
 271         self.volly_counter                      = self.shot_volly;
 272         self.ammo                                       = self.ammo_max;
 273
 274         self.nextthink = time + self.ticrate;
 275         setthink(self, turret_think);
 276
 277         self.SendFlags = TNSF_FULL_UPDATE;
 278
 279         Turret tur = get_turretinfo(self.m_id);
 280         tur.tr_setup(tur, self);
 281 }
 282
 283
 284 // Main functions
 285 #define cvar_base "g_turrets_unit_"
 286 .float clientframe;
 287 void turrets_setframe(float _frame, float client_only)
 288 {SELFPARAM();
 289         if((client_only ? self.clientframe : self.frame ) != _frame)
 290         {
 291                 self.SendFlags |= TNSF_ANIM;
 292                 self.anim_start_time = time;
 293         }
 294
 295          if(client_only)
 296                 self.clientframe = _frame;
 297         else
 298                 self.frame = _frame;
 299
 300 }
 301
 302 bool turret_send(entity this, entity to, float sf)
 303 {
 304
 305         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 306         WriteByte(MSG_ENTITY, sf);
 307         if(sf & TNSF_SETUP)
 308         {
 309                 WriteByte(MSG_ENTITY, self.m_id);
 310
 311                 WriteCoord(MSG_ENTITY, self.origin_x);
 312                 WriteCoord(MSG_ENTITY, self.origin_y);
 313                 WriteCoord(MSG_ENTITY, self.origin_z);
 314
 315                 WriteAngle(MSG_ENTITY, self.angles_x);
 316                 WriteAngle(MSG_ENTITY, self.angles_y);
 317         }
 318
 319         if(sf & TNSF_ANG)
 320         {
 321                 WriteShort(MSG_ENTITY, rint(self.tur_head.angles_x));
 322                 WriteShort(MSG_ENTITY, rint(self.tur_head.angles_y));
 323         }
 324
 325         if(sf & TNSF_AVEL)
 326         {
 327                 WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_x));
 328                 WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_y));
 329         }
 330
 331         if(sf & TNSF_MOVE)
 332         {
 333                 WriteShort(MSG_ENTITY, rint(self.origin_x));
 334                 WriteShort(MSG_ENTITY, rint(self.origin_y));
 335                 WriteShort(MSG_ENTITY, rint(self.origin_z));
 336
 337                 WriteShort(MSG_ENTITY, rint(self.velocity_x));
 338                 WriteShort(MSG_ENTITY, rint(self.velocity_y));
 339                 WriteShort(MSG_ENTITY, rint(self.velocity_z));
 340
 341                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 342         }
 343
 344         if(sf & TNSF_ANIM)
 345         {
 346                 WriteCoord(MSG_ENTITY, self.anim_start_time);
 347                 WriteByte(MSG_ENTITY, self.frame);
 348         }
 349
 350         if(sf & TNSF_STATUS)
 351         {
 352                 WriteByte(MSG_ENTITY, self.team);
 353
 354                 if(self.health <= 0)
 355                         WriteByte(MSG_ENTITY, 0);
 356                 else
 357                         WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 358         }
 359
 360         return true;
 361 }
 362
 363 void load_unit_settings(entity ent, bool is_reload)
 364 {SELFPARAM();
 365         string unitname = ent.netname;
 366         string sbase;
 367
 368         if (ent == world)
 369                 return;
 370
 371         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 372         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 373         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 374         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 375         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 376         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 377         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 378
 379         sbase = strcat(cvar_base,unitname);
 380         if (is_reload)
 381         {
 382                 ent.enemy = world;
 383                 ent.tur_head.avelocity = '0 0 0';
 384
 385                 ent.tur_head.angles = '0 0 0';
 386         }
 387
 388         ent.health       = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
 389         ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
 390
 391         ent.shot_dmg             = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
 392         ent.shot_refire   = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
 393         ent.shot_radius   = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
 394         ent.shot_speed          = cvar(strcat(sbase,"_shot_speed"));
 395         ent.shot_spread   = cvar(strcat(sbase,"_shot_spread"));
 396         ent.shot_force          = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
 397         ent.shot_volly          = cvar(strcat(sbase,"_shot_volly"));
 398         ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
 399
 400         ent.target_range                 = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
 401         ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
 402         ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
 403         //ent.target_range_fire = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
 404
 405         ent.target_select_rangebias = cvar(strcat(sbase,"_target_select_rangebias"));
 406         ent.target_select_samebias  = cvar(strcat(sbase,"_target_select_samebias"));
 407         ent.target_select_anglebias = cvar(strcat(sbase,"_target_select_anglebias"));
 408         ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
 409         //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
 410
 411         ent.ammo_max     = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
 412         ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
 413
 414         ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
 415         ent.aim_speed   = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
 416         ent.aim_maxrotate  = cvar(strcat(sbase,"_aim_maxrot"));
 417         ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
 418
 419         ent.track_type          = cvar(strcat(sbase,"_track_type"));
 420         ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
 421         ent.track_accel_rotate  = cvar(strcat(sbase,"_track_accel_rot"));
 422         ent.track_blendrate  = cvar(strcat(sbase,"_track_blendrate"));
 423
 424         if(is_reload) {
 425                 Turret tur = get_turretinfo(self.m_id);
 426                 tur.tr_setup(tur, self);
 427         }
 428 }
 429
 430 void turret_projectile_explode(entity this)
 431 {
 432
 433         self.takedamage = DAMAGE_NO;
 434         self.event_damage = func_null;
 435 #ifdef TURRET_DEBUG
 436         float d;
 437         d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
 438         self.owner.tur_debug_dmg_t_h = self.owner.tur_debug_dmg_t_h + d;
 439         self.owner.tur_debug_dmg_t_f = self.owner.tur_debug_dmg_t_f + self.owner.shot_dmg;
 440 #else
 441         RadiusDamage (self, self.realowner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
 442 #endif
 443         remove(self);
 444 }
 445
 446 void turret_projectile_touch(entity this)
 447 {
 448         PROJECTILE_TOUCH(this);
 449         turret_projectile_explode(this);
 450 }
 451
 452 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 453 {
 454         this.velocity  += vforce;
 455         this.health     -= damage;
 456         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 457         if(this.health <= 0)
 458                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
 459 }
 460
 461 entity turret_projectile(Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 462 {SELFPARAM();
 463     TC(Sound, _snd);
 464         entity proj;
 465
 466         sound (self, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 467         proj                             = spawn ();
 468         setorigin(proj, self.tur_shotorg);
 469         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 470         proj.owner                = self;
 471         proj.realowner    = self;
 472         proj.bot_dodge    = true;
 473         proj.bot_dodgerating = self.shot_dmg;
 474         setthink(proj, turret_projectile_explode);
 475         settouch(proj, turret_projectile_touch);
 476         proj.nextthink    = time + 9;
 477         proj.movetype           = MOVETYPE_FLYMISSILE;
 478         proj.velocity           = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
 479         proj.flags                = FL_PROJECTILE;
 480         proj.enemy                = self.enemy;
 481         proj.totalfrags  = _death;
 482         PROJECTILE_MAKETRIGGER(proj);
 483         if(_health)
 484         {
 485                 proj.health              = _health;
 486                 proj.takedamage  = DAMAGE_YES;
 487                 proj.event_damage  = turret_projectile_damage;
 488         }
 489         else
 490                 proj.flags |= FL_NOTARGET;
 491
 492         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 493
 494         return proj;
 495 }
 496
 497 /**
 498 ** updates enemy distances, predicted impact point/time
 499 ** and updated aim<->predict impact distance.
 500 **/
 501 void turret_do_updates(entity t_turret)
 502 {
 503         vector enemy_pos = real_origin(t_turret.enemy);
 504
 505         WITHSELF(t_turret, turret_tag_fire_update());
 506
 507         t_turret.tur_shotdir_updated = v_forward;
 508         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
 509         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
 510
 511         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
 512         {
 513                 oldpos = t_turret.enemy.origin;
 514                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
 515                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 516                 setorigin(t_turret.enemy, oldpos);
 517
 518                 if(trace_ent == t_turret.enemy)
 519                         t_turret.tur_dist_impact_to_aimpos = 0;
 520                 else
 521                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
 522         }
 523         else*/
 524                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 525
 526         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
 527         t_turret.tur_impactent                   = trace_ent;
 528         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
 529 }
 530
 531 /**
 532 ** Handles head rotation according to
 533 ** the units .track_type and .track_flags
 534 **/
 535 .float turret_framecounter;
 536 void turret_track()
 537 {SELFPARAM();
 538         vector target_angle; // This is where we want to aim
 539         vector move_angle;   // This is where we can aim
 540         float f_tmp;
 541         vector v1, v2;
 542         v1 = self.tur_head.angles;
 543         v2 = self.tur_head.avelocity;
 544
 545         if (self.track_flags == TFL_TRACK_NO)
 546                 return;
 547
 548         if(!self.active)
 549                 target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
 550         else if (self.enemy == world)
 551         {
 552                 if(time > self.lip)
 553                         target_angle = self.idle_aim + self.angles;
 554                 else
 555                         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 556         }
 557         else
 558         {
 559                 target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 560         }
 561
 562         self.tur_head.angles_x = anglemods(self.tur_head.angles_x);
 563         self.tur_head.angles_y = anglemods(self.tur_head.angles_y);
 564
 565         // Find the diffrence between where we currently aim and where we want to aim
 566         //move_angle = target_angle - (self.angles + self.tur_head.angles);
 567         //move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
 568
 569         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(self.angles), AnglesTransform_FromAngles(target_angle))) - self.tur_head.angles;
 570         move_angle = shortangle_vxy(move_angle, self.tur_head.angles);
 571
 572         switch(self.track_type)
 573         {
 574                 case TFL_TRACKTYPE_STEPMOTOR:
 575                         f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 576                         if (self.track_flags & TFL_TRACK_PITCH)
 577                         {
 578                                 self.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 579                                 if(self.tur_head.angles_x > self.aim_maxpitch)
 580                                         self.tur_head.angles_x = self.aim_maxpitch;
 581
 582                                 if(self.tur_head.angles_x  < -self.aim_maxpitch)
 583                                         self.tur_head.angles_x = self.aim_maxpitch;
 584                         }
 585
 586                         if (self.track_flags & TFL_TRACK_ROTATE)
 587                         {
 588                                 self.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 589                                 if(self.tur_head.angles_y > self.aim_maxrotate)
 590                                         self.tur_head.angles_y = self.aim_maxrotate;
 591
 592                                 if(self.tur_head.angles_y  < -self.aim_maxrotate)
 593                                         self.tur_head.angles_y = self.aim_maxrotate;
 594                         }
 595
 596                         // CSQC
 597                         self.SendFlags  |= TNSF_ANG;
 598
 599                         return;
 600
 601                 case TFL_TRACKTYPE_FLUIDINERTIA:
 602                         f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 603                         move_angle_x = bound(-self.aim_speed, move_angle_x * self.track_accel_pitch * f_tmp, self.aim_speed);
 604                         move_angle_y = bound(-self.aim_speed, move_angle_y * self.track_accel_rotate * f_tmp, self.aim_speed);
 605                         move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
 606                         break;
 607
 608                 case TFL_TRACKTYPE_FLUIDPRECISE:
 609
 610                         move_angle_y = bound(-self.aim_speed, move_angle_y, self.aim_speed);
 611                         move_angle_x = bound(-self.aim_speed, move_angle_x, self.aim_speed);
 612
 613                         break;
 614         }
 615
 616         //  pitch
 617         if (self.track_flags & TFL_TRACK_PITCH)
 618         {
 619                 self.tur_head.avelocity_x = move_angle_x;
 620                 if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) > self.aim_maxpitch)
 621                 {
 622                         self.tur_head.avelocity_x = 0;
 623                         self.tur_head.angles_x = self.aim_maxpitch;
 624
 625                         self.SendFlags  |= TNSF_ANG;
 626                 }
 627
 628                 if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) < -self.aim_maxpitch)
 629                 {
 630                         self.tur_head.avelocity_x = 0;
 631                         self.tur_head.angles_x = -self.aim_maxpitch;
 632
 633                         self.SendFlags  |= TNSF_ANG;
 634                 }
 635         }
 636
 637         //  rot
 638         if (self.track_flags & TFL_TRACK_ROTATE)
 639         {
 640                 self.tur_head.avelocity_y = move_angle_y;
 641
 642                 if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) > self.aim_maxrotate)
 643                 {
 644                         self.tur_head.avelocity_y = 0;
 645                         self.tur_head.angles_y = self.aim_maxrotate;
 646
 647                         self.SendFlags  |= TNSF_ANG;
 648                 }
 649
 650                 if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) < -self.aim_maxrotate)
 651                 {
 652                         self.tur_head.avelocity_y = 0;
 653                         self.tur_head.angles_y = -self.aim_maxrotate;
 654
 655                         self.SendFlags  |= TNSF_ANG;
 656                 }
 657         }
 658
 659         self.SendFlags  |= TNSF_AVEL;
 660
 661         // Force a angle update every 10'th frame
 662         self.turret_framecounter += 1;
 663         if(self.turret_framecounter >= 10)
 664         {
 665                 self.SendFlags |= TNSF_ANG;
 666                 self.turret_framecounter = 0;
 667         }
 668 }
 669
 670 /*
 671  + TFL_TARGETSELECT_NO
 672  + TFL_TARGETSELECT_LOS
 673  + TFL_TARGETSELECT_PLAYERS
 674  + TFL_TARGETSELECT_MISSILES
 675  - TFL_TARGETSELECT_TRIGGERTARGET
 676  + TFL_TARGETSELECT_ANGLELIMITS
 677  + TFL_TARGETSELECT_RANGELIMITS
 678  + TFL_TARGETSELECT_TEAMCHECK
 679  - TFL_TARGETSELECT_NOBUILTIN
 680  + TFL_TARGETSELECT_OWNTEAM
 681 */
 682
 683 /**
 684 ** Evaluate a entity for target valitity based on validate_flags
 685 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 686 **/
 687 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 688 {
 689         vector v_tmp;
 690
 691         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 692         //      return -0.5;
 693
 694         if(!e_target)
 695                 return -2;
 696
 697         if(e_target.owner == e_turret)
 698                 return -0.5;
 699
 700         if(!checkpvs(e_target.origin, e_turret))
 701                 return -1;
 702
 703         if(e_target.alpha <= 0.3)
 704                 return -1;
 705
 706         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 707                 return ret_float;
 708
 709         if (validate_flags & TFL_TARGETSELECT_NO)
 710                 return -4;
 711
 712         // If only this was used more..
 713         if (e_target.flags & FL_NOTARGET)
 714                 return -5;
 715
 716         // Cant touch this
 717         if(IS_VEHICLE(e_target))
 718         {
 719                 if (e_target.vehicle_health <= 0)
 720                         return -6;
 721         }
 722         else if (e_target.health <= 0)
 723                 return -6;
 724         else if(STAT(FROZEN, e_target) > 0)
 725                 return -6;
 726
 727         // player
 728         if (IS_CLIENT(e_target))
 729         {
 730                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 731                         return -7;
 732
 733                 if (IS_DEAD(e_target))
 734                         return -8;
 735         }
 736
 737         // enemy turrets
 738         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 739         if(e_target.owner.tur_head == e_target)
 740         if(e_target.team != e_turret.team) // Dont break support units.
 741                 return -9;
 742
 743         // Missile
 744         if (e_target.flags & FL_PROJECTILE)
 745         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 746                 return -10;
 747
 748         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 749         if(!(e_target.flags & FL_PROJECTILE))
 750                 return -10.5;
 751
 752         // Team check
 753         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 754         {
 755                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 756                 {
 757                         if (e_target.team != e_turret.team)
 758                                 return -11;
 759
 760                         if (e_turret.team != e_target.owner.team)
 761                                 return -12;
 762                 }
 763                 else
 764                 {
 765                         if (e_target.team == e_turret.team)
 766                                 return -13;
 767
 768                         if (e_turret.team == e_target.owner.team)
 769                                 return -14;
 770                 }
 771         }
 772
 773         // Range limits?
 774         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 775         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 776         {
 777                 if (tvt_dist < e_turret.target_range_min)
 778                         return -15;
 779
 780                 if (tvt_dist > e_turret.target_range)
 781                         return -16;
 782         }
 783
 784         // Can we even aim this thing?
 785         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 786         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 787         tvt_thadf = vlen(tvt_thadv);
 788         tvt_tadf = vlen(tvt_tadv);
 789
 790         /*
 791         if(validate_flags & TFL_TARGETSELECT_FOV)
 792         {
 793                 if(e_turret.target_select_fov < tvt_thadf)
 794                         return -21;
 795         }
 796         */
 797
 798         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 799         {
 800                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 801                         return -17;
 802
 803                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrotate)
 804                         return -18;
 805         }
 806
 807         // Line of sight?
 808         if (validate_flags & TFL_TARGETSELECT_LOS)
 809         {
 810                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 811
 812                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 813
 814                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 815                         return -19;
 816         }
 817
 818         if (e_target.classname == "grapplinghook")
 819                 return -20;
 820
 821         /*
 822         if (e_target.classname == "func_button")
 823                 return -21;
 824         */
 825
 826 #ifdef TURRET_DEBUG_TARGETSELECT
 827         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
 828 #endif
 829
 830         return 1;
 831 }
 832
 833 entity turret_select_target()
 834 {SELFPARAM();
 835         entity e;               // target looper entity
 836         float  score;   // target looper entity score
 837         entity e_enemy;  // currently best scoreing target
 838         float  m_score;  // currently best scoreing target's score
 839
 840         m_score = 0;
 841         if(self.enemy && self.enemy.takedamage && turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
 842         {
 843                 e_enemy = self.enemy;
 844                 m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
 845         }
 846         else
 847                 e_enemy = self.enemy = world;
 848
 849         e = findradius(self.origin, self.target_range);
 850
 851         // Nothing to aim at?
 852         if (!e)
 853                 return world;
 854
 855         while (e)
 856         {
 857                 if(e.takedamage)
 858                 {
 859                         float f = turret_validate_target(self, e, self.target_select_flags);
 860                         //dprint("F is: ", ftos(f), "\n");
 861                         if ( f > 0)
 862                         {
 863                                 score = self.turret_score_target(self,e);
 864                                 if ((score > m_score) && (score > 0))
 865                                 {
 866                                         e_enemy = e;
 867                                         m_score = score;
 868                                 }
 869                         }
 870                 }
 871                 e = e.chain;
 872         }
 873
 874         return e_enemy;
 875 }
 876
 877
 878 /*
 879  + = implemented
 880  - = not implemented
 881
 882  + TFL_FIRECHECK_NO
 883  + TFL_FIRECHECK_WORLD
 884  + TFL_FIRECHECK_DEAD
 885  + TFL_FIRECHECK_DISTANCES
 886  - TFL_FIRECHECK_LOS
 887  + TFL_FIRECHECK_AIMDIST
 888  + TFL_FIRECHECK_REALDIST
 889  - TFL_FIRECHECK_ANGLEDIST
 890  - TFL_FIRECHECK_TEAMCECK
 891  + TFL_FIRECHECK_AFF
 892  + TFL_FIRECHECK_AMMO_OWN
 893  + TFL_FIRECHECK_AMMO_OTHER
 894  + TFL_FIRECHECK_REFIRE
 895 */
 896
 897 /**
 898 ** Preforms pre-fire checks based on the uints firecheck_flags
 899 **/
 900 float turret_firecheck()
 901 {SELFPARAM();
 902         // This one just dont care =)
 903         if (self.firecheck_flags & TFL_FIRECHECK_NO)
 904                 return 1;
 905
 906         if (self.enemy == world)
 907                 return 0;
 908
 909         // Ready?
 910         if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
 911                 if (self.attack_finished_single[0] > time) return 0;
 912
 913         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 914         if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 915                 if (self.volly_counter != self.shot_volly)
 916                         if(self.ammo >= self.shot_dmg)
 917                                 return 1;
 918
 919         // Lack of zombies makes shooting dead things unnecessary :P
 920         if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
 921                 if (IS_DEAD(self.enemy))
 922                         return 0;
 923
 924         // Own ammo?
 925         if (self.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 926                 if (self.ammo < self.shot_dmg)
 927                         return 0;
 928
 929         // Other's ammo? (support-supply units)
 930         if (self.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 931                 if (self.enemy.ammo >= self.enemy.ammo_max)
 932                         return 0;
 933
 934         // Target of opertunity?
 935         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 936         {
 937                 self.enemy = self.tur_impactent;
 938                 return 1;
 939         }
 940
 941         if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 942         {
 943                 // To close?
 944                 if (self.tur_dist_aimpos < self.target_range_min)
 945                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 946                                 return 1; // Target of opertunity?
 947                         else
 948                                 return 0;
 949         }
 950
 951         // Try to avoid FF?
 952         if (self.firecheck_flags & TFL_FIRECHECK_AFF)
 953                 if (self.tur_impactent.team == self.team)
 954                         return 0;
 955
 956         // aim<->predicted impact
 957         if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 958                 if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
 959                         return 0;
 960
 961         // Volly status
 962         if (self.shot_volly > 1)
 963                 if (self.volly_counter == self.shot_volly)
 964                         if (self.ammo < (self.shot_dmg * self.shot_volly))
 965                                 return 0;
 966
 967         /*if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 968                 if(self.tur_impactent != self.enemy)
 969                         return 0;*/
 970
 971         return 1;
 972 }
 973
 974 bool turret_checkfire()
 975 {SELFPARAM();
 976         bool ret = false; // dummy
 977         if(MUTATOR_CALLHOOK(Turret_CheckFire, ret))
 978                 return ret_bool;
 979
 980         return self.turret_firecheckfunc();
 981 }
 982
 983 void turret_fire()
 984 {SELFPARAM();
 985         if (autocvar_g_turrets_nofire != 0)
 986                 return;
 987
 988         if(MUTATOR_CALLHOOK(TurretFire, self))
 989                 return;
 990
 991         Turret info = get_turretinfo(self.m_id);
 992         info.tr_attack(info, self);
 993
 994         self.attack_finished_single[0] = time + self.shot_refire;
 995         self.ammo -= self.shot_dmg;
 996         self.volly_counter = self.volly_counter - 1;
 997
 998         if (self.volly_counter <= 0)
 999         {
1000                 self.volly_counter = self.shot_volly;
1001
1002                 if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
1003                         self.enemy = world;
1004
1005                 if (self.shot_volly > 1)
1006                         self.attack_finished_single[0] = time + self.shot_volly_refire;
1007         }
1008
1009 #ifdef TURRET_DEBUG
1010         if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_debug_rvec, self.tur_impacttime + 0.25);
1011 #endif
1012 }
1013
1014 void turret_think(entity this)
1015 {
1016         self.nextthink = time + self.ticrate;
1017
1018         MUTATOR_CALLHOOK(TurretThink, self);
1019
1020 #ifdef TURRET_DEBUG
1021         if (self.tur_debug_tmr1 < time)
1022         {
1023                 if (self.enemy) paint_target (self.enemy,128,self.tur_debug_rvec,0.9);
1024                 paint_target(self,256,self.tur_debug_rvec,0.9);
1025                 self.tur_debug_tmr1 = time + 1;
1026         }
1027 #endif
1028
1029         // Handle ammo
1030         if (!(self.spawnflags & TSF_NO_AMMO_REGEN))
1031         if (self.ammo < self.ammo_max)
1032                 self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
1033
1034         // Inactive turrets needs to run the think loop,
1035         // So they can handle animation and wake up if need be.
1036         if(!self.active)
1037         {
1038                 turret_track();
1039                 return;
1040         }
1041
1042         // This is typicaly used for zaping every target in range
1043         // turret_fusionreactor uses this to recharge friendlys.
1044         if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
1045         {
1046                 // Do a self.turret_fire for every valid target.
1047                 entity e = findradius(self.origin,self.target_range);
1048                 while (e)
1049                 {
1050                         if(e.takedamage)
1051                         {
1052                                 if (turret_validate_target(self,e,self.target_validate_flags))
1053                                 {
1054                                         self.enemy = e;
1055
1056                                         turret_do_updates(self);
1057
1058                                         if (turret_checkfire())
1059                                                 turret_fire();
1060                                 }
1061                         }
1062
1063                         e = e.chain;
1064                 }
1065                 self.enemy = world;
1066         }
1067         else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
1068         {
1069                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1070
1071                 // Predict?
1072                 if(!(self.aim_flags & TFL_AIM_NO))
1073                         self.tur_aimpos = turret_aim_generic();
1074
1075                 // Turn & pitch?
1076                 if(!(self.track_flags & TFL_TRACK_NO))
1077                         turret_track();
1078
1079                 turret_do_updates(self);
1080
1081                 // Fire?
1082                 if (turret_checkfire())
1083                         turret_fire();
1084         }
1085         else
1086         {
1087                 // Special case for volly always. if it fired once it must compleate the volly.
1088                 if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1089                         if(self.volly_counter != self.shot_volly)
1090                         {
1091                                 // Predict or whatnot
1092                                 if(!(self.aim_flags & TFL_AIM_NO))
1093                                         self.tur_aimpos = turret_aim_generic();
1094
1095                                 // Turn & pitch
1096                                 if(!(self.track_flags & TFL_TRACK_NO))
1097                                         turret_track();
1098
1099                                 turret_do_updates(self);
1100
1101                                 // Fire!
1102                                 if (turret_checkfire())
1103                                         turret_fire();
1104
1105                                 Turret tur = get_turretinfo(self.m_id);
1106                                 tur.tr_think(tur, self);
1107
1108                                 return;
1109                         }
1110
1111                 // Check if we have a vailid enemy, and try to find one if we dont.
1112
1113                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1114                 float do_target_scan = 0;
1115                 if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1116                         do_target_scan = 1;
1117
1118                 // Old target (if any) invalid?
1119                 if(self.target_validate_time < time)
1120                 if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
1121                 {
1122                         self.enemy = world;
1123                         self.target_validate_time = time + 0.5;
1124                         do_target_scan = 1;
1125                 }
1126
1127                 // But never more often then g_turrets_targetscan_mindelay!
1128                 if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1129                         do_target_scan = 0;
1130
1131                 if(do_target_scan)
1132                 {
1133                         self.enemy = turret_select_target();
1134                         self.target_select_time = time;
1135                 }
1136
1137                 // No target, just go to idle, do any custom stuff and bail.
1138                 if (self.enemy == world)
1139                 {
1140                         // Turn & pitch
1141                         if(!(self.track_flags & TFL_TRACK_NO))
1142                                 turret_track();
1143
1144                         Turret tur = get_turretinfo(self.m_id);
1145                         tur.tr_think(tur, self);
1146
1147                         // And bail.
1148                         return;
1149                 }
1150                 else
1151                         self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1152
1153                 // Predict?
1154                 if(!(self.aim_flags & TFL_AIM_NO))
1155                         self.tur_aimpos = turret_aim_generic();
1156
1157                 // Turn & pitch?
1158                 if(!(self.track_flags & TFL_TRACK_NO))
1159                         turret_track();
1160
1161                 turret_do_updates(self);
1162
1163                 // Fire?
1164                 if (turret_checkfire())
1165                         turret_fire();
1166         }
1167
1168         Turret tur = get_turretinfo(self.m_id);
1169         tur.tr_think(tur, self);
1170 }
1171
1172 /*
1173         When .used a turret switch team to activator.team.
1174         If activator is world, the turret go inactive.
1175 */
1176 void turret_use(entity this, entity actor, entity trigger)
1177 {
1178         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname, "\n");
1179
1180         this.team = actor.team;
1181
1182         if(this.team == 0)
1183                 this.active = ACTIVE_NOT;
1184         else
1185                 this.active = ACTIVE_ACTIVE;
1186
1187 }
1188
1189 void turret_link()
1190 {SELFPARAM();
1191         Net_LinkEntity(self, true, 0, turret_send);
1192         setthink(self, turret_think);
1193         self.nextthink = time;
1194         self.tur_head.effects = EF_NODRAW;
1195 }
1196
1197 void turrets_manager_think(entity this)
1198 {
1199         this.nextthink = time + 1;
1200
1201         if (autocvar_g_turrets_reloadcvars == 1)
1202         {
1203                 FOREACH_ENTITY(IS_TURRET(it), {
1204                         load_unit_settings(it, true);
1205                         Turret tur = get_turretinfo(it.m_id);
1206                         tur.tr_think(tur, it);
1207                 });
1208                 cvar_set("g_turrets_reloadcvars", "0");
1209         }
1210 }
1211
1212 void turret_initparams(entity tur)
1213 {
1214         #define TRY(x) (x) ? (x)
1215         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1216         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1217         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1218         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1219         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1220         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1221         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1222         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1223         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1224         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), MAX_SHOT_DISTANCE);
1225         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), MAX_SHOT_DISTANCE);
1226         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), MAX_SHOT_DISTANCE);
1227         tur.aim_maxrotate               = bound(0,               (TRY(tur.aim_maxrotate)             :  90                                         ), 360);
1228         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1229         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1230         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), MAX_SHOT_DISTANCE);
1231         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1232         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1233         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1234         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1235         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1236         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1237         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1238         #undef TRY
1239 }
1240
1241 float turret_initialize(Turret tur)
1242 {SELFPARAM();
1243         if(!autocvar_g_turrets)
1244                 return false;
1245
1246         if(tur.m_id == 0)
1247                 return false; // invalid turret
1248
1249         // if tur_head exists, we can assume this turret re-spawned
1250         if(!self.tur_head) {
1251                 tur.tr_precache(tur);
1252         }
1253
1254         entity e = find(world, classname, "turret_manager");
1255         if(!e)
1256         {
1257                 e = new(turret_manager);
1258                 setthink(e, turrets_manager_think);
1259                 e.nextthink = time + 2;
1260         }
1261
1262         if(!(self.spawnflags & TSF_SUSPENDED))
1263                 builtin_droptofloor();
1264
1265         self.netname = tur.netname;
1266         load_unit_settings(self, 0);
1267
1268         if(!self.team || !teamplay)             { self.team = MAX_SHOT_DISTANCE; }
1269         if(!self.ticrate)                               { self.ticrate = ((self.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1270         if(!self.health)                                { self.health = 1000; }
1271         if(!self.shot_refire)                   { self.shot_refire = 1; }
1272         if(!self.tur_shotorg)                   { self.tur_shotorg = '50 0 50'; }
1273         if(!self.turret_flags)                  { self.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1274         if(!self.damage_flags)                  { self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1275         if(!self.aim_flags)                             { self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1276         if(!self.track_type)                    { self.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1277         if(!self.track_flags)                   { self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1278         if(!self.ammo_flags)                    { self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1279         if(!self.target_select_flags)   { self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1280         if(!self.firecheck_flags)               { self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1281                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1282
1283         if(self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1284         {
1285                 // Fluid / Ineria mode. Looks mutch nicer.
1286                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1287
1288                 self.aim_speed = bound(0.1, ((!self.aim_speed) ? 180 : self.aim_speed), 1000);
1289
1290                 if(!self.track_accel_pitch)             { self.track_accel_pitch = 0.5; }
1291                 if(!self.track_accel_rotate)    { self.track_accel_rotate = 0.5; }
1292                 if(!self.track_blendrate)               { self.track_blendrate = 0.35; }
1293         }
1294
1295         turret_initparams(self);
1296
1297         self.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1298
1299         if(self.turret_flags & TUR_FLAG_SPLASH)
1300                 self.aim_flags |= TFL_AIM_SPLASH;
1301
1302         if(self.turret_flags & TUR_FLAG_MISSILE)
1303                 self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1304
1305         if(self.turret_flags & TUR_FLAG_PLAYER)
1306                 self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1307
1308         if(self.spawnflags & TSL_NO_RESPAWN)
1309                 self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1310
1311         if (self.turret_flags & TUR_FLAG_SUPPORT)
1312                 self.turret_score_target = turret_targetscore_support;
1313         else
1314                 self.turret_score_target = turret_targetscore_generic;
1315
1316         ++turret_count;
1317
1318         _setmodel(self, tur.model);
1319         setsize(self, tur.mins, tur.maxs);
1320
1321         self.m_id                                       = tur.m_id;
1322         self.classname                          = "turret_main";
1323         self.active                                     = ACTIVE_ACTIVE;
1324         self.effects                            = EF_NODRAW;
1325         self.netname                            = tur.turret_name;
1326         self.ticrate                            = bound(sys_frametime, self.ticrate, 60);
1327         self.max_health                         = self.health;
1328         self.target_validate_flags      = self.target_select_flags;
1329         self.ammo                                       = self.ammo_max;
1330         self.ammo_recharge                 *= self.ticrate;
1331         self.solid                                      = SOLID_BBOX;
1332         self.takedamage                         = DAMAGE_AIM;
1333         self.movetype                           = MOVETYPE_NOCLIP;
1334         self.view_ofs                           = '0 0 0';
1335         self.turret_firecheckfunc       = turret_firecheck;
1336         self.event_damage                       = turret_damage;
1337         self.use                                        = turret_use;
1338         self.bot_attack                         = true;
1339         self.nextthink                          = time + 1;
1340         self.nextthink                     += turret_count * sys_frametime;
1341
1342         self.tur_head = new(turret_head);
1343         _setmodel(self.tur_head, tur.head_model);
1344         setsize(self.tur_head, '0 0 0', '0 0 0');
1345         setorigin(self.tur_head, '0 0 0');
1346         setattachment(self.tur_head, self, "tag_head");
1347
1348         self.tur_head.netname           = self.tur_head.classname;
1349         self.tur_head.team                      = self.team;
1350         self.tur_head.owner                     = self;
1351         self.tur_head.takedamage        = DAMAGE_NO;
1352         self.tur_head.solid                     = SOLID_NOT;
1353         self.tur_head.movetype          = self.movetype;
1354
1355         if(!self.tur_defend)
1356         if(self.target != "")
1357         {
1358                 self.tur_defend = find(world, targetname, self.target);
1359                 if (self.tur_defend == world)
1360                 {
1361                         self.target = "";
1362                         LOG_TRACE("Turret has invalid defendpoint!\n");
1363                 }
1364         }
1365
1366         if (self.tur_defend)
1367                 self.idle_aim = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1368         else
1369                 self.idle_aim = '0 0 0';
1370
1371 #ifdef TURRET_DEBUG
1372         self.tur_debug_start = self.nextthink;
1373         while(vdist(self.tur_debug_rvec, <, 2))
1374                 self.tur_debug_rvec = randomvec() * 4;
1375
1376         self.tur_debug_rvec_x = fabs(self.tur_debug_rvec_x);
1377         self.tur_debug_rvec_y = fabs(self.tur_debug_rvec_y);
1378         self.tur_debug_rvec_z = fabs(self.tur_debug_rvec_z);
1379 #endif
1380
1381         turret_link();
1382         turret_respawn(self);
1383         turret_tag_fire_update();
1384
1385         tur.tr_setup(tur, self);
1386
1387         if(MUTATOR_CALLHOOK(TurretSpawn, self))
1388                 return false;
1389
1390         return true;
1391 }
1392 #endif