qcsrc/common/vehicles/sv_vehicles.qc

   1 #include "sv_vehicles.qh"
   2
   3 #if 0
   4 bool vehicle_send(entity to, int sf)
   5 {
   6         WriteByte(MSG_ENTITY, ENT_CLIENT_VEHICLE);
   7         WriteByte(MSG_ENTITY, sf);
   8
   9         if(sf & VSF_SPAWN)
  10         {
  11                 WriteByte(MSG_ENTITY, self.vehicleid);
  12         }
  13
  14         if(sf & VSF_SETUP)
  15         {
  16                 // send stuff?
  17         }
  18
  19         if(sf & VSF_ENTER)
  20         {
  21                 // player handles the .vehicle stuff, we need only set ourselves up for driving
  22
  23                 // send stuff?
  24         }
  25
  26         if(sf & VSF_EXIT)
  27         {
  28                 // senf stuff?
  29         }
  30
  31         if(sf & VSF_PRECACHE)
  32         {
  33                 // send stuff?!
  34         }
  35
  36         return true;
  37 }
  38 #endif
  39
  40 bool SendAuxiliaryXhair(entity this, entity to, int sf)
  41 {
  42
  43         WriteHeader(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  44
  45         WriteByte(MSG_ENTITY, this.cnt);
  46
  47         WriteCoord(MSG_ENTITY, this.origin_x);
  48         WriteCoord(MSG_ENTITY, this.origin_y);
  49         WriteCoord(MSG_ENTITY, this.origin_z);
  50
  51         WriteByte(MSG_ENTITY, rint(this.colormod_x * 255));
  52         WriteByte(MSG_ENTITY, rint(this.colormod_y * 255));
  53         WriteByte(MSG_ENTITY, rint(this.colormod_z * 255));
  54
  55         return true;
  56 }
  57
  58 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  59 {
  60         if(!IS_REAL_CLIENT(own))
  61                 return;
  62
  63         entity axh;
  64
  65         axh_id = bound(0, axh_id, MAX_AXH);
  66         axh = own.(AuxiliaryXhair[axh_id]);
  67
  68         if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  69         {
  70                 axh                                      = spawn();
  71                 axh.cnt                          = axh_id;
  72                 axh.drawonlytoclient    = own;
  73                 axh.owner                          = own;
  74                 Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  75         }
  76
  77         setorigin(axh, loc);
  78         axh.colormod                    = clr;
  79         axh.SendFlags              = 0x01;
  80         own.(AuxiliaryXhair[axh_id]) = axh;
  81 }
  82
  83 void CSQCVehicleSetup(entity own, int vehicle_id)
  84 {
  85         if(!IS_REAL_CLIENT(own))
  86                 return;
  87
  88         msg_entity = own;
  89
  90         WriteHeader(MSG_ONE, TE_CSQC_VEHICLESETUP);
  91         WriteByte(MSG_ONE, vehicle_id);
  92 }
  93
  94 void vehicles_locktarget(entity this, float incr, float decr, float _lock_time)
  95 {
  96         if(this.lock_target && IS_DEAD(this.lock_target))
  97         {
  98                 this.lock_target        = world;
  99                 this.lock_strength  = 0;
 100                 this.lock_time    = 0;
 101         }
 102
 103         if(this.lock_time > time)
 104         {
 105                 if(this.lock_target)
 106                 if(this.lock_soundtime < time)
 107                 {
 108                         this.lock_soundtime = time + 0.5;
 109                         play2(this.owner, "vehicles/locked.wav");
 110                 }
 111
 112                 return;
 113         }
 114
 115         if(trace_ent != world)
 116         {
 117                 if(SAME_TEAM(trace_ent, this))
 118                         trace_ent = world;
 119
 120                 if(IS_DEAD(trace_ent))
 121                         trace_ent = world;
 122
 123                 if(!(IS_VEHICLE(trace_ent) || IS_TURRET(trace_ent)))
 124                         trace_ent = world;
 125
 126                 if(trace_ent.alpha <= 0.5 && trace_ent.alpha != 0)
 127                         trace_ent = world; // invisible
 128         }
 129
 130         if(this.lock_target == world && trace_ent != world)
 131                 this.lock_target = trace_ent;
 132
 133         if(this.lock_target && trace_ent == this.lock_target)
 134         {
 135                 if(this.lock_strength != 1 && this.lock_strength + incr >= 1)
 136                 {
 137                         play2(this.owner, "vehicles/lock.wav");
 138                         this.lock_soundtime = time + 0.8;
 139                 }
 140                 else if (this.lock_strength != 1 && this.lock_soundtime < time)
 141                 {
 142                         play2(this.owner, "vehicles/locking.wav");
 143                         this.lock_soundtime = time + 0.3;
 144                 }
 145         }
 146
 147         // Have a locking target
 148         // Trace hit current target
 149         if(trace_ent == this.lock_target && trace_ent != world)
 150         {
 151                 this.lock_strength = min(this.lock_strength + incr, 1);
 152                 if(this.lock_strength == 1)
 153                         this.lock_time = time + _lock_time;
 154         }
 155         else
 156         {
 157                 if(trace_ent)
 158                         this.lock_strength = max(this.lock_strength - decr * 2, 0);
 159                 else
 160                         this.lock_strength = max(this.lock_strength - decr, 0);
 161
 162                 if(this.lock_strength == 0)
 163                         this.lock_target = world;
 164         }
 165 }
 166
 167 vector vehicles_force_fromtag_hover(entity this, string tag_name, float spring_length, float max_power)
 168 {
 169         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 170         v_forward  = normalize(v_forward) * -1;
 171         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 172
 173         force_fromtag_power = (1 - trace_fraction) * max_power;
 174         force_fromtag_normpower = force_fromtag_power / max_power;
 175
 176         return v_forward  * force_fromtag_power;
 177 }
 178
 179 vector vehicles_force_fromtag_maglev(entity this, string tag_name, float spring_length, float max_power)
 180 {
 181         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 182         v_forward  = normalize(v_forward) * -1;
 183         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 184
 185         // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 186         if(trace_fraction == 1.0)
 187         {
 188                 force_fromtag_normpower = -0.25;
 189                 return '0 0 -200';
 190         }
 191
 192         force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 193         force_fromtag_normpower = force_fromtag_power / max_power;
 194
 195         return v_forward  * force_fromtag_power;
 196 }
 197
 198 // projectile handling
 199 void vehicles_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 200 {
 201         // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 202         if(inflictor.owner == this.owner)
 203                 return;
 204
 205         this.health -= damage;
 206         this.velocity += force;
 207         if(this.health < 1)
 208         {
 209                 this.takedamage = DAMAGE_NO;
 210                 this.event_damage = func_null;
 211                 this.think = adaptor_think2use;
 212                 this.nextthink = time;
 213         }
 214 }
 215
 216 void vehicles_projectile_explode()
 217 {SELFPARAM();
 218         if(self.owner && other != world)
 219         {
 220                 if(other == self.owner.vehicle)
 221                         return;
 222
 223                 if(other == self.owner.vehicle.tur_head)
 224                         return;
 225         }
 226
 227         PROJECTILE_TOUCH;
 228
 229         self.event_damage = func_null;
 230         RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, world, self.shot_force, self.totalfrags, other);
 231
 232         remove (self);
 233 }
 234
 235 void vehicles_projectile_explode_use(entity this, entity actor, entity trigger)
 236 {
 237         WITHSELF(this, vehicles_projectile_explode());
 238 }
 239
 240 entity vehicles_projectile(entity this, string _mzlfx, Sound _mzlsound,
 241                                                    vector _org, vector _vel,
 242                                                    float _dmg, float _radi, float _force,  float _size,
 243                                                    int _deahtype, float _projtype, float _health,
 244                                                    bool _cull, bool _clianim, entity _owner)
 245 {
 246     TC(Sound, _mzlsound);
 247         entity proj;
 248
 249         proj = spawn();
 250
 251         PROJECTILE_MAKETRIGGER(proj);
 252         setorigin(proj, _org);
 253
 254         proj.shot_dmg            = _dmg;
 255         proj.shot_radius          = _radi;
 256         proj.shot_force    = _force;
 257         proj.totalfrags    = _deahtype;
 258         proj.solid                      = SOLID_BBOX;
 259         proj.movetype            = MOVETYPE_FLYMISSILE;
 260         proj.flags                      = FL_PROJECTILE;
 261         proj.bot_dodge          = true;
 262         proj.bot_dodgerating  = _dmg;
 263         proj.velocity            = _vel;
 264         proj.touch                      = vehicles_projectile_explode;
 265         proj.use1                         = vehicles_projectile_explode_use;
 266         proj.owner                      = this;
 267         proj.realowner          = _owner;
 268         proj.think                      = SUB_Remove_self;
 269         proj.nextthink          = time + 30;
 270
 271         if(_health)
 272         {
 273                 proj.takedamage    = DAMAGE_AIM;
 274                 proj.event_damage        = vehicles_projectile_damage;
 275                 proj.health                = _health;
 276         }
 277         else
 278                 proj.flags                 = FL_PROJECTILE | FL_NOTARGET;
 279
 280         if(_mzlsound != SND_Null)
 281                 sound (this, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 282
 283         if(_mzlfx)
 284                 Send_Effect_(_mzlfx, proj.origin, proj.velocity, 1);
 285
 286         setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 287
 288         CSQCProjectile(proj, _clianim, _projtype, _cull);
 289
 290         return proj;
 291 }
 292
 293 void vehicles_gib_explode()
 294 {SELFPARAM();
 295         sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 296         Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 297         Send_Effect(EFFECT_EXPLOSION_SMALL, self.wp00.origin + '0 0 64', '0 0 0', 1);
 298         remove(self);
 299 }
 300
 301 void vehicles_gib_think()
 302 {SELFPARAM();
 303         self.alpha -= 0.1;
 304         if(self.cnt >= time)
 305                 remove(self);
 306         else
 307                 self.nextthink = time + 0.1;
 308 }
 309
 310 entity vehicle_tossgib(entity this, entity _template, vector _vel, string _tag, bool _burn, bool _explode, float _maxtime, vector _rot)
 311 {
 312         entity _gib = spawn();
 313         _setmodel(_gib, _template.model);
 314         vector org = gettaginfo(this, gettagindex(this, _tag));
 315         setorigin(_gib, org);
 316         _gib.velocity = _vel;
 317         _gib.movetype = MOVETYPE_TOSS;
 318         _gib.solid = SOLID_CORPSE;
 319         _gib.colormod = '-0.5 -0.5 -0.5';
 320         _gib.effects = EF_LOWPRECISION;
 321         _gib.avelocity = _rot;
 322
 323         if(_burn)
 324                 _gib.effects |= EF_FLAME;
 325
 326         if(_explode)
 327         {
 328                 _gib.think = vehicles_gib_explode;
 329                 _gib.nextthink = time + random() * _explode;
 330                 _gib.touch = vehicles_gib_explode;
 331         }
 332         else
 333         {
 334                 _gib.cnt = time + _maxtime;
 335                 _gib.think = vehicles_gib_think;
 336                 _gib.nextthink = time + _maxtime - 1;
 337                 _gib.alpha = 1;
 338         }
 339         return _gib;
 340 }
 341
 342 bool vehicle_addplayerslot(     entity _owner,
 343                                                                 entity _slot,
 344                                                                 int _hud,
 345                                                                 Model _hud_model,
 346                                                                 bool(entity) _framefunc,
 347                                                                 void(bool) _exitfunc, float(entity, entity) _enterfunc)
 348 {
 349         if(!(_owner.vehicle_flags & VHF_MULTISLOT))
 350                 _owner.vehicle_flags |= VHF_MULTISLOT;
 351
 352         _slot.PlayerPhysplug = _framefunc;
 353         _slot.vehicle_exit = _exitfunc;
 354         _slot.vehicle_enter = _enterfunc;
 355         _slot.hud = _hud;
 356         _slot.vehicle_flags = VHF_PLAYERSLOT;
 357         _slot.vehicle_viewport = spawn();
 358         _slot.vehicle_hudmodel = spawn();
 359         _slot.vehicle_hudmodel.viewmodelforclient = _slot;
 360         _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 361
 362         setmodel(_slot.vehicle_hudmodel, _hud_model);
 363         setmodel(_slot.vehicle_viewport, MDL_Null);
 364
 365         setattachment(_slot.vehicle_hudmodel, _slot, "");
 366         setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
 367
 368         return true;
 369 }
 370
 371 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
 372                                                  float _pichlimit_min, float _pichlimit_max,
 373                                                  float _rotlimit_min, float _rotlimit_max, float _aimspeed)
 374 {
 375         vector vtmp, vtag;
 376         float ftmp;
 377         vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
 378         vtmp = vectoangles(normalize(_target - vtag));
 379         vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
 380         vtmp = AnglesTransform_Normalize(vtmp, true);
 381         ftmp = _aimspeed * frametime;
 382         vtmp_y = bound(-ftmp, vtmp_y, ftmp);
 383         vtmp_x = bound(-ftmp, vtmp_x, ftmp);
 384         _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
 385         _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
 386         return vtag;
 387 }
 388
 389 void vehicles_reset_colors(entity this)
 390 {
 391         int eff = 0, cmap;
 392         const vector cmod = '0 0 0';
 393         if(this.team && teamplay)
 394                 cmap = 1024 + (this.team - 1) * 17;
 395         else
 396                 cmap = 1024;
 397         if(autocvar_g_nodepthtestplayers)
 398                 eff |= EF_NODEPTHTEST;
 399         if(autocvar_g_fullbrightplayers)
 400                 eff |= EF_FULLBRIGHT;
 401
 402         // Find all ents attacked to main model and setup effects, colormod etc.
 403         FOREACH_ENTITY_ENT(tag_entity, this,
 404         {
 405                 if(it != this.vehicle_shieldent)
 406                 {
 407                         it.effects = eff;
 408                         it.colormod = cmod;
 409                         it.colormap = cmap;
 410                         it.alpha = 1;
 411                 }
 412         });
 413
 414         // Also check head tags
 415         FOREACH_ENTITY_ENT(tag_entity, this.tur_head,
 416         {
 417                 if(it != this.vehicle_shieldent)
 418                 {
 419                         it.effects = eff;
 420                         it.colormod = cmod;
 421                         it.colormap = cmap;
 422                         it.alpha = 1;
 423                 }
 424         });
 425
 426         this.vehicle_hudmodel.effects  = this.effects  = eff; // | EF_LOWPRECISION;
 427         this.vehicle_hudmodel.colormod = this.colormod = cmod;
 428         this.vehicle_hudmodel.colormap = this.colormap = cmap;
 429         this.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 430
 431         this.alpha       = 1;
 432         this.avelocity = '0 0 0';
 433         this.velocity  = '0 0 0';
 434         this.effects   = eff;
 435 }
 436
 437 void vehicles_clearreturn(entity veh)
 438 {
 439         // Remove "return helper", if any.
 440         for (entity ret = findchain(classname, "vehicle_return"); ret; ret = ret.chain)
 441         {
 442                 if(ret.wp00 == veh)
 443                 {
 444                         ret.classname   = "";
 445                         ret.think          = SUB_Remove_self;
 446                         ret.nextthink   = time + 0.1;
 447
 448                         if(ret.waypointsprite_attached)
 449                                 WaypointSprite_Kill(ret.waypointsprite_attached);
 450
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 void vehicles_spawn();
 457 void vehicles_return()
 458 {SELFPARAM();
 459         Send_Effect(EFFECT_TELEPORT, self.wp00.origin + '0 0 64', '0 0 0', 1);
 460
 461         self.wp00.think  = vehicles_spawn;
 462         self.wp00.nextthink = time;
 463
 464         if(self.waypointsprite_attached)
 465                 WaypointSprite_Kill(self.waypointsprite_attached);
 466
 467         remove(self);
 468 }
 469
 470 void vehicles_showwp_goaway()
 471 {SELFPARAM();
 472         if(self.waypointsprite_attached)
 473                 WaypointSprite_Kill(self.waypointsprite_attached);
 474
 475         remove(self);
 476
 477 }
 478
 479 void vehicles_showwp()
 480 {SELFPARAM();
 481         entity oldself = world;
 482         vector rgb;
 483
 484         if(self.cnt)
 485         {
 486                 self.think        = vehicles_return;
 487                 self.nextthink  = self.cnt;
 488         }
 489         else
 490         {
 491                 self.think        = vehicles_return;
 492                 self.nextthink  = time +1;
 493
 494                 oldself = self;
 495                 setself(spawn());
 496                 setmodel(self, MDL_Null);
 497                 self.team = oldself.wp00.team;
 498                 self.wp00 = oldself.wp00;
 499                 setorigin(self, oldself.wp00.pos1);
 500
 501                 self.nextthink = time + 5;
 502                 self.think = vehicles_showwp_goaway;
 503         }
 504
 505         if(teamplay && self.team)
 506                 rgb = Team_ColorRGB(self.team);
 507         else
 508                 rgb = '1 1 1';
 509         entity wp = WaypointSprite_Spawn(WP_Vehicle, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Vehicle);
 510         wp.colormod = rgb;
 511         if(self.waypointsprite_attached)
 512         {
 513                 WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
 514                 if(this == NULL)
 515                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 516                 WaypointSprite_Ping(self.waypointsprite_attached);
 517         }
 518
 519         if(this)
 520                 setself(this);
 521 }
 522
 523 void vehicles_setreturn(entity veh)
 524 {
 525         entity ret;
 526
 527         vehicles_clearreturn(veh);
 528
 529         ret = new(vehicle_return);
 530         ret.wp00           = veh;
 531         ret.team                = veh.team;
 532         ret.think          = vehicles_showwp;
 533
 534         if(IS_DEAD(veh))
 535         {
 536                 ret.cnt          = time + veh.respawntime;
 537                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 5);
 538         }
 539         else
 540         {
 541                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 1);
 542         }
 543
 544         setmodel(ret, MDL_Null);
 545         setorigin(ret, veh.pos1 + '0 0 96');
 546
 547 }
 548
 549 void vehicle_use(entity this, entity actor, entity trigger)
 550 {
 551         LOG_TRACE("vehicle ",this.netname, " used by ", actor.classname, "\n");
 552
 553         this.tur_head.team = actor.team;
 554
 555         if(this.tur_head.team == 0)
 556                 this.active = ACTIVE_NOT;
 557         else
 558                 this.active = ACTIVE_ACTIVE;
 559
 560         if(this.active == ACTIVE_ACTIVE && !IS_DEAD(this) && !gameover)
 561         {
 562                 LOG_TRACE("Respawning vehicle: ", this.netname, "\n");
 563                 if(this.effects & EF_NODRAW)
 564                 {
 565                         this.think = vehicles_spawn;
 566                         this.nextthink = time + 3;
 567                 }
 568                 else
 569                 {
 570                         vehicles_setreturn(this);
 571                         vehicles_reset_colors(this);
 572                 }
 573         }
 574 }
 575
 576 void vehicles_regen(entity this, float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 577 {
 578         if(this.(regen_field) < field_max)
 579         if(timer + rpause < time)
 580         {
 581                 if(_healthscale)
 582                         regen = regen * (this.vehicle_health / this.max_health);
 583
 584                 this.(regen_field) = min(this.(regen_field) + regen * delta_time, field_max);
 585
 586                 if(this.owner)
 587                         this.owner.(regen_field) = (this.(regen_field) / field_max) * 100;
 588         }
 589 }
 590
 591 void shieldhit_think()
 592 {SELFPARAM();
 593         self.alpha -= 0.1;
 594         if (self.alpha <= 0)
 595         {
 596                 // setmodel(self, MDL_Null);
 597                 self.alpha = -1;
 598                 self.effects |= EF_NODRAW;
 599         }
 600         else
 601         {
 602                 self.nextthink = time + 0.1;
 603         }
 604 }
 605
 606 void vehicles_painframe(entity this)
 607 {
 608         int myhealth = ((this.owner) ? this.owner.vehicle_health : ((this.vehicle_health / this.max_health) * 100));
 609
 610         if(myhealth <= 50)
 611         if(this.pain_frame < time)
 612         {
 613                 float _ftmp = myhealth / 50;
 614                 this.pain_frame = time + max(0.1, 0.1 + (random() * 0.5 * _ftmp));
 615                 Send_Effect(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);
 616
 617                 if(this.vehicle_flags & VHF_DMGSHAKE)
 618                         this.velocity += randomvec() * 30;
 619
 620                 if(this.vehicle_flags & VHF_DMGROLL)
 621                         if(this.vehicle_flags & VHF_DMGHEADROLL)
 622                                 this.tur_head.angles += randomvec();
 623                         else
 624                                 this.angles += randomvec();
 625         }
 626 }
 627
 628 void vehicles_frame(entity this, entity actor)
 629 {
 630         vehicles_painframe(this);
 631 }
 632
 633 void vehicles_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 634 {
 635         this.dmg_time = time;
 636
 637         // WEAPONTODO
 638         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 639                 damage *= autocvar_g_vehicles_vortex_damagerate;
 640
 641         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 642                 damage *= autocvar_g_vehicles_machinegun_damagerate;
 643
 644         if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 645                 damage *= autocvar_g_vehicles_rifle_damagerate;
 646
 647         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 648                 damage *= autocvar_g_vehicles_vaporizer_damagerate;
 649
 650         if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 651                 damage *= autocvar_g_vehicles_tag_damagerate;
 652
 653         if(DEATH_WEAPONOF(deathtype) != WEP_Null)
 654                 damage *= autocvar_g_vehicles_weapon_damagerate;
 655
 656         this.enemy = attacker;
 657
 658         this.pain_finished = time;
 659
 660         if((this.vehicle_flags & VHF_HASSHIELD) && (this.vehicle_shield > 0))
 661         {
 662                 if (wasfreed(this.vehicle_shieldent) || this.vehicle_shieldent == world)
 663                 {
 664                         this.vehicle_shieldent = spawn();
 665                         this.vehicle_shieldent.effects = EF_LOWPRECISION;
 666
 667                         setmodel(this.vehicle_shieldent, MDL_VEH_SHIELD);
 668                         setattachment(this.vehicle_shieldent, this, "");
 669                         setorigin(this.vehicle_shieldent, real_origin(this) - this.origin);
 670                         this.vehicle_shieldent.scale       = 256 / vlen(this.maxs - this.mins);
 671                         this.vehicle_shieldent.think       = shieldhit_think;
 672                 }
 673
 674                 this.vehicle_shieldent.colormod = '1 1 1';
 675                 this.vehicle_shieldent.alpha = 0.45;
 676                 this.vehicle_shieldent.angles = vectoangles(normalize(hitloc - (this.origin + this.vehicle_shieldent.origin))) - this.angles;
 677                 this.vehicle_shieldent.nextthink = time;
 678                 this.vehicle_shieldent.effects &= ~EF_NODRAW;
 679
 680                 this.vehicle_shield -= damage;
 681
 682                 if(this.vehicle_shield < 0)
 683                 {
 684                         this.vehicle_health -= fabs(this.vehicle_shield);
 685                         this.vehicle_shieldent.colormod = '2 0 0';
 686                         this.vehicle_shield = 0;
 687                         this.vehicle_shieldent.alpha = 0.75;
 688
 689                         if(sound_allowed(MSG_BROADCAST, attacker))
 690                                 spamsound (this, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 691                 }
 692                 else
 693                         if(sound_allowed(MSG_BROADCAST, attacker))
 694                                 spamsound (this, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 695
 696         }
 697         else
 698         {
 699                 this.vehicle_health -= damage;
 700
 701                 if(sound_allowed(MSG_BROADCAST, attacker))
 702                         spamsound (this, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 703         }
 704
 705         if(this.damageforcescale < 1 && this.damageforcescale > 0)
 706                 this.velocity += force * this.damageforcescale;
 707         else
 708                 this.velocity += force;
 709
 710         if(this.vehicle_health <= 0)
 711         {
 712                 if(this.owner)
 713                         if(this.vehicle_flags & VHF_DEATHEJECT)
 714                                 WITHSELF(this, vehicles_exit(VHEF_EJECT));
 715                         else
 716                                 WITHSELF(this, vehicles_exit(VHEF_RELEASE));
 717
 718
 719                 antilag_clear(this, this);
 720
 721                 Vehicle info = Vehicles_from(this.vehicleid);
 722                 info.vr_death(info, this);
 723                 vehicles_setreturn(this);
 724         }
 725 }
 726
 727 float vehicles_crushable(entity e)
 728 {
 729         if(IS_PLAYER(e) && time >= e.vehicle_enter_delay)
 730                 return true;
 731
 732         if(IS_MONSTER(e))
 733                 return true;
 734
 735         return false;
 736 }
 737
 738 void vehicles_impact(entity this, float _minspeed, float _speedfac, float _maxpain)
 739 {
 740         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 741                 return;
 742
 743         if(this.play_time < time)
 744         {
 745                 float wc = vlen(this.velocity - this.oldvelocity);
 746                 //dprint("oldvel: ", vtos(this.oldvelocity), "\n");
 747                 //dprint("vel: ", vtos(this.velocity), "\n");
 748                 if(_minspeed < wc)
 749                 {
 750                         float take = min(_speedfac * wc, _maxpain);
 751                         Damage (this, world, world, take, DEATH_FALL.m_id, this.origin, '0 0 0');
 752                         this.play_time = time + 0.25;
 753
 754                         //dprint("wc: ", ftos(wc), "\n");
 755                         //dprint("take: ", ftos(take), "\n");
 756                 }
 757         }
 758 }
 759
 760 // vehicle enter/exit handling
 761 vector vehicles_findgoodexit(vector prefer_spot)
 762 {SELFPARAM();
 763         //vector exitspot;
 764         float mysize;
 765
 766         tracebox(self.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, self.owner);
 767         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 768                 return prefer_spot;
 769
 770         mysize = 1.5 * vlen(self.maxs - self.mins);
 771         float i;
 772         vector v, v2;
 773         v2 = 0.5 * (self.absmin + self.absmax);
 774         for(i = 0; i < 100; ++i)
 775         {
 776                 v = randomvec();
 777                 v_z = 0;
 778                 v = v2 + normalize(v) * mysize;
 779                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, self.owner);
 780                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 781                         return v;
 782         }
 783
 784         /*
 785         exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 786         tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 787         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 788                 return exitspot;
 789
 790         exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 791         tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 792         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 793                 return exitspot;
 794
 795         exitspot = (self.origin + '0 0 48') + v_right * mysize;
 796         tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 797         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 798                 return exitspot;
 799
 800         exitspot = (self.origin + '0 0 48') - v_right * mysize;
 801         tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 802         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 803                 return exitspot;
 804         */
 805
 806         return self.origin;
 807 }
 808
 809 void vehicles_exit(bool eject)
 810 {SELFPARAM();
 811         entity _vehicle;
 812         entity _player;
 813
 814         if(vehicles_exit_running)
 815         {
 816                 LOG_TRACE("^1vehicles_exit allready running! this is not good..\n");
 817                 return;
 818         }
 819
 820         vehicles_exit_running = true;
 821         if(IS_CLIENT(self))
 822         {
 823                 _vehicle = self.vehicle;
 824
 825                 if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 826                 {
 827                         _vehicle.vehicle_exit(eject);
 828                         setself(this);
 829                         vehicles_exit_running = false;
 830                         return;
 831                 }
 832         }
 833         else
 834                 _vehicle = self;
 835
 836         _player = _vehicle.owner;
 837
 838         setself(_vehicle);
 839
 840         if (_player)
 841         {
 842                 if (IS_REAL_CLIENT(_player))
 843                 {
 844                         msg_entity = _player;
 845                         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 846                         WriteEntity( MSG_ONE, _player);
 847
 848                         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 849                         WriteAngle(MSG_ONE, 0);
 850                         WriteAngle(MSG_ONE, _vehicle.angles_y);
 851                         WriteAngle(MSG_ONE, 0);
 852                 }
 853
 854                 setsize(_player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 855
 856                 _player.takedamage              = DAMAGE_AIM;
 857                 _player.solid                   = SOLID_SLIDEBOX;
 858                 _player.movetype                = MOVETYPE_WALK;
 859                 _player.effects            &= ~EF_NODRAW;
 860                 _player.teleportable    = TELEPORT_NORMAL;
 861                 _player.alpha                   = 1;
 862                 _player.PlayerPhysplug  = func_null;
 863                 _player.vehicle                 = world;
 864                 _player.view_ofs                = STAT(PL_VIEW_OFS, NULL);
 865                 _player.event_damage    = PlayerDamage;
 866                 _player.hud                             = HUD_NORMAL;
 867                 PS(_player).m_switchweapon = _vehicle.m_switchweapon;
 868                 _player.last_vehiclecheck = time + 3;
 869                 _player.vehicle_enter_delay = time + 2;
 870
 871                 CSQCVehicleSetup(_player, HUD_NORMAL);
 872         }
 873         _vehicle.flags |= FL_NOTARGET;
 874
 875         if(!IS_DEAD(_vehicle))
 876                 _vehicle.avelocity = '0 0 0';
 877
 878         _vehicle.tur_head.nodrawtoclient = world;
 879
 880         if(!teamplay)
 881                 _vehicle.team = 0;
 882
 883         Kill_Notification(NOTIF_ONE, _player, MSG_CENTER, CPID_VEHICLES);
 884         Kill_Notification(NOTIF_ONE, _player, MSG_CENTER, CPID_VEHICLES_OTHER); // kill all vehicle notifications when exiting a vehicle?
 885
 886         WaypointSprite_Kill(_vehicle.wps_intruder);
 887
 888         MUTATOR_CALLHOOK(VehicleExit, _player, _vehicle);
 889
 890         _vehicle.team = _vehicle.tur_head.team;
 891
 892         sound (_vehicle, CH_TRIGGER_SINGLE, SND_Null, 1, ATTEN_NORM);
 893         _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 894         _vehicle.phase = time + 1;
 895
 896         _vehicle.vehicle_exit(eject);
 897
 898         vehicles_setreturn(_vehicle);
 899         vehicles_reset_colors(_vehicle);
 900         _vehicle.owner = world;
 901
 902         CSQCMODEL_AUTOINIT(self);
 903
 904         setself(this);
 905         vehicles_exit_running = false;
 906 }
 907
 908 void vehicles_touch()
 909 {SELFPARAM();
 910         if(MUTATOR_CALLHOOK(VehicleTouch, self, other))
 911                 return;
 912
 913         // Vehicle currently in use
 914         if(self.owner)
 915         {
 916                 if(!forbidWeaponUse(self.owner))
 917                 if(other != world)
 918                 if((self.origin_z + self.maxs_z) > (other.origin_z))
 919                 if(vehicles_crushable(other))
 920                 {
 921                         if(vdist(self.velocity, >=, 30))
 922                                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH.m_id, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 923
 924                         return; // Dont do selfdamage when hitting "soft targets".
 925                 }
 926
 927                 if(self.play_time < time) {
 928                         Vehicle info = Vehicles_from(self.vehicleid);
 929                         info.vr_impact(info, self);
 930                 }
 931
 932                 return;
 933         }
 934
 935         if(autocvar_g_vehicles_enter)
 936                 return;
 937
 938         vehicles_enter(other, self);
 939 }
 940
 941 bool vehicle_impulse(entity this, int imp)
 942 {
 943         entity v = this.vehicle;
 944         if (!v) return false;
 945         if (IS_DEAD(v)) return false;
 946         bool(int) f = v.vehicles_impulse;
 947         if (f && f(imp)) return true;
 948         switch (imp)
 949         {
 950                 case IMP_weapon_drop.impulse:
 951                 {
 952                         stuffcmd(self, "\ntoggle cl_eventchase_vehicle\nset _vehicles_shownchasemessage 1\n");
 953                         return true;
 954                 }
 955         }
 956         return false;
 957 }
 958
 959 void vehicles_enter(entity pl, entity veh)
 960 {
 961     SELFPARAM();
 962         entity oldself = self;
 963
 964    // Remove this when bots know how to use vehicles
 965         if((IS_BOT_CLIENT(pl) && !autocvar_g_vehicles_allow_bots))
 966                 return;
 967
 968         if((!IS_PLAYER(pl))
 969         || (veh.phase >= time)
 970         || (pl.vehicle_enter_delay >= time)
 971         || (STAT(FROZEN, pl))
 972         || (IS_DEAD(pl))
 973         || (pl.vehicle)
 974         ) { return; }
 975
 976         if(autocvar_g_vehicles_enter) // vehicle's touch function should handle this if entering via use key is disabled (TODO)
 977         if(veh.vehicle_flags & VHF_MULTISLOT)
 978         if(veh.owner)
 979         {
 980                 if(!veh.gunner1)
 981                 if(time >= veh.gun1.phase)
 982                 if(veh.gun1.vehicle_enter)
 983                 if(veh.gun1.vehicle_enter(veh, pl))
 984                         return;
 985
 986                 if(!veh.gunner2)
 987                 if(time >= veh.gun2.phase)
 988                 if(veh.gun2.vehicle_enter)
 989                 if(veh.gun2.vehicle_enter(veh, pl))
 990                         return;
 991         }
 992
 993         if(teamplay)
 994         if(veh.team)
 995         if(DIFF_TEAM(pl, veh))
 996         if(autocvar_g_vehicles_steal)
 997         {
 998                 FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, veh), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_VEHICLE_STEAL));
 999
1000                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_STEAL_SELF);
1001
1002                 if (autocvar_g_vehicles_steal_show_waypoint) {
1003                         entity wp = WaypointSprite_Spawn(WP_VehicleIntruder, 0, 0, pl, '0 0 68', world, veh.team, veh, wps_intruder, true, RADARICON_DANGER);
1004                         wp.colormod = Team_ColorRGB(pl.team);
1005                 }
1006         }
1007         else return;
1008
1009         RemoveGrapplingHook(pl);
1010
1011         veh.vehicle_ammo1 = 0;
1012         veh.vehicle_ammo2 = 0;
1013         veh.vehicle_reload1 = 0;
1014         veh.vehicle_reload2 = 0;
1015         veh.vehicle_energy = 0;
1016
1017         veh.owner = pl;
1018         pl.vehicle = veh;
1019
1020         // .viewmodelforclient works better.
1021         //veh.vehicle_hudmodel.drawonlytoclient = veh.owner;
1022
1023         veh.vehicle_hudmodel.viewmodelforclient = pl;
1024
1025         tracebox(pl.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), pl.origin, false, pl);
1026         pl.crouch = false;
1027         pl.view_ofs = STAT(PL_VIEW_OFS, NULL);
1028         setsize (pl, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
1029
1030         veh.event_damage        = vehicles_damage;
1031         veh.nextthink           = 0;
1032         pl.angles                       = veh.angles;
1033         pl.takedamage           = DAMAGE_NO;
1034         pl.solid                        = SOLID_NOT;
1035         pl.movetype                     = MOVETYPE_NOCLIP;
1036         pl.teleportable         = false;
1037         pl.alpha                        = -1;
1038         pl.event_damage         = func_null;
1039         pl.view_ofs                     = '0 0 0';
1040         veh.colormap            = pl.colormap;
1041         if(veh.tur_head)
1042                 veh.tur_head.colormap = pl.colormap;
1043         veh.m_switchweapon = PS(pl).m_switchweapon;
1044         pl.hud = veh.vehicleid;
1045         pl.PlayerPhysplug = veh.PlayerPhysplug;
1046
1047         pl.vehicle_ammo1 = veh.vehicle_ammo1;
1048         pl.vehicle_ammo2 = veh.vehicle_ammo2;
1049         pl.vehicle_reload1 = veh.vehicle_reload1;
1050         pl.vehicle_reload2 = veh.vehicle_reload2;
1051         pl.vehicle_energy = veh.vehicle_energy;
1052
1053         // Cant do this, hides attached objects too.
1054         //veh.exteriormodeltoclient = veh.owner;
1055         //veh.tur_head.exteriormodeltoclient = veh.owner;
1056
1057         UNSET_ONGROUND(pl);
1058         UNSET_ONGROUND(veh);
1059
1060         veh.team = pl.team;
1061         veh.flags -= FL_NOTARGET;
1062
1063         if (IS_REAL_CLIENT(pl))
1064         {
1065                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_ENTER);
1066
1067                 msg_entity = pl;
1068                 WriteByte (MSG_ONE, SVC_SETVIEWPORT);
1069                 WriteEntity(MSG_ONE, veh.vehicle_viewport);
1070
1071                 WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1072                 if(veh.tur_head)
1073                 {
1074                         WriteAngle(MSG_ONE, veh.tur_head.angles_x + veh.angles_x); // tilt
1075                         WriteAngle(MSG_ONE, veh.tur_head.angles_y + veh.angles_y); // yaw
1076                         WriteAngle(MSG_ONE, 0);                                                                   // roll
1077                 }
1078                 else
1079                 {
1080                         WriteAngle(MSG_ONE, veh.angles_x * -1); // tilt
1081                         WriteAngle(MSG_ONE, veh.angles_y);        // yaw
1082                         WriteAngle(MSG_ONE, 0);                           // roll
1083                 }
1084         }
1085
1086         vehicles_clearreturn(veh);
1087
1088         CSQCVehicleSetup(pl, veh.vehicleid);
1089
1090         MUTATOR_CALLHOOK(VehicleEnter, pl, veh);
1091
1092         setself(veh);
1093         CSQCModel_UnlinkEntity(veh);
1094         Vehicle info = Vehicles_from(veh.vehicleid);
1095         info.vr_enter(info, veh);
1096         setself(oldself);
1097
1098         antilag_clear(pl, CS(pl));
1099 }
1100
1101 void vehicles_think()
1102 {SELFPARAM();
1103         self.nextthink = time;
1104
1105         if(self.owner)
1106                 self.owner.vehicle_weapon2mode = self.vehicle_weapon2mode;
1107
1108         Vehicle info = Vehicles_from(self.vehicleid);
1109         info.vr_think(info, self);
1110
1111         vehicles_painframe(self);
1112
1113         CSQCMODEL_AUTOUPDATE(self);
1114 }
1115
1116 // initialization
1117 void vehicles_spawn()
1118 {SELFPARAM();
1119         LOG_TRACE("Spawning vehicle: ", self.classname, "\n");
1120
1121         // disown & reset
1122         self.vehicle_hudmodel.viewmodelforclient = self;
1123
1124         self.owner                              = world;
1125         self.touch                              = vehicles_touch;
1126         self.event_damage               = vehicles_damage;
1127         self.iscreature                 = true;
1128         self.teleportable               = false; // no teleporting for vehicles, too buggy
1129         self.damagedbycontents  = true;
1130         self.movetype                   = MOVETYPE_WALK;
1131         self.solid                              = SOLID_SLIDEBOX;
1132         self.takedamage                 = DAMAGE_AIM;
1133         self.deadflag                   = DEAD_NO;
1134         self.bot_attack                 = true;
1135         self.flags                              = FL_NOTARGET;
1136         self.avelocity                  = '0 0 0';
1137         self.velocity                   = '0 0 0';
1138         self.think                              = vehicles_think;
1139         self.nextthink                  = time;
1140
1141         // Reset locking
1142         self.lock_strength = 0;
1143         self.lock_target = world;
1144         self.misc_bulletcounter = 0;
1145
1146         // Return to spawn
1147         self.angles = self.pos2;
1148         setorigin(self, self.pos1);
1149         // Show it
1150         Send_Effect(EFFECT_TELEPORT, self.origin + '0 0 64', '0 0 0', 1);
1151
1152         if(self.vehicle_controller)
1153                 self.team = self.vehicle_controller.team;
1154
1155         FOREACH_CLIENT(IS_PLAYER(it) && it.hook.aiment == self, RemoveGrapplingHook(it));
1156
1157         vehicles_reset_colors(self);
1158
1159         Vehicle info = Vehicles_from(self.vehicleid);
1160         info.vr_spawn(info, self);
1161
1162         CSQCMODEL_AUTOINIT(self);
1163 }
1164
1165 bool vehicle_initialize(entity this, Vehicle info, bool nodrop)
1166 {
1167         if(!autocvar_g_vehicles)
1168                 return false;
1169
1170         if(!info.vehicleid)
1171                 return false;
1172
1173         if(!this.tur_head)
1174                 info.vr_precache(info);
1175
1176         if(this.targetname && this.targetname != "")
1177         {
1178                 this.vehicle_controller = find(world, target, this.targetname);
1179                 if(!this.vehicle_controller)
1180                 {
1181                         bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1182                         this.active = ACTIVE_ACTIVE;
1183                 }
1184                 else
1185                 {
1186                         this.team = this.vehicle_controller.team;
1187                         this.use1 = vehicle_use;
1188
1189                         if(teamplay)
1190                         {
1191                                 if(this.vehicle_controller.team == 0)
1192                                         this.active = ACTIVE_NOT;
1193                                 else
1194                                         this.active = ACTIVE_ACTIVE;
1195                         }
1196                 }
1197         }
1198         else { this.active = ACTIVE_ACTIVE; }
1199
1200         if(this.team && (!teamplay || !autocvar_g_vehicles_teams))
1201                 this.team = 0;
1202
1203         if(this.mdl == "" || !this.mdl)
1204                 _setmodel(this, info.model);
1205         else
1206                 _setmodel(this, this.mdl);
1207
1208         this.vehicle_flags |= VHF_ISVEHICLE;
1209
1210         this.vehicle_viewport           = new(vehicle_viewport);
1211         this.vehicle_hudmodel           = new(vehicle_hudmodel);
1212         this.tur_head                           = new(tur_head);
1213         this.tur_head.owner                     = this;
1214         this.takedamage                         = DAMAGE_NO;
1215         this.bot_attack                         = true;
1216         this.iscreature                         = true;
1217         this.teleportable                       = false; // no teleporting for vehicles, too buggy
1218         this.damagedbycontents          = true;
1219         this.vehicleid                          = info.vehicleid;
1220         this.PlayerPhysplug                     = info.PlayerPhysplug;
1221         this.event_damage                       = func_null;
1222         this.touch                                      = vehicles_touch;
1223         this.think                                      = vehicles_spawn;
1224         this.nextthink                          = time;
1225         this.effects                            = EF_NODRAW;
1226         this.dphitcontentsmask          = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1227
1228         if(autocvar_g_playerclip_collisions)
1229                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1230
1231         if(autocvar_g_nodepthtestplayers)
1232                 this.effects |= EF_NODEPTHTEST;
1233
1234         if(autocvar_g_fullbrightplayers)
1235                 this.effects |= EF_FULLBRIGHT;
1236
1237         _setmodel(this.vehicle_hudmodel, info.hud_model);
1238         setmodel(this.vehicle_viewport, MDL_Null);
1239
1240         if(info.head_model != "")
1241         {
1242                 _setmodel(this.tur_head, info.head_model);
1243                 setattachment(this.tur_head, this, info.tag_head);
1244                 setattachment(this.vehicle_hudmodel, this.tur_head, info.tag_hud);
1245                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1246         }
1247         else
1248         {
1249                 setattachment(this.tur_head, this, "");
1250                 setattachment(this.vehicle_hudmodel, this, info.tag_hud);
1251                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1252         }
1253
1254         setsize(this, info.mins, info.maxs);
1255
1256         if(!nodrop)
1257         {
1258                 setorigin(this, this.origin);
1259                 tracebox(this.origin + '0 0 100', info.mins, info.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1260                 setorigin(this, trace_endpos);
1261         }
1262
1263         this.pos1 = this.origin;
1264         this.pos2 = this.angles;
1265         this.tur_head.team = this.team;
1266
1267         info.vr_setup(info, this);
1268
1269         if(this.active == ACTIVE_NOT)
1270                 this.nextthink = 0; // wait until activated
1271         else if(autocvar_g_vehicles_delayspawn)
1272                 this.nextthink = time + this.respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1273         else
1274                 this.nextthink = time + game_starttime;
1275
1276         if(MUTATOR_CALLHOOK(VehicleSpawn, this))
1277                 return false;
1278
1279         return true;
1280 }