reduce scope of variables
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / util.qc
1 #include "util.qh"
2
3 #if defined(CSQC)
4     #include "../client/defs.qh"
5     #include "constants.qh"
6         #include "../client/mutators/events.qh"
7     #include "mapinfo.qh"
8     #include "notifications/all.qh"
9     #include <common/deathtypes/all.qh>
10 #elif defined(MENUQC)
11 #elif defined(SVQC)
12     #include "constants.qh"
13     #include "../server/autocvars.qh"
14     #include "../server/defs.qh"
15         #include "../server/mutators/events.qh"
16     #include "notifications/all.qh"
17     #include <common/deathtypes/all.qh>
18     #include "mapinfo.qh"
19 #endif
20
21 #ifdef GAMEQC
22 /*
23 * Get "real" origin, in worldspace, even if ent is attached to something else.
24 */
25 vector real_origin(entity ent)
26 {
27         vector v = ((ent.absmin + ent.absmax) * 0.5);
28         entity e = ent.tag_entity;
29
30         while(e)
31         {
32                 v = v + ((e.absmin + e.absmax) * 0.5);
33                 e = e.tag_entity;
34         }
35
36         return v;
37 }
38 #endif
39
40 string wordwrap_buffer;
41
42 void wordwrap_buffer_put(string s)
43 {
44         wordwrap_buffer = strcat(wordwrap_buffer, s);
45 }
46
47 string wordwrap(string s, float l)
48 {
49         string r;
50         wordwrap_buffer = "";
51         wordwrap_cb(s, l, wordwrap_buffer_put);
52         r = wordwrap_buffer;
53         wordwrap_buffer = "";
54         return r;
55 }
56
57 #ifdef SVQC
58 entity _wordwrap_buffer_sprint_ent;
59 void wordwrap_buffer_sprint(string s)
60 {
61         wordwrap_buffer = strcat(wordwrap_buffer, s);
62         if(s == "\n")
63         {
64                 sprint(_wordwrap_buffer_sprint_ent, wordwrap_buffer);
65                 wordwrap_buffer = "";
66         }
67 }
68
69 void wordwrap_sprint(entity to, string s, float l)
70 {
71         wordwrap_buffer = "";
72         _wordwrap_buffer_sprint_ent = to;
73         wordwrap_cb(s, l, wordwrap_buffer_sprint);
74         _wordwrap_buffer_sprint_ent = NULL;
75         if(wordwrap_buffer != "")
76                 sprint(to, strcat(wordwrap_buffer, "\n"));
77         wordwrap_buffer = "";
78         return;
79 }
80 #endif
81
82 #ifndef SVQC
83 string draw_UseSkinFor(string pic)
84 {
85         if(substring(pic, 0, 1) == "/")
86                 return substring(pic, 1, strlen(pic)-1);
87         else
88                 return strcat(draw_currentSkin, "/", pic);
89 }
90 #endif
91
92 void wordwrap_cb(string s, float l, void(string) callback)
93 {
94         string c;
95         float lleft, i, j, wlen;
96
97         s = strzone(s);
98         lleft = l;
99         for (i = 0;i < strlen(s);++i)
100         {
101                 if (substring(s, i, 2) == "\\n")
102                 {
103                         callback("\n");
104                         lleft = l;
105                         ++i;
106                 }
107                 else if (substring(s, i, 1) == "\n")
108                 {
109                         callback("\n");
110                         lleft = l;
111                 }
112                 else if (substring(s, i, 1) == " ")
113                 {
114                         if (lleft > 0)
115                         {
116                                 callback(" ");
117                                 lleft = lleft - 1;
118                         }
119                 }
120                 else
121                 {
122                         for (j = i+1;j < strlen(s);++j)
123                                 //    ^^ this skips over the first character of a word, which
124                                 //       is ALWAYS part of the word
125                                 //       this is safe since if i+1 == strlen(s), i will become
126                                 //       strlen(s)-1 at the end of this block and the function
127                                 //       will terminate. A space can't be the first character we
128                                 //       read here, and neither can a \n be the start, since these
129                                 //       two cases have been handled above.
130                         {
131                                 c = substring(s, j, 1);
132                                 if (c == " ")
133                                         break;
134                                 if (c == "\\")
135                                         break;
136                                 if (c == "\n")
137                                         break;
138                                 // we need to keep this tempstring alive even if substring is
139                                 // called repeatedly, so call strcat even though we're not
140                                 // doing anything
141                                 callback("");
142                         }
143                         wlen = j - i;
144                         if (lleft < wlen)
145                         {
146                                 callback("\n");
147                                 lleft = l;
148                         }
149                         callback(substring(s, i, wlen));
150                         lleft = lleft - wlen;
151                         i = j - 1;
152                 }
153         }
154         strunzone(s);
155 }
156
157 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
158 {
159         entity e;
160         e = start;
161         funcPre(pass, e);
162         while (e.(downleft))
163         {
164                 e = e.(downleft);
165                 funcPre(pass, e);
166         }
167         funcPost(pass, e);
168         while(e != start)
169         {
170                 if (e.(right))
171                 {
172                         e = e.(right);
173                         funcPre(pass, e);
174                         while (e.(downleft))
175                         {
176                                 e = e.(downleft);
177                                 funcPre(pass, e);
178                         }
179                 }
180                 else
181                         e = e.(up);
182                 funcPost(pass, e);
183         }
184 }
185
186 string ScoreString(int pFlags, float pValue)
187 {
188         string valstr;
189         float l;
190
191         pValue = floor(pValue + 0.5); // round
192
193         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
194                 valstr = "";
195         else if(pFlags & SFL_RANK)
196         {
197                 valstr = ftos(pValue);
198                 l = strlen(valstr);
199                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
200                         valstr = strcat(valstr, "th");
201                 else if(substring(valstr, l - 1, 1) == "1")
202                         valstr = strcat(valstr, "st");
203                 else if(substring(valstr, l - 1, 1) == "2")
204                         valstr = strcat(valstr, "nd");
205                 else if(substring(valstr, l - 1, 1) == "3")
206                         valstr = strcat(valstr, "rd");
207                 else
208                         valstr = strcat(valstr, "th");
209         }
210         else if(pFlags & SFL_TIME)
211                 valstr = TIME_ENCODED_TOSTRING(pValue);
212         else
213                 valstr = ftos(pValue);
214
215         return valstr;
216 }
217
218 // compressed vector format:
219 // like MD3, just even shorter
220 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
221 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
222 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
223 //     length = 2^(length_encoded/8) / 8
224 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
225 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
226 // the special value 0 indicates the zero vector
227
228 float lengthLogTable[128];
229
230 float invertLengthLog(float dist)
231 {
232         int l, r, m;
233
234         if(dist >= lengthLogTable[127])
235                 return 127;
236         if(dist <= lengthLogTable[0])
237                 return 0;
238
239         l = 0;
240         r = 127;
241
242         while(r - l > 1)
243         {
244                 m = floor((l + r) / 2);
245                 if(lengthLogTable[m] < dist)
246                         l = m;
247                 else
248                         r = m;
249         }
250
251         // now: r is >=, l is <
252         float lerr = (dist - lengthLogTable[l]);
253         float rerr = (lengthLogTable[r] - dist);
254         if(lerr < rerr)
255                 return l;
256         return r;
257 }
258
259 vector decompressShortVector(int data)
260 {
261         vector out;
262         if(data == 0)
263                 return '0 0 0';
264         float p = (data & 0xF000) / 0x1000;
265         float q = (data & 0x0F80) / 0x80;
266         int len = (data & 0x007F);
267
268         //print("\ndecompress: p ", ftos(p)); print("q ", ftos(q)); print("len ", ftos(len), "\n");
269
270         if(p == 0)
271         {
272                 out.x = 0;
273                 out.y = 0;
274                 if(q == 31)
275                         out.z = -1;
276                 else
277                         out.z = +1;
278         }
279         else
280         {
281                 q   = .19634954084936207740 * q;
282                 p = .19634954084936207740 * p - 1.57079632679489661922;
283                 out.x = cos(q) *  cos(p);
284                 out.y = sin(q) *  cos(p);
285                 out.z =          -sin(p);
286         }
287
288         //print("decompressed: ", vtos(out), "\n");
289
290         return out * lengthLogTable[len];
291 }
292
293 float compressShortVector(vector vec)
294 {
295         vector ang;
296         float p, y, len;
297         if(vec == '0 0 0')
298                 return 0;
299         //print("compress: ", vtos(vec), "\n");
300         ang = vectoangles(vec);
301         ang.x = -ang.x;
302         if(ang.x < -90)
303                 ang.x += 360;
304         if(ang.x < -90 && ang.x > +90)
305                 error("BOGUS vectoangles");
306         //print("angles: ", vtos(ang), "\n");
307
308         p = floor(0.5 + (ang.x + 90) * 16 / 180) & 15; // -90..90 to 0..14
309         if(p == 0)
310         {
311                 if(vec.z < 0)
312                         y = 31;
313                 else
314                         y = 30;
315         }
316         else
317                 y = floor(0.5 + ang.y * 32 / 360)          & 31; // 0..360 to 0..32
318         len = invertLengthLog(vlen(vec));
319
320         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
321
322         return (p * 0x1000) + (y * 0x80) + len;
323 }
324
325 STATIC_INIT(compressShortVector)
326 {
327         float l = 1;
328         float f = pow(2, 1/8);
329         int i;
330         for(i = 0; i < 128; ++i)
331         {
332                 lengthLogTable[i] = l;
333                 l *= f;
334         }
335
336         if(cvar("developer"))
337         {
338                 LOG_INFO("Verifying vector compression table...\n");
339                 for(i = 0x0F00; i < 0xFFFF; ++i)
340                         if(i != compressShortVector(decompressShortVector(i)))
341                         {
342                                 LOG_INFO("BROKEN vector compression: ", ftos(i));
343                                 LOG_INFO(" -> ", vtos(decompressShortVector(i)));
344                                 LOG_INFO(" -> ", ftos(compressShortVector(decompressShortVector(i))));
345                                 LOG_INFO("\n");
346                                 error("b0rk");
347                         }
348                 LOG_INFO("Done.\n");
349         }
350 }
351
352 #ifdef GAMEQC
353 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
354 {
355         traceline(v0, v0 + dvx, true, forent); if(trace_fraction < 1) return 0;
356         traceline(v0, v0 + dvy, true, forent); if(trace_fraction < 1) return 0;
357         traceline(v0, v0 + dvz, true, forent); if(trace_fraction < 1) return 0;
358         traceline(v0 + dvx, v0 + dvx + dvy, true, forent); if(trace_fraction < 1) return 0;
359         traceline(v0 + dvx, v0 + dvx + dvz, true, forent); if(trace_fraction < 1) return 0;
360         traceline(v0 + dvy, v0 + dvy + dvx, true, forent); if(trace_fraction < 1) return 0;
361         traceline(v0 + dvy, v0 + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
362         traceline(v0 + dvz, v0 + dvz + dvx, true, forent); if(trace_fraction < 1) return 0;
363         traceline(v0 + dvz, v0 + dvz + dvy, true, forent); if(trace_fraction < 1) return 0;
364         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
365         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
366         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
367         return 1;
368 }
369 #endif
370
371 string fixPriorityList(string order, float from, float to, float subtract, float complete)
372 {
373         string neworder;
374         float i, n, w;
375
376         n = tokenize_console(order);
377         neworder = "";
378         for(i = 0; i < n; ++i)
379         {
380                 w = stof(argv(i));
381                 if(w == floor(w))
382                 {
383                         if(w >= from && w <= to)
384                                 neworder = strcat(neworder, ftos(w), " ");
385                         else
386                         {
387                                 w -= subtract;
388                                 if(w >= from && w <= to)
389                                         neworder = strcat(neworder, ftos(w), " ");
390                         }
391                 }
392         }
393
394         if(complete)
395         {
396                 n = tokenize_console(neworder);
397                 for(w = to; w >= from; --w)
398                 {
399                         int wflags = Weapons_from(w).spawnflags;
400                         if((wflags & WEP_FLAG_HIDDEN) && (wflags & WEP_FLAG_MUTATORBLOCKED) && !(wflags & WEP_FLAG_NORMAL))
401                                 continue;
402                         for(i = 0; i < n; ++i)
403                                 if(stof(argv(i)) == w)
404                                         break;
405                         if(i == n) // not found
406                                 neworder = strcat(neworder, ftos(w), " ");
407                 }
408         }
409
410         return substring(neworder, 0, strlen(neworder) - 1);
411 }
412
413 string mapPriorityList(string order, string(string) mapfunc)
414 {
415         string neworder;
416         float n;
417
418         n = tokenize_console(order);
419         neworder = "";
420         for(float i = 0; i < n; ++i)
421                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
422
423         return substring(neworder, 0, strlen(neworder) - 1);
424 }
425
426 string swapInPriorityList(string order, float i, float j)
427 {
428         float n = tokenize_console(order);
429
430         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
431         {
432                 string s = "";
433                 for(float w = 0; w < n; ++w)
434                 {
435                         if(w == i)
436                                 s = strcat(s, argv(j), " ");
437                         else if(w == j)
438                                 s = strcat(s, argv(i), " ");
439                         else
440                                 s = strcat(s, argv(w), " ");
441                 }
442                 return substring(s, 0, strlen(s) - 1);
443         }
444
445         return order;
446 }
447
448 #ifdef GAMEQC
449 void get_mi_min_max(float mode)
450 {
451         vector mi, ma;
452
453         if(mi_shortname)
454                 strunzone(mi_shortname);
455         mi_shortname = mapname;
456         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
457                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
458         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
459                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
460         mi_shortname = strzone(mi_shortname);
461
462 #ifdef CSQC
463         mi = world.mins;
464         ma = world.maxs;
465 #else
466         mi = world.absmin;
467         ma = world.absmax;
468 #endif
469
470         mi_min = mi;
471         mi_max = ma;
472         MapInfo_Get_ByName(mi_shortname, 0, NULL);
473         if(MapInfo_Map_mins.x < MapInfo_Map_maxs.x)
474         {
475                 mi_min = MapInfo_Map_mins;
476                 mi_max = MapInfo_Map_maxs;
477         }
478         else
479         {
480                 // not specified
481                 if(mode)
482                 {
483                         // be clever
484                         tracebox('1 0 0' * mi.x,
485                                          '0 1 0' * mi.y + '0 0 1' * mi.z,
486                                          '0 1 0' * ma.y + '0 0 1' * ma.z,
487                                          '1 0 0' * ma.x,
488                                          MOVE_WORLDONLY,
489                                          NULL);
490                         if(!trace_startsolid)
491                                 mi_min.x = trace_endpos.x;
492
493                         tracebox('0 1 0' * mi.y,
494                                          '1 0 0' * mi.x + '0 0 1' * mi.z,
495                                          '1 0 0' * ma.x + '0 0 1' * ma.z,
496                                          '0 1 0' * ma.y,
497                                          MOVE_WORLDONLY,
498                                          NULL);
499                         if(!trace_startsolid)
500                                 mi_min.y = trace_endpos.y;
501
502                         tracebox('0 0 1' * mi.z,
503                                          '1 0 0' * mi.x + '0 1 0' * mi.y,
504                                          '1 0 0' * ma.x + '0 1 0' * ma.y,
505                                          '0 0 1' * ma.z,
506                                          MOVE_WORLDONLY,
507                                          NULL);
508                         if(!trace_startsolid)
509                                 mi_min.z = trace_endpos.z;
510
511                         tracebox('1 0 0' * ma.x,
512                                          '0 1 0' * mi.y + '0 0 1' * mi.z,
513                                          '0 1 0' * ma.y + '0 0 1' * ma.z,
514                                          '1 0 0' * mi.x,
515                                          MOVE_WORLDONLY,
516                                          NULL);
517                         if(!trace_startsolid)
518                                 mi_max.x = trace_endpos.x;
519
520                         tracebox('0 1 0' * ma.y,
521                                          '1 0 0' * mi.x + '0 0 1' * mi.z,
522                                          '1 0 0' * ma.x + '0 0 1' * ma.z,
523                                          '0 1 0' * mi.y,
524                                          MOVE_WORLDONLY,
525                                          NULL);
526                         if(!trace_startsolid)
527                                 mi_max.y = trace_endpos.y;
528
529                         tracebox('0 0 1' * ma.z,
530                                          '1 0 0' * mi.x + '0 1 0' * mi.y,
531                                          '1 0 0' * ma.x + '0 1 0' * ma.y,
532                                          '0 0 1' * mi.z,
533                                          MOVE_WORLDONLY,
534                                          NULL);
535                         if(!trace_startsolid)
536                                 mi_max.z = trace_endpos.z;
537                 }
538         }
539 }
540
541 void get_mi_min_max_texcoords(float mode)
542 {
543         vector extend;
544
545         get_mi_min_max(mode);
546
547         mi_picmin = mi_min;
548         mi_picmax = mi_max;
549
550         // extend mi_picmax to get a square aspect ratio
551         // center the map in that area
552         extend = mi_picmax - mi_picmin;
553         if(extend.y > extend.x)
554         {
555                 mi_picmin.x -= (extend.y - extend.x) * 0.5;
556                 mi_picmax.x += (extend.y - extend.x) * 0.5;
557         }
558         else
559         {
560                 mi_picmin.y -= (extend.x - extend.y) * 0.5;
561                 mi_picmax.y += (extend.x - extend.y) * 0.5;
562         }
563
564         // add another some percent
565         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
566         mi_picmin -= extend;
567         mi_picmax += extend;
568
569         // calculate the texcoords
570         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
571         // first the two corners of the origin
572         mi_pictexcoord0_x = (mi_min.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
573         mi_pictexcoord0_y = (mi_min.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
574         mi_pictexcoord2_x = (mi_max.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
575         mi_pictexcoord2_y = (mi_max.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
576         // then the other corners
577         mi_pictexcoord1_x = mi_pictexcoord0_x;
578         mi_pictexcoord1_y = mi_pictexcoord2_y;
579         mi_pictexcoord3_x = mi_pictexcoord2_x;
580         mi_pictexcoord3_y = mi_pictexcoord0_y;
581 }
582 #endif
583
584 float cvar_settemp(string tmp_cvar, string tmp_value)
585 {
586         float created_saved_value;
587
588         created_saved_value = 0;
589
590         if (!(tmp_cvar || tmp_value))
591         {
592                 LOG_TRACE("Error: Invalid usage of cvar_settemp(string, string); !");
593                 return 0;
594         }
595
596         if(!cvar_type(tmp_cvar))
597         {
598                 LOG_INFOF("Error: cvar %s doesn't exist!\n", tmp_cvar);
599                 return 0;
600         }
601
602         IL_EACH(g_saved_cvars, it.netname == tmp_cvar,
603         {
604                 created_saved_value = -1; // skip creation
605                 break; // no need to continue
606         });
607
608         if(created_saved_value != -1)
609         {
610                 // creating a new entity to keep track of this cvar
611                 entity e = new_pure(saved_cvar_value);
612                 IL_PUSH(g_saved_cvars, e);
613                 e.netname = strzone(tmp_cvar);
614                 e.message = strzone(cvar_string(tmp_cvar));
615                 created_saved_value = 1;
616         }
617
618         // update the cvar to the value given
619         cvar_set(tmp_cvar, tmp_value);
620
621         return created_saved_value;
622 }
623
624 int cvar_settemp_restore()
625 {
626         int j = 0;
627         // FIXME this new-style loop fails!
628 #if 0
629         FOREACH_ENTITY_CLASS("saved_cvar_value", true,
630         {
631                 if(cvar_type(it.netname))
632                 {
633                         cvar_set(it.netname, it.message);
634                         strunzone(it.netname);
635                         strunzone(it.message);
636                         delete(it);
637                         ++j;
638                 }
639                 else
640                         LOG_INFOF("Error: cvar %s doesn't exist anymore! It can still be restored once it's manually recreated.\n", it.netname);
641         });
642
643 #else
644         entity e = NULL;
645         while((e = find(e, classname, "saved_cvar_value")))
646         {
647                 if(cvar_type(e.netname))
648                 {
649                         cvar_set(e.netname, e.message);
650                         delete(e);
651                         ++j;
652                 }
653                 else
654                         print(sprintf("Error: cvar %s doesn't exist anymore! It can still be restored once it's manually recreated.\n", e.netname));
655         }
656 #endif
657
658         return j;
659 }
660
661 bool isCaretEscaped(string theText, float pos)
662 {
663         int i = 0;
664         while(pos - i >= 1 && substring(theText, pos - i - 1, 1) == "^")
665                 ++i;
666         return (i & 1);
667 }
668
669 int skipIncompleteTag(string theText, float pos, int len)
670 {
671         int i = 0, ch = 0;
672         int tag_start = -1;
673
674         if(substring(theText, pos - 1, 1) == "^")
675         {
676                 if(isCaretEscaped(theText, pos - 1) || pos >= len)
677                         return 0;
678
679                 ch = str2chr(theText, pos);
680                 if(ch >= '0' && ch <= '9')
681                         return 1; // ^[0-9] color code found
682                 else if (ch == 'x')
683                         tag_start = pos - 1; // ^x tag found
684                 else
685                         return 0;
686         }
687         else
688         {
689                 for(i = 2; pos - i >= 0 && i <= 4; ++i)
690                 {
691                         if(substring(theText, pos - i, 2) == "^x")
692                         {
693                                 tag_start = pos - i; // ^x tag found
694                                 break;
695                         }
696                 }
697         }
698
699         if(tag_start >= 0)
700         {
701                 if(tag_start + 5 < len)
702                 if(IS_HEXDIGIT(substring(theText, tag_start + 2, 1)))
703                 if(IS_HEXDIGIT(substring(theText, tag_start + 3, 1)))
704                 if(IS_HEXDIGIT(substring(theText, tag_start + 4, 1)))
705                 {
706                         if(!isCaretEscaped(theText, tag_start))
707                                 return 5 - (pos - tag_start); // ^xRGB color code found
708                 }
709         }
710         return 0;
711 }
712
713 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
714 {
715         // STOP.
716         // The following function is SLOW.
717         // For your safety and for the protection of those around you...
718         // DO NOT CALL THIS AT HOME.
719         // No really, don't.
720         if(w(theText, theSize) <= maxWidth)
721                 return strlen(theText); // yeah!
722
723         bool colors = (w("^7", theSize) == 0);
724
725         // binary search for right place to cut string
726         int len, left, right, middle;
727         left = 0;
728         right = len = strlen(theText);
729         int ofs = 0;
730         do
731         {
732                 middle = floor((left + right) / 2);
733                 if(colors)
734                         ofs = skipIncompleteTag(theText, middle, len);
735                 if(w(substring(theText, 0, middle + ofs), theSize) <= maxWidth)
736                         left = middle + ofs;
737                 else
738                         right = middle;
739         }
740         while(left < right - 1);
741
742         return left;
743 }
744
745 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
746 {
747         // STOP.
748         // The following function is SLOW.
749         // For your safety and for the protection of those around you...
750         // DO NOT CALL THIS AT HOME.
751         // No really, don't.
752         if(w(theText) <= maxWidth)
753                 return strlen(theText); // yeah!
754
755         bool colors = (w("^7") == 0);
756
757         // binary search for right place to cut string
758         int len, left, right, middle;
759         left = 0;
760         right = len = strlen(theText);
761         int ofs = 0;
762         do
763         {
764                 middle = floor((left + right) / 2);
765                 if(colors)
766                         ofs = skipIncompleteTag(theText, middle, len);
767                 if(w(substring(theText, 0, middle + ofs)) <= maxWidth)
768                         left = middle + ofs;
769                 else
770                         right = middle;
771         }
772         while(left < right - 1);
773
774         return left;
775 }
776
777 string find_last_color_code(string s)
778 {
779         int start = strstrofs(s, "^", 0);
780         if (start == -1) // no caret found
781                 return "";
782         int len = strlen(s)-1;
783         int i;
784         for(i = len; i >= start; --i)
785         {
786                 if(substring(s, i, 1) != "^")
787                         continue;
788
789                 int carets = 1;
790                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
791                         ++carets;
792
793                 // check if carets aren't all escaped
794                 if (carets & 1)
795                 {
796                         if(i+1 <= len)
797                         if(IS_DIGIT(substring(s, i+1, 1)))
798                                 return substring(s, i, 2);
799
800                         if(i+4 <= len)
801                         if(substring(s, i+1, 1) == "x")
802                         if(IS_HEXDIGIT(substring(s, i + 2, 1)))
803                         if(IS_HEXDIGIT(substring(s, i + 3, 1)))
804                         if(IS_HEXDIGIT(substring(s, i + 4, 1)))
805                                 return substring(s, i, 5);
806                 }
807                 i -= carets; // this also skips one char before the carets
808         }
809
810         return "";
811 }
812
813 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
814 {
815         float cantake;
816         float take;
817         string s;
818
819         s = getWrappedLine_remaining;
820
821         if(w <= 0)
822         {
823                 getWrappedLine_remaining = string_null;
824                 return s; // the line has no size ANYWAY, nothing would be displayed.
825         }
826
827         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
828         if(cantake > 0 && cantake < strlen(s))
829         {
830                 take = cantake - 1;
831                 while(take > 0 && substring(s, take, 1) != " ")
832                         --take;
833                 if(take == 0)
834                 {
835                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
836                         if(getWrappedLine_remaining == "")
837                                 getWrappedLine_remaining = string_null;
838                         else if (tw("^7", theFontSize) == 0)
839                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
840                         return substring(s, 0, cantake);
841                 }
842                 else
843                 {
844                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
845                         if(getWrappedLine_remaining == "")
846                                 getWrappedLine_remaining = string_null;
847                         else if (tw("^7", theFontSize) == 0)
848                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
849                         return substring(s, 0, take);
850                 }
851         }
852         else
853         {
854                 getWrappedLine_remaining = string_null;
855                 return s;
856         }
857 }
858
859 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
860 {
861         float cantake;
862         float take;
863         string s;
864
865         s = getWrappedLine_remaining;
866
867         if(w <= 0)
868         {
869                 getWrappedLine_remaining = string_null;
870                 return s; // the line has no size ANYWAY, nothing would be displayed.
871         }
872
873         cantake = textLengthUpToLength(s, w, tw);
874         if(cantake > 0 && cantake < strlen(s))
875         {
876                 take = cantake - 1;
877                 while(take > 0 && substring(s, take, 1) != " ")
878                         --take;
879                 if(take == 0)
880                 {
881                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
882                         if(getWrappedLine_remaining == "")
883                                 getWrappedLine_remaining = string_null;
884                         else if (tw("^7") == 0)
885                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
886                         return substring(s, 0, cantake);
887                 }
888                 else
889                 {
890                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
891                         if(getWrappedLine_remaining == "")
892                                 getWrappedLine_remaining = string_null;
893                         else if (tw("^7") == 0)
894                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
895                         return substring(s, 0, take);
896                 }
897         }
898         else
899         {
900                 getWrappedLine_remaining = string_null;
901                 return s;
902         }
903 }
904
905 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
906 {
907         if(tw(theText, theFontSize) <= maxWidth)
908                 return theText;
909         else
910                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
911 }
912
913 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
914 {
915         if(tw(theText) <= maxWidth)
916                 return theText;
917         else
918                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
919 }
920
921 float isGametypeInFilter(Gametype gt, float tp, float ts, string pattern)
922 {
923         string subpattern, subpattern2, subpattern3, subpattern4;
924         subpattern = strcat(",", MapInfo_Type_ToString(gt), ",");
925         if(tp)
926                 subpattern2 = ",teams,";
927         else
928                 subpattern2 = ",noteams,";
929         if(ts)
930                 subpattern3 = ",teamspawns,";
931         else
932                 subpattern3 = ",noteamspawns,";
933         if(gt == MAPINFO_TYPE_RACE || gt == MAPINFO_TYPE_CTS)
934                 subpattern4 = ",race,";
935         else
936                 subpattern4 = string_null;
937
938         if(substring(pattern, 0, 1) == "-")
939         {
940                 pattern = substring(pattern, 1, strlen(pattern) - 1);
941                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
942                         return 0;
943                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
944                         return 0;
945                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
946                         return 0;
947                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
948                         return 0;
949         }
950         else
951         {
952                 if(substring(pattern, 0, 1) == "+")
953                         pattern = substring(pattern, 1, strlen(pattern) - 1);
954                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
955                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
956                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
957                 {
958                         if (!subpattern4)
959                                 return 0;
960                         if(strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
961                                 return 0;
962                 }
963         }
964         return 1;
965 }
966
967 vector solve_shotdirection(vector myorg, vector myvel, vector eorg, vector evel, float spd, float newton_style)
968 {
969         vector ret;
970
971         // make origin and speed relative
972         eorg -= myorg;
973         if(newton_style)
974                 evel -= myvel;
975
976         // now solve for ret, ret normalized:
977         //   eorg + t * evel == t * ret * spd
978         // or, rather, solve for t:
979         //   |eorg + t * evel| == t * spd
980         //   eorg^2 + t^2 * evel^2 + 2 * t * (eorg * evel) == t^2 * spd^2
981         //   t^2 * (evel^2 - spd^2) + t * (2 * (eorg * evel)) + eorg^2 == 0
982         vector solution = solve_quadratic(evel * evel - spd * spd, 2 * (eorg * evel), eorg * eorg);
983         // p = 2 * (eorg * evel) / (evel * evel - spd * spd)
984         // q = (eorg * eorg) / (evel * evel - spd * spd)
985         if(!solution.z) // no real solution
986         {
987                 // happens if D < 0
988                 // (eorg * evel)^2 < (evel^2 - spd^2) * eorg^2
989                 // (eorg * evel)^2 / eorg^2 < evel^2 - spd^2
990                 // spd^2 < ((evel^2 * eorg^2) - (eorg * evel)^2) / eorg^2
991                 // spd^2 < evel^2 * (1 - cos^2 angle(evel, eorg))
992                 // spd^2 < evel^2 * sin^2 angle(evel, eorg)
993                 // spd < |evel| * sin angle(evel, eorg)
994                 return '0 0 0';
995         }
996         else if(solution.x > 0)
997         {
998                 // both solutions > 0: take the smaller one
999                 // happens if p < 0 and q > 0
1000                 ret = normalize(eorg + solution.x * evel);
1001         }
1002         else if(solution.y > 0)
1003         {
1004                 // one solution > 0: take the larger one
1005                 // happens if q < 0 or q == 0 and p < 0
1006                 ret = normalize(eorg + solution.y * evel);
1007         }
1008         else
1009         {
1010                 // no solution > 0: reject
1011                 // happens if p > 0 and q >= 0
1012                 // 2 * (eorg * evel) / (evel * evel - spd * spd) > 0
1013                 // (eorg * eorg) / (evel * evel - spd * spd) >= 0
1014                 //
1015                 // |evel| >= spd
1016                 // eorg * evel > 0
1017                 //
1018                 // "Enemy is moving away from me at more than spd"
1019                 return '0 0 0';
1020         }
1021
1022         // NOTE: we always got a solution if spd > |evel|
1023
1024         if(newton_style == 2)
1025                 ret = normalize(ret * spd + myvel);
1026
1027         return ret;
1028 }
1029
1030 vector get_shotvelocity(vector myvel, vector mydir, float spd, float newton_style, float mi, float ma)
1031 {
1032         if(!newton_style)
1033                 return spd * mydir;
1034
1035         if(newton_style == 2)
1036         {
1037                 // true Newtonian projectiles with automatic aim adjustment
1038                 //
1039                 // solve: |outspeed * mydir - myvel| = spd
1040                 // outspeed^2 - 2 * outspeed * (mydir * myvel) + myvel^2 - spd^2 = 0
1041                 // outspeed = (mydir * myvel) +- sqrt((mydir * myvel)^2 - myvel^2 + spd^2)
1042                 // PLUS SIGN!
1043                 // not defined?
1044                 // then...
1045                 // myvel^2 - (mydir * myvel)^2 > spd^2
1046                 // velocity without mydir component > spd
1047                 // fire at smallest possible spd that works?
1048                 // |(mydir * myvel) * myvel - myvel| = spd
1049
1050                 vector solution = solve_quadratic(1, -2 * (mydir * myvel), myvel * myvel - spd * spd);
1051
1052                 float outspeed;
1053                 if(solution.z)
1054                         outspeed = solution.y; // the larger one
1055                 else
1056                 {
1057                         //outspeed = 0; // slowest possible shot
1058                         outspeed = solution.x; // the real part (that is, the average!)
1059                         //dprint("impossible shot, adjusting\n");
1060                 }
1061
1062                 outspeed = bound(spd * mi, outspeed, spd * ma);
1063                 return mydir * outspeed;
1064         }
1065
1066         // real Newtonian
1067         return myvel + spd * mydir;
1068 }
1069
1070 float compressShotOrigin(vector v)
1071 {
1072         float rx = rint(v.x * 2);
1073         float ry = rint(v.y * 4) + 128;
1074         float rz = rint(v.z * 4) + 128;
1075         if(rx > 255 || rx < 0)
1076         {
1077                 LOG_DEBUG("shot origin ", vtos(v), " x out of bounds\n");
1078                 rx = bound(0, rx, 255);
1079         }
1080         if(ry > 255 || ry < 0)
1081         {
1082                 LOG_DEBUG("shot origin ", vtos(v), " y out of bounds\n");
1083                 ry = bound(0, ry, 255);
1084         }
1085         if(rz > 255 || rz < 0)
1086         {
1087                 LOG_DEBUG("shot origin ", vtos(v), " z out of bounds\n");
1088                 rz = bound(0, rz, 255);
1089         }
1090         return rx * 0x10000 + ry * 0x100 + rz;
1091 }
1092 vector decompressShotOrigin(int f)
1093 {
1094         vector v;
1095         v.x = ((f & 0xFF0000) / 0x10000) / 2;
1096         v.y = ((f & 0xFF00) / 0x100 - 128) / 4;
1097         v.z = ((f & 0xFF) - 128) / 4;
1098         return v;
1099 }
1100
1101 #ifdef GAMEQC
1102 vector healtharmor_maxdamage(float h, float a, float armorblock, int deathtype)
1103 {
1104         // NOTE: we'll always choose the SMALLER value...
1105         float healthdamage, armordamage, armorideal;
1106         if (DEATH_IS(deathtype, DEATH_DROWN))  // Why should armor help here...
1107                 armorblock = 0;
1108         vector v;
1109         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1110         armordamage = a + (h - 1); // damage we can take if we could use more armor
1111         armorideal = healthdamage * armorblock;
1112         v.y = armorideal;
1113         if(armordamage < healthdamage)
1114         {
1115                 v.x = armordamage;
1116                 v.z = 1;
1117         }
1118         else
1119         {
1120                 v.x = healthdamage;
1121                 v.z = 0;
1122         }
1123         return v;
1124 }
1125
1126 vector healtharmor_applydamage(float a, float armorblock, int deathtype, float damage)
1127 {
1128         vector v;
1129         if (DEATH_IS(deathtype, DEATH_DROWN))  // Why should armor help here...
1130                 armorblock = 0;
1131         v.y = bound(0, damage * armorblock, a); // save
1132         v.x = bound(0, damage - v.y, damage); // take
1133         v.z = 0;
1134         return v;
1135 }
1136 #endif
1137
1138 string getcurrentmod()
1139 {
1140         float n;
1141         string m;
1142         m = cvar_string("fs_gamedir");
1143         n = tokenize_console(m);
1144         if(n == 0)
1145                 return "data";
1146         else
1147                 return argv(n - 1);
1148 }
1149
1150 float matchacl(string acl, string str)
1151 {
1152         string t, s;
1153         float r, d;
1154         r = 0;
1155         while(acl)
1156         {
1157                 t = car(acl); acl = cdr(acl);
1158
1159                 d = 1;
1160                 if(substring(t, 0, 1) == "-")
1161                 {
1162                         d = -1;
1163                         t = substring(t, 1, strlen(t) - 1);
1164                 }
1165                 else if(substring(t, 0, 1) == "+")
1166                         t = substring(t, 1, strlen(t) - 1);
1167
1168                 if(substring(t, -1, 1) == "*")
1169                 {
1170                         t = substring(t, 0, strlen(t) - 1);
1171                         s = substring(str, 0, strlen(t));
1172                 }
1173                 else
1174                         s = str;
1175
1176                 if(s == t)
1177                 {
1178                         r = d;
1179                 }
1180         }
1181         return r;
1182 }
1183
1184 string get_model_datafilename(string m, float sk, string fil)
1185 {
1186         if(m)
1187                 m = strcat(m, "_");
1188         else
1189                 m = "models/player/*_";
1190         if(sk >= 0)
1191                 m = strcat(m, ftos(sk));
1192         else
1193                 m = strcat(m, "*");
1194         return strcat(m, ".", fil);
1195 }
1196
1197 float get_model_parameters(string m, float sk)
1198 {
1199         get_model_parameters_modelname = string_null;
1200         get_model_parameters_modelskin = -1;
1201         get_model_parameters_name = string_null;
1202         get_model_parameters_species = -1;
1203         get_model_parameters_sex = string_null;
1204         get_model_parameters_weight = -1;
1205         get_model_parameters_age = -1;
1206         get_model_parameters_desc = string_null;
1207         get_model_parameters_bone_upperbody = string_null;
1208         get_model_parameters_bone_weapon = string_null;
1209         for(int i = 0; i < MAX_AIM_BONES; ++i)
1210         {
1211                 get_model_parameters_bone_aim[i] = string_null;
1212                 get_model_parameters_bone_aimweight[i] = 0;
1213         }
1214         get_model_parameters_fixbone = 0;
1215         get_model_parameters_hidden = false;
1216
1217 #ifdef GAMEQC
1218         MUTATOR_CALLHOOK(ClearModelParams);
1219 #endif
1220
1221         if (!m)
1222                 return 1;
1223
1224         if(substring(m, -9, 5) == "_lod1" || substring(m, -9, 5) == "_lod2")
1225                 m = strcat(substring(m, 0, -10), substring(m, -4, -1));
1226
1227         if(sk < 0)
1228         {
1229                 if(substring(m, -4, -1) != ".txt")
1230                         return 0;
1231                 if(substring(m, -6, 1) != "_")
1232                         return 0;
1233                 sk = stof(substring(m, -5, 1));
1234                 m = substring(m, 0, -7);
1235         }
1236
1237         string fn = get_model_datafilename(m, sk, "txt");
1238         int fh = fopen(fn, FILE_READ);
1239         if(fh < 0)
1240         {
1241                 sk = 0;
1242                 fn = get_model_datafilename(m, sk, "txt");
1243                 fh = fopen(fn, FILE_READ);
1244                 if(fh < 0)
1245                         return 0;
1246         }
1247
1248         get_model_parameters_modelname = m;
1249         get_model_parameters_modelskin = sk;
1250         string s, c;
1251         while((s = fgets(fh)))
1252         {
1253                 if(s == "")
1254                         break; // next lines will be description
1255                 c = car(s);
1256                 s = cdr(s);
1257                 if(c == "name")
1258                         get_model_parameters_name = s;
1259                 if(c == "species")
1260                         switch(s)
1261                         {
1262                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1263                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1264                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1265                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1266                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1267                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1268                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1269                         }
1270                 if(c == "sex")
1271                         get_model_parameters_sex = s;
1272                 if(c == "weight")
1273                         get_model_parameters_weight = stof(s);
1274                 if(c == "age")
1275                         get_model_parameters_age = stof(s);
1276                 if(c == "description")
1277                         get_model_parameters_description = s;
1278                 if(c == "bone_upperbody")
1279                         get_model_parameters_bone_upperbody = s;
1280                 if(c == "bone_weapon")
1281                         get_model_parameters_bone_weapon = s;
1282         #ifdef GAMEQC
1283                 MUTATOR_CALLHOOK(GetModelParams, c, s);
1284         #endif
1285                 for(int i = 0; i < MAX_AIM_BONES; ++i)
1286                         if(c == strcat("bone_aim", ftos(i)))
1287                         {
1288                                 get_model_parameters_bone_aimweight[i] = stof(car(s));
1289                                 get_model_parameters_bone_aim[i] = cdr(s);
1290                         }
1291                 if(c == "fixbone")
1292                         get_model_parameters_fixbone = stof(s);
1293                 if(c == "hidden")
1294                         get_model_parameters_hidden = stob(s);
1295         }
1296
1297         while((s = fgets(fh)))
1298         {
1299                 if(get_model_parameters_desc)
1300                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1301                 if(s != "")
1302                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1303         }
1304
1305         fclose(fh);
1306
1307         return 1;
1308 }
1309
1310 // x-encoding (encoding as zero length invisible string)
1311 const string XENCODE_2  = "xX";
1312 const string XENCODE_22 = "0123456789abcdefABCDEF";
1313 string xencode(int f)
1314 {
1315         float a, b, c, d;
1316         d = f % 22; f = floor(f / 22);
1317         c = f % 22; f = floor(f / 22);
1318         b = f % 22; f = floor(f / 22);
1319         a = f %  2; // f = floor(f /  2);
1320         return strcat(
1321                 "^",
1322                 substring(XENCODE_2,  a, 1),
1323                 substring(XENCODE_22, b, 1),
1324                 substring(XENCODE_22, c, 1),
1325                 substring(XENCODE_22, d, 1)
1326         );
1327 }
1328 float xdecode(string s)
1329 {
1330         float a, b, c, d;
1331         if(substring(s, 0, 1) != "^")
1332                 return -1;
1333         if(strlen(s) < 5)
1334                 return -1;
1335         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
1336         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
1337         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
1338         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
1339         if(a < 0 || b < 0 || c < 0 || d < 0)
1340                 return -1;
1341         return ((a * 22 + b) * 22 + c) * 22 + d;
1342 }
1343
1344 /*
1345 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
1346 {
1347         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
1348                 return input;
1349         else
1350                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
1351 }*/
1352
1353 float shutdown_running;
1354 #ifdef SVQC
1355 void SV_Shutdown()
1356 #endif
1357 #ifdef CSQC
1358 void CSQC_Shutdown()
1359 #endif
1360 #ifdef MENUQC
1361 void m_shutdown()
1362 #endif
1363 {
1364         if(shutdown_running)
1365         {
1366                 LOG_INFO("Recursive shutdown detected! Only restoring cvars...\n");
1367         }
1368         else
1369         {
1370                 shutdown_running = 1;
1371                 Shutdown();
1372                 shutdownhooks();
1373         }
1374         cvar_settemp_restore(); // this must be done LAST, but in any case
1375 }
1376
1377 #ifdef GAMEQC
1378 .float skeleton_bones_index;
1379 void Skeleton_SetBones(entity e)
1380 {
1381         // set skeleton_bones to the total number of bones on the model
1382         if(e.skeleton_bones_index == e.modelindex)
1383                 return; // same model, nothing to update
1384
1385         float skelindex;
1386         skelindex = skel_create(e.modelindex);
1387         e.skeleton_bones = skel_get_numbones(skelindex);
1388         skel_delete(skelindex);
1389         e.skeleton_bones_index = e.modelindex;
1390 }
1391 #endif
1392
1393 string to_execute_next_frame;
1394 void execute_next_frame()
1395 {
1396         if(to_execute_next_frame)
1397         {
1398                 localcmd("\n", to_execute_next_frame, "\n");
1399                 strunzone(to_execute_next_frame);
1400                 to_execute_next_frame = string_null;
1401         }
1402 }
1403 void queue_to_execute_next_frame(string s)
1404 {
1405         if(to_execute_next_frame)
1406         {
1407                 s = strcat(s, "\n", to_execute_next_frame);
1408                 strunzone(to_execute_next_frame);
1409         }
1410         to_execute_next_frame = strzone(s);
1411 }
1412
1413 .float FindConnectedComponent_processing;
1414 void FindConnectedComponent(entity e, .entity fld, findNextEntityNearFunction_t nxt, isConnectedFunction_t iscon, entity pass)
1415 {
1416         entity queue_start, queue_end;
1417
1418         // we build a queue of to-be-processed entities.
1419         // queue_start is the next entity to be checked for neighbors
1420         // queue_end is the last entity added
1421
1422         if(e.FindConnectedComponent_processing)
1423                 error("recursion or broken cleanup");
1424
1425         // start with a 1-element queue
1426         queue_start = queue_end = e;
1427         queue_end.(fld) = NULL;
1428         queue_end.FindConnectedComponent_processing = 1;
1429
1430         // for each queued item:
1431         for (; queue_start; queue_start = queue_start.(fld))
1432         {
1433                 // find all neighbors of queue_start
1434                 entity t;
1435                 for(t = NULL; (t = nxt(t, queue_start, pass)); )
1436                 {
1437                         if(t.FindConnectedComponent_processing)
1438                                 continue;
1439                         if(iscon(t, queue_start, pass))
1440                         {
1441                                 // it is connected? ADD IT. It will look for neighbors soon too.
1442                                 queue_end.(fld) = t;
1443                                 queue_end = t;
1444                                 queue_end.(fld) = NULL;
1445                                 queue_end.FindConnectedComponent_processing = 1;
1446                         }
1447                 }
1448         }
1449
1450         // unmark
1451         for (queue_start = e; queue_start; queue_start = queue_start.(fld))
1452                 queue_start.FindConnectedComponent_processing = 0;
1453 }
1454
1455 #ifdef GAMEQC
1456 vector animfixfps(entity e, vector a, vector b)
1457 {
1458         // multi-frame anim: keep as-is
1459         if(a.y == 1)
1460         {
1461                 float dur = frameduration(e.modelindex, a.x);
1462                 if (dur <= 0 && b.y)
1463                 {
1464                         a = b;
1465                         dur = frameduration(e.modelindex, a.x);
1466                 }
1467                 if (dur > 0)
1468                         a.z = 1.0 / dur;
1469         }
1470         return a;
1471 }
1472 #endif
1473
1474 #ifdef GAMEQC
1475 Notification Announcer_PickNumber(int type, int num)
1476 {
1477     return = NULL;
1478         switch (type)
1479         {
1480                 case CNT_GAMESTART:
1481                 {
1482                         switch(num)
1483                         {
1484                                 case 10: return ANNCE_NUM_GAMESTART_10;
1485                                 case 9:  return ANNCE_NUM_GAMESTART_9;
1486                                 case 8:  return ANNCE_NUM_GAMESTART_8;
1487                                 case 7:  return ANNCE_NUM_GAMESTART_7;
1488                                 case 6:  return ANNCE_NUM_GAMESTART_6;
1489                                 case 5:  return ANNCE_NUM_GAMESTART_5;
1490                                 case 4:  return ANNCE_NUM_GAMESTART_4;
1491                                 case 3:  return ANNCE_NUM_GAMESTART_3;
1492                                 case 2:  return ANNCE_NUM_GAMESTART_2;
1493                                 case 1:  return ANNCE_NUM_GAMESTART_1;
1494                         }
1495                         break;
1496                 }
1497                 case CNT_IDLE:
1498                 {
1499                         switch(num)
1500                         {
1501                                 case 10: return ANNCE_NUM_IDLE_10;
1502                                 case 9:  return ANNCE_NUM_IDLE_9;
1503                                 case 8:  return ANNCE_NUM_IDLE_8;
1504                                 case 7:  return ANNCE_NUM_IDLE_7;
1505                                 case 6:  return ANNCE_NUM_IDLE_6;
1506                                 case 5:  return ANNCE_NUM_IDLE_5;
1507                                 case 4:  return ANNCE_NUM_IDLE_4;
1508                                 case 3:  return ANNCE_NUM_IDLE_3;
1509                                 case 2:  return ANNCE_NUM_IDLE_2;
1510                                 case 1:  return ANNCE_NUM_IDLE_1;
1511                         }
1512                         break;
1513                 }
1514                 case CNT_KILL:
1515                 {
1516                         switch(num)
1517                         {
1518                                 case 10: return ANNCE_NUM_KILL_10;
1519                                 case 9:  return ANNCE_NUM_KILL_9;
1520                                 case 8:  return ANNCE_NUM_KILL_8;
1521                                 case 7:  return ANNCE_NUM_KILL_7;
1522                                 case 6:  return ANNCE_NUM_KILL_6;
1523                                 case 5:  return ANNCE_NUM_KILL_5;
1524                                 case 4:  return ANNCE_NUM_KILL_4;
1525                                 case 3:  return ANNCE_NUM_KILL_3;
1526                                 case 2:  return ANNCE_NUM_KILL_2;
1527                                 case 1:  return ANNCE_NUM_KILL_1;
1528                         }
1529                         break;
1530                 }
1531                 case CNT_RESPAWN:
1532                 {
1533                         switch(num)
1534                         {
1535                                 case 10: return ANNCE_NUM_RESPAWN_10;
1536                                 case 9:  return ANNCE_NUM_RESPAWN_9;
1537                                 case 8:  return ANNCE_NUM_RESPAWN_8;
1538                                 case 7:  return ANNCE_NUM_RESPAWN_7;
1539                                 case 6:  return ANNCE_NUM_RESPAWN_6;
1540                                 case 5:  return ANNCE_NUM_RESPAWN_5;
1541                                 case 4:  return ANNCE_NUM_RESPAWN_4;
1542                                 case 3:  return ANNCE_NUM_RESPAWN_3;
1543                                 case 2:  return ANNCE_NUM_RESPAWN_2;
1544                                 case 1:  return ANNCE_NUM_RESPAWN_1;
1545                         }
1546                         break;
1547                 }
1548                 case CNT_ROUNDSTART:
1549                 {
1550                         switch(num)
1551                         {
1552                                 case 10: return ANNCE_NUM_ROUNDSTART_10;
1553                                 case 9:  return ANNCE_NUM_ROUNDSTART_9;
1554                                 case 8:  return ANNCE_NUM_ROUNDSTART_8;
1555                                 case 7:  return ANNCE_NUM_ROUNDSTART_7;
1556                                 case 6:  return ANNCE_NUM_ROUNDSTART_6;
1557                                 case 5:  return ANNCE_NUM_ROUNDSTART_5;
1558                                 case 4:  return ANNCE_NUM_ROUNDSTART_4;
1559                                 case 3:  return ANNCE_NUM_ROUNDSTART_3;
1560                                 case 2:  return ANNCE_NUM_ROUNDSTART_2;
1561                                 case 1:  return ANNCE_NUM_ROUNDSTART_1;
1562                         }
1563                         break;
1564                 }
1565                 default:
1566                 {
1567                         switch(num)
1568                         {
1569                                 case 10: return ANNCE_NUM_10;
1570                                 case 9:  return ANNCE_NUM_9;
1571                                 case 8:  return ANNCE_NUM_8;
1572                                 case 7:  return ANNCE_NUM_7;
1573                                 case 6:  return ANNCE_NUM_6;
1574                                 case 5:  return ANNCE_NUM_5;
1575                                 case 4:  return ANNCE_NUM_4;
1576                                 case 3:  return ANNCE_NUM_3;
1577                                 case 2:  return ANNCE_NUM_2;
1578                                 case 1:  return ANNCE_NUM_1;
1579                         }
1580                         break;
1581                 }
1582         }
1583 }
1584 #endif
1585
1586 #ifdef GAMEQC
1587 int Mod_Q1BSP_SuperContentsFromNativeContents(int nativecontents)
1588 {
1589         switch(nativecontents)
1590         {
1591                 case CONTENT_EMPTY:
1592                         return 0;
1593                 case CONTENT_SOLID:
1594                         return DPCONTENTS_SOLID | DPCONTENTS_OPAQUE;
1595                 case CONTENT_WATER:
1596                         return DPCONTENTS_WATER;
1597                 case CONTENT_SLIME:
1598                         return DPCONTENTS_SLIME;
1599                 case CONTENT_LAVA:
1600                         return DPCONTENTS_LAVA | DPCONTENTS_NODROP;
1601                 case CONTENT_SKY:
1602                         return DPCONTENTS_SKY | DPCONTENTS_NODROP | DPCONTENTS_OPAQUE; // to match behaviour of Q3 maps, let sky count as opaque
1603         }
1604         return 0;
1605 }
1606
1607 int Mod_Q1BSP_NativeContentsFromSuperContents(int supercontents)
1608 {
1609         if(supercontents & (DPCONTENTS_SOLID | DPCONTENTS_BODY))
1610                 return CONTENT_SOLID;
1611         if(supercontents & DPCONTENTS_SKY)
1612                 return CONTENT_SKY;
1613         if(supercontents & DPCONTENTS_LAVA)
1614                 return CONTENT_LAVA;
1615         if(supercontents & DPCONTENTS_SLIME)
1616                 return CONTENT_SLIME;
1617         if(supercontents & DPCONTENTS_WATER)
1618                 return CONTENT_WATER;
1619         return CONTENT_EMPTY;
1620 }
1621 #endif