qcsrc/common/turrets/sv_turrets.qc

   1 #ifdef SVQC
   2 #include <server/autocvars.qh>
   3
   4 // Generic aiming
   5 vector turret_aim_generic()
   6 {SELFPARAM();
   7
   8         vector pre_pos, prep;
   9         float distance, impact_time = 0, i, mintime;
  10
  11         turret_tag_fire_update();
  12
  13         if(self.aim_flags & TFL_AIM_SIMPLE)
  14                 return real_origin(self.enemy);
  15
  16         mintime = max(self.attack_finished_single[0] - time,0) + sys_frametime;
  17
  18         // Baseline
  19         pre_pos = real_origin(self.enemy);
  20
  21         // Lead?
  22         if (self.aim_flags & TFL_AIM_LEAD)
  23         {
  24                 if (self.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  25                 {
  26                         prep = pre_pos;
  27
  28                         distance = vlen(prep - self.tur_shotorg);
  29                         impact_time = distance / self.shot_speed;
  30
  31                         prep = pre_pos + (self.enemy.velocity * (impact_time + mintime));
  32
  33                         if(self.aim_flags & TFL_AIM_ZPREDICT)
  34                         if(!IS_ONGROUND(self.enemy))
  35                         if(self.enemy.movetype == MOVETYPE_WALK || self.enemy.movetype == MOVETYPE_TOSS || self.enemy.movetype == MOVETYPE_BOUNCE)
  36                         {
  37                                 float vz;
  38                                 prep_z = pre_pos_z;
  39                                 vz = self.enemy.velocity_z;
  40                                 for(i = 0; i < impact_time; i += sys_frametime)
  41                                 {
  42                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  43                                         prep_z = prep_z + vz * sys_frametime;
  44                                 }
  45                         }
  46                         pre_pos = prep;
  47                 }
  48                 else
  49                         pre_pos = pre_pos + self.enemy.velocity * mintime;
  50         }
  51
  52         if(self.aim_flags & TFL_AIM_SPLASH)
  53         {
  54                 //tracebox(pre_pos + '0 0 32',self.enemy.mins,self.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,self.enemy);
  55                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,self.enemy);
  56                 if(trace_fraction != 1.0)
  57                         pre_pos = trace_endpos;
  58         }
  59
  60         return pre_pos;
  61 }
  62
  63 float turret_targetscore_support(entity _turret,entity _target)
  64 {
  65         float score;            // Total score
  66         float s_score = 0, d_score;
  67
  68         if (_turret.enemy == _target) s_score = 1;
  69
  70         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  71
  72         score = (d_score * _turret.target_select_rangebias) +
  73                         (s_score * _turret.target_select_samebias);
  74
  75         return score;
  76 }
  77
  78 /*
  79 * Generic bias aware score system.
  80 */
  81 float turret_targetscore_generic(entity _turret, entity _target)
  82 {
  83         float d_dist;      // Defendmode Distance
  84         float score;            // Total score
  85         float d_score;    // Distance score
  86         float a_score;    // Angular score
  87         float m_score = 0;  // missile score
  88         float p_score = 0;  // player score
  89         float ikr;                // ideal kill range
  90
  91         if (_turret.tur_defend)
  92         {
  93                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
  94                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
  95                 d_score = 1 - d_dist / _turret.target_range;
  96         }
  97         else
  98         {
  99                 // Make a normlized value base on the targets distance from our optimal killzone
 100                 ikr = _turret.target_range_optimal;
 101                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 102         }
 103
 104         a_score = 1 - tvt_thadf / _turret.aim_maxrotate;
 105
 106         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 107                 m_score = 1;
 108
 109         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 110                 p_score = 1;
 111
 112         d_score = max(d_score, 0);
 113         a_score = max(a_score, 0);
 114         m_score = max(m_score, 0);
 115         p_score = max(p_score, 0);
 116
 117         score = (d_score * _turret.target_select_rangebias) +
 118                         (a_score * _turret.target_select_anglebias) +
 119                         (m_score * _turret.target_select_missilebias) +
 120                         (p_score * _turret.target_select_playerbias);
 121
 122         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 123         {
 124                 //dprint("Wtf?\n");
 125                 score *= 0.001;
 126         }
 127
 128 #ifdef TURRET_DEBUG
 129         string sd,sa,sm,sp,ss;
 130         string sdt,sat,smt,spt;
 131
 132         sd = ftos(d_score);
 133         d_score *= _turret.target_select_rangebias;
 134         sdt = ftos(d_score);
 135
 136         //sv = ftos(v_score);
 137         //v_score *= _turret.target_select_samebias;
 138         //svt = ftos(v_score);
 139
 140         sa = ftos(a_score);
 141         a_score *= _turret.target_select_anglebias;
 142         sat = ftos(a_score);
 143
 144         sm = ftos(m_score);
 145         m_score *= _turret.target_select_missilebias;
 146         smt = ftos(m_score);
 147
 148         sp = ftos(p_score);
 149         p_score *= _turret.target_select_playerbias;
 150         spt = ftos(p_score);
 151
 152
 153         ss = ftos(score);
 154         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 155         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 156         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 157         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 158         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 159         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 160
 161 #endif
 162
 163         return score;
 164 }
 165
 166 // Generic damage handling
 167 void turret_hide()
 168 {SELFPARAM();
 169         self.effects   |= EF_NODRAW;
 170         self.nextthink = time + self.respawntime - 0.2;
 171         self.think       = turret_respawn;
 172 }
 173
 174 void turret_die()
 175 {SELFPARAM();
 176         self.deadflag             = DEAD_DEAD;
 177         self.tur_head.deadflag = self.deadflag;
 178
 179 // Unsolidify and hide real parts
 180         self.solid                       = SOLID_NOT;
 181         self.tur_head.solid      = self.solid;
 182
 183         self.event_damage                 = func_null;
 184         self.takedamage                  = DAMAGE_NO;
 185
 186         self.health                      = 0;
 187
 188 // Go boom
 189         //RadiusDamage (self,self, min(self.ammo,50),min(self.ammo,50) * 0.25,250,world,min(self.ammo,50)*5,DEATH_TURRET,world);
 190
 191         Turret tur = get_turretinfo(self.m_id);
 192         if(self.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 193         {
 194                 tur.tr_death(tur, self);
 195
 196                 remove(self.tur_head);
 197                 remove(self);
 198         }
 199         else
 200         {
 201                 // Setup respawn
 202                 self.SendFlags    |= TNSF_STATUS;
 203                 self.nextthink   = time + 0.2;
 204                 self.think               = turret_hide;
 205
 206                 tur.tr_death(tur, self);
 207         }
 208 }
 209
 210 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 211 {
 212         // Enough already!
 213         if(this.deadflag == DEAD_DEAD)
 214                 return;
 215
 216         // Inactive turrets take no damage. (hm..)
 217         if(!this.active)
 218                 return;
 219
 220         if(SAME_TEAM(this, attacker))
 221         {
 222                 if(autocvar_g_friendlyfire)
 223                         damage = damage * autocvar_g_friendlyfire;
 224                 else
 225                         return;
 226         }
 227
 228         this.health -= damage;
 229
 230         // thorw head slightly off aim when hit?
 231         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 232         {
 233                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 234                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 235
 236                 this.SendFlags  |= TNSF_ANG;
 237         }
 238
 239         if (this.turret_flags & TUR_FLAG_MOVE)
 240                 this.velocity = this.velocity + vforce;
 241
 242         if (this.health <= 0)
 243         {
 244                 this.event_damage                 = func_null;
 245                 this.tur_head.event_damage = func_null;
 246                 this.takedamage                  = DAMAGE_NO;
 247                 this.nextthink = time;
 248                 this.think = turret_die;
 249         }
 250
 251         this.SendFlags  |= TNSF_STATUS;
 252 }
 253
 254 void() turret_think;
 255 void turret_respawn()
 256 {SELFPARAM();
 257         // Make sure all parts belong to the same team since
 258         // this function doubles as "teamchange" function.
 259         self.tur_head.team      = self.team;
 260         self.effects                       &= ~EF_NODRAW;
 261         self.deadflag                           = DEAD_NO;
 262         self.effects                            = EF_LOWPRECISION;
 263         self.solid                                      = SOLID_BBOX;
 264         self.takedamage                         = DAMAGE_AIM;
 265         self.event_damage                       = turret_damage;
 266         self.avelocity                          = '0 0 0';
 267         self.tur_head.avelocity         = self.avelocity;
 268         self.tur_head.angles            = self.idle_aim;
 269         self.health                                     = self.max_health;
 270         self.enemy                                      = world;
 271         self.volly_counter                      = self.shot_volly;
 272         self.ammo                                       = self.ammo_max;
 273
 274         self.nextthink = time + self.ticrate;
 275         self.think       = turret_think;
 276
 277         self.SendFlags = TNSF_FULL_UPDATE;
 278
 279         Turret tur = get_turretinfo(self.m_id);
 280         tur.tr_setup(tur, self);
 281 }
 282
 283
 284 // Main functions
 285 #define cvar_base "g_turrets_unit_"
 286 .float clientframe;
 287 void turrets_setframe(float _frame, float client_only)
 288 {SELFPARAM();
 289         if((client_only ? self.clientframe : self.frame ) != _frame)
 290         {
 291                 self.SendFlags |= TNSF_ANIM;
 292                 self.anim_start_time = time;
 293         }
 294
 295          if(client_only)
 296                 self.clientframe = _frame;
 297         else
 298                 self.frame = _frame;
 299
 300 }
 301
 302 bool turret_send(entity this, entity to, float sf)
 303 {
 304
 305         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 306         WriteByte(MSG_ENTITY, sf);
 307         if(sf & TNSF_SETUP)
 308         {
 309                 WriteByte(MSG_ENTITY, self.m_id);
 310
 311                 WriteCoord(MSG_ENTITY, self.origin_x);
 312                 WriteCoord(MSG_ENTITY, self.origin_y);
 313                 WriteCoord(MSG_ENTITY, self.origin_z);
 314
 315                 WriteAngle(MSG_ENTITY, self.angles_x);
 316                 WriteAngle(MSG_ENTITY, self.angles_y);
 317         }
 318
 319         if(sf & TNSF_ANG)
 320         {
 321                 WriteShort(MSG_ENTITY, rint(self.tur_head.angles_x));
 322                 WriteShort(MSG_ENTITY, rint(self.tur_head.angles_y));
 323         }
 324
 325         if(sf & TNSF_AVEL)
 326         {
 327                 WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_x));
 328                 WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_y));
 329         }
 330
 331         if(sf & TNSF_MOVE)
 332         {
 333                 WriteShort(MSG_ENTITY, rint(self.origin_x));
 334                 WriteShort(MSG_ENTITY, rint(self.origin_y));
 335                 WriteShort(MSG_ENTITY, rint(self.origin_z));
 336
 337                 WriteShort(MSG_ENTITY, rint(self.velocity_x));
 338                 WriteShort(MSG_ENTITY, rint(self.velocity_y));
 339                 WriteShort(MSG_ENTITY, rint(self.velocity_z));
 340
 341                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 342         }
 343
 344         if(sf & TNSF_ANIM)
 345         {
 346                 WriteCoord(MSG_ENTITY, self.anim_start_time);
 347                 WriteByte(MSG_ENTITY, self.frame);
 348         }
 349
 350         if(sf & TNSF_STATUS)
 351         {
 352                 WriteByte(MSG_ENTITY, self.team);
 353
 354                 if(self.health <= 0)
 355                         WriteByte(MSG_ENTITY, 0);
 356                 else
 357                         WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 358         }
 359
 360         return true;
 361 }
 362
 363 void load_unit_settings(entity ent, bool is_reload)
 364 {SELFPARAM();
 365         string unitname = ent.netname;
 366         string sbase;
 367
 368         if (ent == world)
 369                 return;
 370
 371         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 372         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 373         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 374         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 375         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 376         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 377         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 378
 379         sbase = strcat(cvar_base,unitname);
 380         if (is_reload)
 381         {
 382                 ent.enemy = world;
 383                 ent.tur_head.avelocity = '0 0 0';
 384
 385                 ent.tur_head.angles = '0 0 0';
 386         }
 387
 388         ent.health       = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
 389         ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
 390
 391         ent.shot_dmg             = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
 392         ent.shot_refire   = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
 393         ent.shot_radius   = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
 394         ent.shot_speed          = cvar(strcat(sbase,"_shot_speed"));
 395         ent.shot_spread   = cvar(strcat(sbase,"_shot_spread"));
 396         ent.shot_force          = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
 397         ent.shot_volly          = cvar(strcat(sbase,"_shot_volly"));
 398         ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
 399
 400         ent.target_range                 = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
 401         ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
 402         ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
 403         //ent.target_range_fire = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
 404
 405         ent.target_select_rangebias = cvar(strcat(sbase,"_target_select_rangebias"));
 406         ent.target_select_samebias  = cvar(strcat(sbase,"_target_select_samebias"));
 407         ent.target_select_anglebias = cvar(strcat(sbase,"_target_select_anglebias"));
 408         ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
 409         //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
 410
 411         ent.ammo_max     = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
 412         ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
 413
 414         ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
 415         ent.aim_speed   = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
 416         ent.aim_maxrotate  = cvar(strcat(sbase,"_aim_maxrot"));
 417         ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
 418
 419         ent.track_type          = cvar(strcat(sbase,"_track_type"));
 420         ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
 421         ent.track_accel_rotate  = cvar(strcat(sbase,"_track_accel_rot"));
 422         ent.track_blendrate  = cvar(strcat(sbase,"_track_blendrate"));
 423
 424         if(is_reload) {
 425                 Turret tur = get_turretinfo(self.m_id);
 426                 tur.tr_setup(tur, self);
 427         }
 428 }
 429
 430 void turret_projectile_explode()
 431 {SELFPARAM();
 432
 433         self.takedamage = DAMAGE_NO;
 434         self.event_damage = func_null;
 435 #ifdef TURRET_DEBUG
 436         float d;
 437         d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
 438         self.owner.tur_debug_dmg_t_h = self.owner.tur_debug_dmg_t_h + d;
 439         self.owner.tur_debug_dmg_t_f = self.owner.tur_debug_dmg_t_f + self.owner.shot_dmg;
 440 #else
 441         RadiusDamage (self, self.realowner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
 442 #endif
 443         remove(self);
 444 }
 445
 446 void turret_projectile_touch()
 447 {
 448         PROJECTILE_TOUCH;
 449         turret_projectile_explode();
 450 }
 451
 452 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 453 {
 454         this.velocity  += vforce;
 455         this.health     -= damage;
 456         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 457         if(this.health <= 0)
 458                 WITH(entity, self, this, W_PrepareExplosionByDamage(this.owner, turret_projectile_explode));
 459 }
 460
 461 entity turret_projectile(Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 462 {SELFPARAM();
 463     TC(Sound, _snd);
 464         entity proj;
 465
 466         sound (self, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 467         proj                             = spawn ();
 468         setorigin(proj, self.tur_shotorg);
 469         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 470         proj.owner                = self;
 471         proj.realowner    = self;
 472         proj.bot_dodge    = true;
 473         proj.bot_dodgerating = self.shot_dmg;
 474         proj.think                = turret_projectile_explode;
 475         proj.touch                = turret_projectile_touch;
 476         proj.nextthink    = time + 9;
 477         proj.movetype           = MOVETYPE_FLYMISSILE;
 478         proj.velocity           = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
 479         proj.flags                = FL_PROJECTILE;
 480         proj.enemy                = self.enemy;
 481         proj.totalfrags  = _death;
 482         PROJECTILE_MAKETRIGGER(proj);
 483         if(_health)
 484         {
 485                 proj.health              = _health;
 486                 proj.takedamage  = DAMAGE_YES;
 487                 proj.event_damage  = turret_projectile_damage;
 488         }
 489         else
 490                 proj.flags |= FL_NOTARGET;
 491
 492         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 493
 494         return proj;
 495 }
 496
 497 /**
 498 ** updates enemy distances, predicted impact point/time
 499 ** and updated aim<->predict impact distance.
 500 **/
 501 void turret_do_updates(entity t_turret)
 502 {SELFPARAM();
 503         vector enemy_pos;
 504
 505         setself(t_turret);
 506
 507         enemy_pos = real_origin(self.enemy);
 508
 509         turret_tag_fire_update();
 510
 511         self.tur_shotdir_updated = v_forward;
 512         self.tur_dist_enemy = vlen(self.tur_shotorg - enemy_pos);
 513         self.tur_dist_aimpos = vlen(self.tur_shotorg - self.tur_aimpos);
 514
 515         /*if((self.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (self.enemy))
 516         {
 517                 oldpos = self.enemy.origin;
 518                 setorigin(self.enemy, self.tur_aimpos);
 519                 tracebox(self.tur_shotorg, '-1 -1 -1', '1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
 520                 setorigin(self.enemy, oldpos);
 521
 522                 if(trace_ent == self.enemy)
 523                         self.tur_dist_impact_to_aimpos = 0;
 524                 else
 525                         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos);
 526         }
 527         else*/
 528                 tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
 529
 530         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos) - (vlen(self.enemy.maxs - self.enemy.mins) * 0.5);
 531         self.tur_impactent                       = trace_ent;
 532         self.tur_impacttime                     = vlen(self.tur_shotorg - trace_endpos) / self.shot_speed;
 533
 534         setself(this);
 535 }
 536
 537 /**
 538 ** Handles head rotation according to
 539 ** the units .track_type and .track_flags
 540 **/
 541 .float turret_framecounter;
 542 void turret_track()
 543 {SELFPARAM();
 544         vector target_angle; // This is where we want to aim
 545         vector move_angle;   // This is where we can aim
 546         float f_tmp;
 547         vector v1, v2;
 548         v1 = self.tur_head.angles;
 549         v2 = self.tur_head.avelocity;
 550
 551         if (self.track_flags == TFL_TRACK_NO)
 552                 return;
 553
 554         if(!self.active)
 555                 target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
 556         else if (self.enemy == world)
 557         {
 558                 if(time > self.lip)
 559                         target_angle = self.idle_aim + self.angles;
 560                 else
 561                         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 562         }
 563         else
 564         {
 565                 target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 566         }
 567
 568         self.tur_head.angles_x = anglemods(self.tur_head.angles_x);
 569         self.tur_head.angles_y = anglemods(self.tur_head.angles_y);
 570
 571         // Find the diffrence between where we currently aim and where we want to aim
 572         //move_angle = target_angle - (self.angles + self.tur_head.angles);
 573         //move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
 574
 575         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(self.angles), AnglesTransform_FromAngles(target_angle))) - self.tur_head.angles;
 576         move_angle = shortangle_vxy(move_angle, self.tur_head.angles);
 577
 578         switch(self.track_type)
 579         {
 580                 case TFL_TRACKTYPE_STEPMOTOR:
 581                         f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 582                         if (self.track_flags & TFL_TRACK_PITCH)
 583                         {
 584                                 self.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 585                                 if(self.tur_head.angles_x > self.aim_maxpitch)
 586                                         self.tur_head.angles_x = self.aim_maxpitch;
 587
 588                                 if(self.tur_head.angles_x  < -self.aim_maxpitch)
 589                                         self.tur_head.angles_x = self.aim_maxpitch;
 590                         }
 591
 592                         if (self.track_flags & TFL_TRACK_ROTATE)
 593                         {
 594                                 self.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 595                                 if(self.tur_head.angles_y > self.aim_maxrotate)
 596                                         self.tur_head.angles_y = self.aim_maxrotate;
 597
 598                                 if(self.tur_head.angles_y  < -self.aim_maxrotate)
 599                                         self.tur_head.angles_y = self.aim_maxrotate;
 600                         }
 601
 602                         // CSQC
 603                         self.SendFlags  |= TNSF_ANG;
 604
 605                         return;
 606
 607                 case TFL_TRACKTYPE_FLUIDINERTIA:
 608                         f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 609                         move_angle_x = bound(-self.aim_speed, move_angle_x * self.track_accel_pitch * f_tmp, self.aim_speed);
 610                         move_angle_y = bound(-self.aim_speed, move_angle_y * self.track_accel_rotate * f_tmp, self.aim_speed);
 611                         move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
 612                         break;
 613
 614                 case TFL_TRACKTYPE_FLUIDPRECISE:
 615
 616                         move_angle_y = bound(-self.aim_speed, move_angle_y, self.aim_speed);
 617                         move_angle_x = bound(-self.aim_speed, move_angle_x, self.aim_speed);
 618
 619                         break;
 620         }
 621
 622         //  pitch
 623         if (self.track_flags & TFL_TRACK_PITCH)
 624         {
 625                 self.tur_head.avelocity_x = move_angle_x;
 626                 if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) > self.aim_maxpitch)
 627                 {
 628                         self.tur_head.avelocity_x = 0;
 629                         self.tur_head.angles_x = self.aim_maxpitch;
 630
 631                         self.SendFlags  |= TNSF_ANG;
 632                 }
 633
 634                 if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) < -self.aim_maxpitch)
 635                 {
 636                         self.tur_head.avelocity_x = 0;
 637                         self.tur_head.angles_x = -self.aim_maxpitch;
 638
 639                         self.SendFlags  |= TNSF_ANG;
 640                 }
 641         }
 642
 643         //  rot
 644         if (self.track_flags & TFL_TRACK_ROTATE)
 645         {
 646                 self.tur_head.avelocity_y = move_angle_y;
 647
 648                 if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) > self.aim_maxrotate)
 649                 {
 650                         self.tur_head.avelocity_y = 0;
 651                         self.tur_head.angles_y = self.aim_maxrotate;
 652
 653                         self.SendFlags  |= TNSF_ANG;
 654                 }
 655
 656                 if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) < -self.aim_maxrotate)
 657                 {
 658                         self.tur_head.avelocity_y = 0;
 659                         self.tur_head.angles_y = -self.aim_maxrotate;
 660
 661                         self.SendFlags  |= TNSF_ANG;
 662                 }
 663         }
 664
 665         self.SendFlags  |= TNSF_AVEL;
 666
 667         // Force a angle update every 10'th frame
 668         self.turret_framecounter += 1;
 669         if(self.turret_framecounter >= 10)
 670         {
 671                 self.SendFlags |= TNSF_ANG;
 672                 self.turret_framecounter = 0;
 673         }
 674 }
 675
 676 /*
 677  + TFL_TARGETSELECT_NO
 678  + TFL_TARGETSELECT_LOS
 679  + TFL_TARGETSELECT_PLAYERS
 680  + TFL_TARGETSELECT_MISSILES
 681  - TFL_TARGETSELECT_TRIGGERTARGET
 682  + TFL_TARGETSELECT_ANGLELIMITS
 683  + TFL_TARGETSELECT_RANGELIMITS
 684  + TFL_TARGETSELECT_TEAMCHECK
 685  - TFL_TARGETSELECT_NOBUILTIN
 686  + TFL_TARGETSELECT_OWNTEAM
 687 */
 688
 689 /**
 690 ** Evaluate a entity for target valitity based on validate_flags
 691 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 692 **/
 693 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 694 {
 695         vector v_tmp;
 696
 697         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 698         //      return -0.5;
 699
 700         if(!e_target)
 701                 return -2;
 702
 703         if(e_target.owner == e_turret)
 704                 return -0.5;
 705
 706         if(!checkpvs(e_target.origin, e_turret))
 707                 return -1;
 708
 709         if(e_target.alpha <= 0.3)
 710                 return -1;
 711
 712         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 713                 return ret_float;
 714
 715         if (validate_flags & TFL_TARGETSELECT_NO)
 716                 return -4;
 717
 718         // If only this was used more..
 719         if (e_target.flags & FL_NOTARGET)
 720                 return -5;
 721
 722         // Cant touch this
 723         if(IS_VEHICLE(e_target))
 724         {
 725                 if (e_target.vehicle_health <= 0)
 726                         return -6;
 727         }
 728         else if (e_target.health <= 0)
 729                 return -6;
 730         else if(STAT(FROZEN, e_target) > 0)
 731                 return -6;
 732
 733         // player
 734         if (IS_CLIENT(e_target))
 735         {
 736                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 737                         return -7;
 738
 739                 if (IS_DEAD(e_target))
 740                         return -8;
 741         }
 742
 743         // enemy turrets
 744         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 745         if(e_target.owner.tur_head == e_target)
 746         if(e_target.team != e_turret.team) // Dont break support units.
 747                 return -9;
 748
 749         // Missile
 750         if (e_target.flags & FL_PROJECTILE)
 751         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 752                 return -10;
 753
 754         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 755         if(!(e_target.flags & FL_PROJECTILE))
 756                 return -10.5;
 757
 758         // Team check
 759         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 760         {
 761                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 762                 {
 763                         if (e_target.team != e_turret.team)
 764                                 return -11;
 765
 766                         if (e_turret.team != e_target.owner.team)
 767                                 return -12;
 768                 }
 769                 else
 770                 {
 771                         if (e_target.team == e_turret.team)
 772                                 return -13;
 773
 774                         if (e_turret.team == e_target.owner.team)
 775                                 return -14;
 776                 }
 777         }
 778
 779         // Range limits?
 780         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 781         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 782         {
 783                 if (tvt_dist < e_turret.target_range_min)
 784                         return -15;
 785
 786                 if (tvt_dist > e_turret.target_range)
 787                         return -16;
 788         }
 789
 790         // Can we even aim this thing?
 791         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 792         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 793         tvt_thadf = vlen(tvt_thadv);
 794         tvt_tadf = vlen(tvt_tadv);
 795
 796         /*
 797         if(validate_flags & TFL_TARGETSELECT_FOV)
 798         {
 799                 if(e_turret.target_select_fov < tvt_thadf)
 800                         return -21;
 801         }
 802         */
 803
 804         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 805         {
 806                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 807                         return -17;
 808
 809                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrotate)
 810                         return -18;
 811         }
 812
 813         // Line of sight?
 814         if (validate_flags & TFL_TARGETSELECT_LOS)
 815         {
 816                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 817
 818                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 819
 820                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 821                         return -19;
 822         }
 823
 824         if (e_target.classname == "grapplinghook")
 825                 return -20;
 826
 827         /*
 828         if (e_target.classname == "func_button")
 829                 return -21;
 830         */
 831
 832 #ifdef TURRET_DEBUG_TARGETSELECT
 833         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
 834 #endif
 835
 836         return 1;
 837 }
 838
 839 entity turret_select_target()
 840 {SELFPARAM();
 841         entity e;               // target looper entity
 842         float  score;   // target looper entity score
 843         entity e_enemy;  // currently best scoreing target
 844         float  m_score;  // currently best scoreing target's score
 845
 846         m_score = 0;
 847         if(self.enemy && self.enemy.takedamage && turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
 848         {
 849                 e_enemy = self.enemy;
 850                 m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
 851         }
 852         else
 853                 e_enemy = self.enemy = world;
 854
 855         e = findradius(self.origin, self.target_range);
 856
 857         // Nothing to aim at?
 858         if (!e)
 859                 return world;
 860
 861         while (e)
 862         {
 863                 if(e.takedamage)
 864                 {
 865                         float f = turret_validate_target(self, e, self.target_select_flags);
 866                         //dprint("F is: ", ftos(f), "\n");
 867                         if ( f > 0)
 868                         {
 869                                 score = self.turret_score_target(self,e);
 870                                 if ((score > m_score) && (score > 0))
 871                                 {
 872                                         e_enemy = e;
 873                                         m_score = score;
 874                                 }
 875                         }
 876                 }
 877                 e = e.chain;
 878         }
 879
 880         return e_enemy;
 881 }
 882
 883
 884 /*
 885  + = implemented
 886  - = not implemented
 887
 888  + TFL_FIRECHECK_NO
 889  + TFL_FIRECHECK_WORLD
 890  + TFL_FIRECHECK_DEAD
 891  + TFL_FIRECHECK_DISTANCES
 892  - TFL_FIRECHECK_LOS
 893  + TFL_FIRECHECK_AIMDIST
 894  + TFL_FIRECHECK_REALDIST
 895  - TFL_FIRECHECK_ANGLEDIST
 896  - TFL_FIRECHECK_TEAMCECK
 897  + TFL_FIRECHECK_AFF
 898  + TFL_FIRECHECK_AMMO_OWN
 899  + TFL_FIRECHECK_AMMO_OTHER
 900  + TFL_FIRECHECK_REFIRE
 901 */
 902
 903 /**
 904 ** Preforms pre-fire checks based on the uints firecheck_flags
 905 **/
 906 float turret_firecheck()
 907 {SELFPARAM();
 908         // This one just dont care =)
 909         if (self.firecheck_flags & TFL_FIRECHECK_NO)
 910                 return 1;
 911
 912         if (self.enemy == world)
 913                 return 0;
 914
 915         // Ready?
 916         if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
 917                 if (self.attack_finished_single[0] > time) return 0;
 918
 919         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 920         if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 921                 if (self.volly_counter != self.shot_volly)
 922                         if(self.ammo >= self.shot_dmg)
 923                                 return 1;
 924
 925         // Lack of zombies makes shooting dead things unnecessary :P
 926         if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
 927                 if (IS_DEAD(self.enemy))
 928                         return 0;
 929
 930         // Own ammo?
 931         if (self.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 932                 if (self.ammo < self.shot_dmg)
 933                         return 0;
 934
 935         // Other's ammo? (support-supply units)
 936         if (self.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 937                 if (self.enemy.ammo >= self.enemy.ammo_max)
 938                         return 0;
 939
 940         // Target of opertunity?
 941         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 942         {
 943                 self.enemy = self.tur_impactent;
 944                 return 1;
 945         }
 946
 947         if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 948         {
 949                 // To close?
 950                 if (self.tur_dist_aimpos < self.target_range_min)
 951                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 952                                 return 1; // Target of opertunity?
 953                         else
 954                                 return 0;
 955         }
 956
 957         // Try to avoid FF?
 958         if (self.firecheck_flags & TFL_FIRECHECK_AFF)
 959                 if (self.tur_impactent.team == self.team)
 960                         return 0;
 961
 962         // aim<->predicted impact
 963         if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 964                 if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
 965                         return 0;
 966
 967         // Volly status
 968         if (self.shot_volly > 1)
 969                 if (self.volly_counter == self.shot_volly)
 970                         if (self.ammo < (self.shot_dmg * self.shot_volly))
 971                                 return 0;
 972
 973         /*if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 974                 if(self.tur_impactent != self.enemy)
 975                         return 0;*/
 976
 977         return 1;
 978 }
 979
 980 bool turret_checkfire()
 981 {SELFPARAM();
 982         bool ret = false; // dummy
 983         if(MUTATOR_CALLHOOK(Turret_CheckFire, ret))
 984                 return ret_bool;
 985
 986         return self.turret_firecheckfunc();
 987 }
 988
 989 void turret_fire()
 990 {SELFPARAM();
 991         if (autocvar_g_turrets_nofire != 0)
 992                 return;
 993
 994         if(MUTATOR_CALLHOOK(TurretFire, self))
 995                 return;
 996
 997         Turret info = get_turretinfo(self.m_id);
 998         info.tr_attack(info, self);
 999
1000         self.attack_finished_single[0] = time + self.shot_refire;
1001         self.ammo -= self.shot_dmg;
1002         self.volly_counter = self.volly_counter - 1;
1003
1004         if (self.volly_counter <= 0)
1005         {
1006                 self.volly_counter = self.shot_volly;
1007
1008                 if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
1009                         self.enemy = world;
1010
1011                 if (self.shot_volly > 1)
1012                         self.attack_finished_single[0] = time + self.shot_volly_refire;
1013         }
1014
1015 #ifdef TURRET_DEBUG
1016         if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_debug_rvec, self.tur_impacttime + 0.25);
1017 #endif
1018 }
1019
1020 void turret_think()
1021 {SELFPARAM();
1022         self.nextthink = time + self.ticrate;
1023
1024         MUTATOR_CALLHOOK(TurretThink, self);
1025
1026 #ifdef TURRET_DEBUG
1027         if (self.tur_debug_tmr1 < time)
1028         {
1029                 if (self.enemy) paint_target (self.enemy,128,self.tur_debug_rvec,0.9);
1030                 paint_target(self,256,self.tur_debug_rvec,0.9);
1031                 self.tur_debug_tmr1 = time + 1;
1032         }
1033 #endif
1034
1035         // Handle ammo
1036         if (!(self.spawnflags & TSF_NO_AMMO_REGEN))
1037         if (self.ammo < self.ammo_max)
1038                 self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
1039
1040         // Inactive turrets needs to run the think loop,
1041         // So they can handle animation and wake up if need be.
1042         if(!self.active)
1043         {
1044                 turret_track();
1045                 return;
1046         }
1047
1048         // This is typicaly used for zaping every target in range
1049         // turret_fusionreactor uses this to recharge friendlys.
1050         if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
1051         {
1052                 // Do a self.turret_fire for every valid target.
1053                 entity e = findradius(self.origin,self.target_range);
1054                 while (e)
1055                 {
1056                         if(e.takedamage)
1057                         {
1058                                 if (turret_validate_target(self,e,self.target_validate_flags))
1059                                 {
1060                                         self.enemy = e;
1061
1062                                         turret_do_updates(self);
1063
1064                                         if (turret_checkfire())
1065                                                 turret_fire();
1066                                 }
1067                         }
1068
1069                         e = e.chain;
1070                 }
1071                 self.enemy = world;
1072         }
1073         else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
1074         {
1075                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1076
1077                 // Predict?
1078                 if(!(self.aim_flags & TFL_AIM_NO))
1079                         self.tur_aimpos = turret_aim_generic();
1080
1081                 // Turn & pitch?
1082                 if(!(self.track_flags & TFL_TRACK_NO))
1083                         turret_track();
1084
1085                 turret_do_updates(self);
1086
1087                 // Fire?
1088                 if (turret_checkfire())
1089                         turret_fire();
1090         }
1091         else
1092         {
1093                 // Special case for volly always. if it fired once it must compleate the volly.
1094                 if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1095                         if(self.volly_counter != self.shot_volly)
1096                         {
1097                                 // Predict or whatnot
1098                                 if(!(self.aim_flags & TFL_AIM_NO))
1099                                         self.tur_aimpos = turret_aim_generic();
1100
1101                                 // Turn & pitch
1102                                 if(!(self.track_flags & TFL_TRACK_NO))
1103                                         turret_track();
1104
1105                                 turret_do_updates(self);
1106
1107                                 // Fire!
1108                                 if (turret_checkfire())
1109                                         turret_fire();
1110
1111                                 Turret tur = get_turretinfo(self.m_id);
1112                                 tur.tr_think(tur, self);
1113
1114                                 return;
1115                         }
1116
1117                 // Check if we have a vailid enemy, and try to find one if we dont.
1118
1119                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1120                 float do_target_scan = 0;
1121                 if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1122                         do_target_scan = 1;
1123
1124                 // Old target (if any) invalid?
1125                 if(self.target_validate_time < time)
1126                 if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
1127                 {
1128                         self.enemy = world;
1129                         self.target_validate_time = time + 0.5;
1130                         do_target_scan = 1;
1131                 }
1132
1133                 // But never more often then g_turrets_targetscan_mindelay!
1134                 if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1135                         do_target_scan = 0;
1136
1137                 if(do_target_scan)
1138                 {
1139                         self.enemy = turret_select_target();
1140                         self.target_select_time = time;
1141                 }
1142
1143                 // No target, just go to idle, do any custom stuff and bail.
1144                 if (self.enemy == world)
1145                 {
1146                         // Turn & pitch
1147                         if(!(self.track_flags & TFL_TRACK_NO))
1148                                 turret_track();
1149
1150                         Turret tur = get_turretinfo(self.m_id);
1151                         tur.tr_think(tur, self);
1152
1153                         // And bail.
1154                         return;
1155                 }
1156                 else
1157                         self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1158
1159                 // Predict?
1160                 if(!(self.aim_flags & TFL_AIM_NO))
1161                         self.tur_aimpos = turret_aim_generic();
1162
1163                 // Turn & pitch?
1164                 if(!(self.track_flags & TFL_TRACK_NO))
1165                         turret_track();
1166
1167                 turret_do_updates(self);
1168
1169                 // Fire?
1170                 if (turret_checkfire())
1171                         turret_fire();
1172         }
1173
1174         Turret tur = get_turretinfo(self.m_id);
1175         tur.tr_think(tur, self);
1176 }
1177
1178 /*
1179         When .used a turret switch team to activator.team.
1180         If activator is world, the turret go inactive.
1181 */
1182 void turret_use()
1183 {SELFPARAM();
1184         LOG_TRACE("Turret ",self.netname, " used by ", activator.classname, "\n");
1185
1186         self.team = activator.team;
1187
1188         if(self.team == 0)
1189                 self.active = ACTIVE_NOT;
1190         else
1191                 self.active = ACTIVE_ACTIVE;
1192
1193 }
1194
1195 void turret_link()
1196 {SELFPARAM();
1197         Net_LinkEntity(self, true, 0, turret_send);
1198         self.think       = turret_think;
1199         self.nextthink = time;
1200         self.tur_head.effects = EF_NODRAW;
1201 }
1202
1203 void turrets_manager_think()
1204 {
1205         SELFPARAM();
1206         this.nextthink = time + 1;
1207
1208         if (autocvar_g_turrets_reloadcvars == 1)
1209         {
1210                 FOREACH_ENTITY(IS_TURRET(it), {
1211                         load_unit_settings(it, true);
1212                         Turret tur = get_turretinfo(it.m_id);
1213                         tur.tr_think(tur, it);
1214                 });
1215                 cvar_set("g_turrets_reloadcvars", "0");
1216         }
1217 }
1218
1219 void turret_initparams(entity tur)
1220 {
1221         #define TRY(x) (x) ? (x)
1222         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1223         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1224         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1225         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1226         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1227         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1228         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1229         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1230         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1231         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), MAX_SHOT_DISTANCE);
1232         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), MAX_SHOT_DISTANCE);
1233         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), MAX_SHOT_DISTANCE);
1234         tur.aim_maxrotate               = bound(0,               (TRY(tur.aim_maxrotate)             :  90                                         ), 360);
1235         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1236         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1237         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), MAX_SHOT_DISTANCE);
1238         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1239         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1240         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1241         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1242         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1243         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1244         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1245         #undef TRY
1246 }
1247
1248 float turret_initialize(Turret tur)
1249 {SELFPARAM();
1250         if(!autocvar_g_turrets)
1251                 return false;
1252
1253         if(tur.m_id == 0)
1254                 return false; // invalid turret
1255
1256         // if tur_head exists, we can assume this turret re-spawned
1257         if(!self.tur_head) {
1258                 tur.tr_precache(tur);
1259         }
1260
1261         entity e = find(world, classname, "turret_manager");
1262         if(!e)
1263         {
1264                 e = new(turret_manager);
1265                 e.think = turrets_manager_think;
1266                 e.nextthink = time + 2;
1267         }
1268
1269         if(!(self.spawnflags & TSF_SUSPENDED))
1270                 builtin_droptofloor();
1271
1272         self.netname = tur.netname;
1273         load_unit_settings(self, 0);
1274
1275         if(!self.team || !teamplay)             { self.team = MAX_SHOT_DISTANCE; }
1276         if(!self.ticrate)                               { self.ticrate = ((self.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1277         if(!self.health)                                { self.health = 1000; }
1278         if(!self.shot_refire)                   { self.shot_refire = 1; }
1279         if(!self.tur_shotorg)                   { self.tur_shotorg = '50 0 50'; }
1280         if(!self.turret_flags)                  { self.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1281         if(!self.damage_flags)                  { self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1282         if(!self.aim_flags)                             { self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1283         if(!self.track_type)                    { self.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1284         if(!self.track_flags)                   { self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1285         if(!self.ammo_flags)                    { self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1286         if(!self.target_select_flags)   { self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1287         if(!self.firecheck_flags)               { self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1288                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1289
1290         if(self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1291         {
1292                 // Fluid / Ineria mode. Looks mutch nicer.
1293                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1294
1295                 self.aim_speed = bound(0.1, ((!self.aim_speed) ? 180 : self.aim_speed), 1000);
1296
1297                 if(!self.track_accel_pitch)             { self.track_accel_pitch = 0.5; }
1298                 if(!self.track_accel_rotate)    { self.track_accel_rotate = 0.5; }
1299                 if(!self.track_blendrate)               { self.track_blendrate = 0.35; }
1300         }
1301
1302         turret_initparams(self);
1303
1304         self.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1305
1306         if(self.turret_flags & TUR_FLAG_SPLASH)
1307                 self.aim_flags |= TFL_AIM_SPLASH;
1308
1309         if(self.turret_flags & TUR_FLAG_MISSILE)
1310                 self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1311
1312         if(self.turret_flags & TUR_FLAG_PLAYER)
1313                 self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1314
1315         if(self.spawnflags & TSL_NO_RESPAWN)
1316                 self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1317
1318         if (self.turret_flags & TUR_FLAG_SUPPORT)
1319                 self.turret_score_target = turret_targetscore_support;
1320         else
1321                 self.turret_score_target = turret_targetscore_generic;
1322
1323         ++turret_count;
1324
1325         _setmodel(self, tur.model);
1326         setsize(self, tur.mins, tur.maxs);
1327
1328         self.m_id                                       = tur.m_id;
1329         self.classname                          = "turret_main";
1330         self.active                                     = ACTIVE_ACTIVE;
1331         self.effects                            = EF_NODRAW;
1332         self.netname                            = tur.turret_name;
1333         self.ticrate                            = bound(sys_frametime, self.ticrate, 60);
1334         self.max_health                         = self.health;
1335         self.target_validate_flags      = self.target_select_flags;
1336         self.ammo                                       = self.ammo_max;
1337         self.ammo_recharge                 *= self.ticrate;
1338         self.solid                                      = SOLID_BBOX;
1339         self.takedamage                         = DAMAGE_AIM;
1340         self.movetype                           = MOVETYPE_NOCLIP;
1341         self.view_ofs                           = '0 0 0';
1342         self.turret_firecheckfunc       = turret_firecheck;
1343         self.event_damage                       = turret_damage;
1344         self.use                                        = turret_use;
1345         self.bot_attack                         = true;
1346         self.nextthink                          = time + 1;
1347         self.nextthink                     += turret_count * sys_frametime;
1348
1349         self.tur_head = new(turret_head);
1350         _setmodel(self.tur_head, tur.head_model);
1351         setsize(self.tur_head, '0 0 0', '0 0 0');
1352         setorigin(self.tur_head, '0 0 0');
1353         setattachment(self.tur_head, self, "tag_head");
1354
1355         self.tur_head.netname           = self.tur_head.classname;
1356         self.tur_head.team                      = self.team;
1357         self.tur_head.owner                     = self;
1358         self.tur_head.takedamage        = DAMAGE_NO;
1359         self.tur_head.solid                     = SOLID_NOT;
1360         self.tur_head.movetype          = self.movetype;
1361
1362         if(!self.tur_defend)
1363         if(self.target != "")
1364         {
1365                 self.tur_defend = find(world, targetname, self.target);
1366                 if (self.tur_defend == world)
1367                 {
1368                         self.target = "";
1369                         LOG_TRACE("Turret has invalid defendpoint!\n");
1370                 }
1371         }
1372
1373         if (self.tur_defend)
1374                 self.idle_aim = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1375         else
1376                 self.idle_aim = '0 0 0';
1377
1378 #ifdef TURRET_DEBUG
1379         self.tur_debug_start = self.nextthink;
1380         while(vdist(self.tur_debug_rvec, <, 2))
1381                 self.tur_debug_rvec = randomvec() * 4;
1382
1383         self.tur_debug_rvec_x = fabs(self.tur_debug_rvec_x);
1384         self.tur_debug_rvec_y = fabs(self.tur_debug_rvec_y);
1385         self.tur_debug_rvec_z = fabs(self.tur_debug_rvec_z);
1386 #endif
1387
1388         turret_link();
1389         turret_respawn();
1390         turret_tag_fire_update();
1391
1392         tur.tr_setup(tur, self);
1393
1394         if(MUTATOR_CALLHOOK(TurretSpawn, self))
1395                 return false;
1396
1397         return true;
1398 }
1399 #endif