qcsrc/common/vehicles/sv_vehicles.qc

   1 #include "sv_vehicles.qh"
   2
   3 bool SendAuxiliaryXhair(entity this, entity to, int sf)
   4 {
   5         WriteHeader(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
   6         WriteByte(MSG_ENTITY, sf);
   7
   8         WriteByte(MSG_ENTITY, this.cnt);
   9
  10         if(sf & 2)
  11         {
  12                 WriteCoord(MSG_ENTITY, this.origin_x);
  13                 WriteCoord(MSG_ENTITY, this.origin_y);
  14                 WriteCoord(MSG_ENTITY, this.origin_z);
  15         }
  16
  17         if(sf & 4)
  18         {
  19                 WriteByte(MSG_ENTITY, rint(this.colormod_x * 255));
  20                 WriteByte(MSG_ENTITY, rint(this.colormod_y * 255));
  21                 WriteByte(MSG_ENTITY, rint(this.colormod_z * 255));
  22         }
  23
  24         return true;
  25 }
  26
  27 .vector axh_prevorigin;
  28 .vector axh_prevcolors;
  29
  30 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  31 {
  32         if(!IS_REAL_CLIENT(own))
  33                 return;
  34
  35         axh_id = bound(0, axh_id, MAX_AXH);
  36         entity axh = own.(AuxiliaryXhair[axh_id]);
  37
  38         if(axh == NULL || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist? Mario: because of sloppy code like this)
  39         {
  40                 axh = new(auxiliary_xhair);
  41                 axh.cnt = axh_id;
  42                 axh.drawonlytoclient = own;
  43                 axh.owner = own;
  44                 Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  45         }
  46
  47         if(loc != axh.axh_prevorigin)
  48         {
  49                 setorigin(axh, loc);
  50                 axh.SendFlags |= 2;
  51         }
  52
  53         if(clr != axh.axh_prevcolors)
  54         {
  55                 axh.colormod = clr;
  56                 axh.SendFlags |= 4;
  57         }
  58
  59         own.(AuxiliaryXhair[axh_id]) = axh; // set it anyway...?
  60 }
  61
  62 void CSQCVehicleSetup(entity own, int vehicle_id)
  63 {
  64         if(!IS_REAL_CLIENT(own))
  65                 return;
  66
  67         msg_entity = own;
  68
  69         WriteHeader(MSG_ONE, TE_CSQC_VEHICLESETUP);
  70         WriteByte(MSG_ONE, vehicle_id);
  71 }
  72
  73 void vehicles_locktarget(entity this, float incr, float decr, float _lock_time)
  74 {
  75         if(this.lock_target && IS_DEAD(this.lock_target))
  76         {
  77                 this.lock_target        = NULL;
  78                 this.lock_strength  = 0;
  79                 this.lock_time    = 0;
  80         }
  81
  82         if(this.lock_time > time)
  83         {
  84                 if(this.lock_target)
  85                 if(this.lock_soundtime < time)
  86                 {
  87                         this.lock_soundtime = time + 0.5;
  88                         play2(this.owner, "vehicles/locked.wav");
  89                 }
  90
  91                 return;
  92         }
  93
  94         if(trace_ent != NULL)
  95         {
  96                 if(SAME_TEAM(trace_ent, this))
  97                         trace_ent = NULL;
  98
  99                 if(IS_DEAD(trace_ent))
 100                         trace_ent = NULL;
 101
 102                 if(!(IS_VEHICLE(trace_ent) || IS_TURRET(trace_ent)))
 103                         trace_ent = NULL;
 104
 105                 if(trace_ent.alpha <= 0.5 && trace_ent.alpha != 0)
 106                         trace_ent = NULL; // invisible
 107         }
 108
 109         if(this.lock_target == NULL && trace_ent != NULL)
 110                 this.lock_target = trace_ent;
 111
 112         if(this.lock_target && trace_ent == this.lock_target)
 113         {
 114                 if(this.lock_strength != 1 && this.lock_strength + incr >= 1)
 115                 {
 116                         play2(this.owner, "vehicles/lock.wav");
 117                         this.lock_soundtime = time + 0.8;
 118                 }
 119                 else if (this.lock_strength != 1 && this.lock_soundtime < time)
 120                 {
 121                         play2(this.owner, "vehicles/locking.wav");
 122                         this.lock_soundtime = time + 0.3;
 123                 }
 124         }
 125
 126         // Have a locking target
 127         // Trace hit current target
 128         if(trace_ent == this.lock_target && trace_ent != NULL)
 129         {
 130                 this.lock_strength = min(this.lock_strength + incr, 1);
 131                 if(this.lock_strength == 1)
 132                         this.lock_time = time + _lock_time;
 133         }
 134         else
 135         {
 136                 if(trace_ent)
 137                         this.lock_strength = max(this.lock_strength - decr * 2, 0);
 138                 else
 139                         this.lock_strength = max(this.lock_strength - decr, 0);
 140
 141                 if(this.lock_strength == 0)
 142                         this.lock_target = NULL;
 143         }
 144 }
 145
 146 float vehicle_altitude(entity this, float amax)
 147 {
 148         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * amax), MOVE_WORLDONLY, this);
 149         return vlen(this.origin - trace_endpos);
 150 }
 151
 152 vector vehicles_force_fromtag_hover(entity this, string tag_name, float spring_length, float max_power)
 153 {
 154         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 155         v_forward  = normalize(v_forward) * -1;
 156         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 157
 158         force_fromtag_power = (1 - trace_fraction) * max_power;
 159         force_fromtag_normpower = force_fromtag_power / max_power;
 160
 161         return v_forward  * force_fromtag_power;
 162 }
 163
 164 vector vehicles_force_fromtag_maglev(entity this, string tag_name, float spring_length, float max_power)
 165 {
 166         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 167         v_forward  = normalize(v_forward) * -1;
 168         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 169
 170         // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 171         if(trace_fraction == 1.0)
 172         {
 173                 force_fromtag_normpower = -0.25;
 174                 return '0 0 -200';
 175         }
 176
 177         force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 178         force_fromtag_normpower = force_fromtag_power / max_power;
 179
 180         return v_forward  * force_fromtag_power;
 181 }
 182
 183 // projectile handling
 184 void vehicles_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 185 {
 186         // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 187         if(inflictor.owner == this.owner)
 188                 return;
 189
 190         this.health -= damage;
 191         this.velocity += force;
 192         if(this.health < 1)
 193         {
 194                 this.takedamage = DAMAGE_NO;
 195                 this.event_damage = func_null;
 196                 setthink(this, adaptor_think2use);
 197                 this.nextthink = time;
 198         }
 199 }
 200
 201 void vehicles_projectile_explode(entity this, entity toucher)
 202 {
 203         if(this.owner && toucher != NULL)
 204         {
 205                 if(toucher == this.owner.vehicle)
 206                         return;
 207
 208                 if(toucher == this.owner.vehicle.tur_head)
 209                         return;
 210         }
 211
 212         PROJECTILE_TOUCH(this, toucher);
 213
 214         this.event_damage = func_null;
 215         RadiusDamage (this, this.realowner, this.shot_dmg, 0, this.shot_radius, this, NULL, this.shot_force, this.totalfrags, toucher);
 216
 217         delete (this);
 218 }
 219
 220 void vehicles_projectile_explode_think(entity this)
 221 {
 222         vehicles_projectile_explode(this, NULL);
 223 }
 224
 225 void vehicles_projectile_explode_use(entity this, entity actor, entity trigger)
 226 {
 227         vehicles_projectile_explode(this, trigger);
 228 }
 229
 230 entity vehicles_projectile(entity this, string _mzlfx, Sound _mzlsound,
 231                                                    vector _org, vector _vel,
 232                                                    float _dmg, float _radi, float _force,  float _size,
 233                                                    int _deahtype, float _projtype, float _health,
 234                                                    bool _cull, bool _clianim, entity _owner)
 235 {
 236     TC(Sound, _mzlsound);
 237         entity proj;
 238
 239         proj = spawn();
 240
 241         PROJECTILE_MAKETRIGGER(proj);
 242         setorigin(proj, _org);
 243
 244         proj.shot_dmg            = _dmg;
 245         proj.shot_radius          = _radi;
 246         proj.shot_force    = _force;
 247         proj.totalfrags    = _deahtype;
 248         proj.solid                      = SOLID_BBOX;
 249         set_movetype(proj, MOVETYPE_FLYMISSILE);
 250         proj.flags = FL_PROJECTILE;
 251         IL_PUSH(g_projectiles, proj);
 252         proj.bot_dodge          = true;
 253         proj.bot_dodgerating  = _dmg;
 254         proj.velocity            = _vel;
 255         settouch(proj, vehicles_projectile_explode);
 256         proj.use                          = vehicles_projectile_explode_use;
 257         proj.owner                      = this;
 258         proj.realowner          = _owner;
 259         setthink(proj, SUB_Remove);
 260         proj.nextthink          = time + 30;
 261
 262         if(_health)
 263         {
 264                 proj.takedamage    = DAMAGE_AIM;
 265                 proj.event_damage        = vehicles_projectile_damage;
 266                 proj.health                = _health;
 267         }
 268         else
 269                 proj.flags |= FL_NOTARGET;
 270
 271         if(_mzlsound != SND_Null)
 272                 sound (this, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 273
 274         if(_mzlfx)
 275                 Send_Effect_(_mzlfx, proj.origin, proj.velocity, 1);
 276
 277         setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 278
 279         CSQCProjectile(proj, _clianim, _projtype, _cull);
 280
 281         return proj;
 282 }
 283
 284 void vehicles_gib_explode(entity this)
 285 {
 286         sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 287         Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 288         Send_Effect(EFFECT_EXPLOSION_SMALL, this.wp00.origin + '0 0 64', '0 0 0', 1);
 289         delete(this);
 290 }
 291
 292 void vehicles_gib_touch(entity this, entity toucher)
 293 {
 294         vehicles_gib_explode(this);
 295 }
 296
 297 void vehicles_gib_think(entity this)
 298 {
 299         this.alpha -= 0.1;
 300         if(this.cnt >= time)
 301                 delete(this);
 302         else
 303                 this.nextthink = time + 0.1;
 304 }
 305
 306 entity vehicle_tossgib(entity this, entity _template, vector _vel, string _tag, bool _burn, bool _explode, float _maxtime, vector _rot)
 307 {
 308         entity _gib = spawn();
 309         _setmodel(_gib, _template.model);
 310         vector org = gettaginfo(this, gettagindex(this, _tag));
 311         setorigin(_gib, org);
 312         _gib.velocity = _vel;
 313         set_movetype(_gib, MOVETYPE_TOSS);
 314         _gib.solid = SOLID_CORPSE;
 315         _gib.colormod = '-0.5 -0.5 -0.5';
 316         _gib.effects = EF_LOWPRECISION;
 317         _gib.avelocity = _rot;
 318
 319         if(_burn)
 320                 _gib.effects |= EF_FLAME;
 321
 322         if(_explode)
 323         {
 324                 setthink(_gib, vehicles_gib_explode);
 325                 _gib.nextthink = time + random() * _explode;
 326                 settouch(_gib, vehicles_gib_touch);
 327         }
 328         else
 329         {
 330                 _gib.cnt = time + _maxtime;
 331                 setthink(_gib, vehicles_gib_think);
 332                 _gib.nextthink = time + _maxtime - 1;
 333                 _gib.alpha = 1;
 334         }
 335         return _gib;
 336 }
 337
 338 bool vehicle_addplayerslot(     entity _owner,
 339                                                                 entity _slot,
 340                                                                 int _hud,
 341                                                                 Model _hud_model,
 342                                                                 bool(entity,float) _framefunc,
 343                                                                 void(entity,bool) _exitfunc, float(entity, entity) _enterfunc)
 344 {
 345         if(!(_owner.vehicle_flags & VHF_MULTISLOT))
 346                 _owner.vehicle_flags |= VHF_MULTISLOT;
 347
 348         _slot.PlayerPhysplug = _framefunc;
 349         _slot.vehicle_exit = _exitfunc;
 350         _slot.vehicle_enter = _enterfunc;
 351         _slot.hud = _hud;
 352         _slot.vehicle_flags = VHF_PLAYERSLOT;
 353         _slot.vehicle_viewport = spawn();
 354         _slot.vehicle_hudmodel = spawn();
 355         _slot.vehicle_hudmodel.viewmodelforclient = _slot;
 356         _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 357
 358         setmodel(_slot.vehicle_hudmodel, _hud_model);
 359         setmodel(_slot.vehicle_viewport, MDL_Null);
 360
 361         setattachment(_slot.vehicle_hudmodel, _slot, "");
 362         setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
 363
 364         return true;
 365 }
 366
 367 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
 368                                                  float _pichlimit_min, float _pichlimit_max,
 369                                                  float _rotlimit_min, float _rotlimit_max, float _aimspeed)
 370 {
 371         vector vtmp, vtag;
 372         float ftmp;
 373         vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
 374         vtmp = vectoangles(normalize(_target - vtag));
 375         vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
 376         vtmp = AnglesTransform_Normalize(vtmp, true);
 377         ftmp = _aimspeed * frametime;
 378         vtmp_y = bound(-ftmp, vtmp_y, ftmp);
 379         vtmp_x = bound(-ftmp, vtmp_x, ftmp);
 380         _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
 381         _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
 382         return vtag;
 383 }
 384
 385 void vehicles_reset_colors(entity this)
 386 {
 387         int eff = 0, cmap;
 388         const vector cmod = '0 0 0';
 389         if(this.team && teamplay)
 390                 cmap = 1024 + (this.team - 1) * 17;
 391         else
 392                 cmap = 1024;
 393         if(autocvar_g_nodepthtestplayers)
 394                 eff |= EF_NODEPTHTEST;
 395         if(autocvar_g_fullbrightplayers)
 396                 eff |= EF_FULLBRIGHT;
 397
 398         // Find all ents attacked to main model and setup effects, colormod etc.
 399         FOREACH_ENTITY_ENT(tag_entity, this,
 400         {
 401                 if(it != this.vehicle_shieldent)
 402                 {
 403                         it.effects = eff;
 404                         it.colormod = cmod;
 405                         it.colormap = cmap;
 406                         it.alpha = 1;
 407                 }
 408         });
 409
 410         // Also check head tags
 411         FOREACH_ENTITY_ENT(tag_entity, this.tur_head,
 412         {
 413                 if(it != this.vehicle_shieldent)
 414                 {
 415                         it.effects = eff;
 416                         it.colormod = cmod;
 417                         it.colormap = cmap;
 418                         it.alpha = 1;
 419                 }
 420         });
 421
 422         this.vehicle_hudmodel.effects  = this.effects  = eff; // | EF_LOWPRECISION;
 423         this.vehicle_hudmodel.colormod = this.colormod = cmod;
 424         this.vehicle_hudmodel.colormap = this.colormap = cmap;
 425         this.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 426
 427         this.alpha       = 1;
 428         this.avelocity = '0 0 0';
 429         this.velocity  = '0 0 0';
 430         this.effects   = eff;
 431 }
 432
 433 void vehicles_clearreturn(entity veh)
 434 {
 435         // Remove "return helper" entities, if any.
 436         IL_EACH(g_vehicle_returners, it.wp00 == veh,
 437         {
 438                 it.classname = "";
 439                 setthink(it, SUB_Remove);
 440                 it.nextthink = time + 0.1;
 441                 IL_REMOVE(g_vehicle_returners, it);
 442
 443                 if(it.waypointsprite_attached)
 444                         WaypointSprite_Kill(it.waypointsprite_attached);
 445         });
 446 }
 447
 448 void vehicles_spawn(entity this);
 449 void vehicles_return(entity this)
 450 {
 451         Send_Effect(EFFECT_TELEPORT, this.wp00.origin + '0 0 64', '0 0 0', 1);
 452
 453         setthink(this.wp00, vehicles_spawn);
 454         this.wp00.nextthink = time;
 455
 456         if(this.waypointsprite_attached)
 457                 WaypointSprite_Kill(this.waypointsprite_attached);
 458
 459         delete(this);
 460 }
 461
 462 void vehicles_showwp_goaway(entity this)
 463 {
 464         if(this.waypointsprite_attached)
 465                 WaypointSprite_Kill(this.waypointsprite_attached);
 466
 467         delete(this);
 468 }
 469
 470 void vehicles_showwp(entity this)
 471 {
 472         entity ent = this;
 473
 474         if(ent.cnt)
 475         {
 476                 setthink(ent, vehicles_return);
 477                 ent.nextthink = ent.cnt;
 478         }
 479         else
 480         {
 481                 setthink(ent, vehicles_return);
 482                 ent.nextthink  = time + 1;
 483
 484                 ent = spawn();
 485                 ent.team = this.wp00.team;
 486                 ent.wp00 = this.wp00;
 487                 setorigin(ent, this.wp00.pos1);
 488
 489                 ent.nextthink = time + 5;
 490                 setthink(ent, vehicles_showwp_goaway);
 491         }
 492
 493         vector rgb;
 494         if(teamplay && ent.team)
 495                 rgb = Team_ColorRGB(ent.team);
 496         else
 497                 rgb = '1 1 1';
 498         entity wp = WaypointSprite_Spawn(WP_Vehicle, 0, 0, ent, '0 0 64', NULL, 0, ent, waypointsprite_attached, true, RADARICON_Vehicle);
 499         wp.colormod = rgb;
 500         if(ent.waypointsprite_attached)
 501         {
 502                 WaypointSprite_UpdateRule(ent.waypointsprite_attached, ent.wp00.team, SPRITERULE_DEFAULT);
 503                 if(this == NULL)
 504                         WaypointSprite_UpdateBuildFinished(ent.waypointsprite_attached, ent.nextthink);
 505                 WaypointSprite_Ping(ent.waypointsprite_attached);
 506         }
 507 }
 508
 509 void vehicles_setreturn(entity veh)
 510 {
 511         vehicles_clearreturn(veh);
 512
 513         entity ret = new(vehicle_return);
 514         IL_PUSH(g_vehicle_returners, ret);
 515         ret.wp00           = veh;
 516         ret.team                = veh.team;
 517         setthink(ret, vehicles_showwp);
 518
 519         if(IS_DEAD(veh))
 520         {
 521                 ret.cnt          = time + veh.respawntime;
 522                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 5);
 523         }
 524         else
 525         {
 526                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 1);
 527         }
 528
 529         setorigin(ret, veh.pos1 + '0 0 96');
 530 }
 531
 532 void vehicle_use(entity this, entity actor, entity trigger)
 533 {
 534         LOG_DEBUG("vehicle ", this.netname, " used by ", actor.classname);
 535
 536         this.tur_head.team = actor.team;
 537
 538         if(this.tur_head.team == 0)
 539                 this.active = ACTIVE_NOT;
 540         else
 541                 this.active = ACTIVE_ACTIVE;
 542
 543         if(this.active == ACTIVE_ACTIVE && !IS_DEAD(this) && !gameover)
 544         {
 545                 LOG_DEBUG("Respawning vehicle: ", this.netname);
 546                 if(this.effects & EF_NODRAW)
 547                 {
 548                         setthink(this, vehicles_spawn);
 549                         this.nextthink = time + 3;
 550                 }
 551                 else
 552                 {
 553                         vehicles_setreturn(this);
 554                         vehicles_reset_colors(this);
 555                 }
 556         }
 557 }
 558
 559 void vehicles_regen(entity this, float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 560 {
 561         if(this.(regen_field) < field_max)
 562         if(timer + rpause < time)
 563         {
 564                 if(_healthscale)
 565                         regen = regen * (this.vehicle_health / this.max_health);
 566
 567                 this.(regen_field) = min(this.(regen_field) + regen * delta_time, field_max);
 568
 569                 if(this.owner)
 570                         this.owner.(regen_field) = (this.(regen_field) / field_max) * 100;
 571         }
 572 }
 573
 574 void shieldhit_think(entity this)
 575 {
 576         this.alpha -= 0.1;
 577         if (this.alpha <= 0)
 578         {
 579                 // setmodel(this, MDL_Null);
 580                 this.alpha = -1;
 581                 this.effects |= EF_NODRAW;
 582         }
 583         else
 584         {
 585                 this.nextthink = time + 0.1;
 586         }
 587 }
 588
 589 void vehicles_painframe(entity this)
 590 {
 591         int myhealth = ((this.owner) ? this.owner.vehicle_health : ((this.vehicle_health / this.max_health) * 100));
 592
 593         if(myhealth <= 50)
 594         if(this.pain_frame < time)
 595         {
 596                 float _ftmp = myhealth / 50;
 597                 this.pain_frame = time + max(0.1, 0.1 + (random() * 0.5 * _ftmp));
 598                 Send_Effect(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);
 599
 600                 if(this.vehicle_flags & VHF_DMGSHAKE)
 601                         this.velocity += randomvec() * 30;
 602
 603                 if(this.vehicle_flags & VHF_DMGROLL)
 604                         if(this.vehicle_flags & VHF_DMGHEADROLL)
 605                                 this.tur_head.angles += randomvec();
 606                         else
 607                                 this.angles += randomvec();
 608         }
 609 }
 610
 611 void vehicles_frame(entity this, entity actor)
 612 {
 613         vehicles_painframe(this);
 614 }
 615
 616 void vehicles_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 617 {
 618         this.dmg_time = time;
 619
 620         // WEAPONTODO
 621         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 622                 damage *= autocvar_g_vehicles_vortex_damagerate;
 623         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 624                 damage *= autocvar_g_vehicles_machinegun_damagerate;
 625         else if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 626                 damage *= autocvar_g_vehicles_rifle_damagerate;
 627         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 628                 damage *= autocvar_g_vehicles_vaporizer_damagerate;
 629         else if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 630                 damage *= autocvar_g_vehicles_tag_damagerate;
 631         else if(DEATH_WEAPONOF(deathtype) != WEP_Null)
 632                 damage *= autocvar_g_vehicles_weapon_damagerate;
 633
 634         this.enemy = attacker;
 635
 636         this.pain_finished = time;
 637
 638         if((this.vehicle_flags & VHF_HASSHIELD) && (this.vehicle_shield > 0))
 639         {
 640                 if (wasfreed(this.vehicle_shieldent) || this.vehicle_shieldent == NULL)
 641                 {
 642                         this.vehicle_shieldent = spawn();
 643                         this.vehicle_shieldent.effects = EF_LOWPRECISION;
 644
 645                         setmodel(this.vehicle_shieldent, MDL_VEH_SHIELD);
 646                         setattachment(this.vehicle_shieldent, this, "");
 647                         setorigin(this.vehicle_shieldent, real_origin(this) - this.origin);
 648                         this.vehicle_shieldent.scale       = 256 / vlen(this.maxs - this.mins);
 649                         setthink(this.vehicle_shieldent, shieldhit_think);
 650                 }
 651
 652                 this.vehicle_shieldent.colormod = '1 1 1';
 653                 this.vehicle_shieldent.alpha = 0.45;
 654                 this.vehicle_shieldent.angles = vectoangles(normalize(hitloc - (this.origin + this.vehicle_shieldent.origin))) - this.angles;
 655                 this.vehicle_shieldent.nextthink = time;
 656                 this.vehicle_shieldent.effects &= ~EF_NODRAW;
 657
 658                 this.vehicle_shield -= damage;
 659
 660                 if(this.vehicle_shield < 0)
 661                 {
 662                         this.vehicle_health -= fabs(this.vehicle_shield);
 663                         this.vehicle_shieldent.colormod = '2 0 0';
 664                         this.vehicle_shield = 0;
 665                         this.vehicle_shieldent.alpha = 0.75;
 666
 667                         if(sound_allowed(MSG_BROADCAST, attacker))
 668                                 spamsound (this, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 669                 }
 670                 else
 671                         if(sound_allowed(MSG_BROADCAST, attacker))
 672                                 spamsound (this, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 673
 674         }
 675         else
 676         {
 677                 this.vehicle_health -= damage;
 678
 679                 if(sound_allowed(MSG_BROADCAST, attacker))
 680                         spamsound (this, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 681         }
 682
 683         if(this.damageforcescale < 1 && this.damageforcescale > 0)
 684                 this.velocity += force * this.damageforcescale;
 685         else
 686                 this.velocity += force;
 687
 688         if(this.vehicle_health <= 0)
 689         {
 690                 if(this.owner)
 691                         if(this.vehicle_flags & VHF_DEATHEJECT)
 692                                 vehicles_exit(this, VHEF_EJECT);
 693                         else
 694                                 vehicles_exit(this, VHEF_RELEASE);
 695
 696
 697                 antilag_clear(this, this);
 698
 699                 Vehicle info = Vehicles_from(this.vehicleid);
 700                 info.vr_death(info, this);
 701                 vehicles_setreturn(this);
 702         }
 703 }
 704
 705 bool vehicles_crushable(entity e)
 706 {
 707         if(IS_PLAYER(e) && time >= e.vehicle_enter_delay)
 708                 return true;
 709
 710         if(IS_MONSTER(e))
 711                 return true;
 712
 713         return false;
 714 }
 715
 716 void vehicles_impact(entity this, float _minspeed, float _speedfac, float _maxpain)
 717 {
 718         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 719                 return;
 720
 721         if(this.play_time < time)
 722         {
 723                 float wc = vlen(this.velocity - this.oldvelocity);
 724                 //dprint("oldvel: ", vtos(this.oldvelocity), "\n");
 725                 //dprint("vel: ", vtos(this.velocity), "\n");
 726                 if(_minspeed < wc)
 727                 {
 728                         float take = min(_speedfac * wc, _maxpain);
 729                         Damage (this, NULL, NULL, take, DEATH_FALL.m_id, this.origin, '0 0 0');
 730                         this.play_time = time + 0.25;
 731
 732                         //dprint("wc: ", ftos(wc), "\n");
 733                         //dprint("take: ", ftos(take), "\n");
 734                 }
 735         }
 736 }
 737
 738 // vehicle enter/exit handling
 739 vector vehicles_findgoodexit(entity this, vector prefer_spot)
 740 {
 741         tracebox(this.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, this.owner);
 742         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 743                 return prefer_spot;
 744
 745         float mysize = 1.5 * vlen(this.maxs - this.mins);
 746         vector v;
 747         vector v2 = 0.5 * (this.absmin + this.absmax);
 748         for(int i = 0; i < autocvar_g_vehicles_exit_attempts; ++i)
 749         {
 750                 v = randomvec();
 751                 v_z = 0;
 752                 v = v2 + normalize(v) * mysize;
 753                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, this.owner);
 754                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 755                         return v;
 756         }
 757
 758         return this.origin;
 759 }
 760
 761 void vehicles_exit(entity vehic, bool eject)
 762 {
 763         entity player = vehic.owner;
 764
 765         if(vehicles_exit_running)
 766         {
 767                 LOG_TRACE("^1vehicles_exit already running! this is not good...");
 768                 return;
 769         }
 770
 771         vehicles_exit_running = true;
 772
 773         // TODO: this was in an IS_CLIENT check, make sure it isn't actually needed!
 774         if(vehic.vehicle_flags & VHF_PLAYERSLOT)
 775         {
 776                 vehic.vehicle_exit(vehic, eject);
 777                 vehicles_exit_running = false;
 778                 return;
 779         }
 780
 781         if (player)
 782         {
 783                 if (IS_REAL_CLIENT(player))
 784                 {
 785                         msg_entity = player;
 786                         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 787                         WriteEntity( MSG_ONE, player);
 788
 789                         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 790                         WriteAngle(MSG_ONE, 0);
 791                         WriteAngle(MSG_ONE, vehic.angles_y);
 792                         WriteAngle(MSG_ONE, 0);
 793                 }
 794
 795                 setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 796
 797                 player.takedamage               = DAMAGE_AIM;
 798                 player.solid                    = SOLID_SLIDEBOX;
 799                 set_movetype(player, MOVETYPE_WALK);
 800                 player.effects             &= ~EF_NODRAW;
 801                 player.teleportable     = TELEPORT_NORMAL;
 802                 player.alpha                    = 1;
 803                 player.PlayerPhysplug   = func_null;
 804                 player.vehicle                  = NULL;
 805                 player.view_ofs         = STAT(PL_VIEW_OFS, NULL);
 806                 player.event_damage     = PlayerDamage;
 807                 player.hud                              = HUD_NORMAL;
 808                 PS(player).m_switchweapon = vehic.m_switchweapon;
 809                 player.last_vehiclecheck = time + 3;
 810                 player.vehicle_enter_delay = time + 2;
 811
 812                 CSQCVehicleSetup(player, HUD_NORMAL);
 813
 814                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES);
 815                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES_OTHER); // kill all vehicle notifications when exiting a vehicle?
 816         }
 817
 818         vehic.flags |= FL_NOTARGET;
 819
 820         if(!IS_DEAD(vehic))
 821                 vehic.avelocity = '0 0 0';
 822
 823         vehic.tur_head.nodrawtoclient = NULL;
 824
 825         if(!teamplay)
 826                 vehic.team = 0;
 827
 828         WaypointSprite_Kill(vehic.wps_intruder);
 829
 830         MUTATOR_CALLHOOK(VehicleExit, player, vehic);
 831
 832         vehic.team = vehic.tur_head.team;
 833
 834         sound (vehic, CH_TRIGGER_SINGLE, SND_Null, 1, ATTEN_NORM);
 835         vehic.vehicle_hudmodel.viewmodelforclient = vehic;
 836         vehic.phase = time + 1;
 837
 838         vehic.vehicle_exit(vehic, eject);
 839
 840         vehicles_setreturn(vehic);
 841         vehicles_reset_colors(vehic);
 842         vehic.owner = NULL;
 843
 844         CSQCMODEL_AUTOINIT(vehic);
 845
 846         vehicles_exit_running = false;
 847 }
 848
 849 void vehicles_touch(entity this, entity toucher)
 850 {
 851         if(MUTATOR_CALLHOOK(VehicleTouch, this, toucher))
 852                 return;
 853
 854         // Vehicle currently in use
 855         if(this.owner)
 856         {
 857                 if(!forbidWeaponUse(this.owner))
 858                 if(toucher != NULL)
 859                 if((this.origin_z + this.maxs_z) > (toucher.origin_z))
 860                 if(vehicles_crushable(toucher))
 861                 {
 862                         if(vdist(this.velocity, >=, 30))
 863                                 Damage(toucher, this, this.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH.m_id, '0 0 0', normalize(toucher.origin - this.origin) * autocvar_g_vehicles_crush_force);
 864
 865                         return; // Dont do selfdamage when hitting "soft targets".
 866                 }
 867
 868                 if(this.play_time < time) {
 869                         Vehicle info = Vehicles_from(this.vehicleid);
 870                         info.vr_impact(info, this);
 871                 }
 872
 873                 return;
 874         }
 875
 876         if(autocvar_g_vehicles_enter)
 877                 return;
 878
 879         vehicles_enter(toucher, this);
 880 }
 881
 882 bool vehicle_impulse(entity this, int imp)
 883 {
 884         entity v = this.vehicle;
 885         if (!v) return false;
 886         if (IS_DEAD(v)) return false;
 887         bool(entity,int) f = v.vehicles_impulse;
 888         if (f && f(this,imp)) return true;
 889         switch (imp)
 890         {
 891                 case IMP_weapon_drop.impulse:
 892                 {
 893                         stuffcmd(this, "\ntoggle cl_eventchase_vehicle\nset _vehicles_shownchasemessage 1\n");
 894                         return true;
 895                 }
 896         }
 897         return false;
 898 }
 899
 900 void vehicles_enter(entity pl, entity veh)
 901 {
 902    // Remove this when bots know how to use vehicles
 903         if((IS_BOT_CLIENT(pl) && !autocvar_g_vehicles_allow_bots))
 904                 return;
 905
 906         if((!IS_PLAYER(pl))
 907         || (veh.phase >= time)
 908         || (pl.vehicle_enter_delay >= time)
 909         || (STAT(FROZEN, pl))
 910         || (IS_DEAD(pl))
 911         || (pl.vehicle)
 912         ) { return; }
 913
 914         Vehicle info = Vehicles_from(veh.vehicleid);
 915
 916         if(autocvar_g_vehicles_enter) // vehicle's touch function should handle this if entering via use key is disabled (TODO)
 917         if(veh.vehicle_flags & VHF_MULTISLOT)
 918         if(veh.owner && SAME_TEAM(pl, veh))
 919         {
 920                 // we don't need a return value or anything here
 921                 // if successful the owner check below will prevent anything weird
 922                 info.vr_gunner_enter(info, veh, pl);
 923         }
 924
 925         if(veh.owner)
 926                 return; // got here and didn't enter the gunner, return
 927
 928         if(teamplay)
 929         if(veh.team)
 930         if(DIFF_TEAM(pl, veh))
 931         if(autocvar_g_vehicles_steal)
 932         {
 933                 FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, veh), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_VEHICLE_STEAL));
 934
 935                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_STEAL_SELF);
 936
 937                 if (autocvar_g_vehicles_steal_show_waypoint) {
 938                         entity wp = WaypointSprite_Spawn(WP_VehicleIntruder, 0, 0, pl, '0 0 68', NULL, veh.team, veh, wps_intruder, true, RADARICON_DANGER);
 939                         wp.colormod = Team_ColorRGB(pl.team);
 940                 }
 941         }
 942         else return;
 943
 944         RemoveGrapplingHook(pl);
 945
 946         veh.vehicle_ammo1 = 0;
 947         veh.vehicle_ammo2 = 0;
 948         veh.vehicle_reload1 = 0;
 949         veh.vehicle_reload2 = 0;
 950         veh.vehicle_energy = 0;
 951
 952         veh.owner = pl;
 953         pl.vehicle = veh;
 954
 955         // .viewmodelforclient works better.
 956         //veh.vehicle_hudmodel.drawonlytoclient = veh.owner;
 957
 958         veh.vehicle_hudmodel.viewmodelforclient = pl;
 959
 960         pl.crouch = false;
 961         pl.view_ofs = STAT(PL_VIEW_OFS, NULL);
 962         setsize (pl, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 963
 964         veh.event_damage        = vehicles_damage;
 965         veh.nextthink           = 0;
 966         pl.angles                       = veh.angles;
 967         pl.takedamage           = DAMAGE_NO;
 968         pl.solid                        = SOLID_NOT;
 969         pl.disableclientprediction = 1; // physics is no longer run, so this won't be reset
 970         set_movetype(pl, MOVETYPE_NOCLIP);
 971         pl.teleportable         = false;
 972         pl.alpha                        = -1;
 973         pl.event_damage         = func_null;
 974         pl.view_ofs                     = '0 0 0';
 975         veh.colormap            = pl.colormap;
 976         if(veh.tur_head)
 977                 veh.tur_head.colormap = pl.colormap;
 978         veh.m_switchweapon = PS(pl).m_switchweapon;
 979         pl.hud = veh.vehicleid;
 980         pl.PlayerPhysplug = veh.PlayerPhysplug;
 981
 982         pl.vehicle_ammo1 = veh.vehicle_ammo1;
 983         pl.vehicle_ammo2 = veh.vehicle_ammo2;
 984         pl.vehicle_reload1 = veh.vehicle_reload1;
 985         pl.vehicle_reload2 = veh.vehicle_reload2;
 986         pl.vehicle_energy = veh.vehicle_energy;
 987
 988         // Cant do this, hides attached objects too.
 989         //veh.exteriormodeltoclient = veh.owner;
 990         //veh.tur_head.exteriormodeltoclient = veh.owner;
 991
 992         UNSET_ONGROUND(pl);
 993         UNSET_ONGROUND(veh);
 994
 995         veh.team = pl.team;
 996         veh.flags -= FL_NOTARGET;
 997
 998         if (IS_REAL_CLIENT(pl))
 999         {
1000                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_ENTER);
1001
1002                 msg_entity = pl;
1003                 WriteByte (MSG_ONE, SVC_SETVIEWPORT);
1004                 WriteEntity(MSG_ONE, veh.vehicle_viewport);
1005
1006                 WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1007                 if(veh.tur_head)
1008                 {
1009                         WriteAngle(MSG_ONE, veh.tur_head.angles_x + veh.angles_x); // tilt
1010                         WriteAngle(MSG_ONE, veh.tur_head.angles_y + veh.angles_y); // yaw
1011                         WriteAngle(MSG_ONE, 0);                                                                   // roll
1012                 }
1013                 else
1014                 {
1015                         WriteAngle(MSG_ONE, veh.angles_x * -1); // tilt
1016                         WriteAngle(MSG_ONE, veh.angles_y);        // yaw
1017                         WriteAngle(MSG_ONE, 0);                           // roll
1018                 }
1019         }
1020
1021         vehicles_clearreturn(veh);
1022
1023         CSQCVehicleSetup(pl, veh.vehicleid);
1024
1025         MUTATOR_CALLHOOK(VehicleEnter, pl, veh);
1026
1027         CSQCModel_UnlinkEntity(veh);
1028         info.vr_enter(info, veh);
1029
1030         antilag_clear(pl, CS(pl));
1031 }
1032
1033 void vehicles_think(entity this)
1034 {
1035         this.nextthink = time + autocvar_g_vehicles_thinkrate;
1036
1037         if(this.owner)
1038                 this.owner.vehicle_weapon2mode = this.vehicle_weapon2mode;
1039
1040         Vehicle info = Vehicles_from(this.vehicleid);
1041         info.vr_think(info, this);
1042
1043         vehicles_painframe(this);
1044
1045         CSQCMODEL_AUTOUPDATE(this);
1046 }
1047
1048 void vehicles_reset(entity this)
1049 {
1050         if(this.owner)
1051                 vehicles_exit(this, VHEF_RELEASE);
1052
1053         vehicles_clearreturn(this);
1054
1055         if(this.active != ACTIVE_NOT)
1056                 vehicles_spawn(this);
1057 }
1058
1059 // initialization
1060 void vehicles_spawn(entity this)
1061 {
1062         LOG_DEBUG("Spawning vehicle: ", this.classname);
1063
1064         // disown & reset
1065         this.vehicle_hudmodel.viewmodelforclient = this;
1066
1067         this.owner                              = NULL;
1068         settouch(this, vehicles_touch);
1069         this.event_damage               = vehicles_damage;
1070         this.reset                              = vehicles_reset;
1071         this.iscreature                 = true;
1072         this.teleportable               = false; // no teleporting for vehicles, too buggy
1073         this.damagedbycontents  = true;
1074         set_movetype(this, MOVETYPE_WALK);
1075         this.solid                              = SOLID_SLIDEBOX;
1076         this.takedamage                 = DAMAGE_AIM;
1077         this.deadflag                   = DEAD_NO;
1078         if(!this.bot_attack)
1079                 IL_PUSH(g_bot_targets, this);
1080         this.bot_attack                 = true;
1081         this.flags                              = FL_NOTARGET;
1082         this.avelocity                  = '0 0 0';
1083         this.velocity                   = '0 0 0';
1084         setthink(this, vehicles_think);
1085         this.nextthink                  = time;
1086
1087         // Reset locking
1088         this.lock_strength = 0;
1089         this.lock_target = NULL;
1090         this.misc_bulletcounter = 0;
1091
1092         // Return to spawn
1093         this.angles = this.pos2;
1094         setorigin(this, this.pos1);
1095         // Show it
1096         Send_Effect(EFFECT_TELEPORT, this.origin + '0 0 64', '0 0 0', 1);
1097
1098         if(this.vehicle_controller)
1099                 this.team = this.vehicle_controller.team;
1100
1101         FOREACH_CLIENT(IS_PLAYER(it) && it.hook.aiment == this, RemoveGrapplingHook(it));
1102
1103         vehicles_reset_colors(this);
1104
1105         Vehicle info = Vehicles_from(this.vehicleid);
1106         info.vr_spawn(info, this);
1107
1108         CSQCMODEL_AUTOINIT(this);
1109 }
1110
1111 bool vehicle_initialize(entity this, Vehicle info, bool nodrop)
1112 {
1113         if(!autocvar_g_vehicles)
1114                 return false;
1115
1116         if(!info.vehicleid)
1117                 return false;
1118
1119         if(!this.tur_head)
1120         {
1121                 info.vr_precache(info);
1122                 IL_PUSH(g_vehicles, this);
1123         }
1124
1125         if(this.targetname && this.targetname != "")
1126         {
1127                 this.vehicle_controller = find(NULL, target, this.targetname);
1128                 if(!this.vehicle_controller)
1129                 {
1130                         LOG_DEBUG("^1WARNING: ^7Vehicle with invalid .targetname");
1131                         this.active = ACTIVE_ACTIVE;
1132                 }
1133                 else
1134                 {
1135                         this.team = this.vehicle_controller.team;
1136                         this.use = vehicle_use;
1137
1138                         if(teamplay)
1139                         {
1140                                 if(this.vehicle_controller.team == 0)
1141                                         this.active = ACTIVE_NOT;
1142                                 else
1143                                         this.active = ACTIVE_ACTIVE;
1144                         }
1145                 }
1146         }
1147         else { this.active = ACTIVE_ACTIVE; }
1148
1149         if(this.team && (!teamplay || !autocvar_g_vehicles_teams))
1150                 this.team = 0;
1151
1152         if(this.mdl == "" || !this.mdl)
1153                 _setmodel(this, info.model);
1154         else
1155                 _setmodel(this, this.mdl);
1156
1157         this.vehicle_flags |= VHF_ISVEHICLE;
1158
1159         this.vehicle_viewport           = new(vehicle_viewport);
1160         this.vehicle_hudmodel           = new(vehicle_hudmodel);
1161         this.tur_head                           = new(tur_head);
1162         this.tur_head.owner                     = this;
1163         this.takedamage                         = DAMAGE_NO;
1164         this.bot_attack                         = true;
1165         IL_PUSH(g_bot_targets, this);
1166         this.iscreature                         = true;
1167         this.teleportable                       = false; // no teleporting for vehicles, too buggy
1168         this.damagedbycontents          = true;
1169         this.vehicleid                          = info.vehicleid;
1170         this.PlayerPhysplug                     = info.PlayerPhysplug;
1171         this.event_damage                       = func_null;
1172         settouch(this, vehicles_touch);
1173         setthink(this, vehicles_spawn);
1174         this.nextthink                          = time;
1175         this.effects                            = EF_NODRAW;
1176         this.dphitcontentsmask          = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1177
1178         if(autocvar_g_playerclip_collisions)
1179                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1180
1181         if(autocvar_g_nodepthtestplayers)
1182                 this.effects |= EF_NODEPTHTEST;
1183
1184         if(autocvar_g_fullbrightplayers)
1185                 this.effects |= EF_FULLBRIGHT;
1186
1187         _setmodel(this.vehicle_hudmodel, info.hud_model);
1188         setmodel(this.vehicle_viewport, MDL_Null);
1189
1190         if(info.head_model != "")
1191         {
1192                 _setmodel(this.tur_head, info.head_model);
1193                 setattachment(this.tur_head, this, info.tag_head);
1194                 setattachment(this.vehicle_hudmodel, this.tur_head, info.tag_hud);
1195                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1196         }
1197         else
1198         {
1199                 setattachment(this.tur_head, this, "");
1200                 setattachment(this.vehicle_hudmodel, this, info.tag_hud);
1201                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1202         }
1203
1204         setsize(this, info.mins, info.maxs);
1205
1206         info.vr_setup(info, this);
1207
1208         if(!nodrop)
1209         {
1210                 setorigin(this, this.origin);
1211                 tracebox(this.origin + '0 0 100', info.mins, info.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1212                 setorigin(this, trace_endpos);
1213         }
1214
1215         this.pos1 = this.origin;
1216         this.pos2 = this.angles;
1217         this.tur_head.team = this.team;
1218
1219         if(this.active == ACTIVE_NOT)
1220                 this.nextthink = 0; // wait until activated
1221         else if(autocvar_g_vehicles_delayspawn)
1222                 this.nextthink = time + this.respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1223         else
1224                 this.nextthink = time + game_starttime;
1225
1226         if(MUTATOR_CALLHOOK(VehicleSpawn, this))
1227                 return false;
1228
1229         return true;
1230 }