qcsrc/common/vehicles/sv_vehicles.qc

   1 #include "sv_vehicles.qh"
   2
   3 bool SendAuxiliaryXhair(entity this, entity to, int sf)
   4 {
   5         WriteHeader(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
   6         WriteByte(MSG_ENTITY, sf);
   7
   8         WriteByte(MSG_ENTITY, this.cnt);
   9
  10         if(sf & 2)
  11         {
  12                 WriteCoord(MSG_ENTITY, this.origin_x);
  13                 WriteCoord(MSG_ENTITY, this.origin_y);
  14                 WriteCoord(MSG_ENTITY, this.origin_z);
  15         }
  16
  17         if(sf & 4)
  18         {
  19                 WriteByte(MSG_ENTITY, rint(this.colormod_x * 255));
  20                 WriteByte(MSG_ENTITY, rint(this.colormod_y * 255));
  21                 WriteByte(MSG_ENTITY, rint(this.colormod_z * 255));
  22         }
  23
  24         return true;
  25 }
  26
  27 bool AuxiliaryXhair_customize(entity this, entity client)
  28 {
  29         //entity e = WaypointSprite_getviewentity(client);
  30         entity axh = client.(AuxiliaryXhair[this.cnt]);
  31         return axh.owner == this.owner; // cheaply check if the client's axh owner is the same as our real owner
  32 }
  33
  34 .vector axh_prevorigin;
  35 .vector axh_prevcolors;
  36
  37 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  38 {
  39         if(!IS_REAL_CLIENT(own))
  40                 return;
  41
  42         axh_id = bound(0, axh_id, MAX_AXH);
  43         entity axh = own.(AuxiliaryXhair[axh_id]);
  44
  45         if(axh == NULL || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist? Mario: because of sloppy code like this)
  46         {
  47                 axh = new(auxiliary_xhair);
  48                 axh.cnt = axh_id;
  49                 //axh.drawonlytoclient = own; // not spectatable
  50                 setcefc(axh, AuxiliaryXhair_customize);
  51                 axh.owner = own;
  52                 Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  53         }
  54
  55         if(loc != axh.axh_prevorigin)
  56         {
  57                 setorigin(axh, loc);
  58                 axh.SendFlags |= 2;
  59         }
  60
  61         if(clr != axh.axh_prevcolors)
  62         {
  63                 axh.colormod = clr;
  64                 axh.SendFlags |= 4;
  65         }
  66
  67         own.(AuxiliaryXhair[axh_id]) = axh; // set it anyway...?
  68 }
  69
  70 void CSQCVehicleSetup(entity own, int vehicle_id)
  71 {
  72         if(!IS_REAL_CLIENT(own))
  73                 return;
  74
  75         msg_entity = own;
  76
  77         WriteHeader(MSG_ONE, TE_CSQC_VEHICLESETUP);
  78         WriteByte(MSG_ONE, vehicle_id);
  79
  80         if(vehicle_id == 0 || vehicle_id == HUD_NORMAL)
  81         {
  82                 for(int i = 0; i < MAX_AXH; ++i)
  83                 {
  84                         entity axh = own.(AuxiliaryXhair[i]);
  85                         own.(AuxiliaryXhair[i]) = NULL;
  86
  87                         if(axh.owner == own && axh != NULL && !wasfreed(axh))
  88                                 delete(axh);
  89                 }
  90         }
  91 }
  92
  93 void vehicles_locktarget(entity this, float incr, float decr, float _lock_time)
  94 {
  95         if(this.lock_target && IS_DEAD(this.lock_target))
  96         {
  97                 this.lock_target        = NULL;
  98                 this.lock_strength  = 0;
  99                 this.lock_time    = 0;
 100         }
 101
 102         if(this.lock_time > time)
 103         {
 104                 if(this.lock_target)
 105                 if(this.lock_soundtime < time)
 106                 {
 107                         this.lock_soundtime = time + 0.5;
 108                         play2(this.owner, "vehicles/locked.wav");
 109                 }
 110
 111                 return;
 112         }
 113
 114         if(trace_ent != NULL)
 115         {
 116                 if(SAME_TEAM(trace_ent, this))
 117                         trace_ent = NULL;
 118
 119                 if(IS_DEAD(trace_ent))
 120                         trace_ent = NULL;
 121
 122                 if(!(IS_VEHICLE(trace_ent) || IS_TURRET(trace_ent)))
 123                         trace_ent = NULL;
 124
 125                 if(trace_ent.alpha <= 0.5 && trace_ent.alpha != 0)
 126                         trace_ent = NULL; // invisible
 127         }
 128
 129         if(this.lock_target == NULL && trace_ent != NULL)
 130                 this.lock_target = trace_ent;
 131
 132         if(this.lock_target && trace_ent == this.lock_target)
 133         {
 134                 if(this.lock_strength != 1 && this.lock_strength + incr >= 1)
 135                 {
 136                         play2(this.owner, "vehicles/lock.wav");
 137                         this.lock_soundtime = time + 0.8;
 138                 }
 139                 else if (this.lock_strength != 1 && this.lock_soundtime < time)
 140                 {
 141                         play2(this.owner, "vehicles/locking.wav");
 142                         this.lock_soundtime = time + 0.3;
 143                 }
 144         }
 145
 146         // Have a locking target
 147         // Trace hit current target
 148         if(trace_ent == this.lock_target && trace_ent != NULL)
 149         {
 150                 this.lock_strength = min(this.lock_strength + incr, 1);
 151                 if(this.lock_strength == 1)
 152                         this.lock_time = time + _lock_time;
 153         }
 154         else
 155         {
 156                 if(trace_ent)
 157                         this.lock_strength = max(this.lock_strength - decr * 2, 0);
 158                 else
 159                         this.lock_strength = max(this.lock_strength - decr, 0);
 160
 161                 if(this.lock_strength == 0)
 162                         this.lock_target = NULL;
 163         }
 164 }
 165
 166 float vehicle_altitude(entity this, float amax)
 167 {
 168         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * amax), MOVE_WORLDONLY, this);
 169         return vlen(this.origin - trace_endpos);
 170 }
 171
 172 vector vehicles_force_fromtag_hover(entity this, string tag_name, float spring_length, float max_power)
 173 {
 174         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 175         v_forward  = normalize(v_forward) * -1;
 176         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 177
 178         force_fromtag_power = (1 - trace_fraction) * max_power;
 179         force_fromtag_normpower = force_fromtag_power / max_power;
 180
 181         return v_forward  * force_fromtag_power;
 182 }
 183
 184 vector vehicles_force_fromtag_maglev(entity this, string tag_name, float spring_length, float max_power)
 185 {
 186         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 187         v_forward  = normalize(v_forward) * -1;
 188         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 189
 190         // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 191         if(trace_fraction == 1.0)
 192         {
 193                 force_fromtag_normpower = -0.25;
 194                 return '0 0 -200';
 195         }
 196
 197         force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 198         force_fromtag_normpower = force_fromtag_power / max_power;
 199
 200         return v_forward  * force_fromtag_power;
 201 }
 202
 203 // projectile handling
 204 void vehicles_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 205 {
 206         // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 207         if(inflictor.owner == this.owner)
 208                 return;
 209
 210         this.health -= damage;
 211         this.velocity += force;
 212         if(this.health < 1)
 213         {
 214                 this.takedamage = DAMAGE_NO;
 215                 this.event_damage = func_null;
 216                 setthink(this, adaptor_think2use);
 217                 this.nextthink = time;
 218         }
 219 }
 220
 221 void vehicles_projectile_explode(entity this, entity toucher)
 222 {
 223         if(this.owner && toucher != NULL)
 224         {
 225                 if(toucher == this.owner.vehicle)
 226                         return;
 227
 228                 if(toucher == this.owner.vehicle.tur_head)
 229                         return;
 230         }
 231
 232         PROJECTILE_TOUCH(this, toucher);
 233
 234         this.event_damage = func_null;
 235         RadiusDamage (this, this.realowner, this.shot_dmg, 0, this.shot_radius, this, NULL, this.shot_force, this.totalfrags, toucher);
 236
 237         delete (this);
 238 }
 239
 240 void vehicles_projectile_explode_think(entity this)
 241 {
 242         vehicles_projectile_explode(this, NULL);
 243 }
 244
 245 void vehicles_projectile_explode_use(entity this, entity actor, entity trigger)
 246 {
 247         vehicles_projectile_explode(this, trigger);
 248 }
 249
 250 entity vehicles_projectile(entity this, string _mzlfx, Sound _mzlsound,
 251                                                    vector _org, vector _vel,
 252                                                    float _dmg, float _radi, float _force,  float _size,
 253                                                    int _deahtype, float _projtype, float _health,
 254                                                    bool _cull, bool _clianim, entity _owner)
 255 {
 256     TC(Sound, _mzlsound);
 257         entity proj;
 258
 259         proj = spawn();
 260
 261         PROJECTILE_MAKETRIGGER(proj);
 262         setorigin(proj, _org);
 263
 264         proj.shot_dmg            = _dmg;
 265         proj.shot_radius          = _radi;
 266         proj.shot_force    = _force;
 267         proj.totalfrags    = _deahtype;
 268         proj.solid                      = SOLID_BBOX;
 269         set_movetype(proj, MOVETYPE_FLYMISSILE);
 270         proj.flags = FL_PROJECTILE;
 271         IL_PUSH(g_projectiles, proj);
 272         IL_PUSH(g_bot_dodge, proj);
 273         proj.bot_dodge          = true;
 274         proj.bot_dodgerating  = _dmg;
 275         proj.velocity            = _vel;
 276         settouch(proj, vehicles_projectile_explode);
 277         proj.use                          = vehicles_projectile_explode_use;
 278         proj.owner                      = this;
 279         proj.realowner          = _owner;
 280         setthink(proj, SUB_Remove);
 281         proj.nextthink          = time + 30;
 282
 283         if(_health)
 284         {
 285                 proj.takedamage    = DAMAGE_AIM;
 286                 proj.event_damage        = vehicles_projectile_damage;
 287                 proj.health                = _health;
 288         }
 289         else
 290                 proj.flags |= FL_NOTARGET;
 291
 292         if(_mzlsound != SND_Null)
 293                 sound (this, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 294
 295         if(_mzlfx)
 296                 Send_Effect_(_mzlfx, proj.origin, proj.velocity, 1);
 297
 298         setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 299
 300         CSQCProjectile(proj, _clianim, _projtype, _cull);
 301
 302         return proj;
 303 }
 304
 305 void vehicles_gib_explode(entity this)
 306 {
 307         sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 308         Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 309         Send_Effect(EFFECT_EXPLOSION_SMALL, this.wp00.origin + '0 0 64', '0 0 0', 1);
 310         delete(this);
 311 }
 312
 313 void vehicles_gib_touch(entity this, entity toucher)
 314 {
 315         vehicles_gib_explode(this);
 316 }
 317
 318 void vehicles_gib_think(entity this)
 319 {
 320         this.alpha -= 0.1;
 321         if(this.cnt >= time)
 322                 delete(this);
 323         else
 324                 this.nextthink = time + 0.1;
 325 }
 326
 327 entity vehicle_tossgib(entity this, entity _template, vector _vel, string _tag, bool _burn, bool _explode, float _maxtime, vector _rot)
 328 {
 329         entity _gib = spawn();
 330         _setmodel(_gib, _template.model);
 331         vector org = gettaginfo(this, gettagindex(this, _tag));
 332         setorigin(_gib, org);
 333         _gib.velocity = _vel;
 334         set_movetype(_gib, MOVETYPE_TOSS);
 335         _gib.solid = SOLID_CORPSE;
 336         _gib.colormod = '-0.5 -0.5 -0.5';
 337         _gib.effects = EF_LOWPRECISION;
 338         _gib.avelocity = _rot;
 339
 340         if(_burn)
 341                 _gib.effects |= EF_FLAME;
 342
 343         if(_explode)
 344         {
 345                 setthink(_gib, vehicles_gib_explode);
 346                 _gib.nextthink = time + random() * _explode;
 347                 settouch(_gib, vehicles_gib_touch);
 348         }
 349         else
 350         {
 351                 _gib.cnt = time + _maxtime;
 352                 setthink(_gib, vehicles_gib_think);
 353                 _gib.nextthink = time + _maxtime - 1;
 354                 _gib.alpha = 1;
 355         }
 356         return _gib;
 357 }
 358
 359 bool vehicle_addplayerslot(     entity _owner,
 360                                                                 entity _slot,
 361                                                                 int _hud,
 362                                                                 Model _hud_model,
 363                                                                 bool(entity,float) _framefunc,
 364                                                                 void(entity,bool) _exitfunc, float(entity, entity) _enterfunc)
 365 {
 366         if(!(_owner.vehicle_flags & VHF_MULTISLOT))
 367                 _owner.vehicle_flags |= VHF_MULTISLOT;
 368
 369         _slot.PlayerPhysplug = _framefunc;
 370         _slot.vehicle_exit = _exitfunc;
 371         _slot.vehicle_enter = _enterfunc;
 372         _slot.hud = _hud;
 373         _slot.vehicle_flags = VHF_PLAYERSLOT;
 374         _slot.vehicle_viewport = spawn();
 375         _slot.vehicle_hudmodel = spawn();
 376         _slot.vehicle_hudmodel.viewmodelforclient = _slot;
 377         _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 378
 379         setmodel(_slot.vehicle_hudmodel, _hud_model);
 380         setmodel(_slot.vehicle_viewport, MDL_Null);
 381
 382         setattachment(_slot.vehicle_hudmodel, _slot, "");
 383         setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
 384
 385         return true;
 386 }
 387
 388 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
 389                                                  float _pichlimit_min, float _pichlimit_max,
 390                                                  float _rotlimit_min, float _rotlimit_max, float _aimspeed)
 391 {
 392         vector vtmp, vtag;
 393         float ftmp;
 394         vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
 395         vtmp = vectoangles(normalize(_target - vtag));
 396         vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
 397         vtmp = AnglesTransform_Normalize(vtmp, true);
 398         ftmp = _aimspeed * frametime;
 399         vtmp_y = bound(-ftmp, vtmp_y, ftmp);
 400         vtmp_x = bound(-ftmp, vtmp_x, ftmp);
 401         _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
 402         _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
 403         return vtag;
 404 }
 405
 406 void vehicles_reset_colors(entity this)
 407 {
 408         int eff = 0, cmap;
 409         const vector cmod = '0 0 0';
 410         if(this.team && teamplay)
 411                 cmap = 1024 + (this.team - 1) * 17;
 412         else
 413                 cmap = 1024;
 414         if(autocvar_g_nodepthtestplayers)
 415                 eff |= EF_NODEPTHTEST;
 416         if(autocvar_g_fullbrightplayers)
 417                 eff |= EF_FULLBRIGHT;
 418
 419         // Find all ents attacked to main model and setup effects, colormod etc.
 420         FOREACH_ENTITY_ENT(tag_entity, this,
 421         {
 422                 if(it != this.vehicle_shieldent)
 423                 {
 424                         it.effects = eff;
 425                         it.colormod = cmod;
 426                         it.colormap = cmap;
 427                         it.alpha = 1;
 428                 }
 429         });
 430
 431         // Also check head tags
 432         FOREACH_ENTITY_ENT(tag_entity, this.tur_head,
 433         {
 434                 if(it != this.vehicle_shieldent)
 435                 {
 436                         it.effects = eff;
 437                         it.colormod = cmod;
 438                         it.colormap = cmap;
 439                         it.alpha = 1;
 440                 }
 441         });
 442
 443         this.vehicle_hudmodel.effects  = this.effects  = eff; // | EF_LOWPRECISION;
 444         this.vehicle_hudmodel.colormod = this.colormod = cmod;
 445         this.vehicle_hudmodel.colormap = this.colormap = cmap;
 446         this.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 447
 448         this.alpha       = 1;
 449         this.avelocity = '0 0 0';
 450         this.velocity  = '0 0 0';
 451         this.effects   = eff;
 452 }
 453
 454 void vehicles_clearreturn(entity veh)
 455 {
 456         // Remove "return helper" entities, if any.
 457         IL_EACH(g_vehicle_returners, it.wp00 == veh,
 458         {
 459                 it.classname = "";
 460                 setthink(it, SUB_Remove);
 461                 it.nextthink = time + 0.1;
 462                 IL_REMOVE(g_vehicle_returners, it);
 463
 464                 if(it.waypointsprite_attached)
 465                         WaypointSprite_Kill(it.waypointsprite_attached);
 466         });
 467 }
 468
 469 void vehicles_spawn(entity this);
 470 void vehicles_return(entity this)
 471 {
 472         Send_Effect(EFFECT_TELEPORT, this.wp00.origin + '0 0 64', '0 0 0', 1);
 473
 474         setthink(this.wp00, vehicles_spawn);
 475         this.wp00.nextthink = time;
 476
 477         if(this.waypointsprite_attached)
 478                 WaypointSprite_Kill(this.waypointsprite_attached);
 479
 480         delete(this);
 481 }
 482
 483 void vehicles_showwp_goaway(entity this)
 484 {
 485         if(this.waypointsprite_attached)
 486                 WaypointSprite_Kill(this.waypointsprite_attached);
 487
 488         delete(this);
 489 }
 490
 491 void vehicles_showwp(entity this)
 492 {
 493         entity ent = this;
 494
 495         if(ent.cnt)
 496         {
 497                 setthink(ent, vehicles_return);
 498                 ent.nextthink = ent.cnt;
 499         }
 500         else
 501         {
 502                 setthink(ent, vehicles_return);
 503                 ent.nextthink  = time + 1;
 504
 505                 ent = spawn();
 506                 ent.team = this.wp00.team;
 507                 ent.wp00 = this.wp00;
 508                 setorigin(ent, this.wp00.pos1);
 509
 510                 ent.nextthink = time + 5;
 511                 setthink(ent, vehicles_showwp_goaway);
 512         }
 513
 514         vector rgb;
 515         if(teamplay && ent.team)
 516                 rgb = Team_ColorRGB(ent.team);
 517         else
 518                 rgb = '1 1 1';
 519         entity wp = WaypointSprite_Spawn(WP_Vehicle, 0, 0, ent, '0 0 64', NULL, 0, ent, waypointsprite_attached, true, RADARICON_Vehicle);
 520         wp.colormod = rgb;
 521         if(ent.waypointsprite_attached)
 522         {
 523                 WaypointSprite_UpdateRule(ent.waypointsprite_attached, ent.wp00.team, SPRITERULE_DEFAULT);
 524                 if(this == NULL)
 525                         WaypointSprite_UpdateBuildFinished(ent.waypointsprite_attached, ent.nextthink);
 526                 WaypointSprite_Ping(ent.waypointsprite_attached);
 527         }
 528 }
 529
 530 void vehicles_setreturn(entity veh)
 531 {
 532         vehicles_clearreturn(veh);
 533
 534         entity ret = new(vehicle_return);
 535         IL_PUSH(g_vehicle_returners, ret);
 536         ret.wp00           = veh;
 537         ret.team                = veh.team;
 538         setthink(ret, vehicles_showwp);
 539
 540         if(IS_DEAD(veh))
 541         {
 542                 ret.cnt          = time + veh.respawntime;
 543                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 5);
 544         }
 545         else
 546         {
 547                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 1);
 548         }
 549
 550         setorigin(ret, veh.pos1 + '0 0 96');
 551 }
 552
 553 void vehicle_use(entity this, entity actor, entity trigger)
 554 {
 555         LOG_DEBUG("vehicle ", this.netname, " used by ", actor.classname);
 556
 557         this.tur_head.team = actor.team;
 558
 559         if(this.tur_head.team == 0)
 560                 this.active = ACTIVE_NOT;
 561         else
 562                 this.active = ACTIVE_ACTIVE;
 563
 564         if(this.active == ACTIVE_ACTIVE && !IS_DEAD(this) && !game_stopped)
 565         {
 566                 LOG_DEBUG("Respawning vehicle: ", this.netname);
 567                 if(this.effects & EF_NODRAW)
 568                 {
 569                         setthink(this, vehicles_spawn);
 570                         this.nextthink = time + 3;
 571                 }
 572                 else
 573                 {
 574                         vehicles_setreturn(this);
 575                         vehicles_reset_colors(this);
 576                 }
 577         }
 578 }
 579
 580 void vehicles_regen(entity this, float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 581 {
 582         if(this.(regen_field) < field_max)
 583         if(timer + rpause < time)
 584         {
 585                 if(_healthscale)
 586                         regen = regen * (this.vehicle_health / this.max_health);
 587
 588                 this.(regen_field) = min(this.(regen_field) + regen * delta_time, field_max);
 589
 590                 if(this.owner)
 591                         this.owner.(regen_field) = (this.(regen_field) / field_max) * 100;
 592         }
 593 }
 594
 595 void shieldhit_think(entity this)
 596 {
 597         this.alpha -= 0.1;
 598         if (this.alpha <= 0)
 599         {
 600                 // setmodel(this, MDL_Null);
 601                 this.alpha = -1;
 602                 this.effects |= EF_NODRAW;
 603         }
 604         else
 605         {
 606                 this.nextthink = time + 0.1;
 607         }
 608 }
 609
 610 void vehicles_painframe(entity this)
 611 {
 612         int myhealth = ((this.owner) ? this.owner.vehicle_health : ((this.vehicle_health / this.max_health) * 100));
 613
 614         if(myhealth <= 50)
 615         if(this.pain_frame < time)
 616         {
 617                 float _ftmp = myhealth / 50;
 618                 this.pain_frame = time + max(0.1, 0.1 + (random() * 0.5 * _ftmp));
 619                 Send_Effect(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);
 620
 621                 if(this.vehicle_flags & VHF_DMGSHAKE)
 622                         this.velocity += randomvec() * 30;
 623
 624                 if(this.vehicle_flags & VHF_DMGROLL)
 625                         if(this.vehicle_flags & VHF_DMGHEADROLL)
 626                                 this.tur_head.angles += randomvec();
 627                         else
 628                                 this.angles += randomvec();
 629         }
 630 }
 631
 632 void vehicles_frame(entity this, entity actor)
 633 {
 634         vehicles_painframe(this);
 635 }
 636
 637 void vehicles_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 638 {
 639         this.dmg_time = time;
 640
 641         // WEAPONTODO
 642         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 643                 damage *= autocvar_g_vehicles_vortex_damagerate;
 644         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 645                 damage *= autocvar_g_vehicles_machinegun_damagerate;
 646         else if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 647                 damage *= autocvar_g_vehicles_rifle_damagerate;
 648         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 649                 damage *= autocvar_g_vehicles_vaporizer_damagerate;
 650         else if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 651                 damage *= autocvar_g_vehicles_tag_damagerate;
 652         else if(DEATH_WEAPONOF(deathtype) != WEP_Null)
 653                 damage *= autocvar_g_vehicles_weapon_damagerate;
 654
 655         this.enemy = attacker;
 656
 657         this.pain_finished = time;
 658
 659         if((this.vehicle_flags & VHF_HASSHIELD) && (this.vehicle_shield > 0))
 660         {
 661                 if (wasfreed(this.vehicle_shieldent) || this.vehicle_shieldent == NULL)
 662                 {
 663                         this.vehicle_shieldent = spawn();
 664                         this.vehicle_shieldent.effects = EF_LOWPRECISION;
 665
 666                         setmodel(this.vehicle_shieldent, MDL_VEH_SHIELD);
 667                         setattachment(this.vehicle_shieldent, this, "");
 668                         setorigin(this.vehicle_shieldent, real_origin(this) - this.origin);
 669                         this.vehicle_shieldent.scale       = 256 / vlen(this.maxs - this.mins);
 670                         setthink(this.vehicle_shieldent, shieldhit_think);
 671                 }
 672
 673                 this.vehicle_shieldent.colormod = '1 1 1';
 674                 this.vehicle_shieldent.alpha = 0.45;
 675                 this.vehicle_shieldent.angles = vectoangles(normalize(hitloc - (this.origin + this.vehicle_shieldent.origin))) - this.angles;
 676                 this.vehicle_shieldent.nextthink = time;
 677                 this.vehicle_shieldent.effects &= ~EF_NODRAW;
 678
 679                 this.vehicle_shield -= damage;
 680
 681                 if(this.vehicle_shield < 0)
 682                 {
 683                         this.vehicle_health -= fabs(this.vehicle_shield);
 684                         this.vehicle_shieldent.colormod = '2 0 0';
 685                         this.vehicle_shield = 0;
 686                         this.vehicle_shieldent.alpha = 0.75;
 687
 688                         if(sound_allowed(MSG_BROADCAST, attacker))
 689                                 spamsound (this, CH_PAIN, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 690                 }
 691                 else
 692                         if(sound_allowed(MSG_BROADCAST, attacker))
 693                                 spamsound (this, CH_PAIN, SND_ONS_ELECTRICITY_EXPLODE, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 694
 695         }
 696         else
 697         {
 698                 this.vehicle_health -= damage;
 699
 700                 if(sound_allowed(MSG_BROADCAST, attacker))
 701                         spamsound (this, CH_PAIN, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 702         }
 703
 704         if(this.damageforcescale < 1 && this.damageforcescale > 0)
 705                 this.velocity += force * this.damageforcescale;
 706         else
 707                 this.velocity += force;
 708
 709         if(this.vehicle_health <= 0)
 710         {
 711                 if(this.owner)
 712                         if(this.vehicle_flags & VHF_DEATHEJECT)
 713                                 vehicles_exit(this, VHEF_EJECT);
 714                         else
 715                                 vehicles_exit(this, VHEF_RELEASE);
 716
 717
 718                 antilag_clear(this, this);
 719
 720                 Vehicle info = Vehicles_from(this.vehicleid);
 721                 info.vr_death(info, this);
 722                 vehicles_setreturn(this);
 723         }
 724 }
 725
 726 bool vehicles_crushable(entity e)
 727 {
 728         if(IS_PLAYER(e) && time >= e.vehicle_enter_delay)
 729                 return true;
 730
 731         if(IS_MONSTER(e))
 732                 return true;
 733
 734         return false;
 735 }
 736
 737 void vehicles_impact(entity this, float _minspeed, float _speedfac, float _maxpain)
 738 {
 739         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 740                 return;
 741
 742         if(this.play_time < time)
 743         {
 744                 float wc = vlen(this.velocity - this.oldvelocity);
 745                 //dprint("oldvel: ", vtos(this.oldvelocity), "\n");
 746                 //dprint("vel: ", vtos(this.velocity), "\n");
 747                 if(_minspeed < wc)
 748                 {
 749                         float take = min(_speedfac * wc, _maxpain);
 750                         Damage (this, NULL, NULL, take, DEATH_FALL.m_id, this.origin, '0 0 0');
 751                         this.play_time = time + 0.25;
 752
 753                         //dprint("wc: ", ftos(wc), "\n");
 754                         //dprint("take: ", ftos(take), "\n");
 755                 }
 756         }
 757 }
 758
 759 // vehicle enter/exit handling
 760 vector vehicles_findgoodexit(entity this, entity player, vector prefer_spot)
 761 {
 762         // TODO: we actually want the player's size here
 763         tracebox(this.origin + '0 0 32', PL_MIN_CONST, PL_MAX_CONST, prefer_spot, MOVE_NORMAL, player);
 764         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 765                 return prefer_spot;
 766
 767         float mysize = 1.5 * vlen(this.maxs - this.mins);
 768         vector v;
 769         vector v2 = 0.5 * (this.absmin + this.absmax);
 770         for(int i = 0; i < autocvar_g_vehicles_exit_attempts; ++i)
 771         {
 772                 v = randomvec();
 773                 v_z = 0;
 774                 v = v2 + normalize(v) * mysize;
 775                 tracebox(v2, PL_MIN_CONST, PL_MAX_CONST, v, MOVE_NORMAL, player);
 776                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 777                         return v;
 778         }
 779
 780         return this.origin;
 781 }
 782
 783 void vehicles_exit(entity vehic, bool eject)
 784 {
 785         entity player = vehic.owner;
 786
 787         if(vehicles_exit_running)
 788         {
 789                 LOG_TRACE("^1vehicles_exit already running! this is not good...");
 790                 return;
 791         }
 792
 793         vehicles_exit_running = true;
 794
 795         // TODO: this was in an IS_CLIENT check, make sure it isn't actually needed!
 796         if(vehic.vehicle_flags & VHF_PLAYERSLOT)
 797         {
 798                 vehic.vehicle_exit(vehic, eject);
 799                 vehicles_exit_running = false;
 800                 return;
 801         }
 802
 803         if (player)
 804         {
 805                 if (IS_REAL_CLIENT(player))
 806                 {
 807                         msg_entity = player;
 808                         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 809                         WriteEntity( MSG_ONE, player);
 810
 811                         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 812                         WriteAngle(MSG_ONE, 0);
 813                         WriteAngle(MSG_ONE, vehic.angles_y);
 814                         WriteAngle(MSG_ONE, 0);
 815                 }
 816
 817                 setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
 818
 819                 player.takedamage               = DAMAGE_AIM;
 820                 player.solid                    = SOLID_SLIDEBOX;
 821                 set_movetype(player, MOVETYPE_WALK);
 822                 player.effects             &= ~EF_NODRAW;
 823                 player.teleportable     = TELEPORT_NORMAL;
 824                 player.alpha                    = 1;
 825                 player.PlayerPhysplug   = func_null;
 826                 player.vehicle                  = NULL;
 827                 player.view_ofs         = STAT(PL_VIEW_OFS, player);
 828                 player.event_damage     = PlayerDamage;
 829                 player.hud                              = HUD_NORMAL;
 830                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++ slot)
 831                 {
 832                         .entity weaponentity = weaponentities[slot];
 833                         player.(weaponentity).m_switchweapon = vehic.(weaponentity).m_switchweapon;
 834                         delete(vehic.(weaponentity)); // no longer needed
 835                 }
 836                 player.last_vehiclecheck = time + 3;
 837                 player.vehicle_enter_delay = time + 2;
 838
 839                 CSQCVehicleSetup(player, HUD_NORMAL);
 840
 841                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES);
 842                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES_OTHER); // kill all vehicle notifications when exiting a vehicle?
 843         }
 844
 845         vehic.flags |= FL_NOTARGET;
 846
 847         if(!IS_DEAD(vehic))
 848                 vehic.avelocity = '0 0 0';
 849
 850         vehic.tur_head.nodrawtoclient = NULL;
 851
 852         if(!teamplay)
 853                 vehic.team = 0;
 854
 855         WaypointSprite_Kill(vehic.wps_intruder);
 856
 857         MUTATOR_CALLHOOK(VehicleExit, player, vehic);
 858
 859         vehic.team = vehic.tur_head.team;
 860
 861         sound (vehic, CH_TRIGGER_SINGLE, SND_Null, 1, ATTEN_NORM);
 862         vehic.vehicle_hudmodel.viewmodelforclient = vehic;
 863         vehic.phase = time + 1;
 864
 865         vehic.vehicle_exit(vehic, eject);
 866
 867         vehicles_setreturn(vehic);
 868         vehicles_reset_colors(vehic);
 869         vehic.owner = NULL;
 870
 871         CSQCMODEL_AUTOINIT(vehic);
 872
 873         if(player)
 874                 player.oldorigin = player.origin; // player's location is set by the exit functions, so we need to do this after everything
 875
 876         vehicles_exit_running = false;
 877 }
 878
 879 void vehicles_touch(entity this, entity toucher)
 880 {
 881         if(MUTATOR_CALLHOOK(VehicleTouch, this, toucher))
 882                 return;
 883
 884         // Vehicle currently in use
 885         if(this.owner)
 886         {
 887                 if(!forbidWeaponUse(this.owner))
 888                 if(toucher != NULL)
 889                 if((this.origin_z + this.maxs_z) > (toucher.origin_z))
 890                 if(vehicles_crushable(toucher))
 891                 {
 892                         if(vdist(this.velocity, >=, 30))
 893                                 Damage(toucher, this, this.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH.m_id, '0 0 0', normalize(toucher.origin - this.origin) * autocvar_g_vehicles_crush_force);
 894
 895                         return; // Dont do selfdamage when hitting "soft targets".
 896                 }
 897
 898                 if(this.play_time < time) {
 899                         Vehicle info = Vehicles_from(this.vehicleid);
 900                         info.vr_impact(info, this);
 901                 }
 902
 903                 return;
 904         }
 905
 906         if(autocvar_g_vehicles_enter)
 907                 return;
 908
 909         vehicles_enter(toucher, this);
 910 }
 911
 912 bool vehicle_impulse(entity this, int imp)
 913 {
 914         entity v = this.vehicle;
 915         if (!v) return false;
 916         if (IS_DEAD(v)) return false;
 917         bool(entity,int) f = v.vehicles_impulse;
 918         if (f && f(this,imp)) return true;
 919         switch (imp)
 920         {
 921                 case IMP_weapon_drop.impulse:
 922                 {
 923                         stuffcmd(this, "\ntoggle cl_eventchase_vehicle\nset _vehicles_shownchasemessage 1\n");
 924                         return true;
 925                 }
 926         }
 927         return false;
 928 }
 929
 930 void vehicles_enter(entity pl, entity veh)
 931 {
 932    // Remove this when bots know how to use vehicles
 933         if((IS_BOT_CLIENT(pl) && !autocvar_g_vehicles_allow_bots))
 934                 return;
 935
 936         if((!IS_PLAYER(pl))
 937         || (veh.phase >= time)
 938         || (pl.vehicle_enter_delay >= time)
 939         || (STAT(FROZEN, pl))
 940         || (IS_DEAD(pl))
 941         || (pl.vehicle)
 942         ) { return; }
 943
 944         Vehicle info = Vehicles_from(veh.vehicleid);
 945
 946         if(autocvar_g_vehicles_enter) // vehicle's touch function should handle this if entering via use key is disabled (TODO)
 947         if(veh.vehicle_flags & VHF_MULTISLOT)
 948         if(veh.owner && SAME_TEAM(pl, veh))
 949         {
 950                 // we don't need a return value or anything here
 951                 // if successful the owner check below will prevent anything weird
 952                 info.vr_gunner_enter(info, veh, pl);
 953         }
 954
 955         if(veh.owner)
 956                 return; // got here and didn't enter the gunner, return
 957
 958         if(teamplay)
 959         if(veh.team)
 960         if(DIFF_TEAM(pl, veh))
 961         if(autocvar_g_vehicles_steal)
 962         {
 963                 FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, veh), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_VEHICLE_STEAL));
 964
 965                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_STEAL_SELF);
 966
 967                 if (autocvar_g_vehicles_steal_show_waypoint) {
 968                         entity wp = WaypointSprite_Spawn(WP_VehicleIntruder, 0, 0, pl, '0 0 68', NULL, veh.team, veh, wps_intruder, true, RADARICON_DANGER);
 969                         wp.colormod = Team_ColorRGB(pl.team);
 970                 }
 971         }
 972         else return;
 973
 974         RemoveGrapplingHooks(pl);
 975
 976         veh.vehicle_ammo1 = 0;
 977         veh.vehicle_ammo2 = 0;
 978         veh.vehicle_reload1 = 0;
 979         veh.vehicle_reload2 = 0;
 980         veh.vehicle_energy = 0;
 981
 982         veh.owner = pl;
 983         pl.vehicle = veh;
 984
 985         // .viewmodelforclient works better.
 986         //veh.vehicle_hudmodel.drawonlytoclient = veh.owner;
 987
 988         veh.vehicle_hudmodel.viewmodelforclient = pl;
 989
 990         pl.crouch = false;
 991         pl.view_ofs = STAT(PL_VIEW_OFS, pl);
 992         setsize(pl, STAT(PL_MIN, pl), STAT(PL_MAX, pl));
 993
 994         veh.event_damage        = vehicles_damage;
 995         veh.nextthink           = 0;
 996         pl.items &= ~IT_USING_JETPACK;
 997         pl.angles                       = veh.angles;
 998         pl.takedamage           = DAMAGE_NO;
 999         pl.solid                        = SOLID_NOT;
1000         pl.disableclientprediction = 1; // physics is no longer run, so this won't be reset
1001         set_movetype(pl, MOVETYPE_NOCLIP);
1002         pl.teleportable         = false;
1003         pl.alpha                        = -1;
1004         pl.event_damage         = func_null;
1005         pl.view_ofs                     = '0 0 0';
1006         veh.colormap            = pl.colormap;
1007         if(veh.tur_head)
1008                 veh.tur_head.colormap = pl.colormap;
1009         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1010         {
1011                 .entity weaponentity = weaponentities[slot];
1012                 veh.(weaponentity) = new(temp_wepent);
1013                 veh.(weaponentity).m_switchweapon = pl.(weaponentity).m_switchweapon;
1014         }
1015         pl.hud = veh.vehicleid;
1016         pl.PlayerPhysplug = veh.PlayerPhysplug;
1017
1018         pl.vehicle_ammo1 = veh.vehicle_ammo1;
1019         pl.vehicle_ammo2 = veh.vehicle_ammo2;
1020         pl.vehicle_reload1 = veh.vehicle_reload1;
1021         pl.vehicle_reload2 = veh.vehicle_reload2;
1022         pl.vehicle_energy = veh.vehicle_energy;
1023
1024         // Cant do this, hides attached objects too.
1025         //veh.exteriormodeltoclient = veh.owner;
1026         //veh.tur_head.exteriormodeltoclient = veh.owner;
1027
1028         UNSET_ONGROUND(pl);
1029         UNSET_ONGROUND(veh);
1030
1031         veh.team = pl.team;
1032         veh.flags -= FL_NOTARGET;
1033
1034         if (IS_REAL_CLIENT(pl))
1035         {
1036                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_ENTER);
1037
1038                 msg_entity = pl;
1039                 WriteByte (MSG_ONE, SVC_SETVIEWPORT);
1040                 WriteEntity(MSG_ONE, veh.vehicle_viewport);
1041
1042                 WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1043                 if(veh.tur_head)
1044                 {
1045                         WriteAngle(MSG_ONE, veh.tur_head.angles_x + veh.angles_x); // tilt
1046                         WriteAngle(MSG_ONE, veh.tur_head.angles_y + veh.angles_y); // yaw
1047                         WriteAngle(MSG_ONE, 0);                                                                   // roll
1048                 }
1049                 else
1050                 {
1051                         WriteAngle(MSG_ONE, veh.angles_x * -1); // tilt
1052                         WriteAngle(MSG_ONE, veh.angles_y);        // yaw
1053                         WriteAngle(MSG_ONE, 0);                           // roll
1054                 }
1055         }
1056
1057         vehicles_clearreturn(veh);
1058
1059         CSQCVehicleSetup(pl, veh.vehicleid);
1060
1061         MUTATOR_CALLHOOK(VehicleEnter, pl, veh);
1062
1063         CSQCModel_UnlinkEntity(veh);
1064         info.vr_enter(info, veh);
1065
1066         antilag_clear(pl, CS(pl));
1067 }
1068
1069 void vehicles_think(entity this)
1070 {
1071         this.nextthink = time + autocvar_g_vehicles_thinkrate;
1072
1073         if(this.owner)
1074                 this.owner.vehicle_weapon2mode = this.vehicle_weapon2mode;
1075
1076         Vehicle info = Vehicles_from(this.vehicleid);
1077         info.vr_think(info, this);
1078
1079         vehicles_painframe(this);
1080
1081         CSQCMODEL_AUTOUPDATE(this);
1082 }
1083
1084 void vehicles_reset(entity this)
1085 {
1086         if(this.owner)
1087                 vehicles_exit(this, VHEF_RELEASE);
1088
1089         vehicles_clearreturn(this);
1090
1091         if(this.active != ACTIVE_NOT)
1092                 vehicles_spawn(this);
1093 }
1094
1095 // initialization
1096 void vehicles_spawn(entity this)
1097 {
1098         LOG_DEBUG("Spawning vehicle: ", this.classname);
1099
1100         // disown & reset
1101         this.vehicle_hudmodel.viewmodelforclient = this;
1102
1103         this.owner                              = NULL;
1104         settouch(this, vehicles_touch);
1105         this.event_damage               = vehicles_damage;
1106         this.reset                              = vehicles_reset;
1107         this.iscreature                 = true;
1108         this.teleportable               = false; // no teleporting for vehicles, too buggy
1109         this.damagedbycontents  = true;
1110         set_movetype(this, MOVETYPE_WALK);
1111         this.solid                              = SOLID_SLIDEBOX;
1112         this.takedamage                 = DAMAGE_AIM;
1113         this.deadflag                   = DEAD_NO;
1114         if(!this.bot_attack)
1115                 IL_PUSH(g_bot_targets, this);
1116         this.bot_attack                 = true;
1117         this.flags                              = FL_NOTARGET;
1118         this.avelocity                  = '0 0 0';
1119         this.velocity                   = '0 0 0';
1120         setthink(this, vehicles_think);
1121         this.nextthink                  = time;
1122
1123         // Reset locking
1124         this.lock_strength = 0;
1125         this.lock_target = NULL;
1126         this.misc_bulletcounter = 0;
1127
1128         // Return to spawn
1129         this.angles = this.pos2;
1130         setorigin(this, this.pos1);
1131         // Show it
1132         Send_Effect(EFFECT_TELEPORT, this.origin + '0 0 64', '0 0 0', 1);
1133
1134         if(this.vehicle_controller)
1135                 this.team = this.vehicle_controller.team;
1136
1137         FOREACH_CLIENT(IS_PLAYER(it),
1138         {
1139                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1140             {
1141                 .entity weaponentity = weaponentities[slot];
1142                 if(it.(weaponentity).hook.aiment == this)
1143                         RemoveHook(it.(weaponentity).hook);
1144             }
1145         });
1146
1147         vehicles_reset_colors(this);
1148
1149         Vehicle info = Vehicles_from(this.vehicleid);
1150         info.vr_spawn(info, this);
1151
1152         CSQCMODEL_AUTOINIT(this);
1153 }
1154
1155 bool vehicle_initialize(entity this, Vehicle info, bool nodrop)
1156 {
1157         if(!autocvar_g_vehicles)
1158                 return false;
1159
1160         if(!info.vehicleid)
1161                 return false;
1162
1163         if(!this.tur_head)
1164         {
1165                 info.vr_precache(info);
1166                 IL_PUSH(g_vehicles, this);
1167         }
1168
1169         if(this.targetname && this.targetname != "")
1170         {
1171                 this.vehicle_controller = find(NULL, target, this.targetname);
1172                 if(!this.vehicle_controller)
1173                 {
1174                         LOG_DEBUG("^1WARNING: ^7Vehicle with invalid .targetname");
1175                         this.active = ACTIVE_ACTIVE;
1176                 }
1177                 else
1178                 {
1179                         this.team = this.vehicle_controller.team;
1180                         this.use = vehicle_use;
1181
1182                         if(teamplay)
1183                         {
1184                                 if(this.vehicle_controller.team == 0)
1185                                         this.active = ACTIVE_NOT;
1186                                 else
1187                                         this.active = ACTIVE_ACTIVE;
1188                         }
1189                 }
1190         }
1191         else { this.active = ACTIVE_ACTIVE; }
1192
1193         if(this.team && (!teamplay || !autocvar_g_vehicles_teams))
1194                 this.team = 0;
1195
1196         if(this.mdl == "" || !this.mdl)
1197                 _setmodel(this, info.model);
1198         else
1199                 _setmodel(this, this.mdl);
1200
1201         this.vehicle_flags |= VHF_ISVEHICLE;
1202
1203         this.vehicle_viewport           = new(vehicle_viewport);
1204         this.vehicle_hudmodel           = new(vehicle_hudmodel);
1205         this.tur_head                           = new(tur_head);
1206         this.tur_head.owner                     = this;
1207         this.takedamage                         = DAMAGE_NO;
1208         this.bot_attack                         = true;
1209         IL_PUSH(g_bot_targets, this);
1210         this.iscreature                         = true;
1211         this.teleportable                       = false; // no teleporting for vehicles, too buggy
1212         this.damagedbycontents          = true;
1213         IL_PUSH(g_damagedbycontents, this);
1214         this.vehicleid                          = info.vehicleid;
1215         this.PlayerPhysplug                     = info.PlayerPhysplug;
1216         this.event_damage                       = func_null;
1217         settouch(this, vehicles_touch);
1218         setthink(this, vehicles_spawn);
1219         this.nextthink                          = time;
1220         this.effects                            = EF_NODRAW;
1221         this.dphitcontentsmask          = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1222
1223         if(autocvar_g_playerclip_collisions)
1224                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1225
1226         if(autocvar_g_nodepthtestplayers)
1227                 this.effects |= EF_NODEPTHTEST;
1228
1229         if(autocvar_g_fullbrightplayers)
1230                 this.effects |= EF_FULLBRIGHT;
1231
1232         _setmodel(this.vehicle_hudmodel, info.hud_model);
1233         setmodel(this.vehicle_viewport, MDL_Null);
1234
1235         if(info.head_model != "")
1236         {
1237                 _setmodel(this.tur_head, info.head_model);
1238                 setattachment(this.tur_head, this, info.tag_head);
1239                 setattachment(this.vehicle_hudmodel, this.tur_head, info.tag_hud);
1240                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1241         }
1242         else
1243         {
1244                 setattachment(this.tur_head, this, "");
1245                 setattachment(this.vehicle_hudmodel, this, info.tag_hud);
1246                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1247         }
1248
1249         setsize(this, info.m_mins, info.m_maxs);
1250
1251         info.vr_setup(info, this);
1252
1253         if(!nodrop)
1254         {
1255                 setorigin(this, this.origin);
1256                 tracebox(this.origin + '0 0 100', info.m_mins, info.m_maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1257                 setorigin(this, trace_endpos);
1258         }
1259
1260         this.pos1 = this.origin;
1261         this.pos2 = this.angles;
1262         this.tur_head.team = this.team;
1263
1264         if(this.active == ACTIVE_NOT)
1265                 this.nextthink = 0; // wait until activated
1266         else if(autocvar_g_vehicles_delayspawn)
1267                 this.nextthink = time + this.respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1268         else
1269                 this.nextthink = time + game_starttime;
1270
1271         if(MUTATOR_CALLHOOK(VehicleInit, this))
1272                 return false;
1273
1274         return true;
1275 }