qcsrc/common/turrets/sv_turrets.qc

   1 #include "sv_turrets.qh"
   2 #ifdef SVQC
   3 #include <server/autocvars.qh>
   4
   5 // Generic aiming
   6 vector turret_aim_generic(entity this)
   7 {
   8
   9         vector pre_pos, prep;
  10         float distance, impact_time = 0, i, mintime;
  11
  12         turret_tag_fire_update(this);
  13
  14         if(this.aim_flags & TFL_AIM_SIMPLE)
  15                 return real_origin(this.enemy);
  16
  17         mintime = max(this.attack_finished_single[0] - time,0) + sys_frametime;
  18
  19         // Baseline
  20         pre_pos = real_origin(this.enemy);
  21
  22         // Lead?
  23         if (this.aim_flags & TFL_AIM_LEAD)
  24         {
  25                 if (this.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  26                 {
  27                         prep = pre_pos;
  28
  29                         distance = vlen(prep - this.tur_shotorg);
  30                         impact_time = distance / this.shot_speed;
  31
  32                         prep = pre_pos + (this.enemy.velocity * (impact_time + mintime));
  33
  34                         if(this.aim_flags & TFL_AIM_ZPREDICT)
  35                         if(!IS_ONGROUND(this.enemy))
  36                         if(this.enemy.move_movetype == MOVETYPE_WALK || this.enemy.move_movetype == MOVETYPE_TOSS || this.enemy.move_movetype == MOVETYPE_BOUNCE)
  37                         {
  38                                 float vz;
  39                                 prep_z = pre_pos_z;
  40                                 vz = this.enemy.velocity_z;
  41                                 for(i = 0; i < impact_time; i += sys_frametime)
  42                                 {
  43                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  44                                         prep_z = prep_z + vz * sys_frametime;
  45                                 }
  46                         }
  47                         pre_pos = prep;
  48                 }
  49                 else
  50                         pre_pos = pre_pos + this.enemy.velocity * mintime;
  51         }
  52
  53         if(this.aim_flags & TFL_AIM_SPLASH)
  54         {
  55                 //tracebox(pre_pos + '0 0 32',this.enemy.mins,this.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  56                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  57                 if(trace_fraction != 1.0)
  58                         pre_pos = trace_endpos;
  59         }
  60
  61         return pre_pos;
  62 }
  63
  64 float turret_targetscore_support(entity _turret,entity _target)
  65 {
  66         float score;            // Total score
  67         float s_score = 0, d_score;
  68
  69         if (_turret.enemy == _target) s_score = 1;
  70
  71         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  72
  73         score = (d_score * _turret.target_select_rangebias) +
  74                         (s_score * _turret.target_select_samebias);
  75
  76         return score;
  77 }
  78
  79 /*
  80 * Generic bias aware score system.
  81 */
  82 float turret_targetscore_generic(entity _turret, entity _target)
  83 {
  84         float d_dist;      // Defendmode Distance
  85         float score;            // Total score
  86         float d_score;    // Distance score
  87         float a_score;    // Angular score
  88         float m_score = 0;  // missile score
  89         float p_score = 0;  // player score
  90         float ikr;                // ideal kill range
  91
  92         if (_turret.tur_defend)
  93         {
  94                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
  95                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
  96                 d_score = 1 - d_dist / _turret.target_range;
  97         }
  98         else
  99         {
 100                 // Make a normlized value base on the targets distance from our optimal killzone
 101                 ikr = _turret.target_range_optimal;
 102                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 103         }
 104
 105         a_score = 1 - tvt_thadf / _turret.aim_maxrot;
 106
 107         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 108                 m_score = 1;
 109
 110         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 111                 p_score = 1;
 112
 113         d_score = max(d_score, 0);
 114         a_score = max(a_score, 0);
 115         m_score = max(m_score, 0);
 116         p_score = max(p_score, 0);
 117
 118         score = (d_score * _turret.target_select_rangebias) +
 119                         (a_score * _turret.target_select_anglebias) +
 120                         (m_score * _turret.target_select_missilebias) +
 121                         (p_score * _turret.target_select_playerbias);
 122
 123         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 124         {
 125                 //dprint("Wtf?\n");
 126                 score *= 0.001;
 127         }
 128
 129 #ifdef TURRET_DEBUG
 130         string sd,sa,sm,sp,ss;
 131         string sdt,sat,smt,spt;
 132
 133         sd = ftos(d_score);
 134         d_score *= _turret.target_select_rangebias;
 135         sdt = ftos(d_score);
 136
 137         //sv = ftos(v_score);
 138         //v_score *= _turret.target_select_samebias;
 139         //svt = ftos(v_score);
 140
 141         sa = ftos(a_score);
 142         a_score *= _turret.target_select_anglebias;
 143         sat = ftos(a_score);
 144
 145         sm = ftos(m_score);
 146         m_score *= _turret.target_select_missilebias;
 147         smt = ftos(m_score);
 148
 149         sp = ftos(p_score);
 150         p_score *= _turret.target_select_playerbias;
 151         spt = ftos(p_score);
 152
 153
 154         ss = ftos(score);
 155         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 156         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 157         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 158         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 159         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 160         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 161
 162 #endif
 163
 164         return score;
 165 }
 166
 167 // Generic damage handling
 168 void turret_hide(entity this)
 169 {
 170         this.effects   |= EF_NODRAW;
 171         this.nextthink = time + this.respawntime - 0.2;
 172         setthink(this, turret_respawn);
 173 }
 174
 175 void turret_die(entity this)
 176 {
 177         this.deadflag             = DEAD_DEAD;
 178         this.tur_head.deadflag = this.deadflag;
 179
 180 // Unsolidify and hide real parts
 181         this.solid                       = SOLID_NOT;
 182         this.tur_head.solid      = this.solid;
 183
 184         this.event_damage                 = func_null;
 185         this.event_heal = func_null;
 186         this.takedamage                  = DAMAGE_NO;
 187
 188         SetResourceExplicit(this, RES_HEALTH, 0);
 189
 190 // Go boom
 191         //RadiusDamage (this,this, min(this.ammo,50),min(this.ammo,50) * 0.25,250,NULL,min(this.ammo,50)*5,DEATH_TURRET,NULL);
 192
 193         Turret tur = get_turretinfo(this.m_id);
 194         if(this.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 195         {
 196                 // do a simple explosion effect here, since CSQC can't do it on a to-be-removed entity
 197                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 198                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 199
 200                 tur.tr_death(tur, this);
 201
 202                 delete(this.tur_head);
 203                 delete(this);
 204         }
 205         else
 206         {
 207                 // Setup respawn
 208                 this.SendFlags    |= TNSF_STATUS;
 209                 this.nextthink   = time + 0.2;
 210                 setthink(this, turret_hide);
 211
 212                 tur.tr_death(tur, this);
 213         }
 214 }
 215
 216 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 217 {
 218         // Enough already!
 219         if(this.deadflag == DEAD_DEAD)
 220                 return;
 221
 222         // Inactive turrets take no damage. (hm..)
 223         if(!this.active)
 224                 return;
 225
 226         if(SAME_TEAM(this, attacker))
 227         {
 228                 if(autocvar_g_friendlyfire)
 229                         damage = damage * autocvar_g_friendlyfire;
 230                 else
 231                         return;
 232         }
 233
 234         TakeResource(this, RES_HEALTH, damage);
 235
 236         // thorw head slightly off aim when hit?
 237         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 238         {
 239                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 240                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 241
 242                 this.SendFlags  |= TNSF_ANG;
 243         }
 244
 245         if (this.turret_flags & TUR_FLAG_MOVE)
 246                 this.velocity = this.velocity + vforce;
 247
 248         if (GetResource(this, RES_HEALTH) <= 0)
 249         {
 250                 this.event_damage                 = func_null;
 251                 this.tur_head.event_damage = func_null;
 252                 this.event_heal = func_null;
 253                 this.tur_head.event_heal = func_null;
 254                 this.takedamage                  = DAMAGE_NO;
 255                 this.nextthink = time;
 256                 setthink(this, turret_die);
 257         }
 258
 259         this.SendFlags  |= TNSF_STATUS;
 260 }
 261
 262 bool turret_heal(entity targ, entity inflictor, float amount, float limit)
 263 {
 264         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
 265         if(GetResource(targ, RES_HEALTH) <= 0 || GetResource(targ, RES_HEALTH) >= true_limit)
 266                 return false;
 267
 268         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
 269         targ.SendFlags |= TNSF_STATUS;
 270         return true;
 271 }
 272
 273 void turret_think(entity this);
 274 void turret_respawn(entity this)
 275 {
 276         // Make sure all parts belong to the same team since
 277         // this function doubles as "teamchange" function.
 278         this.tur_head.team      = this.team;
 279         this.effects                       &= ~EF_NODRAW;
 280         this.deadflag                           = DEAD_NO;
 281         this.effects                            = EF_LOWPRECISION;
 282         this.solid                                      = SOLID_BBOX;
 283         this.takedamage                         = DAMAGE_AIM;
 284         this.event_damage                       = turret_damage;
 285         this.event_heal                         = turret_heal;
 286         this.avelocity                          = '0 0 0';
 287         this.tur_head.avelocity         = this.avelocity;
 288         this.tur_head.angles            = this.idle_aim;
 289         SetResourceExplicit(this, RES_HEALTH, this.max_health);
 290         this.enemy                                      = NULL;
 291         this.volly_counter                      = this.shot_volly;
 292         this.ammo                                       = this.ammo_max;
 293
 294         this.nextthink = time + this.ticrate;
 295         setthink(this, turret_think);
 296
 297         this.SendFlags = TNSF_FULL_UPDATE;
 298
 299         Turret tur = get_turretinfo(this.m_id);
 300         tur.tr_setup(tur, this);
 301 }
 302
 303
 304 // Main functions
 305 .float clientframe;
 306 void turrets_setframe(entity this, float _frame, float client_only)
 307 {
 308         if((client_only ? this.clientframe : this.frame ) != _frame)
 309         {
 310                 this.SendFlags |= TNSF_ANIM;
 311                 this.anim_start_time = time;
 312         }
 313
 314          if(client_only)
 315                 this.clientframe = _frame;
 316         else
 317                 this.frame = _frame;
 318
 319 }
 320
 321 bool turret_send(entity this, entity to, float sf)
 322 {
 323
 324         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 325         WriteByte(MSG_ENTITY, sf);
 326         if(sf & TNSF_SETUP)
 327         {
 328                 WriteByte(MSG_ENTITY, this.m_id);
 329
 330                 WriteVector(MSG_ENTITY, this.origin);
 331
 332                 WriteAngle(MSG_ENTITY, this.angles_x);
 333                 WriteAngle(MSG_ENTITY, this.angles_y);
 334         }
 335
 336         if(sf & TNSF_ANG)
 337         {
 338                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_x));
 339                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_y));
 340         }
 341
 342         if(sf & TNSF_AVEL)
 343         {
 344                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_x));
 345                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_y));
 346         }
 347
 348         if(sf & TNSF_MOVE)
 349         {
 350                 WriteVector(MSG_ENTITY, this.origin);
 351
 352                 WriteVector(MSG_ENTITY, this.velocity);
 353
 354                 WriteShort(MSG_ENTITY, rint(this.angles_y));
 355         }
 356
 357         if(sf & TNSF_ANIM)
 358         {
 359                 WriteCoord(MSG_ENTITY, this.anim_start_time);
 360                 WriteByte(MSG_ENTITY, this.frame);
 361         }
 362
 363         if(sf & TNSF_STATUS)
 364         {
 365                 WriteByte(MSG_ENTITY, this.team);
 366
 367                 if(GetResource(this, RES_HEALTH) <= 0)
 368                         WriteByte(MSG_ENTITY, 0);
 369                 else
 370                         WriteByte(MSG_ENTITY, ceil((GetResource(this, RES_HEALTH) / this.max_health) * 255));
 371         }
 372
 373         return true;
 374 }
 375
 376 void load_unit_settings(entity ent, bool is_reload)
 377 {
 378         if (ent == NULL)
 379                 return;
 380
 381         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 382         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 383         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 384         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 385         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 386         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 387         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 388
 389         if (is_reload)
 390         {
 391                 ent.enemy = NULL;
 392                 ent.tur_head.avelocity = '0 0 0';
 393
 394                 ent.tur_head.angles = '0 0 0';
 395         }
 396
 397         string unitname = ent.netname;
 398         #define X(class, prefix, fld, type) ent.fld = cvar(strcat("g_turrets_unit_", prefix, "_", #fld));
 399         TR_PROPS_COMMON(X, , unitname)
 400         #undef X
 401
 402         ent.ammo_max             *= ent.turret_scale_ammo;
 403         ent.ammo_recharge        *= ent.turret_scale_ammo;
 404         ent.aim_speed            *= ent.turret_scale_aim;
 405         ent.health               *= ent.turret_scale_health;
 406         ent.respawntime          *= ent.turret_scale_respawn;
 407         ent.shot_dmg             *= ent.turret_scale_damage;
 408         ent.shot_refire          *= ent.turret_scale_refire;
 409         ent.shot_radius          *= ent.turret_scale_damage;
 410         ent.shot_force           *= ent.turret_scale_damage;
 411         ent.shot_volly_refire    *= ent.turret_scale_refire;
 412         ent.target_range         *= ent.turret_scale_range;
 413         ent.target_range_min     *= ent.turret_scale_range;
 414         ent.target_range_optimal *= ent.turret_scale_range;
 415
 416         if(is_reload) {
 417                 Turret tur = get_turretinfo(ent.m_id);
 418                 tur.tr_setup(tur, ent);
 419         }
 420 }
 421
 422 void turret_projectile_explode(entity this)
 423 {
 424
 425         this.takedamage = DAMAGE_NO;
 426         this.event_damage = func_null;
 427 #ifdef TURRET_DEBUG
 428         float d;
 429         d = RadiusDamage (this, this.owner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, DMG_NOWEP, NULL);
 430         this.owner.tur_debug_dmg_t_h = this.owner.tur_debug_dmg_t_h + d;
 431         this.owner.tur_debug_dmg_t_f = this.owner.tur_debug_dmg_t_f + this.owner.shot_dmg;
 432 #else
 433         RadiusDamage (this, this.realowner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, DMG_NOWEP, NULL);
 434 #endif
 435         delete(this);
 436 }
 437
 438 void turret_projectile_touch(entity this, entity toucher)
 439 {
 440         PROJECTILE_TOUCH(this, toucher);
 441         turret_projectile_explode(this);
 442 }
 443
 444 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 445 {
 446         this.velocity  += vforce;
 447         TakeResource(this, RES_HEALTH, damage);
 448         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 449         if(GetResource(this, RES_HEALTH) <= 0)
 450                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
 451 }
 452
 453 entity turret_projectile(entity actor, Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 454 {
 455         TC(Sound, _snd);
 456         entity proj;
 457
 458         sound (actor, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 459         proj                             = spawn ();
 460         setorigin(proj, actor.tur_shotorg);
 461         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 462         proj.owner                = actor;
 463         proj.realowner    = actor;
 464         proj.bot_dodge    = true;
 465         proj.bot_dodgerating = actor.shot_dmg;
 466         setthink(proj, turret_projectile_explode);
 467         settouch(proj, turret_projectile_touch);
 468         proj.nextthink    = time + 9;
 469         set_movetype(proj, MOVETYPE_FLYMISSILE);
 470         proj.velocity           = normalize(actor.tur_shotdir_updated + randomvec() * actor.shot_spread) * actor.shot_speed;
 471         proj.flags = FL_PROJECTILE;
 472         IL_PUSH(g_projectiles, proj);
 473         IL_PUSH(g_bot_dodge, proj);
 474         proj.enemy                = actor.enemy;
 475         proj.totalfrags  = _death;
 476         PROJECTILE_MAKETRIGGER(proj);
 477         if(_health)
 478         {
 479                 SetResourceExplicit(proj, RES_HEALTH, _health);
 480                 proj.takedamage  = DAMAGE_YES;
 481                 proj.event_damage  = turret_projectile_damage;
 482         }
 483         else
 484                 proj.flags |= FL_NOTARGET;
 485
 486         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 487
 488         return proj;
 489 }
 490
 491 /**
 492 ** updates enemy distances, predicted impact point/time
 493 ** and updated aim<->predict impact distance.
 494 **/
 495 void turret_do_updates(entity t_turret)
 496 {
 497         vector enemy_pos = real_origin(t_turret.enemy);
 498
 499         turret_tag_fire_update(t_turret);
 500
 501         t_turret.tur_shotdir_updated = v_forward;
 502         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
 503         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
 504
 505         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
 506         {
 507                 oldpos = t_turret.enemy.origin;
 508                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
 509                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 510                 setorigin(t_turret.enemy, oldpos);
 511
 512                 if(trace_ent == t_turret.enemy)
 513                         t_turret.tur_dist_impact_to_aimpos = 0;
 514                 else
 515                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
 516         }
 517         else*/
 518                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 519
 520         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
 521         t_turret.tur_impactent                   = trace_ent;
 522         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
 523 }
 524
 525 /**
 526 ** Handles head rotation according to
 527 ** the units .track_type and .track_flags
 528 **/
 529 .float turret_framecounter;
 530 void turret_track(entity this)
 531 {
 532         vector target_angle; // This is where we want to aim
 533         vector move_angle;   // This is where we can aim
 534         float f_tmp;
 535         vector v1, v2;
 536         v1 = this.tur_head.angles;
 537         v2 = this.tur_head.avelocity;
 538
 539         if (this.track_flags == TFL_TRACK_NO)
 540                 return;
 541
 542         if(!this.active)
 543                 target_angle = this.idle_aim - ('1 0 0' * this.aim_maxpitch);
 544         else if (this.enemy == NULL)
 545         {
 546                 if(time > this.lip)
 547                         target_angle = this.idle_aim + this.angles;
 548                 else
 549                         target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 550         }
 551         else
 552         {
 553                 target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 554         }
 555
 556         this.tur_head.angles_x = anglemods(this.tur_head.angles_x);
 557         this.tur_head.angles_y = anglemods(this.tur_head.angles_y);
 558
 559         // Find the diffrence between where we currently aim and where we want to aim
 560         //move_angle = target_angle - (this.angles + this.tur_head.angles);
 561         //move_angle = shortangle_vxy(move_angle,(this.angles + this.tur_head.angles));
 562
 563         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(this.angles), AnglesTransform_FromAngles(target_angle))) - this.tur_head.angles;
 564         move_angle = shortangle_vxy(move_angle, this.tur_head.angles);
 565
 566         switch(this.track_type)
 567         {
 568                 case TFL_TRACKTYPE_STEPMOTOR:
 569                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 570                         if (this.track_flags & TFL_TRACK_PITCH)
 571                         {
 572                                 this.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 573                                 if(this.tur_head.angles_x > this.aim_maxpitch)
 574                                         this.tur_head.angles_x = this.aim_maxpitch;
 575
 576                                 if(this.tur_head.angles_x  < -this.aim_maxpitch)
 577                                         this.tur_head.angles_x = this.aim_maxpitch;
 578                         }
 579
 580                         if (this.track_flags & TFL_TRACK_ROTATE)
 581                         {
 582                                 this.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 583                                 if(this.tur_head.angles_y > this.aim_maxrot)
 584                                         this.tur_head.angles_y = this.aim_maxrot;
 585
 586                                 if(this.tur_head.angles_y  < -this.aim_maxrot)
 587                                         this.tur_head.angles_y = this.aim_maxrot;
 588                         }
 589
 590                         // CSQC
 591                         this.SendFlags  |= TNSF_ANG;
 592
 593                         return;
 594
 595                 case TFL_TRACKTYPE_FLUIDINERTIA:
 596                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 597                         move_angle_x = bound(-this.aim_speed, move_angle_x * this.track_accel_pitch * f_tmp, this.aim_speed);
 598                         move_angle_y = bound(-this.aim_speed, move_angle_y * this.track_accel_rot * f_tmp, this.aim_speed);
 599                         move_angle = (this.tur_head.avelocity * this.track_blendrate) + (move_angle * (1 - this.track_blendrate));
 600                         break;
 601
 602                 case TFL_TRACKTYPE_FLUIDPRECISE:
 603
 604                         move_angle_y = bound(-this.aim_speed, move_angle_y, this.aim_speed);
 605                         move_angle_x = bound(-this.aim_speed, move_angle_x, this.aim_speed);
 606
 607                         break;
 608         }
 609
 610         //  pitch
 611         if (this.track_flags & TFL_TRACK_PITCH)
 612         {
 613                 this.tur_head.avelocity_x = move_angle_x;
 614                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) > this.aim_maxpitch)
 615                 {
 616                         this.tur_head.avelocity_x = 0;
 617                         this.tur_head.angles_x = this.aim_maxpitch;
 618
 619                         this.SendFlags  |= TNSF_ANG;
 620                 }
 621
 622                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) < -this.aim_maxpitch)
 623                 {
 624                         this.tur_head.avelocity_x = 0;
 625                         this.tur_head.angles_x = -this.aim_maxpitch;
 626
 627                         this.SendFlags  |= TNSF_ANG;
 628                 }
 629         }
 630
 631         //  rot
 632         if (this.track_flags & TFL_TRACK_ROTATE)
 633         {
 634                 this.tur_head.avelocity_y = move_angle_y;
 635
 636                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) > this.aim_maxrot)
 637                 {
 638                         this.tur_head.avelocity_y = 0;
 639                         this.tur_head.angles_y = this.aim_maxrot;
 640
 641                         this.SendFlags  |= TNSF_ANG;
 642                 }
 643
 644                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) < -this.aim_maxrot)
 645                 {
 646                         this.tur_head.avelocity_y = 0;
 647                         this.tur_head.angles_y = -this.aim_maxrot;
 648
 649                         this.SendFlags  |= TNSF_ANG;
 650                 }
 651         }
 652
 653         this.SendFlags  |= TNSF_AVEL;
 654
 655         // Force a angle update every 10'th frame
 656         this.turret_framecounter += 1;
 657         if(this.turret_framecounter >= 10)
 658         {
 659                 this.SendFlags |= TNSF_ANG;
 660                 this.turret_framecounter = 0;
 661         }
 662 }
 663
 664 /*
 665  + TFL_TARGETSELECT_NO
 666  + TFL_TARGETSELECT_LOS
 667  + TFL_TARGETSELECT_PLAYERS
 668  + TFL_TARGETSELECT_MISSILES
 669  + TFL_TARGETSELECT_VEHICLES
 670  - TFL_TARGETSELECT_TRIGGERTARGET
 671  + TFL_TARGETSELECT_ANGLELIMITS
 672  + TFL_TARGETSELECT_RANGELIMITS
 673  + TFL_TARGETSELECT_TEAMCHECK
 674  - TFL_TARGETSELECT_NOBUILTIN
 675  + TFL_TARGETSELECT_OWNTEAM
 676 */
 677
 678 /**
 679 ** Evaluate a entity for target valitity based on validate_flags
 680 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 681 **/
 682 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 683 {
 684         vector v_tmp;
 685
 686         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 687         //      return -0.5;
 688
 689         if(!e_target)
 690                 return -2;
 691
 692         if(e_target.owner == e_turret)
 693                 return -0.5;
 694
 695         if(!checkpvs(e_target.origin, e_turret))
 696                 return -1;
 697
 698         if(e_target.alpha != 0 && e_target.alpha <= 0.3)
 699                 return -1;
 700
 701         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 702                 return M_ARGV(3, float);
 703
 704         if (validate_flags & TFL_TARGETSELECT_NO)
 705                 return -4;
 706
 707         // If only this was used more..
 708         if (e_target.flags & FL_NOTARGET)
 709                 return -5;
 710
 711         // Cant touch this
 712         if (GetResource(e_target, RES_HEALTH) <= 0)
 713                 return -6;
 714         else if (STAT(FROZEN, e_target))
 715                 return -6;
 716
 717         // vehicle
 718         if(IS_VEHICLE(e_target))
 719         {
 720                 if ((validate_flags & TFL_TARGETSELECT_VEHICLES) && !e_target.owner)
 721                         return -7;
 722         }
 723
 724         // player
 725         if (IS_CLIENT(e_target))
 726         {
 727                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 728                         return -7;
 729
 730                 if (IS_DEAD(e_target))
 731                         return -8;
 732         }
 733
 734         // enemy turrets
 735         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 736         if(e_target.owner.tur_head == e_target)
 737         if(e_target.team != e_turret.team) // Dont break support units.
 738                 return -9;
 739
 740         // Missile
 741         if (e_target.flags & FL_PROJECTILE)
 742         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 743                 return -10;
 744
 745         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 746         if(!(e_target.flags & FL_PROJECTILE))
 747                 return -10.5;
 748
 749         // Team check
 750         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 751         {
 752                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 753                 {
 754                         if (e_target.team != e_turret.team)
 755                                 return -11;
 756
 757                         if (e_turret.team != e_target.owner.team)
 758                                 return -12;
 759
 760                         if (e_turret.team != e_target.aiment.team)
 761                                 return -12; // portals
 762                 }
 763                 else
 764                 {
 765                         if (e_target.team == e_turret.team)
 766                                 return -13;
 767
 768                         if (e_turret.team == e_target.owner.team)
 769                                 return -14;
 770
 771                         if (e_turret.team == e_target.aiment.team)
 772                                 return -14; // portals
 773                 }
 774         }
 775
 776         // Range limits?
 777         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 778         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 779         {
 780                 if (tvt_dist < e_turret.target_range_min)
 781                         return -15;
 782
 783                 if (tvt_dist > e_turret.target_range)
 784                         return -16;
 785         }
 786
 787         // Can we even aim this thing?
 788         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target.origin);
 789         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 790         tvt_thadf = vlen(tvt_thadv);
 791         tvt_tadf = vlen(tvt_tadv);
 792
 793         /*
 794         if(validate_flags & TFL_TARGETSELECT_FOV)
 795         {
 796                 if(e_turret.target_select_fov < tvt_thadf)
 797                         return -21;
 798         }
 799         */
 800
 801         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 802         {
 803                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 804                         return -17;
 805
 806                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrot)
 807                         return -18;
 808         }
 809
 810         // Line of sight?
 811         if (validate_flags & TFL_TARGETSELECT_LOS)
 812         {
 813                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 814
 815                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 816
 817                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 818                         return -19;
 819         }
 820
 821         if (e_target.classname == "grapplinghook")
 822                 return -20;
 823
 824         /*
 825         if (e_target.classname == "func_button")
 826                 return -21;
 827         */
 828
 829 #ifdef TURRET_DEBUG_TARGETSELECT
 830         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname);
 831 #endif
 832
 833         return 1;
 834 }
 835
 836 entity turret_select_target(entity this)
 837 {
 838         entity e;               // target looper entity
 839         float  score;   // target looper entity score
 840         entity e_enemy;  // currently best scoreing target
 841         float  m_score;  // currently best scoreing target's score
 842
 843         m_score = 0;
 844         if(this.enemy && this.enemy.takedamage && turret_validate_target(this,this.enemy,this.target_validate_flags) > 0)
 845         {
 846                 e_enemy = this.enemy;
 847                 m_score = this.turret_score_target(this,e_enemy) * this.target_select_samebias;
 848         }
 849         else
 850                 e_enemy = this.enemy = NULL;
 851
 852         e = findradius(this.origin, this.target_range);
 853
 854         // Nothing to aim at?
 855         if (!e)
 856                 return NULL;
 857
 858         while (e)
 859         {
 860                 if(e.takedamage)
 861                 {
 862                         float f = turret_validate_target(this, e, this.target_select_flags);
 863                         //dprint("F is: ", ftos(f), "\n");
 864                         if ( f > 0)
 865                         {
 866                                 score = this.turret_score_target(this,e);
 867                                 if ((score > m_score) && (score > 0))
 868                                 {
 869                                         e_enemy = e;
 870                                         m_score = score;
 871                                 }
 872                         }
 873                 }
 874                 e = e.chain;
 875         }
 876
 877         return e_enemy;
 878 }
 879
 880
 881 /*
 882  + = implemented
 883  - = not implemented
 884
 885  + TFL_FIRECHECK_NO
 886  + TFL_FIRECHECK_WORLD
 887  + TFL_FIRECHECK_DEAD
 888  + TFL_FIRECHECK_DISTANCES
 889  - TFL_FIRECHECK_LOS
 890  + TFL_FIRECHECK_AIMDIST
 891  + TFL_FIRECHECK_REALDIST
 892  - TFL_FIRECHECK_ANGLEDIST
 893  - TFL_FIRECHECK_TEAMCECK
 894  + TFL_FIRECHECK_AFF
 895  + TFL_FIRECHECK_AMMO_OWN
 896  + TFL_FIRECHECK_AMMO_OTHER
 897  + TFL_FIRECHECK_REFIRE
 898 */
 899
 900 /**
 901 ** Preforms pre-fire checks based on the uints firecheck_flags
 902 **/
 903 bool turret_firecheck(entity this)
 904 {
 905         // This one just dont care =)
 906         if (this.firecheck_flags & TFL_FIRECHECK_NO)
 907                 return true;
 908
 909         if (this.enemy == NULL)
 910                 return false;
 911
 912         // Ready?
 913         if (this.firecheck_flags & TFL_FIRECHECK_REFIRE)
 914                 if (this.attack_finished_single[0] > time) return false;
 915
 916         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 917         if (this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 918                 if (this.volly_counter != this.shot_volly)
 919                         if(this.ammo >= this.shot_dmg)
 920                                 return true;
 921
 922         // Lack of zombies makes shooting dead things unnecessary :P
 923         if (this.firecheck_flags & TFL_FIRECHECK_DEAD)
 924                 if (IS_DEAD(this.enemy))
 925                         return false;
 926
 927         // Own ammo?
 928         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 929                 if (this.ammo < this.shot_dmg)
 930                         return false;
 931
 932         // Other's ammo? (support-supply units)
 933         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 934                 if (this.enemy.ammo >= this.enemy.ammo_max)
 935                         return false;
 936
 937         // Target of opertunity?
 938         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 939         {
 940                 this.enemy = this.tur_impactent;
 941                 return true;
 942         }
 943
 944         if (this.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 945         {
 946                 // To close?
 947                 if (this.tur_dist_aimpos < this.target_range_min)
 948                 {
 949                         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 950                                 return true; // Target of opertunity?
 951                         return false;
 952                 }
 953         }
 954
 955         // Try to avoid FF?
 956         if (this.firecheck_flags & TFL_FIRECHECK_AFF)
 957                 if (this.tur_impactent.team == this.team)
 958                         return false;
 959
 960         // aim<->predicted impact
 961         if (this.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 962                 if (this.tur_dist_impact_to_aimpos > this.aim_firetolerance_dist)
 963                         return false;
 964
 965         // Volly status
 966         if (this.shot_volly > 1)
 967                 if (this.volly_counter == this.shot_volly)
 968                         if (this.ammo < (this.shot_dmg * this.shot_volly))
 969                                 return false;
 970
 971         /*if(this.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 972                 if(this.tur_impactent != this.enemy)
 973                         return false;*/
 974
 975         return true;
 976 }
 977
 978 bool turret_checkfire(entity this)
 979 {
 980         if(MUTATOR_CALLHOOK(Turret_CheckFire, this))
 981                 return M_ARGV(1, bool);
 982
 983         return this.turret_firecheckfunc(this);
 984 }
 985
 986 void turret_fire(entity this)
 987 {
 988         if (autocvar_g_turrets_nofire != 0)
 989                 return;
 990
 991         if(MUTATOR_CALLHOOK(TurretFire, this))
 992                 return;
 993
 994         Turret info = get_turretinfo(this.m_id);
 995         info.tr_attack(info, this);
 996
 997         this.attack_finished_single[0] = time + this.shot_refire;
 998         this.ammo -= this.shot_dmg;
 999         this.volly_counter = this.volly_counter - 1;
1000
1001         if (this.volly_counter <= 0)
1002         {
1003                 this.volly_counter = this.shot_volly;
1004
1005                 if (this.shoot_flags & TFL_SHOOT_CLEARTARGET)
1006                         this.enemy = NULL;
1007
1008                 if (this.shot_volly > 1)
1009                         this.attack_finished_single[0] = time + this.shot_volly_refire;
1010         }
1011
1012 #ifdef TURRET_DEBUG
1013         if (this.enemy) paint_target3(this.tur_aimpos, 64, this.tur_debug_rvec, this.tur_impacttime + 0.25);
1014 #endif
1015 }
1016
1017 void turret_think(entity this)
1018 {
1019         this.nextthink = time + this.ticrate;
1020
1021         MUTATOR_CALLHOOK(TurretThink, this);
1022
1023 #ifdef TURRET_DEBUG
1024         if (this.tur_debug_tmr1 < time)
1025         {
1026                 if (this.enemy) paint_target (this.enemy,128,this.tur_debug_rvec,0.9);
1027                 paint_target(this,256,this.tur_debug_rvec,0.9);
1028                 this.tur_debug_tmr1 = time + 1;
1029         }
1030 #endif
1031
1032         // Handle ammo
1033         if (!(this.spawnflags & TSF_NO_AMMO_REGEN))
1034         if (this.ammo < this.ammo_max)
1035                 this.ammo = min(this.ammo + this.ammo_recharge, this.ammo_max);
1036
1037         // Inactive turrets needs to run the think loop,
1038         // So they can handle animation and wake up if need be.
1039         if(!this.active)
1040         {
1041                 turret_track(this);
1042                 return;
1043         }
1044
1045         // This is typicaly used for zaping every target in range
1046         // turret_fusionreactor uses this to recharge friendlys.
1047         if (this.shoot_flags & TFL_SHOOT_HITALLVALID)
1048         {
1049                 // Do a this.turret_fire for every valid target.
1050                 entity e = findradius(this.origin,this.target_range);
1051                 while (e)
1052                 {
1053                         if(e.takedamage)
1054                         {
1055                                 if (turret_validate_target(this,e,this.target_validate_flags))
1056                                 {
1057                                         this.enemy = e;
1058
1059                                         turret_do_updates(this);
1060
1061                                         if (turret_checkfire(this))
1062                                                 turret_fire(this);
1063                                 }
1064                         }
1065
1066                         e = e.chain;
1067                 }
1068                 this.enemy = NULL;
1069         }
1070         else if(this.shoot_flags & TFL_SHOOT_CUSTOM)
1071         {
1072                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1073
1074                 // Predict?
1075                 if(!(this.aim_flags & TFL_AIM_NO))
1076                         this.tur_aimpos = turret_aim_generic(this);
1077
1078                 // Turn & pitch?
1079                 if(!(this.track_flags & TFL_TRACK_NO))
1080                         turret_track(this);
1081
1082                 turret_do_updates(this);
1083
1084                 // Fire?
1085                 if (turret_checkfire(this))
1086                         turret_fire(this);
1087         }
1088         else
1089         {
1090                 // Special case for volly always. if it fired once it must compleate the volly.
1091                 if(this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1092                         if(this.volly_counter != this.shot_volly)
1093                         {
1094                                 // Predict or whatnot
1095                                 if(!(this.aim_flags & TFL_AIM_NO))
1096                                         this.tur_aimpos = turret_aim_generic(this);
1097
1098                                 // Turn & pitch
1099                                 if(!(this.track_flags & TFL_TRACK_NO))
1100                                         turret_track(this);
1101
1102                                 turret_do_updates(this);
1103
1104                                 // Fire!
1105                                 if (turret_checkfire(this))
1106                                         turret_fire(this);
1107
1108                                 Turret tur = get_turretinfo(this.m_id);
1109                                 tur.tr_think(tur, this);
1110
1111                                 return;
1112                         }
1113
1114                 // Check if we have a vailid enemy, and try to find one if we dont.
1115
1116                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1117                 float do_target_scan = 0;
1118                 if((this.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1119                         do_target_scan = 1;
1120
1121                 // Old target (if any) invalid?
1122                 if(this.target_validate_time < time)
1123                 if (turret_validate_target(this, this.enemy, this.target_validate_flags) <= 0)
1124                 {
1125                         this.enemy = NULL;
1126                         this.target_validate_time = time + 0.5;
1127                         do_target_scan = 1;
1128                 }
1129
1130                 // But never more often then g_turrets_targetscan_mindelay!
1131                 if (this.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1132                         do_target_scan = 0;
1133
1134                 if(do_target_scan)
1135                 {
1136                         this.enemy = turret_select_target(this);
1137                         this.target_select_time = time;
1138                 }
1139
1140                 // No target, just go to idle, do any custom stuff and bail.
1141                 if (this.enemy == NULL)
1142                 {
1143                         // Turn & pitch
1144                         if(!(this.track_flags & TFL_TRACK_NO))
1145                                 turret_track(this);
1146
1147                         Turret tur = get_turretinfo(this.m_id);
1148                         tur.tr_think(tur, this);
1149
1150                         // And bail.
1151                         return;
1152                 }
1153                 else
1154                         this.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1155
1156                 // Predict?
1157                 if(!(this.aim_flags & TFL_AIM_NO))
1158                         this.tur_aimpos = turret_aim_generic(this);
1159
1160                 // Turn & pitch?
1161                 if(!(this.track_flags & TFL_TRACK_NO))
1162                         turret_track(this);
1163
1164                 turret_do_updates(this);
1165
1166                 // Fire?
1167                 if (turret_checkfire(this))
1168                         turret_fire(this);
1169         }
1170
1171         Turret tur = get_turretinfo(this.m_id);
1172         tur.tr_think(tur, this);
1173 }
1174
1175 /*
1176         When .used a turret switch team to activator.team.
1177         If activator is NULL, the turret go inactive.
1178 */
1179 void turret_use(entity this, entity actor, entity trigger)
1180 {
1181         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname);
1182
1183         this.team = actor.team;
1184
1185         if(this.team == 0)
1186                 this.active = ACTIVE_NOT;
1187         else
1188                 this.active = ACTIVE_ACTIVE;
1189
1190 }
1191
1192 void turret_link(entity this)
1193 {
1194         Net_LinkEntity(this, true, 0, turret_send);
1195         setthink(this, turret_think);
1196         this.nextthink = time;
1197         this.tur_head.effects = EF_NODRAW;
1198 }
1199
1200 void turrets_manager_think(entity this)
1201 {
1202         this.nextthink = time + 1;
1203
1204         if (autocvar_g_turrets_reloadcvars == 1)
1205         {
1206                 IL_EACH(g_turrets, true,
1207                 {
1208                         load_unit_settings(it, true);
1209                         Turret tur = get_turretinfo(it.m_id);
1210                         tur.tr_think(tur, it);
1211                 });
1212                 cvar_set("g_turrets_reloadcvars", "0");
1213         }
1214 }
1215
1216 void turret_initparams(entity tur)
1217 {
1218         #define TRY(x) (x) ? (x)
1219         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1220         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1221         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1222         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1223         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1224         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1225         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1226         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1227         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1228         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), max_shot_distance);
1229         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), max_shot_distance);
1230         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), max_shot_distance);
1231         tur.aim_maxrot                  = bound(0,               (TRY(tur.aim_maxrot)                :  90                                         ), 360);
1232         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1233         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1234         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), max_shot_distance);
1235         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1236         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1237         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1238         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1239         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1240         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1241         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1242         #undef TRY
1243 }
1244
1245 bool turret_closetotarget(entity this, vector targ)
1246 {
1247         vector path_extra_size = '64 64 64';
1248         return boxesoverlap(targ - path_extra_size, targ + path_extra_size, this.absmin - path_extra_size, this.absmax + path_extra_size);
1249 }
1250
1251 void turret_findtarget(entity this)
1252 {
1253         entity e = find(NULL, classname, "turret_manager");
1254         if(!e)
1255         {
1256                 e = new(turret_manager);
1257                 setthink(e, turrets_manager_think);
1258                 e.nextthink = time + 2;
1259         }
1260
1261         entity targ = find(NULL, targetname, this.target);
1262         if(targ.classname == "turret_checkpoint")
1263                 return; // turrets don't defend checkpoints?
1264
1265         if (!targ)
1266         {
1267                 this.target = "";
1268                 LOG_TRACE("Turret has invalid defendpoint!");
1269         }
1270
1271         this.tur_defend = targ;
1272         this.idle_aim = this.tur_head.angles + angleofs(this.tur_head, targ);
1273 }
1274
1275 void turret_reset(entity this)
1276 {
1277         turret_respawn(this);
1278 }
1279
1280 bool turret_initialize(entity this, Turret tur)
1281 {
1282         if(!autocvar_g_turrets)
1283                 return false;
1284
1285         if(tur.m_id == 0)
1286                 return false; // invalid turret
1287
1288         // if tur_head exists, we can assume this turret re-spawned
1289         if(!this.tur_head) {
1290                 tur.tr_precache(tur);
1291                 IL_PUSH(g_turrets, this);
1292                 IL_PUSH(g_bot_targets, this);
1293         }
1294
1295         if(!(this.spawnflags & TSF_SUSPENDED))
1296                 droptofloor(this);
1297
1298         this.netname = tur.netname;
1299         load_unit_settings(this, 0);
1300
1301         if(!this.team || !teamplay)             { this.team = FLOAT_MAX; }
1302         if(!this.ticrate)                               { this.ticrate = ((this.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1303         if(!GetResource(this, RES_HEALTH)) { SetResourceExplicit(this, RES_HEALTH, 1000); }
1304         if(!this.shot_refire)                   { this.shot_refire = 1; }
1305         if(!this.tur_shotorg)                   { this.tur_shotorg = '50 0 50'; }
1306         if(!this.turret_flags)                  { this.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1307         if(!this.damage_flags)                  { this.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1308         if(!this.aim_flags)                             { this.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1309         if(!this.track_type)                    { this.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1310         if(!this.track_flags)                   { this.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1311         if(!this.ammo_flags)                    { this.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1312         if(!this.target_select_flags)   { this.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1313         if(!this.firecheck_flags)               { this.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1314                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1315
1316         if(this.track_type != TFL_TRACKTYPE_STEPMOTOR)
1317         {
1318                 // Fluid / Ineria mode. Looks mutch nicer.
1319                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1320
1321                 this.aim_speed = bound(0.1, ((!this.aim_speed) ? 180 : this.aim_speed), 1000);
1322
1323                 if(!this.track_accel_pitch)             { this.track_accel_pitch = 0.5; }
1324                 if(!this.track_accel_rot)               { this.track_accel_rot = 0.5; }
1325                 if(!this.track_blendrate)               { this.track_blendrate = 0.35; }
1326         }
1327
1328         turret_initparams(this);
1329
1330         this.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1331
1332         if(this.turret_flags & TUR_FLAG_SPLASH)
1333                 this.aim_flags |= TFL_AIM_SPLASH;
1334
1335         if(this.turret_flags & TUR_FLAG_MISSILE)
1336                 this.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1337
1338         if(this.turret_flags & TUR_FLAG_PLAYER)
1339                 this.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1340
1341         if(this.spawnflags & TSL_NO_RESPAWN)
1342                 this.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1343
1344         if (this.turret_flags & TUR_FLAG_SUPPORT)
1345                 this.turret_score_target = turret_targetscore_support;
1346         else
1347                 this.turret_score_target = turret_targetscore_generic;
1348
1349         ++turret_count;
1350
1351         _setmodel(this, tur.model);
1352         setsize(this, tur.m_mins, tur.m_maxs);
1353
1354         this.m_id                                       = tur.m_id;
1355         this.active                                     = ACTIVE_ACTIVE;
1356         this.effects                            = EF_NODRAW;
1357         this.netname                            = tur.turret_name;
1358         this.ticrate                            = bound(sys_frametime, this.ticrate, 60);
1359         this.max_health                         = GetResource(this, RES_HEALTH);
1360         this.target_validate_flags      = this.target_select_flags;
1361         this.ammo                                       = this.ammo_max;
1362         this.ammo_recharge                 *= this.ticrate;
1363         this.solid                                      = SOLID_BBOX;
1364         this.takedamage                         = DAMAGE_AIM;
1365         set_movetype(this, MOVETYPE_NOCLIP);
1366         this.view_ofs                           = '0 0 0';
1367         this.idle_aim                           = '0 0 0';
1368         this.turret_firecheckfunc       = turret_firecheck;
1369         this.event_damage                       = turret_damage;
1370         this.event_heal                         = turret_heal;
1371         this.use                                        = turret_use;
1372         this.bot_attack                         = true;
1373         this.nextthink                          = time + 1 + turret_count * sys_frametime;
1374         this.reset                                      = turret_reset;
1375
1376         this.tur_head = new(turret_head);
1377         _setmodel(this.tur_head, tur.head_model);
1378         setsize(this.tur_head, '0 0 0', '0 0 0');
1379         setorigin(this.tur_head, '0 0 0');
1380         setattachment(this.tur_head, this, "tag_head");
1381
1382         this.tur_head.netname           = this.tur_head.classname;
1383         this.tur_head.team                      = this.team;
1384         this.tur_head.owner                     = this;
1385         this.tur_head.takedamage        = DAMAGE_NO;
1386         this.tur_head.solid                     = SOLID_NOT;
1387         set_movetype(this.tur_head, this.move_movetype);
1388
1389         this.weaponentities[0] = this; // lol
1390
1391         if(!this.tur_defend && this.target != "")
1392                 InitializeEntity(this, turret_findtarget, INITPRIO_FINDTARGET);
1393
1394 #ifdef TURRET_DEBUG
1395         this.tur_debug_start = this.nextthink;
1396         while(vdist(this.tur_debug_rvec, <, 2))
1397                 this.tur_debug_rvec = randomvec() * 4;
1398
1399         this.tur_debug_rvec_x = fabs(this.tur_debug_rvec_x);
1400         this.tur_debug_rvec_y = fabs(this.tur_debug_rvec_y);
1401         this.tur_debug_rvec_z = fabs(this.tur_debug_rvec_z);
1402 #endif
1403
1404         turret_link(this);
1405         turret_respawn(this);
1406         turret_tag_fire_update(this);
1407
1408         tur.tr_setup(tur, this);
1409
1410         if(MUTATOR_CALLHOOK(TurretSpawn, this))
1411                 return false;
1412
1413         return true;
1414 }
1415 #endif