qcsrc/common/turrets/sv_turrets.qc

   1 #include "sv_turrets.qh"
   2
   3 #ifdef SVQC
   4 #include <common/mapobjects/defs.qh>
   5 #include <server/bot/api.qh>
   6 #include <server/damage.qh>
   7 #include <server/weapons/common.qh>
   8 #include <server/weapons/weaponsystem.qh>
   9 #include <server/world.qh>
  10
  11 // Generic aiming
  12 vector turret_aim_generic(entity this)
  13 {
  14
  15         vector pre_pos, prep;
  16         float distance, impact_time = 0, i, mintime;
  17
  18         turret_tag_fire_update(this);
  19
  20         if(this.aim_flags & TFL_AIM_SIMPLE)
  21                 return real_origin(this.enemy);
  22
  23         mintime = max(this.attack_finished_single[0] - time,0) + sys_frametime;
  24
  25         // Baseline
  26         pre_pos = real_origin(this.enemy);
  27
  28         // Lead?
  29         if (this.aim_flags & TFL_AIM_LEAD)
  30         {
  31                 if (this.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  32                 {
  33                         prep = pre_pos;
  34
  35                         distance = vlen(prep - this.tur_shotorg);
  36                         impact_time = distance / this.shot_speed;
  37
  38                         prep = pre_pos + (this.enemy.velocity * (impact_time + mintime));
  39
  40                         if(this.aim_flags & TFL_AIM_ZPREDICT)
  41                         if(!IS_ONGROUND(this.enemy))
  42                         if(this.enemy.move_movetype == MOVETYPE_WALK || this.enemy.move_movetype == MOVETYPE_TOSS || this.enemy.move_movetype == MOVETYPE_BOUNCE)
  43                         {
  44                                 float vz;
  45                                 prep_z = pre_pos_z;
  46                                 vz = this.enemy.velocity_z;
  47                                 for(i = 0; i < impact_time; i += sys_frametime)
  48                                 {
  49                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  50                                         prep_z = prep_z + vz * sys_frametime;
  51                                 }
  52                         }
  53                         pre_pos = prep;
  54                 }
  55                 else
  56                         pre_pos = pre_pos + this.enemy.velocity * mintime;
  57         }
  58
  59         if(this.aim_flags & TFL_AIM_SPLASH)
  60         {
  61                 //tracebox(pre_pos + '0 0 32',this.enemy.mins,this.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  62                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  63                 if(trace_fraction != 1.0)
  64                         pre_pos = trace_endpos;
  65         }
  66
  67         return pre_pos;
  68 }
  69
  70 float turret_targetscore_support(entity _turret,entity _target)
  71 {
  72         float score;            // Total score
  73         float s_score = 0, d_score;
  74
  75         if (_turret.enemy == _target) s_score = 1;
  76
  77         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  78
  79         score = (d_score * _turret.target_select_rangebias) +
  80                         (s_score * _turret.target_select_samebias);
  81
  82         return score;
  83 }
  84
  85 /*
  86 * Generic bias aware score system.
  87 */
  88 float turret_targetscore_generic(entity _turret, entity _target)
  89 {
  90         float d_dist;      // Defendmode Distance
  91         float score;            // Total score
  92         float d_score;    // Distance score
  93         float a_score;    // Angular score
  94         float m_score = 0;  // missile score
  95         float p_score = 0;  // player score
  96         float ikr;                // ideal kill range
  97
  98         if (_turret.tur_defend)
  99         {
 100                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
 101                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
 102                 d_score = 1 - d_dist / _turret.target_range;
 103         }
 104         else
 105         {
 106                 // Make a normlized value base on the targets distance from our optimal killzone
 107                 ikr = _turret.target_range_optimal;
 108                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 109         }
 110
 111         a_score = 1 - tvt_thadf / _turret.aim_maxrot;
 112
 113         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 114                 m_score = 1;
 115
 116         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 117                 p_score = 1;
 118
 119         d_score = max(d_score, 0);
 120         a_score = max(a_score, 0);
 121         m_score = max(m_score, 0);
 122         p_score = max(p_score, 0);
 123
 124         score = (d_score * _turret.target_select_rangebias) +
 125                         (a_score * _turret.target_select_anglebias) +
 126                         (m_score * _turret.target_select_missilebias) +
 127                         (p_score * _turret.target_select_playerbias);
 128
 129         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 130         {
 131                 //dprint("Wtf?\n");
 132                 score *= 0.001;
 133         }
 134
 135 #ifdef TURRET_DEBUG
 136         string sd,sa,sm,sp,ss;
 137         string sdt,sat,smt,spt;
 138
 139         sd = ftos(d_score);
 140         d_score *= _turret.target_select_rangebias;
 141         sdt = ftos(d_score);
 142
 143         //sv = ftos(v_score);
 144         //v_score *= _turret.target_select_samebias;
 145         //svt = ftos(v_score);
 146
 147         sa = ftos(a_score);
 148         a_score *= _turret.target_select_anglebias;
 149         sat = ftos(a_score);
 150
 151         sm = ftos(m_score);
 152         m_score *= _turret.target_select_missilebias;
 153         smt = ftos(m_score);
 154
 155         sp = ftos(p_score);
 156         p_score *= _turret.target_select_playerbias;
 157         spt = ftos(p_score);
 158
 159
 160         ss = ftos(score);
 161         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 162         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 163         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 164         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 165         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 166         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 167
 168 #endif
 169
 170         return score;
 171 }
 172
 173 // Generic damage handling
 174 void turret_hide(entity this)
 175 {
 176         this.effects   |= EF_NODRAW;
 177         this.nextthink = time + this.respawntime - 0.2;
 178         setthink(this, turret_respawn);
 179 }
 180
 181 void turret_die(entity this)
 182 {
 183         this.deadflag             = DEAD_DEAD;
 184         this.tur_head.deadflag = this.deadflag;
 185
 186 // Unsolidify and hide real parts
 187         this.solid                       = SOLID_NOT;
 188         this.tur_head.solid      = this.solid;
 189
 190         this.event_damage                 = func_null;
 191         this.event_heal = func_null;
 192         this.takedamage                  = DAMAGE_NO;
 193
 194         SetResourceExplicit(this, RES_HEALTH, 0);
 195
 196 // Go boom
 197         //RadiusDamage (this,this, min(this.ammo,50),min(this.ammo,50) * 0.25,250,NULL,min(this.ammo,50)*5,DEATH_TURRET,NULL);
 198
 199         Turret tur = get_turretinfo(this.m_id);
 200         if(this.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 201         {
 202                 // do a simple explosion effect here, since CSQC can't do it on a to-be-removed entity
 203                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 204                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 205
 206                 tur.tr_death(tur, this);
 207
 208                 delete(this.tur_head);
 209                 delete(this);
 210         }
 211         else
 212         {
 213                 // Setup respawn
 214                 this.SendFlags    |= TNSF_STATUS;
 215                 this.nextthink   = time + 0.2;
 216                 setthink(this, turret_hide);
 217
 218                 tur.tr_death(tur, this);
 219         }
 220 }
 221
 222 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 223 {
 224         // Enough already!
 225         if(this.deadflag == DEAD_DEAD)
 226                 return;
 227
 228         // Inactive turrets take no damage. (hm..)
 229         if(!this.active)
 230                 return;
 231
 232         if(SAME_TEAM(this, attacker))
 233         {
 234                 if(autocvar_g_friendlyfire)
 235                         damage = damage * autocvar_g_friendlyfire;
 236                 else
 237                         return;
 238         }
 239
 240         TakeResource(this, RES_HEALTH, damage);
 241
 242         // thorw head slightly off aim when hit?
 243         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 244         {
 245                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 246                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 247
 248                 this.SendFlags  |= TNSF_ANG;
 249         }
 250
 251         if (this.turret_flags & TUR_FLAG_MOVE)
 252                 this.velocity = this.velocity + vforce;
 253
 254         if (GetResource(this, RES_HEALTH) <= 0)
 255         {
 256                 this.event_damage                 = func_null;
 257                 this.tur_head.event_damage = func_null;
 258                 this.event_heal = func_null;
 259                 this.tur_head.event_heal = func_null;
 260                 this.takedamage                  = DAMAGE_NO;
 261                 this.nextthink = time;
 262                 setthink(this, turret_die);
 263         }
 264
 265         this.SendFlags  |= TNSF_STATUS;
 266 }
 267
 268 bool turret_heal(entity targ, entity inflictor, float amount, float limit)
 269 {
 270         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
 271         if(GetResource(targ, RES_HEALTH) <= 0 || GetResource(targ, RES_HEALTH) >= true_limit)
 272                 return false;
 273
 274         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
 275         targ.SendFlags |= TNSF_STATUS;
 276         return true;
 277 }
 278
 279 void turret_think(entity this);
 280 void turret_respawn(entity this)
 281 {
 282         // Make sure all parts belong to the same team since
 283         // this function doubles as "teamchange" function.
 284         this.tur_head.team      = this.team;
 285         this.effects                       &= ~EF_NODRAW;
 286         this.deadflag                           = DEAD_NO;
 287         this.effects                            = EF_LOWPRECISION;
 288         this.solid                                      = SOLID_BBOX;
 289         this.takedamage                         = DAMAGE_AIM;
 290         this.event_damage                       = turret_damage;
 291         this.event_heal                         = turret_heal;
 292         this.avelocity                          = '0 0 0';
 293         this.tur_head.avelocity         = this.avelocity;
 294         this.tur_head.angles            = this.idle_aim;
 295         SetResourceExplicit(this, RES_HEALTH, this.max_health);
 296         this.enemy                                      = NULL;
 297         this.volly_counter                      = this.shot_volly;
 298         this.ammo                                       = this.ammo_max;
 299
 300         this.nextthink = time + this.ticrate;
 301         setthink(this, turret_think);
 302
 303         this.SendFlags = TNSF_FULL_UPDATE;
 304
 305         Turret tur = get_turretinfo(this.m_id);
 306         tur.tr_setup(tur, this);
 307
 308         setorigin(this, this.origin); // make sure it's linked to the area grid
 309 }
 310
 311
 312 // Main functions
 313 .float clientframe;
 314 void turrets_setframe(entity this, float _frame, float client_only)
 315 {
 316         if((client_only ? this.clientframe : this.frame ) != _frame)
 317         {
 318                 this.SendFlags |= TNSF_ANIM;
 319                 this.anim_start_time = time;
 320         }
 321
 322          if(client_only)
 323                 this.clientframe = _frame;
 324         else
 325                 this.frame = _frame;
 326
 327 }
 328
 329 bool turret_send(entity this, entity to, float sf)
 330 {
 331         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 332         WriteByte(MSG_ENTITY, sf);
 333         if(sf & TNSF_SETUP)
 334         {
 335                 WriteByte(MSG_ENTITY, this.m_id);
 336
 337                 WriteVector(MSG_ENTITY, this.origin);
 338
 339                 WriteAngleVector2D(MSG_ENTITY, this.angles);
 340         }
 341
 342         if(sf & TNSF_ANG)
 343         {
 344                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_x));
 345                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_y));
 346         }
 347
 348         if(sf & TNSF_AVEL)
 349         {
 350                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_x));
 351                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_y));
 352         }
 353
 354         if(sf & TNSF_MOVE)
 355         {
 356                 WriteVector(MSG_ENTITY, this.origin);
 357
 358                 WriteVector(MSG_ENTITY, this.velocity);
 359
 360                 WriteShort(MSG_ENTITY, rint(this.angles_y));
 361         }
 362
 363         if(sf & TNSF_ANIM)
 364         {
 365                 WriteCoord(MSG_ENTITY, this.anim_start_time);
 366                 WriteByte(MSG_ENTITY, this.frame);
 367         }
 368
 369         if(sf & TNSF_STATUS)
 370         {
 371                 WriteByte(MSG_ENTITY, this.team);
 372
 373                 if(GetResource(this, RES_HEALTH) <= 0)
 374                         WriteByte(MSG_ENTITY, 0);
 375                 else
 376                         WriteByte(MSG_ENTITY, ceil((GetResource(this, RES_HEALTH) / this.max_health) * 255));
 377         }
 378
 379         return true;
 380 }
 381
 382 void load_unit_settings(entity ent, bool is_reload)
 383 {
 384         if (ent == NULL)
 385                 return;
 386
 387         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 388         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 389         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 390         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 391         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 392         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 393         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 394
 395         if (is_reload)
 396         {
 397                 ent.enemy = NULL;
 398                 ent.tur_head.avelocity = '0 0 0';
 399
 400                 ent.tur_head.angles = '0 0 0';
 401         }
 402
 403         string unitname = ent.netname;
 404         #define X(class, prefix, fld, type) ent.fld = cvar(strcat("g_turrets_unit_", prefix, "_", #fld));
 405         TR_PROPS_COMMON(X, , unitname)
 406         #undef X
 407
 408         ent.ammo_max             *= ent.turret_scale_ammo;
 409         ent.ammo_recharge        *= ent.turret_scale_ammo;
 410         ent.aim_speed            *= ent.turret_scale_aim;
 411         SetResourceExplicit(ent, RES_HEALTH, GetResource(ent, RES_HEALTH) * ent.turret_scale_health);
 412         ent.respawntime          *= ent.turret_scale_respawn;
 413         ent.shot_dmg             *= ent.turret_scale_damage;
 414         ent.shot_refire          *= ent.turret_scale_refire;
 415         ent.shot_radius          *= ent.turret_scale_damage;
 416         ent.shot_force           *= ent.turret_scale_damage;
 417         ent.shot_volly_refire    *= ent.turret_scale_refire;
 418         ent.target_range         *= ent.turret_scale_range;
 419         ent.target_range_min     *= ent.turret_scale_range;
 420         ent.target_range_optimal *= ent.turret_scale_range;
 421
 422         if(is_reload) {
 423                 Turret tur = get_turretinfo(ent.m_id);
 424                 tur.tr_setup(tur, ent);
 425         }
 426 }
 427
 428 void turret_projectile_explode(entity this)
 429 {
 430
 431         this.takedamage = DAMAGE_NO;
 432         this.event_damage = func_null;
 433 #ifdef TURRET_DEBUG
 434         float d;
 435         d = RadiusDamage (this, this.owner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.projectiledeathtype, DMG_NOWEP, NULL);
 436         this.owner.tur_debug_dmg_t_h = this.owner.tur_debug_dmg_t_h + d;
 437         this.owner.tur_debug_dmg_t_f = this.owner.tur_debug_dmg_t_f + this.owner.shot_dmg;
 438 #else
 439         RadiusDamage (this, this.realowner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.projectiledeathtype, DMG_NOWEP, NULL);
 440 #endif
 441         delete(this);
 442 }
 443
 444 void turret_projectile_touch(entity this, entity toucher)
 445 {
 446         PROJECTILE_TOUCH(this, toucher);
 447         turret_projectile_explode(this);
 448 }
 449
 450 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector vforce)
 451 {
 452         this.velocity  += vforce;
 453         TakeResource(this, RES_HEALTH, damage);
 454         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 455         if(GetResource(this, RES_HEALTH) <= 0)
 456                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
 457 }
 458
 459 entity turret_projectile(entity actor, Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 460 {
 461         TC(Sound, _snd);
 462         entity proj;
 463
 464         sound (actor, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 465         proj                             = spawn ();
 466         setorigin(proj, actor.tur_shotorg);
 467         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 468         proj.owner                = actor;
 469         proj.realowner    = actor;
 470         proj.bot_dodge    = true;
 471         proj.bot_dodgerating = actor.shot_dmg;
 472         setthink(proj, turret_projectile_explode);
 473         settouch(proj, turret_projectile_touch);
 474         proj.nextthink    = time + 9;
 475         set_movetype(proj, MOVETYPE_FLYMISSILE);
 476         proj.velocity           = normalize(actor.tur_shotdir_updated + randomvec() * actor.shot_spread) * actor.shot_speed;
 477         proj.flags = FL_PROJECTILE;
 478         IL_PUSH(g_projectiles, proj);
 479         IL_PUSH(g_bot_dodge, proj);
 480         proj.enemy                = actor.enemy;
 481         proj.projectiledeathtype         = _death;
 482         PROJECTILE_MAKETRIGGER(proj);
 483         if(_health)
 484         {
 485                 SetResourceExplicit(proj, RES_HEALTH, _health);
 486                 proj.takedamage  = DAMAGE_YES;
 487                 proj.event_damage  = turret_projectile_damage;
 488         }
 489         else
 490                 proj.flags |= FL_NOTARGET;
 491
 492         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 493
 494         return proj;
 495 }
 496
 497 /**
 498 ** updates enemy distances, predicted impact point/time
 499 ** and updated aim<->predict impact distance.
 500 **/
 501 void turret_do_updates(entity t_turret)
 502 {
 503         vector enemy_pos = real_origin(t_turret.enemy);
 504
 505         turret_tag_fire_update(t_turret);
 506
 507         t_turret.tur_shotdir_updated = v_forward;
 508         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
 509         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
 510
 511         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
 512         {
 513                 oldpos = t_turret.enemy.origin;
 514                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
 515                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 516                 setorigin(t_turret.enemy, oldpos);
 517
 518                 if(trace_ent == t_turret.enemy)
 519                         t_turret.tur_dist_impact_to_aimpos = 0;
 520                 else
 521                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
 522         }
 523         else*/
 524                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 525
 526         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
 527         t_turret.tur_impactent                   = trace_ent;
 528         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
 529 }
 530
 531 /**
 532 ** Handles head rotation according to
 533 ** the units .track_type and .track_flags
 534 **/
 535 .float turret_framecounter;
 536 void turret_track(entity this)
 537 {
 538         vector target_angle; // This is where we want to aim
 539         vector move_angle;   // This is where we can aim
 540         float f_tmp;
 541         vector v1, v2;
 542         v1 = this.tur_head.angles;
 543         v2 = this.tur_head.avelocity;
 544
 545         if (this.track_flags == TFL_TRACK_NO)
 546                 return;
 547
 548         if(!this.active)
 549                 target_angle = this.idle_aim - ('1 0 0' * this.aim_maxpitch);
 550         else if (this.enemy == NULL)
 551         {
 552                 if(time > this.lip)
 553                         target_angle = this.idle_aim + this.angles;
 554                 else
 555                         target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 556         }
 557         else
 558         {
 559                 target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 560         }
 561
 562         this.tur_head.angles_x = anglemods(this.tur_head.angles_x);
 563         this.tur_head.angles_y = anglemods(this.tur_head.angles_y);
 564
 565         // Find the diffrence between where we currently aim and where we want to aim
 566         //move_angle = target_angle - (this.angles + this.tur_head.angles);
 567         //move_angle = shortangle_vxy(move_angle,(this.angles + this.tur_head.angles));
 568
 569         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(this.angles), AnglesTransform_FromAngles(target_angle))) - this.tur_head.angles;
 570         move_angle = shortangle_vxy(move_angle, this.tur_head.angles);
 571
 572         switch(this.track_type)
 573         {
 574                 case TFL_TRACKTYPE_STEPMOTOR:
 575                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 576                         if (this.track_flags & TFL_TRACK_PITCH)
 577                         {
 578                                 this.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 579                                 if(this.tur_head.angles_x > this.aim_maxpitch)
 580                                         this.tur_head.angles_x = this.aim_maxpitch;
 581
 582                                 if(this.tur_head.angles_x  < -this.aim_maxpitch)
 583                                         this.tur_head.angles_x = this.aim_maxpitch;
 584                         }
 585
 586                         if (this.track_flags & TFL_TRACK_ROTATE)
 587                         {
 588                                 this.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 589                                 if(this.tur_head.angles_y > this.aim_maxrot)
 590                                         this.tur_head.angles_y = this.aim_maxrot;
 591
 592                                 if(this.tur_head.angles_y  < -this.aim_maxrot)
 593                                         this.tur_head.angles_y = this.aim_maxrot;
 594                         }
 595
 596                         // CSQC
 597                         this.SendFlags  |= TNSF_ANG;
 598
 599                         return;
 600
 601                 case TFL_TRACKTYPE_FLUIDINERTIA:
 602                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 603                         move_angle_x = bound(-this.aim_speed, move_angle_x * this.track_accel_pitch * f_tmp, this.aim_speed);
 604                         move_angle_y = bound(-this.aim_speed, move_angle_y * this.track_accel_rot * f_tmp, this.aim_speed);
 605                         move_angle = (this.tur_head.avelocity * this.track_blendrate) + (move_angle * (1 - this.track_blendrate));
 606                         break;
 607
 608                 case TFL_TRACKTYPE_FLUIDPRECISE:
 609
 610                         move_angle_y = bound(-this.aim_speed, move_angle_y, this.aim_speed);
 611                         move_angle_x = bound(-this.aim_speed, move_angle_x, this.aim_speed);
 612
 613                         break;
 614         }
 615
 616         //  pitch
 617         if (this.track_flags & TFL_TRACK_PITCH)
 618         {
 619                 this.tur_head.avelocity_x = move_angle_x;
 620                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) > this.aim_maxpitch)
 621                 {
 622                         this.tur_head.avelocity_x = 0;
 623                         this.tur_head.angles_x = this.aim_maxpitch;
 624
 625                         this.SendFlags  |= TNSF_ANG;
 626                 }
 627
 628                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) < -this.aim_maxpitch)
 629                 {
 630                         this.tur_head.avelocity_x = 0;
 631                         this.tur_head.angles_x = -this.aim_maxpitch;
 632
 633                         this.SendFlags  |= TNSF_ANG;
 634                 }
 635         }
 636
 637         //  rot
 638         if (this.track_flags & TFL_TRACK_ROTATE)
 639         {
 640                 this.tur_head.avelocity_y = move_angle_y;
 641
 642                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) > this.aim_maxrot)
 643                 {
 644                         this.tur_head.avelocity_y = 0;
 645                         this.tur_head.angles_y = this.aim_maxrot;
 646
 647                         this.SendFlags  |= TNSF_ANG;
 648                 }
 649
 650                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) < -this.aim_maxrot)
 651                 {
 652                         this.tur_head.avelocity_y = 0;
 653                         this.tur_head.angles_y = -this.aim_maxrot;
 654
 655                         this.SendFlags  |= TNSF_ANG;
 656                 }
 657         }
 658
 659         this.SendFlags  |= TNSF_AVEL;
 660
 661         // Force a angle update every 10'th frame
 662         this.turret_framecounter += 1;
 663         if(this.turret_framecounter >= 10)
 664         {
 665                 this.SendFlags |= TNSF_ANG;
 666                 this.turret_framecounter = 0;
 667         }
 668 }
 669
 670 /*
 671  + TFL_TARGETSELECT_NO
 672  + TFL_TARGETSELECT_LOS
 673  + TFL_TARGETSELECT_PLAYERS
 674  + TFL_TARGETSELECT_MISSILES
 675  + TFL_TARGETSELECT_VEHICLES
 676  - TFL_TARGETSELECT_TRIGGERTARGET
 677  + TFL_TARGETSELECT_ANGLELIMITS
 678  + TFL_TARGETSELECT_RANGELIMITS
 679  + TFL_TARGETSELECT_TEAMCHECK
 680  - TFL_TARGETSELECT_NOBUILTIN
 681  + TFL_TARGETSELECT_OWNTEAM
 682 */
 683
 684 /**
 685 ** Evaluate a entity for target valitity based on validate_flags
 686 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 687 **/
 688 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 689 {
 690         vector v_tmp;
 691
 692         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 693         //      return -0.5;
 694
 695         if(!e_target)
 696                 return -2;
 697
 698         // Don't attack against owner
 699         if(e_target.owner == e_turret || e_target == e_turret.realowner)
 700                 return -0.5;
 701
 702         if(!checkpvs(e_target.origin, e_turret))
 703                 return -1;
 704
 705         if(e_target.alpha != 0 && e_target.alpha <= 0.3)
 706                 return -1;
 707
 708         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 709                 return M_ARGV(3, float);
 710
 711         if (validate_flags & TFL_TARGETSELECT_NO)
 712                 return -4;
 713
 714         // If only this was used more..
 715         if (e_target.flags & FL_NOTARGET)
 716                 return -5;
 717
 718         // Cant touch this
 719         if (GetResource(e_target, RES_HEALTH) <= 0)
 720                 return -6;
 721         else if (STAT(FROZEN, e_target))
 722                 return -6;
 723
 724         // vehicle
 725         if(IS_VEHICLE(e_target))
 726         {
 727                 if ((validate_flags & TFL_TARGETSELECT_VEHICLES) && !e_target.owner)
 728                         return -7;
 729         }
 730
 731         // player
 732         if (IS_CLIENT(e_target))
 733         {
 734                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 735                         return -7;
 736
 737                 if (IS_DEAD(e_target))
 738                         return -8;
 739         }
 740
 741         // enemy turrets
 742         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 743         if(e_target.owner.tur_head == e_target)
 744         if(e_target.team != e_turret.team) // Dont break support units.
 745                 return -9;
 746
 747         // Missile
 748         if (e_target.flags & FL_PROJECTILE)
 749         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 750                 return -10;
 751
 752         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 753         if(!(e_target.flags & FL_PROJECTILE))
 754                 return -10.5;
 755
 756         // Team check
 757         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 758         {
 759                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 760                 {
 761                         if (e_target.team != e_turret.team)
 762                                 return -11;
 763
 764                         if (e_turret.team != e_target.owner.team)
 765                                 return -12;
 766
 767                         if (e_turret.team != e_target.aiment.team)
 768                                 return -12; // portals
 769                 }
 770                 else
 771                 {
 772                         if (e_target.team == e_turret.team)
 773                                 return -13;
 774
 775                         if (e_turret.team == e_target.owner.team)
 776                                 return -14;
 777
 778                         if (e_turret.team == e_target.aiment.team)
 779                                 return -14; // portals
 780                 }
 781         }
 782
 783         // Range limits?
 784         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 785         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 786         {
 787                 if (tvt_dist < e_turret.target_range_min)
 788                         return -15;
 789
 790                 if (tvt_dist > e_turret.target_range)
 791                         return -16;
 792         }
 793
 794         // Can we even aim this thing?
 795         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target.origin);
 796         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 797         tvt_thadf = vlen(tvt_thadv);
 798
 799         /*
 800         if(validate_flags & TFL_TARGETSELECT_FOV)
 801         {
 802                 if(e_turret.target_select_fov < tvt_thadf)
 803                         return -21;
 804         }
 805         */
 806
 807         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 808         {
 809                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 810                         return -17;
 811
 812                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrot)
 813                         return -18;
 814         }
 815
 816         // Line of sight?
 817         if (validate_flags & TFL_TARGETSELECT_LOS)
 818         {
 819                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 820
 821                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 822
 823                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 824                         return -19;
 825         }
 826
 827         if (e_target.classname == "grapplinghook")
 828                 return -20;
 829
 830         /*
 831         if (e_target.classname == "func_button")
 832                 return -21;
 833         */
 834
 835 #ifdef TURRET_DEBUG_TARGETSELECT
 836         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname);
 837 #endif
 838
 839         return 1;
 840 }
 841
 842 entity turret_select_target(entity this)
 843 {
 844         entity e;               // target looper entity
 845         float  score;   // target looper entity score
 846         entity e_enemy;  // currently best scoreing target
 847         float  m_score;  // currently best scoreing target's score
 848
 849         m_score = 0;
 850         if(this.enemy && this.enemy.takedamage && turret_validate_target(this,this.enemy,this.target_validate_flags) > 0)
 851         {
 852                 e_enemy = this.enemy;
 853                 m_score = this.turret_score_target(this,e_enemy) * this.target_select_samebias;
 854         }
 855         else
 856                 e_enemy = this.enemy = NULL;
 857
 858         e = findradius(this.origin, this.target_range);
 859
 860         // Nothing to aim at?
 861         if (!e)
 862                 return NULL;
 863
 864         while (e)
 865         {
 866                 if(e.takedamage)
 867                 {
 868                         float f = turret_validate_target(this, e, this.target_select_flags);
 869                         //dprint("F is: ", ftos(f), "\n");
 870                         if ( f > 0)
 871                         {
 872                                 score = this.turret_score_target(this,e);
 873                                 if ((score > m_score) && (score > 0))
 874                                 {
 875                                         e_enemy = e;
 876                                         m_score = score;
 877                                 }
 878                         }
 879                 }
 880                 e = e.chain;
 881         }
 882
 883         return e_enemy;
 884 }
 885
 886
 887 /*
 888  + = implemented
 889  - = not implemented
 890
 891  + TFL_FIRECHECK_NO
 892  + TFL_FIRECHECK_WORLD
 893  + TFL_FIRECHECK_DEAD
 894  + TFL_FIRECHECK_DISTANCES
 895  - TFL_FIRECHECK_LOS
 896  + TFL_FIRECHECK_AIMDIST
 897  + TFL_FIRECHECK_REALDIST
 898  - TFL_FIRECHECK_ANGLEDIST
 899  - TFL_FIRECHECK_TEAMCECK
 900  + TFL_FIRECHECK_AFF
 901  + TFL_FIRECHECK_AMMO_OWN
 902  + TFL_FIRECHECK_AMMO_OTHER
 903  + TFL_FIRECHECK_REFIRE
 904 */
 905
 906 /**
 907 ** Preforms pre-fire checks based on the uints firecheck_flags
 908 **/
 909 bool turret_firecheck(entity this)
 910 {
 911         // This one just dont care =)
 912         if (this.firecheck_flags & TFL_FIRECHECK_NO)
 913                 return true;
 914
 915         if (this.enemy == NULL)
 916                 return false;
 917
 918         // Ready?
 919         if (this.firecheck_flags & TFL_FIRECHECK_REFIRE)
 920                 if (this.attack_finished_single[0] > time) return false;
 921
 922         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 923         if (this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 924                 if (this.volly_counter != this.shot_volly)
 925                         if(this.ammo >= this.shot_dmg)
 926                                 return true;
 927
 928         // Lack of zombies makes shooting dead things unnecessary :P
 929         if (this.firecheck_flags & TFL_FIRECHECK_DEAD)
 930                 if (IS_DEAD(this.enemy))
 931                         return false;
 932
 933         // Own ammo?
 934         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 935                 if (this.ammo < this.shot_dmg)
 936                         return false;
 937
 938         // Other's ammo? (support-supply units)
 939         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 940                 if (this.enemy.ammo >= this.enemy.ammo_max)
 941                         return false;
 942
 943         // Target of opertunity?
 944         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 945         {
 946                 this.enemy = this.tur_impactent;
 947                 return true;
 948         }
 949
 950         if (this.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 951         {
 952                 // To close?
 953                 if (this.tur_dist_aimpos < this.target_range_min)
 954                 {
 955                         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 956                                 return true; // Target of opertunity?
 957                         return false;
 958                 }
 959         }
 960
 961         // Try to avoid FF?
 962         if (this.firecheck_flags & TFL_FIRECHECK_AFF)
 963                 if (this.tur_impactent.team == this.team)
 964                         return false;
 965
 966         // aim<->predicted impact
 967         if (this.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 968                 if (this.tur_dist_impact_to_aimpos > this.aim_firetolerance_dist)
 969                         return false;
 970
 971         // Volly status
 972         if (this.shot_volly > 1)
 973                 if (this.volly_counter == this.shot_volly)
 974                         if (this.ammo < (this.shot_dmg * this.shot_volly))
 975                                 return false;
 976
 977         /*if(this.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 978                 if(this.tur_impactent != this.enemy)
 979                         return false;*/
 980
 981         return true;
 982 }
 983
 984 bool turret_checkfire(entity this)
 985 {
 986         if(MUTATOR_CALLHOOK(Turret_CheckFire, this))
 987                 return M_ARGV(1, bool);
 988
 989         return this.turret_firecheckfunc(this);
 990 }
 991
 992 void turret_fire(entity this)
 993 {
 994         if (autocvar_g_turrets_nofire != 0)
 995                 return;
 996
 997         if(MUTATOR_CALLHOOK(TurretFire, this))
 998                 return;
 999
1000         Turret info = get_turretinfo(this.m_id);
1001         info.tr_attack(info, this);
1002
1003         this.attack_finished_single[0] = time + this.shot_refire;
1004         this.ammo -= this.shot_dmg;
1005         this.volly_counter = this.volly_counter - 1;
1006
1007         if (this.volly_counter <= 0)
1008         {
1009                 this.volly_counter = this.shot_volly;
1010
1011                 if (this.shoot_flags & TFL_SHOOT_CLEARTARGET)
1012                         this.enemy = NULL;
1013
1014                 if (this.shot_volly > 1)
1015                         this.attack_finished_single[0] = time + this.shot_volly_refire;
1016         }
1017
1018 #ifdef TURRET_DEBUG
1019         if (this.enemy) paint_target3(this.tur_aimpos, 64, this.tur_debug_rvec, this.tur_impacttime + 0.25);
1020 #endif
1021 }
1022
1023 void turret_think(entity this)
1024 {
1025         this.nextthink = time + this.ticrate;
1026
1027         MUTATOR_CALLHOOK(TurretThink, this);
1028
1029 #ifdef TURRET_DEBUG
1030         if (this.tur_debug_tmr1 < time)
1031         {
1032                 if (this.enemy) paint_target (this.enemy,128,this.tur_debug_rvec,0.9);
1033                 paint_target(this,256,this.tur_debug_rvec,0.9);
1034                 this.tur_debug_tmr1 = time + 1;
1035         }
1036 #endif
1037
1038         // Handle ammo
1039         if (!(this.spawnflags & TSF_NO_AMMO_REGEN))
1040         if (this.ammo < this.ammo_max)
1041                 this.ammo = min(this.ammo + this.ammo_recharge, this.ammo_max);
1042
1043         // Inactive turrets needs to run the think loop,
1044         // So they can handle animation and wake up if need be.
1045         if(!this.active)
1046         {
1047                 turret_track(this);
1048                 return;
1049         }
1050
1051         // This is typicaly used for zaping every target in range
1052         // turret_fusionreactor uses this to recharge friendlys.
1053         if (this.shoot_flags & TFL_SHOOT_HITALLVALID)
1054         {
1055                 // Do a this.turret_fire for every valid target.
1056                 entity e = findradius(this.origin,this.target_range);
1057                 while (e)
1058                 {
1059                         if(e.takedamage)
1060                         {
1061                                 if (turret_validate_target(this,e,this.target_validate_flags))
1062                                 {
1063                                         this.enemy = e;
1064
1065                                         turret_do_updates(this);
1066
1067                                         if (turret_checkfire(this))
1068                                                 turret_fire(this);
1069                                 }
1070                         }
1071
1072                         e = e.chain;
1073                 }
1074                 this.enemy = NULL;
1075         }
1076         else if(this.shoot_flags & TFL_SHOOT_CUSTOM)
1077         {
1078                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1079
1080                 // Predict?
1081                 if(!(this.aim_flags & TFL_AIM_NO))
1082                         this.tur_aimpos = turret_aim_generic(this);
1083
1084                 // Turn & pitch?
1085                 if(!(this.track_flags & TFL_TRACK_NO))
1086                         turret_track(this);
1087
1088                 turret_do_updates(this);
1089
1090                 // Fire?
1091                 if (turret_checkfire(this))
1092                         turret_fire(this);
1093         }
1094         else
1095         {
1096                 // Special case for volly always. if it fired once it must compleate the volly.
1097                 if(this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1098                         if(this.volly_counter != this.shot_volly)
1099                         {
1100                                 // Predict or whatnot
1101                                 if(!(this.aim_flags & TFL_AIM_NO))
1102                                         this.tur_aimpos = turret_aim_generic(this);
1103
1104                                 // Turn & pitch
1105                                 if(!(this.track_flags & TFL_TRACK_NO))
1106                                         turret_track(this);
1107
1108                                 turret_do_updates(this);
1109
1110                                 // Fire!
1111                                 if (turret_checkfire(this))
1112                                         turret_fire(this);
1113
1114                                 Turret tur = get_turretinfo(this.m_id);
1115                                 tur.tr_think(tur, this);
1116
1117                                 return;
1118                         }
1119
1120                 // Check if we have a vailid enemy, and try to find one if we dont.
1121
1122                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1123                 float do_target_scan = 0;
1124                 if((this.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1125                         do_target_scan = 1;
1126
1127                 // Old target (if any) invalid?
1128                 if(this.target_validate_time < time)
1129                 if (turret_validate_target(this, this.enemy, this.target_validate_flags) <= 0)
1130                 {
1131                         this.enemy = NULL;
1132                         this.target_validate_time = time + 0.5;
1133                         do_target_scan = 1;
1134                 }
1135
1136                 // But never more often then g_turrets_targetscan_mindelay!
1137                 if (this.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1138                         do_target_scan = 0;
1139
1140                 if(do_target_scan)
1141                 {
1142                         this.enemy = turret_select_target(this);
1143                         this.target_select_time = time;
1144                 }
1145
1146                 // No target, just go to idle, do any custom stuff and bail.
1147                 if (this.enemy == NULL)
1148                 {
1149                         // Turn & pitch
1150                         if(!(this.track_flags & TFL_TRACK_NO))
1151                                 turret_track(this);
1152
1153                         Turret tur = get_turretinfo(this.m_id);
1154                         tur.tr_think(tur, this);
1155
1156                         // And bail.
1157                         return;
1158                 }
1159                 else
1160                         this.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1161
1162                 // Predict?
1163                 if(!(this.aim_flags & TFL_AIM_NO))
1164                         this.tur_aimpos = turret_aim_generic(this);
1165
1166                 // Turn & pitch?
1167                 if(!(this.track_flags & TFL_TRACK_NO))
1168                         turret_track(this);
1169
1170                 turret_do_updates(this);
1171
1172                 // Fire?
1173                 if (turret_checkfire(this))
1174                         turret_fire(this);
1175         }
1176
1177         Turret tur = get_turretinfo(this.m_id);
1178         tur.tr_think(tur, this);
1179 }
1180
1181 /*
1182         When .used a turret switch team to activator.team.
1183         If activator is NULL, the turret go inactive.
1184 */
1185 void turret_use(entity this, entity actor, entity trigger)
1186 {
1187         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname);
1188
1189         this.team = actor.team;
1190
1191         if(this.team == 0)
1192                 this.active = ACTIVE_NOT;
1193         else
1194                 this.active = ACTIVE_ACTIVE;
1195
1196 }
1197
1198 void turret_link(entity this)
1199 {
1200         Net_LinkEntity(this, true, 0, turret_send);
1201         setthink(this, turret_think);
1202         this.nextthink = time;
1203         this.tur_head.effects = EF_NODRAW;
1204 }
1205
1206 void turrets_manager_think(entity this)
1207 {
1208         this.nextthink = time + 1;
1209
1210         if (autocvar_g_turrets_reloadcvars == 1)
1211         {
1212                 IL_EACH(g_turrets, true,
1213                 {
1214                         load_unit_settings(it, true);
1215                         Turret tur = get_turretinfo(it.m_id);
1216                         tur.tr_think(tur, it);
1217                 });
1218                 cvar_set("g_turrets_reloadcvars", "0");
1219         }
1220 }
1221
1222 void turret_initparams(entity tur)
1223 {
1224         #define TRY(x) (x) ? (x)
1225         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1226         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1227         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1228         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1229         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1230         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1231         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1232         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1233         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1234         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), max_shot_distance);
1235         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), max_shot_distance);
1236         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), max_shot_distance);
1237         tur.aim_maxrot                  = bound(0,               (TRY(tur.aim_maxrot)                :  90                                         ), 360);
1238         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1239         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1240         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), max_shot_distance);
1241         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1242         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1243         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1244         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1245         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1246         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1247         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1248         #undef TRY
1249 }
1250
1251 bool turret_closetotarget(entity this, vector targ, float range)
1252 {
1253         vector path_extra_size = '1 1 1' * range;
1254         return boxesoverlap(targ - path_extra_size, targ + path_extra_size, this.absmin - path_extra_size, this.absmax + path_extra_size);
1255 }
1256
1257 void turret_findtarget(entity this)
1258 {
1259         entity e = find(NULL, classname, "turret_manager");
1260         if(!e)
1261         {
1262                 e = new_pure(turret_manager);
1263                 setthink(e, turrets_manager_think);
1264                 e.nextthink = time + 2;
1265         }
1266
1267         entity targ = find(NULL, targetname, this.target);
1268         if(targ.classname == "turret_checkpoint")
1269                 return; // turrets don't defend checkpoints?
1270
1271         if (!targ)
1272         {
1273                 this.target = "";
1274                 LOG_TRACE("Turret has invalid defendpoint!");
1275         }
1276
1277         this.tur_defend = targ;
1278         this.idle_aim = this.tur_head.angles + angleofs(this.tur_head, targ);
1279 }
1280
1281 void turret_reset(entity this)
1282 {
1283         turret_respawn(this);
1284 }
1285
1286 bool turret_initialize(entity this, Turret tur)
1287 {
1288         if(!autocvar_g_turrets)
1289                 return false;
1290
1291         if(tur.m_id == 0)
1292                 return false; // invalid turret
1293
1294         // if tur_head exists, we can assume this turret re-spawned
1295         if(!this.tur_head) {
1296                 tur.tr_precache(tur);
1297                 IL_PUSH(g_turrets, this);
1298                 IL_PUSH(g_bot_targets, this);
1299         }
1300
1301         if(!(this.spawnflags & TSF_SUSPENDED))
1302                 DropToFloor_QC_DelayedInit(this);
1303
1304         this.netname = tur.netname;
1305         load_unit_settings(this, 0);
1306
1307         if(!this.team || !teamplay)             { this.team = FLOAT_MAX; }
1308         if(!this.ticrate)                               { this.ticrate = ((this.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1309         if(!GetResource(this, RES_HEALTH)) { SetResourceExplicit(this, RES_HEALTH, 1000); }
1310         if(!this.shot_refire)                   { this.shot_refire = 1; }
1311         if(!this.tur_shotorg)                   { this.tur_shotorg = '50 0 50'; }
1312         if(!this.turret_flags)                  { this.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1313         if(!this.damage_flags)                  { this.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1314         if(!this.aim_flags)                             { this.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1315         if(!this.track_type)                    { this.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1316         if(!this.track_flags)                   { this.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1317         if(!this.ammo_flags)                    { this.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1318         if(!this.target_select_flags)   { this.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1319         if(!this.firecheck_flags)               { this.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1320                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1321
1322         if(this.track_type != TFL_TRACKTYPE_STEPMOTOR)
1323         {
1324                 // Fluid / Ineria mode. Looks mutch nicer.
1325                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1326
1327                 this.aim_speed = bound(0.1, ((!this.aim_speed) ? 180 : this.aim_speed), 1000);
1328
1329                 if(!this.track_accel_pitch)             { this.track_accel_pitch = 0.5; }
1330                 if(!this.track_accel_rot)               { this.track_accel_rot = 0.5; }
1331                 if(!this.track_blendrate)               { this.track_blendrate = 0.35; }
1332         }
1333
1334         turret_initparams(this);
1335
1336         this.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1337
1338         if(this.turret_flags & TUR_FLAG_SPLASH)
1339                 this.aim_flags |= TFL_AIM_SPLASH;
1340
1341         if(this.turret_flags & TUR_FLAG_MISSILE)
1342                 this.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1343
1344         if(this.turret_flags & TUR_FLAG_PLAYER)
1345                 this.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1346
1347         if(this.spawnflags & TSL_NO_RESPAWN)
1348                 this.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1349
1350         if (this.turret_flags & TUR_FLAG_SUPPORT)
1351                 this.turret_score_target = turret_targetscore_support;
1352         else
1353                 this.turret_score_target = turret_targetscore_generic;
1354
1355         ++turret_count;
1356
1357         _setmodel(this, tur.model);
1358         setsize(this, tur.m_mins, tur.m_maxs);
1359
1360         this.m_id                                       = tur.m_id;
1361         this.active                                     = ACTIVE_ACTIVE;
1362         this.effects                            = EF_NODRAW;
1363         this.netname                            = tur.turret_name;
1364         this.ticrate                            = bound(sys_frametime, this.ticrate, 60);
1365         this.max_health                         = GetResource(this, RES_HEALTH);
1366         this.target_validate_flags      = this.target_select_flags;
1367         this.ammo                                       = this.ammo_max;
1368         this.ammo_recharge                 *= this.ticrate;
1369         this.solid                                      = SOLID_BBOX;
1370         this.takedamage                         = DAMAGE_AIM;
1371         set_movetype(this, MOVETYPE_NOCLIP);
1372         this.view_ofs                           = '0 0 0';
1373         this.idle_aim                           = '0 0 0';
1374         this.turret_firecheckfunc       = turret_firecheck;
1375         this.event_damage                       = turret_damage;
1376         this.event_heal                         = turret_heal;
1377         this.use                                        = turret_use;
1378         this.bot_attack                         = true;
1379         this.nextthink                          = time + 1 + turret_count * sys_frametime;
1380         this.reset                                      = turret_reset;
1381
1382         this.tur_head = new(turret_head);
1383         _setmodel(this.tur_head, tur.head_model);
1384         setsize(this.tur_head, '0 0 0', '0 0 0');
1385         setorigin(this.tur_head, '0 0 0');
1386         setattachment(this.tur_head, this, "tag_head");
1387
1388         this.tur_head.netname           = this.tur_head.classname;
1389         this.tur_head.team                      = this.team;
1390         this.tur_head.owner                     = this;
1391         this.tur_head.takedamage        = DAMAGE_NO;
1392         this.tur_head.solid                     = SOLID_NOT;
1393         set_movetype(this.tur_head, this.move_movetype);
1394
1395         this.weaponentities[0] = this; // lol
1396
1397         if(!this.tur_defend && this.target != "")
1398                 InitializeEntity(this, turret_findtarget, INITPRIO_FINDTARGET);
1399
1400 #ifdef TURRET_DEBUG
1401         this.tur_debug_start = this.nextthink;
1402         while(vdist(this.tur_debug_rvec, <, 2))
1403                 this.tur_debug_rvec = randomvec() * 4;
1404
1405         this.tur_debug_rvec_x = fabs(this.tur_debug_rvec_x);
1406         this.tur_debug_rvec_y = fabs(this.tur_debug_rvec_y);
1407         this.tur_debug_rvec_z = fabs(this.tur_debug_rvec_z);
1408 #endif
1409
1410         turret_link(this);
1411         turret_respawn(this);
1412         turret_tag_fire_update(this);
1413
1414         tur.tr_setup(tur, this);
1415
1416         if(MUTATOR_CALLHOOK(TurretSpawn, this))
1417                 return false;
1418
1419         return true;
1420 }
1421 #endif