qcsrc/common/turrets/sv_turrets.qc

   1 #ifdef SVQC
   2 #include "../../server/autocvars.qh"
   3
   4 // Generic aiming
   5 vector turret_aim_generic()
   6 {SELFPARAM();
   7
   8         vector pre_pos, prep;
   9         float distance, impact_time = 0, i, mintime;
  10
  11         turret_tag_fire_update();
  12
  13         if(self.aim_flags & TFL_AIM_SIMPLE)
  14                 return real_origin(self.enemy);
  15
  16         mintime = max(self.attack_finished_single - time,0) + sys_frametime;
  17
  18         // Baseline
  19         pre_pos = real_origin(self.enemy);
  20
  21         // Lead?
  22         if (self.aim_flags & TFL_AIM_LEAD)
  23         {
  24                 if (self.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  25                 {
  26                         prep = pre_pos;
  27
  28                         distance = vlen(prep - self.tur_shotorg);
  29                         impact_time = distance / self.shot_speed;
  30
  31                         prep = pre_pos + (self.enemy.velocity * (impact_time + mintime));
  32
  33                         if(self.aim_flags & TFL_AIM_ZPREDICT)
  34                         if(!(self.enemy.flags & FL_ONGROUND))
  35                         if(self.enemy.movetype == MOVETYPE_WALK || self.enemy.movetype == MOVETYPE_TOSS || self.enemy.movetype == MOVETYPE_BOUNCE)
  36                         {
  37                                 float vz;
  38                                 prep_z = pre_pos_z;
  39                                 vz = self.enemy.velocity_z;
  40                                 for(i = 0; i < impact_time; i += sys_frametime)
  41                                 {
  42                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  43                                         prep_z = prep_z + vz * sys_frametime;
  44                                 }
  45                         }
  46                         pre_pos = prep;
  47                 }
  48                 else
  49                         pre_pos = pre_pos + self.enemy.velocity * mintime;
  50         }
  51
  52         if(self.aim_flags & TFL_AIM_SPLASH)
  53         {
  54                 //tracebox(pre_pos + '0 0 32',self.enemy.mins,self.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,self.enemy);
  55                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,self.enemy);
  56                 if(trace_fraction != 1.0)
  57                         pre_pos = trace_endpos;
  58         }
  59
  60         return pre_pos;
  61 }
  62
  63 float turret_targetscore_support(entity _turret,entity _target)
  64 {
  65         float score;            // Total score
  66         float s_score = 0, d_score;
  67
  68         if (_turret.enemy == _target) s_score = 1;
  69
  70         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  71
  72         score = (d_score * _turret.target_select_rangebias) +
  73                         (s_score * _turret.target_select_samebias);
  74
  75         return score;
  76 }
  77
  78 /*
  79 * Generic bias aware score system.
  80 */
  81 float turret_targetscore_generic(entity _turret, entity _target)
  82 {
  83         float d_dist;      // Defendmode Distance
  84         float score;            // Total score
  85         float d_score;    // Distance score
  86         float a_score;    // Angular score
  87         float m_score = 0;  // missile score
  88         float p_score = 0;  // player score
  89         float ikr;                // ideal kill range
  90
  91         if (_turret.tur_defend)
  92         {
  93                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
  94                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
  95                 d_score = 1 - d_dist / _turret.target_range;
  96         }
  97         else
  98         {
  99                 // Make a normlized value base on the targets distance from our optimal killzone
 100                 ikr = _turret.target_range_optimal;
 101                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 102         }
 103
 104         a_score = 1 - tvt_thadf / _turret.aim_maxrotate;
 105
 106         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 107                 m_score = 1;
 108
 109         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 110                 p_score = 1;
 111
 112         d_score = max(d_score, 0);
 113         a_score = max(a_score, 0);
 114         m_score = max(m_score, 0);
 115         p_score = max(p_score, 0);
 116
 117         score = (d_score * _turret.target_select_rangebias) +
 118                         (a_score * _turret.target_select_anglebias) +
 119                         (m_score * _turret.target_select_missilebias) +
 120                         (p_score * _turret.target_select_playerbias);
 121
 122         if(_turret.target_range < vlen(_turret.tur_shotorg - real_origin(_target)))
 123         {
 124                 //dprint("Wtf?\n");
 125                 score *= 0.001;
 126         }
 127
 128 #ifdef TURRET_DEBUG
 129         string sd,sa,sm,sp,ss;
 130         string sdt,sat,smt,spt;
 131
 132         sd = ftos(d_score);
 133         d_score *= _turret.target_select_rangebias;
 134         sdt = ftos(d_score);
 135
 136         //sv = ftos(v_score);
 137         //v_score *= _turret.target_select_samebias;
 138         //svt = ftos(v_score);
 139
 140         sa = ftos(a_score);
 141         a_score *= _turret.target_select_anglebias;
 142         sat = ftos(a_score);
 143
 144         sm = ftos(m_score);
 145         m_score *= _turret.target_select_missilebias;
 146         smt = ftos(m_score);
 147
 148         sp = ftos(p_score);
 149         p_score *= _turret.target_select_playerbias;
 150         spt = ftos(p_score);
 151
 152
 153         ss = ftos(score);
 154         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 155         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 156         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 157         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 158         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 159         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 160
 161 #endif
 162
 163         return score;
 164 }
 165
 166 // Generic damage handling
 167 void turret_hide()
 168 {SELFPARAM();
 169         self.effects   |= EF_NODRAW;
 170         self.nextthink = time + self.respawntime - 0.2;
 171         self.think       = turret_respawn;
 172 }
 173
 174 void turret_die()
 175 {SELFPARAM();
 176         self.deadflag             = DEAD_DEAD;
 177         self.tur_head.deadflag = self.deadflag;
 178
 179 // Unsolidify and hide real parts
 180         self.solid                       = SOLID_NOT;
 181         self.tur_head.solid      = self.solid;
 182
 183         self.event_damage                 = func_null;
 184         self.takedamage                  = DAMAGE_NO;
 185
 186         self.health                      = 0;
 187
 188 // Go boom
 189         //RadiusDamage (self,self, min(self.ammo,50),min(self.ammo,50) * 0.25,250,world,min(self.ammo,50)*5,DEATH_TURRET,world);
 190
 191         Turret tur = get_turretinfo(self.m_id);
 192         if(self.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 193         {
 194                 tur.tr_death(tur, self);
 195
 196                 remove(self.tur_head);
 197                 remove(self);
 198         }
 199         else
 200         {
 201                 // Setup respawn
 202                 self.SendFlags    |= TNSF_STATUS;
 203                 self.nextthink   = time + 0.2;
 204                 self.think               = turret_hide;
 205
 206                 tur.tr_death(tur, self);
 207         }
 208 }
 209
 210 void turret_damage (entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 211 {SELFPARAM();
 212         // Enough already!
 213         if(self.deadflag == DEAD_DEAD)
 214                 return;
 215
 216         // Inactive turrets take no damage. (hm..)
 217         if(!self.active)
 218                 return;
 219
 220         if(SAME_TEAM(self, attacker))
 221         {
 222                 if(autocvar_g_friendlyfire)
 223                         damage = damage * autocvar_g_friendlyfire;
 224                 else
 225                         return;
 226         }
 227
 228         self.health -= damage;
 229
 230         // thorw head slightly off aim when hit?
 231         if (self.damage_flags & TFL_DMG_HEADSHAKE)
 232         {
 233                 self.tur_head.angles_x = self.tur_head.angles_x + (-0.5 + random()) * damage;
 234                 self.tur_head.angles_y = self.tur_head.angles_y + (-0.5 + random()) * damage;
 235
 236                 self.SendFlags  |= TNSF_ANG;
 237         }
 238
 239         if (self.turret_flags & TUR_FLAG_MOVE)
 240                 self.velocity = self.velocity + vforce;
 241
 242         if (self.health <= 0)
 243         {
 244                 self.event_damage                 = func_null;
 245                 self.tur_head.event_damage = func_null;
 246                 self.takedamage                  = DAMAGE_NO;
 247                 self.nextthink = time;
 248                 self.think = turret_die;
 249         }
 250
 251         self.SendFlags  |= TNSF_STATUS;
 252 }
 253
 254 void() turret_think;
 255 void turret_respawn()
 256 {SELFPARAM();
 257         // Make sure all parts belong to the same team since
 258         // this function doubles as "teamchange" function.
 259         self.tur_head.team      = self.team;
 260         self.effects                       &= ~EF_NODRAW;
 261         self.deadflag                           = DEAD_NO;
 262         self.effects                            = EF_LOWPRECISION;
 263         self.solid                                      = SOLID_BBOX;
 264         self.takedamage                         = DAMAGE_AIM;
 265         self.event_damage                       = turret_damage;
 266         self.avelocity                          = '0 0 0';
 267         self.tur_head.avelocity         = self.avelocity;
 268         self.tur_head.angles            = self.idle_aim;
 269         self.health                                     = self.max_health;
 270         self.enemy                                      = world;
 271         self.volly_counter                      = self.shot_volly;
 272         self.ammo                                       = self.ammo_max;
 273
 274         self.nextthink = time + self.ticrate;
 275         self.think       = turret_think;
 276
 277         self.SendFlags = TNSF_FULL_UPDATE;
 278
 279         Turret tur = get_turretinfo(self.m_id);
 280         tur.tr_setup(tur, self);
 281 }
 282
 283
 284 // Main functions
 285 #define cvar_base "g_turrets_unit_"
 286 .float clientframe;
 287 void turrets_setframe(float _frame, float client_only)
 288 {SELFPARAM();
 289         if((client_only ? self.clientframe : self.frame ) != _frame)
 290         {
 291                 self.SendFlags |= TNSF_ANIM;
 292                 self.anim_start_time = time;
 293         }
 294
 295          if(client_only)
 296                 self.clientframe = _frame;
 297         else
 298                 self.frame = _frame;
 299
 300 }
 301
 302 bool turret_send(entity this, entity to, float sf)
 303 {
 304
 305         WriteByte(MSG_ENTITY, ENT_CLIENT_TURRET);
 306         WriteByte(MSG_ENTITY, sf);
 307         if(sf & TNSF_SETUP)
 308         {
 309                 WriteByte(MSG_ENTITY, self.m_id);
 310
 311                 WriteCoord(MSG_ENTITY, self.origin_x);
 312                 WriteCoord(MSG_ENTITY, self.origin_y);
 313                 WriteCoord(MSG_ENTITY, self.origin_z);
 314
 315                 WriteAngle(MSG_ENTITY, self.angles_x);
 316                 WriteAngle(MSG_ENTITY, self.angles_y);
 317         }
 318
 319         if(sf & TNSF_ANG)
 320         {
 321                 WriteShort(MSG_ENTITY, rint(self.tur_head.angles_x));
 322                 WriteShort(MSG_ENTITY, rint(self.tur_head.angles_y));
 323         }
 324
 325         if(sf & TNSF_AVEL)
 326         {
 327                 WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_x));
 328                 WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_y));
 329         }
 330
 331         if(sf & TNSF_MOVE)
 332         {
 333                 WriteShort(MSG_ENTITY, rint(self.origin_x));
 334                 WriteShort(MSG_ENTITY, rint(self.origin_y));
 335                 WriteShort(MSG_ENTITY, rint(self.origin_z));
 336
 337                 WriteShort(MSG_ENTITY, rint(self.velocity_x));
 338                 WriteShort(MSG_ENTITY, rint(self.velocity_y));
 339                 WriteShort(MSG_ENTITY, rint(self.velocity_z));
 340
 341                 WriteShort(MSG_ENTITY, rint(self.angles_y));
 342         }
 343
 344         if(sf & TNSF_ANIM)
 345         {
 346                 WriteCoord(MSG_ENTITY, self.anim_start_time);
 347                 WriteByte(MSG_ENTITY, self.frame);
 348         }
 349
 350         if(sf & TNSF_STATUS)
 351         {
 352                 WriteByte(MSG_ENTITY, self.team);
 353
 354                 if(self.health <= 0)
 355                         WriteByte(MSG_ENTITY, 0);
 356                 else
 357                         WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 358         }
 359
 360         return true;
 361 }
 362
 363 void load_unit_settings(entity ent, float is_reload)
 364 {SELFPARAM();
 365         string unitname = ent.netname;
 366         string sbase;
 367
 368         if (ent == world)
 369                 return;
 370
 371         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 372         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 373         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 374         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 375         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 376         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 377         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 378
 379         sbase = strcat(cvar_base,unitname);
 380         if (is_reload)
 381         {
 382                 ent.enemy = world;
 383                 ent.tur_head.avelocity = '0 0 0';
 384
 385                 ent.tur_head.angles = '0 0 0';
 386         }
 387
 388         ent.health       = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
 389         ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
 390
 391         ent.shot_dmg             = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
 392         ent.shot_refire   = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
 393         ent.shot_radius   = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
 394         ent.shot_speed          = cvar(strcat(sbase,"_shot_speed"));
 395         ent.shot_spread   = cvar(strcat(sbase,"_shot_spread"));
 396         ent.shot_force          = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
 397         ent.shot_volly          = cvar(strcat(sbase,"_shot_volly"));
 398         ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
 399
 400         ent.target_range                 = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
 401         ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
 402         ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
 403         //ent.target_range_fire = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
 404
 405         ent.target_select_rangebias = cvar(strcat(sbase,"_target_select_rangebias"));
 406         ent.target_select_samebias  = cvar(strcat(sbase,"_target_select_samebias"));
 407         ent.target_select_anglebias = cvar(strcat(sbase,"_target_select_anglebias"));
 408         ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
 409         //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
 410
 411         ent.ammo_max     = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
 412         ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
 413
 414         ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
 415         ent.aim_speed   = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
 416         ent.aim_maxrotate  = cvar(strcat(sbase,"_aim_maxrot"));
 417         ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
 418
 419         ent.track_type          = cvar(strcat(sbase,"_track_type"));
 420         ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
 421         ent.track_accel_rotate  = cvar(strcat(sbase,"_track_accel_rot"));
 422         ent.track_blendrate  = cvar(strcat(sbase,"_track_blendrate"));
 423
 424         if(is_reload) {
 425                 Turret tur = get_turretinfo(self.m_id);
 426                 tur.tr_setup(tur, self);
 427         }
 428 }
 429
 430 void turret_projectile_explode()
 431 {SELFPARAM();
 432
 433         self.takedamage = DAMAGE_NO;
 434         self.event_damage = func_null;
 435 #ifdef TURRET_DEBUG
 436         float d;
 437         d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
 438         self.owner.tur_debug_dmg_t_h = self.owner.tur_debug_dmg_t_h + d;
 439         self.owner.tur_debug_dmg_t_f = self.owner.tur_debug_dmg_t_f + self.owner.shot_dmg;
 440 #else
 441         RadiusDamage (self, self.realowner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, world, self.owner.shot_force, self.totalfrags, world);
 442 #endif
 443         remove(self);
 444 }
 445
 446 void turret_projectile_touch()
 447 {
 448         PROJECTILE_TOUCH;
 449         turret_projectile_explode();
 450 }
 451
 452 void turret_projectile_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 453 {SELFPARAM();
 454         self.velocity  += vforce;
 455         self.health     -= damage;
 456         //self.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 457         if(self.health <= 0)
 458                 W_PrepareExplosionByDamage(self.owner, turret_projectile_explode);
 459 }
 460
 461 entity turret_projectile(string _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 462 {SELFPARAM();
 463         entity proj;
 464
 465         _sound (self, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 466         proj                             = spawn ();
 467         setorigin(proj, self.tur_shotorg);
 468         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 469         proj.owner                = self;
 470         proj.realowner    = self;
 471         proj.bot_dodge    = true;
 472         proj.bot_dodgerating = self.shot_dmg;
 473         proj.think                = turret_projectile_explode;
 474         proj.touch                = turret_projectile_touch;
 475         proj.nextthink    = time + 9;
 476         proj.movetype           = MOVETYPE_FLYMISSILE;
 477         proj.velocity           = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
 478         proj.flags                = FL_PROJECTILE;
 479         proj.enemy                = self.enemy;
 480         proj.totalfrags  = _death;
 481         PROJECTILE_MAKETRIGGER(proj);
 482         if(_health)
 483         {
 484                 proj.health              = _health;
 485                 proj.takedamage  = DAMAGE_YES;
 486                 proj.event_damage  = turret_projectile_damage;
 487         }
 488         else
 489                 proj.flags |= FL_NOTARGET;
 490
 491         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 492
 493         return proj;
 494 }
 495
 496 /**
 497 ** updates enemy distances, predicted impact point/time
 498 ** and updated aim<->predict impact distance.
 499 **/
 500 void turret_do_updates(entity t_turret)
 501 {SELFPARAM();
 502         vector enemy_pos;
 503
 504         setself(t_turret);
 505
 506         enemy_pos = real_origin(self.enemy);
 507
 508         turret_tag_fire_update();
 509
 510         self.tur_shotdir_updated = v_forward;
 511         self.tur_dist_enemy = vlen(self.tur_shotorg - enemy_pos);
 512         self.tur_dist_aimpos = vlen(self.tur_shotorg - self.tur_aimpos);
 513
 514         /*if((self.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (self.enemy))
 515         {
 516                 oldpos = self.enemy.origin;
 517                 setorigin(self.enemy, self.tur_aimpos);
 518                 tracebox(self.tur_shotorg, '-1 -1 -1', '1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
 519                 setorigin(self.enemy, oldpos);
 520
 521                 if(trace_ent == self.enemy)
 522                         self.tur_dist_impact_to_aimpos = 0;
 523                 else
 524                         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos);
 525         }
 526         else*/
 527                 tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
 528
 529         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos) - (vlen(self.enemy.maxs - self.enemy.mins) * 0.5);
 530         self.tur_impactent                       = trace_ent;
 531         self.tur_impacttime                     = vlen(self.tur_shotorg - trace_endpos) / self.shot_speed;
 532
 533         setself(this);
 534 }
 535
 536 /**
 537 ** Handles head rotation according to
 538 ** the units .track_type and .track_flags
 539 **/
 540 .float turret_framecounter;
 541 void turret_track()
 542 {SELFPARAM();
 543         vector target_angle; // This is where we want to aim
 544         vector move_angle;   // This is where we can aim
 545         float f_tmp;
 546         vector v1, v2;
 547         v1 = self.tur_head.angles;
 548         v2 = self.tur_head.avelocity;
 549
 550         if (self.track_flags == TFL_TRACK_NO)
 551                 return;
 552
 553         if(!self.active)
 554                 target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
 555         else if (self.enemy == world)
 556         {
 557                 if(time > self.lip)
 558                         target_angle = self.idle_aim + self.angles;
 559                 else
 560                         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 561         }
 562         else
 563         {
 564                 target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 565         }
 566
 567         self.tur_head.angles_x = anglemods(self.tur_head.angles_x);
 568         self.tur_head.angles_y = anglemods(self.tur_head.angles_y);
 569
 570         // Find the diffrence between where we currently aim and where we want to aim
 571         //move_angle = target_angle - (self.angles + self.tur_head.angles);
 572         //move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
 573
 574         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(self.angles), AnglesTransform_FromAngles(target_angle))) - self.tur_head.angles;
 575         move_angle = shortangle_vxy(move_angle, self.tur_head.angles);
 576
 577         switch(self.track_type)
 578         {
 579                 case TFL_TRACKTYPE_STEPMOTOR:
 580                         f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 581                         if (self.track_flags & TFL_TRACK_PITCH)
 582                         {
 583                                 self.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 584                                 if(self.tur_head.angles_x > self.aim_maxpitch)
 585                                         self.tur_head.angles_x = self.aim_maxpitch;
 586
 587                                 if(self.tur_head.angles_x  < -self.aim_maxpitch)
 588                                         self.tur_head.angles_x = self.aim_maxpitch;
 589                         }
 590
 591                         if (self.track_flags & TFL_TRACK_ROTATE)
 592                         {
 593                                 self.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 594                                 if(self.tur_head.angles_y > self.aim_maxrotate)
 595                                         self.tur_head.angles_y = self.aim_maxrotate;
 596
 597                                 if(self.tur_head.angles_y  < -self.aim_maxrotate)
 598                                         self.tur_head.angles_y = self.aim_maxrotate;
 599                         }
 600
 601                         // CSQC
 602                         self.SendFlags  |= TNSF_ANG;
 603
 604                         return;
 605
 606                 case TFL_TRACKTYPE_FLUIDINERTIA:
 607                         f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 608                         move_angle_x = bound(-self.aim_speed, move_angle_x * self.track_accel_pitch * f_tmp, self.aim_speed);
 609                         move_angle_y = bound(-self.aim_speed, move_angle_y * self.track_accel_rotate * f_tmp, self.aim_speed);
 610                         move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
 611                         break;
 612
 613                 case TFL_TRACKTYPE_FLUIDPRECISE:
 614
 615                         move_angle_y = bound(-self.aim_speed, move_angle_y, self.aim_speed);
 616                         move_angle_x = bound(-self.aim_speed, move_angle_x, self.aim_speed);
 617
 618                         break;
 619         }
 620
 621         //  pitch
 622         if (self.track_flags & TFL_TRACK_PITCH)
 623         {
 624                 self.tur_head.avelocity_x = move_angle_x;
 625                 if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) > self.aim_maxpitch)
 626                 {
 627                         self.tur_head.avelocity_x = 0;
 628                         self.tur_head.angles_x = self.aim_maxpitch;
 629
 630                         self.SendFlags  |= TNSF_ANG;
 631                 }
 632
 633                 if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) < -self.aim_maxpitch)
 634                 {
 635                         self.tur_head.avelocity_x = 0;
 636                         self.tur_head.angles_x = -self.aim_maxpitch;
 637
 638                         self.SendFlags  |= TNSF_ANG;
 639                 }
 640         }
 641
 642         //  rot
 643         if (self.track_flags & TFL_TRACK_ROTATE)
 644         {
 645                 self.tur_head.avelocity_y = move_angle_y;
 646
 647                 if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) > self.aim_maxrotate)
 648                 {
 649                         self.tur_head.avelocity_y = 0;
 650                         self.tur_head.angles_y = self.aim_maxrotate;
 651
 652                         self.SendFlags  |= TNSF_ANG;
 653                 }
 654
 655                 if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) < -self.aim_maxrotate)
 656                 {
 657                         self.tur_head.avelocity_y = 0;
 658                         self.tur_head.angles_y = -self.aim_maxrotate;
 659
 660                         self.SendFlags  |= TNSF_ANG;
 661                 }
 662         }
 663
 664         self.SendFlags  |= TNSF_AVEL;
 665
 666         // Force a angle update every 10'th frame
 667         self.turret_framecounter += 1;
 668         if(self.turret_framecounter >= 10)
 669         {
 670                 self.SendFlags |= TNSF_ANG;
 671                 self.turret_framecounter = 0;
 672         }
 673 }
 674
 675 /*
 676  + TFL_TARGETSELECT_NO
 677  + TFL_TARGETSELECT_LOS
 678  + TFL_TARGETSELECT_PLAYERS
 679  + TFL_TARGETSELECT_MISSILES
 680  - TFL_TARGETSELECT_TRIGGERTARGET
 681  + TFL_TARGETSELECT_ANGLELIMITS
 682  + TFL_TARGETSELECT_RANGELIMITS
 683  + TFL_TARGETSELECT_TEAMCHECK
 684  - TFL_TARGETSELECT_NOBUILTIN
 685  + TFL_TARGETSELECT_OWNTEAM
 686 */
 687
 688 /**
 689 ** Evaluate a entity for target valitity based on validate_flags
 690 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 691 **/
 692 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 693 {
 694         vector v_tmp;
 695
 696         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 697         //      return -0.5;
 698
 699         if(!e_target)
 700                 return -2;
 701
 702         if(e_target.owner == e_turret)
 703                 return -0.5;
 704
 705         if(!checkpvs(e_target.origin, e_turret))
 706                 return -1;
 707
 708         if(e_target.alpha <= 0.3)
 709                 return -1;
 710
 711         if(g_onslaught)
 712                 if (substring(e_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
 713                         return - 3;
 714
 715         if (validate_flags & TFL_TARGETSELECT_NO)
 716                 return -4;
 717
 718         // If only this was used more..
 719         if (e_target.flags & FL_NOTARGET)
 720                 return -5;
 721
 722         // Cant touch this
 723         if(IS_VEHICLE(e_target))
 724         {
 725                 if (e_target.vehicle_health <= 0)
 726                         return -6;
 727         }
 728         else if (e_target.health <= 0)
 729                 return -6;
 730         else if(e_target.frozen > 0)
 731                 return -6;
 732
 733         // player
 734         if (IS_CLIENT(e_target))
 735         {
 736                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 737                         return -7;
 738
 739                 if (e_target.deadflag != DEAD_NO)
 740                         return -8;
 741         }
 742
 743         // enemy turrets
 744         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 745         if(e_target.owner.tur_head == e_target)
 746         if(e_target.team != e_turret.team) // Dont break support units.
 747                 return -9;
 748
 749         // Missile
 750         if (e_target.flags & FL_PROJECTILE)
 751         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 752                 return -10;
 753
 754         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 755         if(!(e_target.flags & FL_PROJECTILE))
 756                 return -10.5;
 757
 758         // Team check
 759         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 760         {
 761                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 762                 {
 763                         if (e_target.team != e_turret.team)
 764                                 return -11;
 765
 766                         if (e_turret.team != e_target.owner.team)
 767                                 return -12;
 768                 }
 769                 else
 770                 {
 771                         if (e_target.team == e_turret.team)
 772                                 return -13;
 773
 774                         if (e_turret.team == e_target.owner.team)
 775                                 return -14;
 776                 }
 777         }
 778
 779         // Range limits?
 780         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 781         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 782         {
 783                 if (tvt_dist < e_turret.target_range_min)
 784                         return -15;
 785
 786                 if (tvt_dist > e_turret.target_range)
 787                         return -16;
 788         }
 789
 790         // Can we even aim this thing?
 791         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 792         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 793         tvt_thadf = vlen(tvt_thadv);
 794         tvt_tadf = vlen(tvt_tadv);
 795
 796         /*
 797         if(validate_flags & TFL_TARGETSELECT_FOV)
 798         {
 799                 if(e_turret.target_select_fov < tvt_thadf)
 800                         return -21;
 801         }
 802         */
 803
 804         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 805         {
 806                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 807                         return -17;
 808
 809                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrotate)
 810                         return -18;
 811         }
 812
 813         // Line of sight?
 814         if (validate_flags & TFL_TARGETSELECT_LOS)
 815         {
 816                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 817
 818                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 819
 820                 if (e_turret.aim_firetolerance_dist < vlen(v_tmp - trace_endpos))
 821                         return -19;
 822         }
 823
 824         if (e_target.classname == "grapplinghook")
 825                 return -20;
 826
 827         /*
 828         if (e_target.classname == "func_button")
 829                 return -21;
 830         */
 831
 832 #ifdef TURRET_DEBUG_TARGETSELECT
 833         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
 834 #endif
 835
 836         return 1;
 837 }
 838
 839 entity turret_select_target()
 840 {SELFPARAM();
 841         entity e;               // target looper entity
 842         float  score;   // target looper entity score
 843         entity e_enemy;  // currently best scoreing target
 844         float  m_score;  // currently best scoreing target's score
 845
 846         m_score = 0;
 847         if(self.enemy && self.enemy.takedamage && turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
 848         {
 849                 e_enemy = self.enemy;
 850                 m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
 851         }
 852         else
 853                 e_enemy = self.enemy = world;
 854
 855         e = findradius(self.origin, self.target_range);
 856
 857         // Nothing to aim at?
 858         if (!e)
 859                 return world;
 860
 861         while (e)
 862         {
 863                 if(e.takedamage)
 864                 {
 865                         float f = turret_validate_target(self, e, self.target_select_flags);
 866                         //dprint("F is: ", ftos(f), "\n");
 867                         if ( f > 0)
 868                         {
 869                                 score = self.turret_score_target(self,e);
 870                                 if ((score > m_score) && (score > 0))
 871                                 {
 872                                         e_enemy = e;
 873                                         m_score = score;
 874                                 }
 875                         }
 876                 }
 877                 e = e.chain;
 878         }
 879
 880         return e_enemy;
 881 }
 882
 883
 884 /*
 885  + = implemented
 886  - = not implemented
 887
 888  + TFL_FIRECHECK_NO
 889  + TFL_FIRECHECK_WORLD
 890  + TFL_FIRECHECK_DEAD
 891  + TFL_FIRECHECK_DISTANCES
 892  - TFL_FIRECHECK_LOS
 893  + TFL_FIRECHECK_AIMDIST
 894  + TFL_FIRECHECK_REALDIST
 895  - TFL_FIRECHECK_ANGLEDIST
 896  - TFL_FIRECHECK_TEAMCECK
 897  + TFL_FIRECHECK_AFF
 898  + TFL_FIRECHECK_AMMO_OWN
 899  + TFL_FIRECHECK_AMMO_OTHER
 900  + TFL_FIRECHECK_REFIRE
 901 */
 902
 903 /**
 904 ** Preforms pre-fire checks based on the uints firecheck_flags
 905 **/
 906 float turret_firecheck()
 907 {SELFPARAM();
 908         // This one just dont care =)
 909         if (self.firecheck_flags & TFL_FIRECHECK_NO)
 910                 return 1;
 911
 912         if (self.enemy == world)
 913                 return 0;
 914
 915         // Ready?
 916         if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
 917                 if (self.attack_finished_single > time) return 0;
 918
 919         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 920         if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 921                 if (self.volly_counter != self.shot_volly)
 922                         if(self.ammo >= self.shot_dmg)
 923                                 return 1;
 924
 925         // Lack of zombies makes shooting dead things unnecessary :P
 926         if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
 927                 if (self.enemy.deadflag != DEAD_NO)
 928                         return 0;
 929
 930         // Own ammo?
 931         if (self.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 932                 if (self.ammo < self.shot_dmg)
 933                         return 0;
 934
 935         // Other's ammo? (support-supply units)
 936         if (self.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 937                 if (self.enemy.ammo >= self.enemy.ammo_max)
 938                         return 0;
 939
 940         // Target of opertunity?
 941         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 942         {
 943                 self.enemy = self.tur_impactent;
 944                 return 1;
 945         }
 946
 947         if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 948         {
 949                 // To close?
 950                 if (self.tur_dist_aimpos < self.target_range_min)
 951                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 952                                 return 1; // Target of opertunity?
 953                         else
 954                                 return 0;
 955         }
 956
 957         // Try to avoid FF?
 958         if (self.firecheck_flags & TFL_FIRECHECK_AFF)
 959                 if (self.tur_impactent.team == self.team)
 960                         return 0;
 961
 962         // aim<->predicted impact
 963         if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 964                 if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
 965                         return 0;
 966
 967         // Volly status
 968         if (self.shot_volly > 1)
 969                 if (self.volly_counter == self.shot_volly)
 970                         if (self.ammo < (self.shot_dmg * self.shot_volly))
 971                                 return 0;
 972
 973         /*if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 974                 if(self.tur_impactent != self.enemy)
 975                         return 0;*/
 976
 977         return 1;
 978 }
 979
 980 bool turret_checkfire()
 981 {SELFPARAM();
 982         bool ret = false; // dummy
 983         if(MUTATOR_CALLHOOK(Turret_CheckFire, ret))
 984                 return ret_bool;
 985
 986         return self.turret_firecheckfunc();
 987 }
 988
 989 void turret_fire()
 990 {SELFPARAM();
 991         if (autocvar_g_turrets_nofire != 0)
 992                 return;
 993
 994         if(MUTATOR_CALLHOOK(TurretFire, self))
 995                 return;
 996
 997         Turret info = get_turretinfo(self.m_id);
 998         info.tr_attack(info);
 999
1000         self.attack_finished_single = time + self.shot_refire;
1001         self.ammo -= self.shot_dmg;
1002         self.volly_counter = self.volly_counter - 1;
1003
1004         if (self.volly_counter <= 0)
1005         {
1006                 self.volly_counter = self.shot_volly;
1007
1008                 if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
1009                         self.enemy = world;
1010
1011                 if (self.shot_volly > 1)
1012                         self.attack_finished_single = time + self.shot_volly_refire;
1013         }
1014
1015 #ifdef TURRET_DEBUG
1016         if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_debug_rvec, self.tur_impacttime + 0.25);
1017 #endif
1018 }
1019
1020 void turret_think()
1021 {SELFPARAM();
1022         entity e;
1023
1024         self.nextthink = time + self.ticrate;
1025
1026         // ONS uses somewhat backwards linking.
1027         if (teamplay)
1028         {
1029                 if (g_onslaught)
1030                         if (self.target)
1031                         {
1032                                 e = find(world, targetname,self.target);
1033                                 if (e != world)
1034                                         self.team = e.team;
1035                         }
1036
1037                 if (self.team != self.tur_head.team)
1038                         turret_respawn();
1039         }
1040
1041 #ifdef TURRET_DEBUG
1042         if (self.tur_debug_tmr1 < time)
1043         {
1044                 if (self.enemy) paint_target (self.enemy,128,self.tur_debug_rvec,0.9);
1045                 paint_target(self,256,self.tur_debug_rvec,0.9);
1046                 self.tur_debug_tmr1 = time + 1;
1047         }
1048 #endif
1049
1050         // Handle ammo
1051         if (!(self.spawnflags & TSF_NO_AMMO_REGEN))
1052         if (self.ammo < self.ammo_max)
1053                 self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
1054
1055         // Inactive turrets needs to run the think loop,
1056         // So they can handle animation and wake up if need be.
1057         if(!self.active)
1058         {
1059                 turret_track();
1060                 return;
1061         }
1062
1063         // This is typicaly used for zaping every target in range
1064         // turret_fusionreactor uses this to recharge friendlys.
1065         if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
1066         {
1067                 // Do a self.turret_fire for every valid target.
1068                 e = findradius(self.origin,self.target_range);
1069                 while (e)
1070                 {
1071                         if(e.takedamage)
1072                         {
1073                                 if (turret_validate_target(self,e,self.target_validate_flags))
1074                                 {
1075                                         self.enemy = e;
1076
1077                                         turret_do_updates(self);
1078
1079                                         if (turret_checkfire())
1080                                                 turret_fire();
1081                                 }
1082                         }
1083
1084                         e = e.chain;
1085                 }
1086                 self.enemy = world;
1087         }
1088         else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
1089         {
1090                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1091
1092                 // Predict?
1093                 if(!(self.aim_flags & TFL_AIM_NO))
1094                         self.tur_aimpos = turret_aim_generic();
1095
1096                 // Turn & pitch?
1097                 if(!(self.track_flags & TFL_TRACK_NO))
1098                         turret_track();
1099
1100                 turret_do_updates(self);
1101
1102                 // Fire?
1103                 if (turret_checkfire())
1104                         turret_fire();
1105         }
1106         else
1107         {
1108                 // Special case for volly always. if it fired once it must compleate the volly.
1109                 if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1110                         if(self.volly_counter != self.shot_volly)
1111                         {
1112                                 // Predict or whatnot
1113                                 if(!(self.aim_flags & TFL_AIM_NO))
1114                                         self.tur_aimpos = turret_aim_generic();
1115
1116                                 // Turn & pitch
1117                                 if(!(self.track_flags & TFL_TRACK_NO))
1118                                         turret_track();
1119
1120                                 turret_do_updates(self);
1121
1122                                 // Fire!
1123                                 if (turret_checkfire())
1124                                         turret_fire();
1125
1126                                 Turret tur = get_turretinfo(self.m_id);
1127                                 tur.tr_think(tur);
1128
1129                                 return;
1130                         }
1131
1132                 // Check if we have a vailid enemy, and try to find one if we dont.
1133
1134                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1135                 float do_target_scan = 0;
1136                 if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1137                         do_target_scan = 1;
1138
1139                 // Old target (if any) invalid?
1140                 if(self.target_validate_time < time)
1141                 if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
1142                 {
1143                         self.enemy = world;
1144                         self.target_validate_time = time + 0.5;
1145                         do_target_scan = 1;
1146                 }
1147
1148                 // But never more often then g_turrets_targetscan_mindelay!
1149                 if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1150                         do_target_scan = 0;
1151
1152                 if(do_target_scan)
1153                 {
1154                         self.enemy = turret_select_target();
1155                         self.target_select_time = time;
1156                 }
1157
1158                 // No target, just go to idle, do any custom stuff and bail.
1159                 if (self.enemy == world)
1160                 {
1161                         // Turn & pitch
1162                         if(!(self.track_flags & TFL_TRACK_NO))
1163                                 turret_track();
1164
1165                         Turret tur = get_turretinfo(self.m_id);
1166                         tur.tr_think(tur);
1167
1168                         // And bail.
1169                         return;
1170                 }
1171                 else
1172                         self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1173
1174                 // Predict?
1175                 if(!(self.aim_flags & TFL_AIM_NO))
1176                         self.tur_aimpos = turret_aim_generic();
1177
1178                 // Turn & pitch?
1179                 if(!(self.track_flags & TFL_TRACK_NO))
1180                         turret_track();
1181
1182                 turret_do_updates(self);
1183
1184                 // Fire?
1185                 if (turret_checkfire())
1186                         turret_fire();
1187         }
1188
1189         Turret tur = get_turretinfo(self.m_id);
1190         tur.tr_think(tur);
1191 }
1192
1193 /*
1194         When .used a turret switch team to activator.team.
1195         If activator is world, the turret go inactive.
1196 */
1197 void turret_use()
1198 {SELFPARAM();
1199         LOG_TRACE("Turret ",self.netname, " used by ", activator.classname, "\n");
1200
1201         self.team = activator.team;
1202
1203         if(self.team == 0)
1204                 self.active = ACTIVE_NOT;
1205         else
1206                 self.active = ACTIVE_ACTIVE;
1207
1208 }
1209
1210 void turret_link()
1211 {SELFPARAM();
1212         Net_LinkEntity(self, true, 0, turret_send);
1213         self.think       = turret_think;
1214         self.nextthink = time;
1215         self.tur_head.effects = EF_NODRAW;
1216 }
1217
1218 void turrets_manager_think()
1219 {SELFPARAM();
1220         self.nextthink = time + 1;
1221
1222         entity e;
1223         if (autocvar_g_turrets_reloadcvars == 1)
1224         {
1225                 e = nextent(world);
1226                 while (e)
1227                 {
1228                         if (IS_TURRET(e))
1229                         {
1230                                 load_unit_settings(e,1);
1231                                 Turret tur = get_turretinfo(self.m_id);
1232                                 tur.tr_think(tur);
1233                         }
1234
1235                         e = nextent(e);
1236                 }
1237                 cvar_set("g_turrets_reloadcvars","0");
1238         }
1239 }
1240
1241 void turret_initparams(entity tur)
1242 {
1243         #define TRY(x) (x) ? (x)
1244         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1245         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1246         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1247         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1248         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1249         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1250         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1251         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1252         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1253         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), MAX_SHOT_DISTANCE);
1254         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), MAX_SHOT_DISTANCE);
1255         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), MAX_SHOT_DISTANCE);
1256         tur.aim_maxrotate               = bound(0,               (TRY(tur.aim_maxrotate)             :  90                                         ), 360);
1257         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1258         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1259         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), MAX_SHOT_DISTANCE);
1260         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1261         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1262         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1263         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1264         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1265         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1266         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1267         #undef TRY
1268 }
1269
1270 float turret_initialize(Turret tur)
1271 {SELFPARAM();
1272         if(!autocvar_g_turrets)
1273                 return false;
1274
1275         if(tur.m_id == 0)
1276                 return false; // invalid turret
1277
1278         // if tur_head exists, we can assume this turret re-spawned
1279         if(!self.tur_head) {
1280                 tur.tr_precache(tur);
1281         }
1282
1283         entity e = find(world, classname, "turret_manager");
1284         if(!e)
1285         {
1286                 e = spawn();
1287                 e.classname = "turret_manager";
1288                 e.think = turrets_manager_think;
1289                 e.nextthink = time + 2;
1290         }
1291
1292         if(!(self.spawnflags & TSF_SUSPENDED))
1293                 builtin_droptofloor();
1294
1295         self.netname = tur.netname;
1296         load_unit_settings(self, 0);
1297
1298         if(!self.team || !teamplay)             { self.team = MAX_SHOT_DISTANCE; }
1299         if(!self.ticrate)                               { self.ticrate = ((self.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1300         if(!self.health)                                { self.health = 1000; }
1301         if(!self.shot_refire)                   { self.shot_refire = 1; }
1302         if(!self.tur_shotorg)                   { self.tur_shotorg = '50 0 50'; }
1303         if(!self.turret_flags)                  { self.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1304         if(!self.damage_flags)                  { self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1305         if(!self.aim_flags)                             { self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1306         if(!self.track_type)                    { self.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1307         if(!self.track_flags)                   { self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1308         if(!self.ammo_flags)                    { self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1309         if(!self.target_select_flags)   { self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1310         if(!self.firecheck_flags)               { self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1311                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1312
1313         if(self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1314         {
1315                 // Fluid / Ineria mode. Looks mutch nicer.
1316                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1317
1318                 self.aim_speed = bound(0.1, ((!self.aim_speed) ? 180 : self.aim_speed), 1000);
1319
1320                 if(!self.track_accel_pitch)             { self.track_accel_pitch = 0.5; }
1321                 if(!self.track_accel_rotate)    { self.track_accel_rotate = 0.5; }
1322                 if(!self.track_blendrate)               { self.track_blendrate = 0.35; }
1323         }
1324
1325         turret_initparams(self);
1326
1327         self.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1328
1329         if(self.turret_flags & TUR_FLAG_SPLASH)
1330                 self.aim_flags |= TFL_AIM_SPLASH;
1331
1332         if(self.turret_flags & TUR_FLAG_MISSILE)
1333                 self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1334
1335         if(self.turret_flags & TUR_FLAG_PLAYER)
1336                 self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1337
1338         if(self.spawnflags & TSL_NO_RESPAWN)
1339                 self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1340
1341         if (self.turret_flags & TUR_FLAG_SUPPORT)
1342                 self.turret_score_target = turret_targetscore_support;
1343         else
1344                 self.turret_score_target = turret_targetscore_generic;
1345
1346         ++turret_count;
1347
1348         _setmodel(self, tur.model);
1349         setsize(self, tur.mins, tur.maxs);
1350
1351         self.m_id                                       = tur.m_id;
1352         self.classname                          = "turret_main";
1353         self.active                                     = ACTIVE_ACTIVE;
1354         self.effects                            = EF_NODRAW;
1355         self.netname                            = tur.turret_name;
1356         self.ticrate                            = bound(sys_frametime, self.ticrate, 60);
1357         self.max_health                         = self.health;
1358         self.target_validate_flags      = self.target_select_flags;
1359         self.ammo                                       = self.ammo_max;
1360         self.ammo_recharge                 *= self.ticrate;
1361         self.solid                                      = SOLID_BBOX;
1362         self.takedamage                         = DAMAGE_AIM;
1363         self.movetype                           = MOVETYPE_NOCLIP;
1364         self.view_ofs                           = '0 0 0';
1365         self.turret_firecheckfunc       = turret_firecheck;
1366         self.event_damage                       = turret_damage;
1367         self.use                                        = turret_use;
1368         self.bot_attack                         = true;
1369         self.nextthink                          = time + 1;
1370         self.nextthink                     += turret_count * sys_frametime;
1371
1372         self.tur_head = spawn();
1373         _setmodel(self.tur_head, tur.head_model);
1374         setsize(self.tur_head, '0 0 0', '0 0 0');
1375         setorigin(self.tur_head, '0 0 0');
1376         setattachment(self.tur_head, self, "tag_head");
1377
1378         self.tur_head.netname           = self.tur_head.classname = "turret_head";
1379         self.tur_head.team                      = self.team;
1380         self.tur_head.owner                     = self;
1381         self.tur_head.takedamage        = DAMAGE_NO;
1382         self.tur_head.solid                     = SOLID_NOT;
1383         self.tur_head.movetype          = self.movetype;
1384
1385         if(!self.tur_defend)
1386         if(self.target != "")
1387         {
1388                 self.tur_defend = find(world, targetname, self.target);
1389                 if (self.tur_defend == world)
1390                 {
1391                         self.target = "";
1392                         LOG_TRACE("Turret has invalid defendpoint!\n");
1393                 }
1394         }
1395
1396         if (self.tur_defend)
1397                 self.idle_aim = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1398         else
1399                 self.idle_aim = '0 0 0';
1400
1401 #ifdef TURRET_DEBUG
1402         self.tur_debug_start = self.nextthink;
1403         while (vlen(self.tur_debug_rvec) < 2)
1404                 self.tur_debug_rvec = randomvec() * 4;
1405
1406         self.tur_debug_rvec_x = fabs(self.tur_debug_rvec_x);
1407         self.tur_debug_rvec_y = fabs(self.tur_debug_rvec_y);
1408         self.tur_debug_rvec_z = fabs(self.tur_debug_rvec_z);
1409 #endif
1410
1411         turret_link();
1412         turret_respawn();
1413         turret_tag_fire_update();
1414
1415         tur.tr_setup(tur, self);
1416
1417         if(MUTATOR_CALLHOOK(TurretSpawn, self))
1418                 return false;
1419
1420         return true;
1421 }
1422 #endif