qcsrc/common/turrets/turret/tesla_weapon.qc

   1 #include "tesla_weapon.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6
   7 entity toast(entity actor, entity from, float range, float damage);
   8 SOUND(TeslaCoilTurretAttack_FIRE, W_Sound("electro_fire"));
   9 METHOD(TeslaCoilTurretAttack, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire)) {
  10     bool isPlayer = IS_PLAYER(actor);
  11     if (fire & 1)
  12     if (!isPlayer || weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(electro, refire))) {
  13         if (isPlayer) {
  14             turret_initparams(actor);
  15             W_SetupShot_Dir(actor, weaponentity, v_forward, false, 0, SND_TeslaCoilTurretAttack_FIRE, CH_WEAPON_B, 0);
  16             actor.tur_shotdir_updated = w_shotdir;
  17             actor.tur_shotorg = w_shotorg;
  18             actor.tur_head = actor;
  19             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
  20         }
  21
  22         float d = actor.shot_dmg;
  23         float r = actor.target_range;
  24         entity e = spawn();
  25         setorigin(e, actor.tur_shotorg);
  26
  27         actor.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_MISSILES | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK;
  28
  29         entity t = toast(actor, e,r,d);
  30         delete(e);
  31
  32         if (t == NULL) return;
  33
  34         actor.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_MISSILES | TFL_TARGETSELECT_TEAMCHECK;
  35
  36         actor.attack_finished_single[0] = time + actor.shot_refire;
  37         for (int i = 0; i < 10; ++i) {
  38             d *= 0.75;
  39             r *= 0.85;
  40             t = toast(actor, t, r, d);
  41             if (t == NULL) break;
  42
  43         }
  44
  45         IL_EACH(g_railgunhit, it.railgunhit,
  46         {
  47             it.railgunhit = 0;
  48         });
  49         IL_CLEAR(g_railgunhit);
  50     }
  51 }
  52
  53 entity toast(entity actor, entity from, float range, float damage)
  54 {
  55     float dd = range + 1;
  56     entity etarget = NULL;
  57     FOREACH_ENTITY_RADIUS(from.origin, range, it != from && !it.railgunhit,
  58     {
  59         float r = turret_validate_target(actor, it, actor.target_validate_flags);
  60         if(r > 0)
  61         {
  62             traceline(from.origin, 0.5 * (it.absmin + it.absmax), MOVE_WORLDONLY, from);
  63             if(trace_fraction == 1.0)
  64             {
  65                 float d = vlen(it.origin - from.origin);
  66                 if(d < dd)
  67                 {
  68                     dd = d;
  69                     etarget = it;
  70                 }
  71             }
  72         }
  73     });
  74
  75     if (etarget)
  76     {
  77         te_csqc_lightningarc(from.origin, etarget.origin);
  78         Damage(etarget, actor, actor, damage, DEATH_TURRET_TESLA.m_id, etarget.origin, '0 0 0');
  79         etarget.railgunhit = 1;
  80         IL_PUSH(g_railgunhit, etarget);
  81     }
  82
  83     return etarget;
  84 }
  85
  86 #endif
  87
  88 #endif