qcsrc/common/vehicles/sv_vehicles.qc

   1 #include "sv_vehicles.qh"
   2
   3 #if 0
   4 bool vehicle_send(entity to, int sf)
   5 {
   6         WriteByte(MSG_ENTITY, ENT_CLIENT_VEHICLE);
   7         WriteByte(MSG_ENTITY, sf);
   8
   9         if(sf & VSF_SPAWN)
  10         {
  11                 WriteByte(MSG_ENTITY, this.vehicleid);
  12         }
  13
  14         if(sf & VSF_SETUP)
  15         {
  16                 // send stuff?
  17         }
  18
  19         if(sf & VSF_ENTER)
  20         {
  21                 // player handles the .vehicle stuff, we need only set ourselves up for driving
  22
  23                 // send stuff?
  24         }
  25
  26         if(sf & VSF_EXIT)
  27         {
  28                 // senf stuff?
  29         }
  30
  31         if(sf & VSF_PRECACHE)
  32         {
  33                 // send stuff?!
  34         }
  35
  36         return true;
  37 }
  38 #endif
  39
  40 bool SendAuxiliaryXhair(entity this, entity to, int sf)
  41 {
  42
  43         WriteHeader(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  44
  45         WriteByte(MSG_ENTITY, this.cnt);
  46
  47         WriteCoord(MSG_ENTITY, this.origin_x);
  48         WriteCoord(MSG_ENTITY, this.origin_y);
  49         WriteCoord(MSG_ENTITY, this.origin_z);
  50
  51         WriteByte(MSG_ENTITY, rint(this.colormod_x * 255));
  52         WriteByte(MSG_ENTITY, rint(this.colormod_y * 255));
  53         WriteByte(MSG_ENTITY, rint(this.colormod_z * 255));
  54
  55         return true;
  56 }
  57
  58 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  59 {
  60         if(!IS_REAL_CLIENT(own))
  61                 return;
  62
  63         entity axh;
  64
  65         axh_id = bound(0, axh_id, MAX_AXH);
  66         axh = own.(AuxiliaryXhair[axh_id]);
  67
  68         if(axh == NULL || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  69         {
  70                 axh                                      = spawn();
  71                 axh.cnt                          = axh_id;
  72                 axh.drawonlytoclient    = own;
  73                 axh.owner                          = own;
  74                 Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  75         }
  76
  77         setorigin(axh, loc);
  78         axh.colormod                    = clr;
  79         axh.SendFlags              = 0x01;
  80         own.(AuxiliaryXhair[axh_id]) = axh;
  81 }
  82
  83 void CSQCVehicleSetup(entity own, int vehicle_id)
  84 {
  85         if(!IS_REAL_CLIENT(own))
  86                 return;
  87
  88         msg_entity = own;
  89
  90         WriteHeader(MSG_ONE, TE_CSQC_VEHICLESETUP);
  91         WriteByte(MSG_ONE, vehicle_id);
  92 }
  93
  94 void vehicles_locktarget(entity this, float incr, float decr, float _lock_time)
  95 {
  96         if(this.lock_target && IS_DEAD(this.lock_target))
  97         {
  98                 this.lock_target        = NULL;
  99                 this.lock_strength  = 0;
 100                 this.lock_time    = 0;
 101         }
 102
 103         if(this.lock_time > time)
 104         {
 105                 if(this.lock_target)
 106                 if(this.lock_soundtime < time)
 107                 {
 108                         this.lock_soundtime = time + 0.5;
 109                         play2(this.owner, "vehicles/locked.wav");
 110                 }
 111
 112                 return;
 113         }
 114
 115         if(trace_ent != NULL)
 116         {
 117                 if(SAME_TEAM(trace_ent, this))
 118                         trace_ent = NULL;
 119
 120                 if(IS_DEAD(trace_ent))
 121                         trace_ent = NULL;
 122
 123                 if(!(IS_VEHICLE(trace_ent) || IS_TURRET(trace_ent)))
 124                         trace_ent = NULL;
 125
 126                 if(trace_ent.alpha <= 0.5 && trace_ent.alpha != 0)
 127                         trace_ent = NULL; // invisible
 128         }
 129
 130         if(this.lock_target == NULL && trace_ent != NULL)
 131                 this.lock_target = trace_ent;
 132
 133         if(this.lock_target && trace_ent == this.lock_target)
 134         {
 135                 if(this.lock_strength != 1 && this.lock_strength + incr >= 1)
 136                 {
 137                         play2(this.owner, "vehicles/lock.wav");
 138                         this.lock_soundtime = time + 0.8;
 139                 }
 140                 else if (this.lock_strength != 1 && this.lock_soundtime < time)
 141                 {
 142                         play2(this.owner, "vehicles/locking.wav");
 143                         this.lock_soundtime = time + 0.3;
 144                 }
 145         }
 146
 147         // Have a locking target
 148         // Trace hit current target
 149         if(trace_ent == this.lock_target && trace_ent != NULL)
 150         {
 151                 this.lock_strength = min(this.lock_strength + incr, 1);
 152                 if(this.lock_strength == 1)
 153                         this.lock_time = time + _lock_time;
 154         }
 155         else
 156         {
 157                 if(trace_ent)
 158                         this.lock_strength = max(this.lock_strength - decr * 2, 0);
 159                 else
 160                         this.lock_strength = max(this.lock_strength - decr, 0);
 161
 162                 if(this.lock_strength == 0)
 163                         this.lock_target = NULL;
 164         }
 165 }
 166
 167 vector vehicles_force_fromtag_hover(entity this, string tag_name, float spring_length, float max_power)
 168 {
 169         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 170         v_forward  = normalize(v_forward) * -1;
 171         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 172
 173         force_fromtag_power = (1 - trace_fraction) * max_power;
 174         force_fromtag_normpower = force_fromtag_power / max_power;
 175
 176         return v_forward  * force_fromtag_power;
 177 }
 178
 179 vector vehicles_force_fromtag_maglev(entity this, string tag_name, float spring_length, float max_power)
 180 {
 181         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 182         v_forward  = normalize(v_forward) * -1;
 183         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 184
 185         // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 186         if(trace_fraction == 1.0)
 187         {
 188                 force_fromtag_normpower = -0.25;
 189                 return '0 0 -200';
 190         }
 191
 192         force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 193         force_fromtag_normpower = force_fromtag_power / max_power;
 194
 195         return v_forward  * force_fromtag_power;
 196 }
 197
 198 // projectile handling
 199 void vehicles_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 200 {
 201         // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 202         if(inflictor.owner == this.owner)
 203                 return;
 204
 205         this.health -= damage;
 206         this.velocity += force;
 207         if(this.health < 1)
 208         {
 209                 this.takedamage = DAMAGE_NO;
 210                 this.event_damage = func_null;
 211                 setthink(this, adaptor_think2use);
 212                 this.nextthink = time;
 213         }
 214 }
 215
 216 void vehicles_projectile_explode(entity this)
 217 {
 218         if(this.owner && other != NULL)
 219         {
 220                 if(other == this.owner.vehicle)
 221                         return;
 222
 223                 if(other == this.owner.vehicle.tur_head)
 224                         return;
 225         }
 226
 227         PROJECTILE_TOUCH(this);
 228
 229         this.event_damage = func_null;
 230         RadiusDamage (this, this.realowner, this.shot_dmg, 0, this.shot_radius, this, NULL, this.shot_force, this.totalfrags, other);
 231
 232         remove (this);
 233 }
 234
 235 void vehicles_projectile_explode_use(entity this, entity actor, entity trigger)
 236 {
 237         vehicles_projectile_explode(this);
 238 }
 239
 240 entity vehicles_projectile(entity this, string _mzlfx, Sound _mzlsound,
 241                                                    vector _org, vector _vel,
 242                                                    float _dmg, float _radi, float _force,  float _size,
 243                                                    int _deahtype, float _projtype, float _health,
 244                                                    bool _cull, bool _clianim, entity _owner)
 245 {
 246     TC(Sound, _mzlsound);
 247         entity proj;
 248
 249         proj = spawn();
 250
 251         PROJECTILE_MAKETRIGGER(proj);
 252         setorigin(proj, _org);
 253
 254         proj.shot_dmg            = _dmg;
 255         proj.shot_radius          = _radi;
 256         proj.shot_force    = _force;
 257         proj.totalfrags    = _deahtype;
 258         proj.solid                      = SOLID_BBOX;
 259         proj.movetype            = MOVETYPE_FLYMISSILE;
 260         proj.flags                      = FL_PROJECTILE;
 261         proj.bot_dodge          = true;
 262         proj.bot_dodgerating  = _dmg;
 263         proj.velocity            = _vel;
 264         settouch(proj, vehicles_projectile_explode);
 265         proj.use                          = vehicles_projectile_explode_use;
 266         proj.owner                      = this;
 267         proj.realowner          = _owner;
 268         setthink(proj, SUB_Remove);
 269         proj.nextthink          = time + 30;
 270
 271         if(_health)
 272         {
 273                 proj.takedamage    = DAMAGE_AIM;
 274                 proj.event_damage        = vehicles_projectile_damage;
 275                 proj.health                = _health;
 276         }
 277         else
 278                 proj.flags                 = FL_PROJECTILE | FL_NOTARGET;
 279
 280         if(_mzlsound != SND_Null)
 281                 sound (this, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 282
 283         if(_mzlfx)
 284                 Send_Effect_(_mzlfx, proj.origin, proj.velocity, 1);
 285
 286         setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 287
 288         CSQCProjectile(proj, _clianim, _projtype, _cull);
 289
 290         return proj;
 291 }
 292
 293 void vehicles_gib_explode(entity this)
 294 {
 295         sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 296         Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 297         Send_Effect(EFFECT_EXPLOSION_SMALL, this.wp00.origin + '0 0 64', '0 0 0', 1);
 298         remove(this);
 299 }
 300
 301 void vehicles_gib_think(entity this)
 302 {
 303         this.alpha -= 0.1;
 304         if(this.cnt >= time)
 305                 remove(this);
 306         else
 307                 this.nextthink = time + 0.1;
 308 }
 309
 310 entity vehicle_tossgib(entity this, entity _template, vector _vel, string _tag, bool _burn, bool _explode, float _maxtime, vector _rot)
 311 {
 312         entity _gib = spawn();
 313         _setmodel(_gib, _template.model);
 314         vector org = gettaginfo(this, gettagindex(this, _tag));
 315         setorigin(_gib, org);
 316         _gib.velocity = _vel;
 317         _gib.movetype = MOVETYPE_TOSS;
 318         _gib.solid = SOLID_CORPSE;
 319         _gib.colormod = '-0.5 -0.5 -0.5';
 320         _gib.effects = EF_LOWPRECISION;
 321         _gib.avelocity = _rot;
 322
 323         if(_burn)
 324                 _gib.effects |= EF_FLAME;
 325
 326         if(_explode)
 327         {
 328                 setthink(_gib, vehicles_gib_explode);
 329                 _gib.nextthink = time + random() * _explode;
 330                 settouch(_gib, vehicles_gib_explode);
 331         }
 332         else
 333         {
 334                 _gib.cnt = time + _maxtime;
 335                 setthink(_gib, vehicles_gib_think);
 336                 _gib.nextthink = time + _maxtime - 1;
 337                 _gib.alpha = 1;
 338         }
 339         return _gib;
 340 }
 341
 342 bool vehicle_addplayerslot(     entity _owner,
 343                                                                 entity _slot,
 344                                                                 int _hud,
 345                                                                 Model _hud_model,
 346                                                                 bool(entity) _framefunc,
 347                                                                 void(entity,bool) _exitfunc, float(entity, entity) _enterfunc)
 348 {
 349         if(!(_owner.vehicle_flags & VHF_MULTISLOT))
 350                 _owner.vehicle_flags |= VHF_MULTISLOT;
 351
 352         _slot.PlayerPhysplug = _framefunc;
 353         _slot.vehicle_exit = _exitfunc;
 354         _slot.vehicle_enter = _enterfunc;
 355         _slot.hud = _hud;
 356         _slot.vehicle_flags = VHF_PLAYERSLOT;
 357         _slot.vehicle_viewport = spawn();
 358         _slot.vehicle_hudmodel = spawn();
 359         _slot.vehicle_hudmodel.viewmodelforclient = _slot;
 360         _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 361
 362         setmodel(_slot.vehicle_hudmodel, _hud_model);
 363         setmodel(_slot.vehicle_viewport, MDL_Null);
 364
 365         setattachment(_slot.vehicle_hudmodel, _slot, "");
 366         setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
 367
 368         return true;
 369 }
 370
 371 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
 372                                                  float _pichlimit_min, float _pichlimit_max,
 373                                                  float _rotlimit_min, float _rotlimit_max, float _aimspeed)
 374 {
 375         vector vtmp, vtag;
 376         float ftmp;
 377         vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
 378         vtmp = vectoangles(normalize(_target - vtag));
 379         vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
 380         vtmp = AnglesTransform_Normalize(vtmp, true);
 381         ftmp = _aimspeed * frametime;
 382         vtmp_y = bound(-ftmp, vtmp_y, ftmp);
 383         vtmp_x = bound(-ftmp, vtmp_x, ftmp);
 384         _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
 385         _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
 386         return vtag;
 387 }
 388
 389 void vehicles_reset_colors(entity this)
 390 {
 391         int eff = 0, cmap;
 392         const vector cmod = '0 0 0';
 393         if(this.team && teamplay)
 394                 cmap = 1024 + (this.team - 1) * 17;
 395         else
 396                 cmap = 1024;
 397         if(autocvar_g_nodepthtestplayers)
 398                 eff |= EF_NODEPTHTEST;
 399         if(autocvar_g_fullbrightplayers)
 400                 eff |= EF_FULLBRIGHT;
 401
 402         // Find all ents attacked to main model and setup effects, colormod etc.
 403         FOREACH_ENTITY_ENT(tag_entity, this,
 404         {
 405                 if(it != this.vehicle_shieldent)
 406                 {
 407                         it.effects = eff;
 408                         it.colormod = cmod;
 409                         it.colormap = cmap;
 410                         it.alpha = 1;
 411                 }
 412         });
 413
 414         // Also check head tags
 415         FOREACH_ENTITY_ENT(tag_entity, this.tur_head,
 416         {
 417                 if(it != this.vehicle_shieldent)
 418                 {
 419                         it.effects = eff;
 420                         it.colormod = cmod;
 421                         it.colormap = cmap;
 422                         it.alpha = 1;
 423                 }
 424         });
 425
 426         this.vehicle_hudmodel.effects  = this.effects  = eff; // | EF_LOWPRECISION;
 427         this.vehicle_hudmodel.colormod = this.colormod = cmod;
 428         this.vehicle_hudmodel.colormap = this.colormap = cmap;
 429         this.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 430
 431         this.alpha       = 1;
 432         this.avelocity = '0 0 0';
 433         this.velocity  = '0 0 0';
 434         this.effects   = eff;
 435 }
 436
 437 void vehicles_clearreturn(entity veh)
 438 {
 439         // Remove "return helper", if any.
 440         for (entity ret = findchain(classname, "vehicle_return"); ret; ret = ret.chain)
 441         {
 442                 if(ret.wp00 == veh)
 443                 {
 444                         ret.classname   = "";
 445                         setthink(ret, SUB_Remove);
 446                         ret.nextthink   = time + 0.1;
 447
 448                         if(ret.waypointsprite_attached)
 449                                 WaypointSprite_Kill(ret.waypointsprite_attached);
 450
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 void vehicles_spawn(entity this);
 457 void vehicles_return(entity this)
 458 {
 459         Send_Effect(EFFECT_TELEPORT, this.wp00.origin + '0 0 64', '0 0 0', 1);
 460
 461         setthink(this.wp00, vehicles_spawn);
 462         this.wp00.nextthink = time;
 463
 464         if(this.waypointsprite_attached)
 465                 WaypointSprite_Kill(this.waypointsprite_attached);
 466
 467         remove(this);
 468 }
 469
 470 void vehicles_showwp_goaway(entity this)
 471 {
 472         if(this.waypointsprite_attached)
 473                 WaypointSprite_Kill(this.waypointsprite_attached);
 474
 475         remove(this);
 476
 477 }
 478
 479 void vehicles_showwp(entity this)
 480 {
 481         vector rgb;
 482
 483         entity ent = this;
 484
 485         if(ent.cnt)
 486         {
 487                 setthink(ent, vehicles_return);
 488                 ent.nextthink = ent.cnt;
 489         }
 490         else
 491         {
 492                 setthink(ent, vehicles_return);
 493                 ent.nextthink  = time + 1;
 494
 495                 ent = spawn();
 496                 setmodel(ent, MDL_Null);
 497                 ent.team = this.wp00.team;
 498                 ent.wp00 = this.wp00;
 499                 setorigin(ent, this.wp00.pos1);
 500
 501                 ent.nextthink = time + 5;
 502                 setthink(ent, vehicles_showwp_goaway);
 503         }
 504
 505         if(teamplay && ent.team)
 506                 rgb = Team_ColorRGB(ent.team);
 507         else
 508                 rgb = '1 1 1';
 509         entity wp = WaypointSprite_Spawn(WP_Vehicle, 0, 0, ent, '0 0 64', NULL, 0, ent, waypointsprite_attached, true, RADARICON_Vehicle);
 510         wp.colormod = rgb;
 511         if(ent.waypointsprite_attached)
 512         {
 513                 WaypointSprite_UpdateRule(ent.waypointsprite_attached, ent.wp00.team, SPRITERULE_DEFAULT);
 514                 if(this == NULL)
 515                         WaypointSprite_UpdateBuildFinished(ent.waypointsprite_attached, ent.nextthink);
 516                 WaypointSprite_Ping(ent.waypointsprite_attached);
 517         }
 518 }
 519
 520 void vehicles_setreturn(entity veh)
 521 {
 522         entity ret;
 523
 524         vehicles_clearreturn(veh);
 525
 526         ret = new(vehicle_return);
 527         ret.wp00           = veh;
 528         ret.team                = veh.team;
 529         setthink(ret, vehicles_showwp);
 530
 531         if(IS_DEAD(veh))
 532         {
 533                 ret.cnt          = time + veh.respawntime;
 534                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 5);
 535         }
 536         else
 537         {
 538                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 1);
 539         }
 540
 541         setmodel(ret, MDL_Null);
 542         setorigin(ret, veh.pos1 + '0 0 96');
 543
 544 }
 545
 546 void vehicle_use(entity this, entity actor, entity trigger)
 547 {
 548         LOG_TRACE("vehicle ",this.netname, " used by ", actor.classname, "\n");
 549
 550         this.tur_head.team = actor.team;
 551
 552         if(this.tur_head.team == 0)
 553                 this.active = ACTIVE_NOT;
 554         else
 555                 this.active = ACTIVE_ACTIVE;
 556
 557         if(this.active == ACTIVE_ACTIVE && !IS_DEAD(this) && !gameover)
 558         {
 559                 LOG_TRACE("Respawning vehicle: ", this.netname, "\n");
 560                 if(this.effects & EF_NODRAW)
 561                 {
 562                         setthink(this, vehicles_spawn);
 563                         this.nextthink = time + 3;
 564                 }
 565                 else
 566                 {
 567                         vehicles_setreturn(this);
 568                         vehicles_reset_colors(this);
 569                 }
 570         }
 571 }
 572
 573 void vehicles_regen(entity this, float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 574 {
 575         if(this.(regen_field) < field_max)
 576         if(timer + rpause < time)
 577         {
 578                 if(_healthscale)
 579                         regen = regen * (this.vehicle_health / this.max_health);
 580
 581                 this.(regen_field) = min(this.(regen_field) + regen * delta_time, field_max);
 582
 583                 if(this.owner)
 584                         this.owner.(regen_field) = (this.(regen_field) / field_max) * 100;
 585         }
 586 }
 587
 588 void shieldhit_think(entity this)
 589 {
 590         this.alpha -= 0.1;
 591         if (this.alpha <= 0)
 592         {
 593                 // setmodel(this, MDL_Null);
 594                 this.alpha = -1;
 595                 this.effects |= EF_NODRAW;
 596         }
 597         else
 598         {
 599                 this.nextthink = time + 0.1;
 600         }
 601 }
 602
 603 void vehicles_painframe(entity this)
 604 {
 605         int myhealth = ((this.owner) ? this.owner.vehicle_health : ((this.vehicle_health / this.max_health) * 100));
 606
 607         if(myhealth <= 50)
 608         if(this.pain_frame < time)
 609         {
 610                 float _ftmp = myhealth / 50;
 611                 this.pain_frame = time + max(0.1, 0.1 + (random() * 0.5 * _ftmp));
 612                 Send_Effect(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);
 613
 614                 if(this.vehicle_flags & VHF_DMGSHAKE)
 615                         this.velocity += randomvec() * 30;
 616
 617                 if(this.vehicle_flags & VHF_DMGROLL)
 618                         if(this.vehicle_flags & VHF_DMGHEADROLL)
 619                                 this.tur_head.angles += randomvec();
 620                         else
 621                                 this.angles += randomvec();
 622         }
 623 }
 624
 625 void vehicles_frame(entity this, entity actor)
 626 {
 627         vehicles_painframe(this);
 628 }
 629
 630 void vehicles_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 631 {
 632         this.dmg_time = time;
 633
 634         // WEAPONTODO
 635         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 636                 damage *= autocvar_g_vehicles_vortex_damagerate;
 637
 638         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 639                 damage *= autocvar_g_vehicles_machinegun_damagerate;
 640
 641         if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 642                 damage *= autocvar_g_vehicles_rifle_damagerate;
 643
 644         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 645                 damage *= autocvar_g_vehicles_vaporizer_damagerate;
 646
 647         if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 648                 damage *= autocvar_g_vehicles_tag_damagerate;
 649
 650         if(DEATH_WEAPONOF(deathtype) != WEP_Null)
 651                 damage *= autocvar_g_vehicles_weapon_damagerate;
 652
 653         this.enemy = attacker;
 654
 655         this.pain_finished = time;
 656
 657         if((this.vehicle_flags & VHF_HASSHIELD) && (this.vehicle_shield > 0))
 658         {
 659                 if (wasfreed(this.vehicle_shieldent) || this.vehicle_shieldent == NULL)
 660                 {
 661                         this.vehicle_shieldent = spawn();
 662                         this.vehicle_shieldent.effects = EF_LOWPRECISION;
 663
 664                         setmodel(this.vehicle_shieldent, MDL_VEH_SHIELD);
 665                         setattachment(this.vehicle_shieldent, this, "");
 666                         setorigin(this.vehicle_shieldent, real_origin(this) - this.origin);
 667                         this.vehicle_shieldent.scale       = 256 / vlen(this.maxs - this.mins);
 668                         setthink(this.vehicle_shieldent, shieldhit_think);
 669                 }
 670
 671                 this.vehicle_shieldent.colormod = '1 1 1';
 672                 this.vehicle_shieldent.alpha = 0.45;
 673                 this.vehicle_shieldent.angles = vectoangles(normalize(hitloc - (this.origin + this.vehicle_shieldent.origin))) - this.angles;
 674                 this.vehicle_shieldent.nextthink = time;
 675                 this.vehicle_shieldent.effects &= ~EF_NODRAW;
 676
 677                 this.vehicle_shield -= damage;
 678
 679                 if(this.vehicle_shield < 0)
 680                 {
 681                         this.vehicle_health -= fabs(this.vehicle_shield);
 682                         this.vehicle_shieldent.colormod = '2 0 0';
 683                         this.vehicle_shield = 0;
 684                         this.vehicle_shieldent.alpha = 0.75;
 685
 686                         if(sound_allowed(MSG_BROADCAST, attacker))
 687                                 spamsound (this, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 688                 }
 689                 else
 690                         if(sound_allowed(MSG_BROADCAST, attacker))
 691                                 spamsound (this, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 692
 693         }
 694         else
 695         {
 696                 this.vehicle_health -= damage;
 697
 698                 if(sound_allowed(MSG_BROADCAST, attacker))
 699                         spamsound (this, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 700         }
 701
 702         if(this.damageforcescale < 1 && this.damageforcescale > 0)
 703                 this.velocity += force * this.damageforcescale;
 704         else
 705                 this.velocity += force;
 706
 707         if(this.vehicle_health <= 0)
 708         {
 709                 if(this.owner)
 710                         if(this.vehicle_flags & VHF_DEATHEJECT)
 711                                 vehicles_exit(this, VHEF_EJECT);
 712                         else
 713                                 vehicles_exit(this, VHEF_RELEASE);
 714
 715
 716                 antilag_clear(this, this);
 717
 718                 Vehicle info = Vehicles_from(this.vehicleid);
 719                 info.vr_death(info, this);
 720                 vehicles_setreturn(this);
 721         }
 722 }
 723
 724 float vehicles_crushable(entity e)
 725 {
 726         if(IS_PLAYER(e) && time >= e.vehicle_enter_delay)
 727                 return true;
 728
 729         if(IS_MONSTER(e))
 730                 return true;
 731
 732         return false;
 733 }
 734
 735 void vehicles_impact(entity this, float _minspeed, float _speedfac, float _maxpain)
 736 {
 737         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 738                 return;
 739
 740         if(this.play_time < time)
 741         {
 742                 float wc = vlen(this.velocity - this.oldvelocity);
 743                 //dprint("oldvel: ", vtos(this.oldvelocity), "\n");
 744                 //dprint("vel: ", vtos(this.velocity), "\n");
 745                 if(_minspeed < wc)
 746                 {
 747                         float take = min(_speedfac * wc, _maxpain);
 748                         Damage (this, NULL, NULL, take, DEATH_FALL.m_id, this.origin, '0 0 0');
 749                         this.play_time = time + 0.25;
 750
 751                         //dprint("wc: ", ftos(wc), "\n");
 752                         //dprint("take: ", ftos(take), "\n");
 753                 }
 754         }
 755 }
 756
 757 // vehicle enter/exit handling
 758 vector vehicles_findgoodexit(entity this, vector prefer_spot)
 759 {
 760         //vector exitspot;
 761         float mysize;
 762
 763         tracebox(this.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, this.owner);
 764         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 765                 return prefer_spot;
 766
 767         mysize = 1.5 * vlen(this.maxs - this.mins);
 768         float i;
 769         vector v, v2;
 770         v2 = 0.5 * (this.absmin + this.absmax);
 771         for(i = 0; i < 100; ++i)
 772         {
 773                 v = randomvec();
 774                 v_z = 0;
 775                 v = v2 + normalize(v) * mysize;
 776                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, this.owner);
 777                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 778                         return v;
 779         }
 780
 781         /*
 782         exitspot = (this.origin + '0 0 48') + v_forward * mysize;
 783         tracebox(this.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, this.owner);
 784         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 785                 return exitspot;
 786
 787         exitspot = (this.origin + '0 0 48') - v_forward * mysize;
 788         tracebox(this.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, this.owner);
 789         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 790                 return exitspot;
 791
 792         exitspot = (this.origin + '0 0 48') + v_right * mysize;
 793         tracebox(this.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, this.owner);
 794         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 795                 return exitspot;
 796
 797         exitspot = (this.origin + '0 0 48') - v_right * mysize;
 798         tracebox(this.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, this.owner);
 799         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 800                 return exitspot;
 801         */
 802
 803         return this.origin;
 804 }
 805
 806 void vehicles_exit(entity vehic, bool eject)
 807 {
 808         entity player = vehic.owner;
 809
 810         if(vehicles_exit_running)
 811         {
 812                 LOG_TRACE("^1vehicles_exit already running! this is not good...\n");
 813                 return;
 814         }
 815
 816         vehicles_exit_running = true;
 817
 818         // TODO: this was in an IS_CLIENT check, make sure it isn't actually needed!
 819         if(vehic.vehicle_flags & VHF_PLAYERSLOT)
 820         {
 821                 vehic.vehicle_exit(vehic, eject);
 822                 vehicles_exit_running = false;
 823                 return;
 824         }
 825
 826         if (player)
 827         {
 828                 if (IS_REAL_CLIENT(player))
 829                 {
 830                         msg_entity = player;
 831                         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 832                         WriteEntity( MSG_ONE, player);
 833
 834                         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 835                         WriteAngle(MSG_ONE, 0);
 836                         WriteAngle(MSG_ONE, vehic.angles_y);
 837                         WriteAngle(MSG_ONE, 0);
 838                 }
 839
 840                 setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 841
 842                 player.takedamage               = DAMAGE_AIM;
 843                 player.solid                    = SOLID_SLIDEBOX;
 844                 player.movetype         = MOVETYPE_WALK;
 845                 player.effects             &= ~EF_NODRAW;
 846                 player.teleportable     = TELEPORT_NORMAL;
 847                 player.alpha                    = 1;
 848                 player.PlayerPhysplug   = func_null;
 849                 player.vehicle                  = NULL;
 850                 player.view_ofs         = STAT(PL_VIEW_OFS, NULL);
 851                 player.event_damage     = PlayerDamage;
 852                 player.hud                              = HUD_NORMAL;
 853                 PS(player).m_switchweapon = vehic.m_switchweapon;
 854                 player.last_vehiclecheck = time + 3;
 855                 player.vehicle_enter_delay = time + 2;
 856
 857                 CSQCVehicleSetup(player, HUD_NORMAL);
 858
 859                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES);
 860                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES_OTHER); // kill all vehicle notifications when exiting a vehicle?
 861         }
 862
 863         vehic.flags |= FL_NOTARGET;
 864
 865         if(!IS_DEAD(vehic))
 866                 vehic.avelocity = '0 0 0';
 867
 868         vehic.tur_head.nodrawtoclient = NULL;
 869
 870         if(!teamplay)
 871                 vehic.team = 0;
 872
 873         WaypointSprite_Kill(vehic.wps_intruder);
 874
 875         MUTATOR_CALLHOOK(VehicleExit, player, vehic);
 876
 877         vehic.team = vehic.tur_head.team;
 878
 879         sound (vehic, CH_TRIGGER_SINGLE, SND_Null, 1, ATTEN_NORM);
 880         vehic.vehicle_hudmodel.viewmodelforclient = vehic;
 881         vehic.phase = time + 1;
 882
 883         vehic.vehicle_exit(vehic, eject);
 884
 885         vehicles_setreturn(vehic);
 886         vehicles_reset_colors(vehic);
 887         vehic.owner = NULL;
 888
 889         CSQCMODEL_AUTOINIT(vehic);
 890
 891         vehicles_exit_running = false;
 892 }
 893
 894 void vehicles_touch(entity this)
 895 {
 896         if(MUTATOR_CALLHOOK(VehicleTouch, this, other))
 897                 return;
 898
 899         // Vehicle currently in use
 900         if(this.owner)
 901         {
 902                 if(!forbidWeaponUse(this.owner))
 903                 if(other != NULL)
 904                 if((this.origin_z + this.maxs_z) > (other.origin_z))
 905                 if(vehicles_crushable(other))
 906                 {
 907                         if(vdist(this.velocity, >=, 30))
 908                                 Damage(other, this, this.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH.m_id, '0 0 0', normalize(other.origin - this.origin) * autocvar_g_vehicles_crush_force);
 909
 910                         return; // Dont do selfdamage when hitting "soft targets".
 911                 }
 912
 913                 if(this.play_time < time) {
 914                         Vehicle info = Vehicles_from(this.vehicleid);
 915                         info.vr_impact(info, this);
 916                 }
 917
 918                 return;
 919         }
 920
 921         if(autocvar_g_vehicles_enter)
 922                 return;
 923
 924         vehicles_enter(other, this);
 925 }
 926
 927 bool vehicle_impulse(entity this, int imp)
 928 {
 929         entity v = this.vehicle;
 930         if (!v) return false;
 931         if (IS_DEAD(v)) return false;
 932         bool(entity,int) f = v.vehicles_impulse;
 933         if (f && f(this,imp)) return true;
 934         switch (imp)
 935         {
 936                 case IMP_weapon_drop.impulse:
 937                 {
 938                         stuffcmd(this, "\ntoggle cl_eventchase_vehicle\nset _vehicles_shownchasemessage 1\n");
 939                         return true;
 940                 }
 941         }
 942         return false;
 943 }
 944
 945 void vehicles_enter(entity pl, entity veh)
 946 {
 947    // Remove this when bots know how to use vehicles
 948         if((IS_BOT_CLIENT(pl) && !autocvar_g_vehicles_allow_bots))
 949                 return;
 950
 951         if((!IS_PLAYER(pl))
 952         || (veh.phase >= time)
 953         || (pl.vehicle_enter_delay >= time)
 954         || (STAT(FROZEN, pl))
 955         || (IS_DEAD(pl))
 956         || (pl.vehicle)
 957         ) { return; }
 958
 959         if(autocvar_g_vehicles_enter) // vehicle's touch function should handle this if entering via use key is disabled (TODO)
 960         if(veh.vehicle_flags & VHF_MULTISLOT)
 961         if(veh.owner)
 962         {
 963                 if(!veh.gunner1)
 964                 if(time >= veh.gun1.phase)
 965                 if(veh.gun1.vehicle_enter)
 966                 if(veh.gun1.vehicle_enter(veh, pl))
 967                         return;
 968
 969                 if(!veh.gunner2)
 970                 if(time >= veh.gun2.phase)
 971                 if(veh.gun2.vehicle_enter)
 972                 if(veh.gun2.vehicle_enter(veh, pl))
 973                         return;
 974         }
 975
 976         if(teamplay)
 977         if(veh.team)
 978         if(DIFF_TEAM(pl, veh))
 979         if(autocvar_g_vehicles_steal)
 980         {
 981                 FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, veh), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_VEHICLE_STEAL));
 982
 983                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_STEAL_SELF);
 984
 985                 if (autocvar_g_vehicles_steal_show_waypoint) {
 986                         entity wp = WaypointSprite_Spawn(WP_VehicleIntruder, 0, 0, pl, '0 0 68', NULL, veh.team, veh, wps_intruder, true, RADARICON_DANGER);
 987                         wp.colormod = Team_ColorRGB(pl.team);
 988                 }
 989         }
 990         else return;
 991
 992         RemoveGrapplingHook(pl);
 993
 994         veh.vehicle_ammo1 = 0;
 995         veh.vehicle_ammo2 = 0;
 996         veh.vehicle_reload1 = 0;
 997         veh.vehicle_reload2 = 0;
 998         veh.vehicle_energy = 0;
 999
1000         veh.owner = pl;
1001         pl.vehicle = veh;
1002
1003         // .viewmodelforclient works better.
1004         //veh.vehicle_hudmodel.drawonlytoclient = veh.owner;
1005
1006         veh.vehicle_hudmodel.viewmodelforclient = pl;
1007
1008         tracebox(pl.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), pl.origin, false, pl);
1009         pl.crouch = false;
1010         pl.view_ofs = STAT(PL_VIEW_OFS, NULL);
1011         setsize (pl, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
1012
1013         veh.event_damage        = vehicles_damage;
1014         veh.nextthink           = 0;
1015         pl.angles                       = veh.angles;
1016         pl.takedamage           = DAMAGE_NO;
1017         pl.solid                        = SOLID_NOT;
1018         pl.movetype                     = MOVETYPE_NOCLIP;
1019         pl.teleportable         = false;
1020         pl.alpha                        = -1;
1021         pl.event_damage         = func_null;
1022         pl.view_ofs                     = '0 0 0';
1023         veh.colormap            = pl.colormap;
1024         if(veh.tur_head)
1025                 veh.tur_head.colormap = pl.colormap;
1026         veh.m_switchweapon = PS(pl).m_switchweapon;
1027         pl.hud = veh.vehicleid;
1028         pl.PlayerPhysplug = veh.PlayerPhysplug;
1029
1030         pl.vehicle_ammo1 = veh.vehicle_ammo1;
1031         pl.vehicle_ammo2 = veh.vehicle_ammo2;
1032         pl.vehicle_reload1 = veh.vehicle_reload1;
1033         pl.vehicle_reload2 = veh.vehicle_reload2;
1034         pl.vehicle_energy = veh.vehicle_energy;
1035
1036         // Cant do this, hides attached objects too.
1037         //veh.exteriormodeltoclient = veh.owner;
1038         //veh.tur_head.exteriormodeltoclient = veh.owner;
1039
1040         UNSET_ONGROUND(pl);
1041         UNSET_ONGROUND(veh);
1042
1043         veh.team = pl.team;
1044         veh.flags -= FL_NOTARGET;
1045
1046         if (IS_REAL_CLIENT(pl))
1047         {
1048                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_ENTER);
1049
1050                 msg_entity = pl;
1051                 WriteByte (MSG_ONE, SVC_SETVIEWPORT);
1052                 WriteEntity(MSG_ONE, veh.vehicle_viewport);
1053
1054                 WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1055                 if(veh.tur_head)
1056                 {
1057                         WriteAngle(MSG_ONE, veh.tur_head.angles_x + veh.angles_x); // tilt
1058                         WriteAngle(MSG_ONE, veh.tur_head.angles_y + veh.angles_y); // yaw
1059                         WriteAngle(MSG_ONE, 0);                                                                   // roll
1060                 }
1061                 else
1062                 {
1063                         WriteAngle(MSG_ONE, veh.angles_x * -1); // tilt
1064                         WriteAngle(MSG_ONE, veh.angles_y);        // yaw
1065                         WriteAngle(MSG_ONE, 0);                           // roll
1066                 }
1067         }
1068
1069         vehicles_clearreturn(veh);
1070
1071         CSQCVehicleSetup(pl, veh.vehicleid);
1072
1073         MUTATOR_CALLHOOK(VehicleEnter, pl, veh);
1074
1075         CSQCModel_UnlinkEntity(veh);
1076         Vehicle info = Vehicles_from(veh.vehicleid);
1077         info.vr_enter(info, veh);
1078
1079         antilag_clear(pl, CS(pl));
1080 }
1081
1082 void vehicles_think(entity this)
1083 {
1084         this.nextthink = time;
1085
1086         if(this.owner)
1087                 this.owner.vehicle_weapon2mode = this.vehicle_weapon2mode;
1088
1089         Vehicle info = Vehicles_from(this.vehicleid);
1090         info.vr_think(info, this);
1091
1092         vehicles_painframe(this);
1093
1094         CSQCMODEL_AUTOUPDATE(this);
1095 }
1096
1097 // initialization
1098 void vehicles_spawn(entity this)
1099 {
1100         LOG_TRACE("Spawning vehicle: ", this.classname, "\n");
1101
1102         // disown & reset
1103         this.vehicle_hudmodel.viewmodelforclient = this;
1104
1105         this.owner                              = NULL;
1106         settouch(this, vehicles_touch);
1107         this.event_damage               = vehicles_damage;
1108         this.iscreature                 = true;
1109         this.teleportable               = false; // no teleporting for vehicles, too buggy
1110         this.damagedbycontents  = true;
1111         this.movetype                   = MOVETYPE_WALK;
1112         this.solid                              = SOLID_SLIDEBOX;
1113         this.takedamage                 = DAMAGE_AIM;
1114         this.deadflag                   = DEAD_NO;
1115         this.bot_attack                 = true;
1116         this.flags                              = FL_NOTARGET;
1117         this.avelocity                  = '0 0 0';
1118         this.velocity                   = '0 0 0';
1119         setthink(this, vehicles_think);
1120         this.nextthink                  = time;
1121
1122         // Reset locking
1123         this.lock_strength = 0;
1124         this.lock_target = NULL;
1125         this.misc_bulletcounter = 0;
1126
1127         // Return to spawn
1128         this.angles = this.pos2;
1129         setorigin(this, this.pos1);
1130         // Show it
1131         Send_Effect(EFFECT_TELEPORT, this.origin + '0 0 64', '0 0 0', 1);
1132
1133         if(this.vehicle_controller)
1134                 this.team = this.vehicle_controller.team;
1135
1136         FOREACH_CLIENT(IS_PLAYER(it) && it.hook.aiment == this, RemoveGrapplingHook(it));
1137
1138         vehicles_reset_colors(this);
1139
1140         Vehicle info = Vehicles_from(this.vehicleid);
1141         info.vr_spawn(info, this);
1142
1143         CSQCMODEL_AUTOINIT(this);
1144 }
1145
1146 bool vehicle_initialize(entity this, Vehicle info, bool nodrop)
1147 {
1148         if(!autocvar_g_vehicles)
1149                 return false;
1150
1151         if(!info.vehicleid)
1152                 return false;
1153
1154         if(!this.tur_head)
1155                 info.vr_precache(info);
1156
1157         if(this.targetname && this.targetname != "")
1158         {
1159                 this.vehicle_controller = find(NULL, target, this.targetname);
1160                 if(!this.vehicle_controller)
1161                 {
1162                         bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1163                         this.active = ACTIVE_ACTIVE;
1164                 }
1165                 else
1166                 {
1167                         this.team = this.vehicle_controller.team;
1168                         this.use = vehicle_use;
1169
1170                         if(teamplay)
1171                         {
1172                                 if(this.vehicle_controller.team == 0)
1173                                         this.active = ACTIVE_NOT;
1174                                 else
1175                                         this.active = ACTIVE_ACTIVE;
1176                         }
1177                 }
1178         }
1179         else { this.active = ACTIVE_ACTIVE; }
1180
1181         if(this.team && (!teamplay || !autocvar_g_vehicles_teams))
1182                 this.team = 0;
1183
1184         if(this.mdl == "" || !this.mdl)
1185                 _setmodel(this, info.model);
1186         else
1187                 _setmodel(this, this.mdl);
1188
1189         this.vehicle_flags |= VHF_ISVEHICLE;
1190
1191         this.vehicle_viewport           = new(vehicle_viewport);
1192         this.vehicle_hudmodel           = new(vehicle_hudmodel);
1193         this.tur_head                           = new(tur_head);
1194         this.tur_head.owner                     = this;
1195         this.takedamage                         = DAMAGE_NO;
1196         this.bot_attack                         = true;
1197         this.iscreature                         = true;
1198         this.teleportable                       = false; // no teleporting for vehicles, too buggy
1199         this.damagedbycontents          = true;
1200         this.vehicleid                          = info.vehicleid;
1201         this.PlayerPhysplug                     = info.PlayerPhysplug;
1202         this.event_damage                       = func_null;
1203         settouch(this, vehicles_touch);
1204         setthink(this, vehicles_spawn);
1205         this.nextthink                          = time;
1206         this.effects                            = EF_NODRAW;
1207         this.dphitcontentsmask          = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1208
1209         if(autocvar_g_playerclip_collisions)
1210                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1211
1212         if(autocvar_g_nodepthtestplayers)
1213                 this.effects |= EF_NODEPTHTEST;
1214
1215         if(autocvar_g_fullbrightplayers)
1216                 this.effects |= EF_FULLBRIGHT;
1217
1218         _setmodel(this.vehicle_hudmodel, info.hud_model);
1219         setmodel(this.vehicle_viewport, MDL_Null);
1220
1221         if(info.head_model != "")
1222         {
1223                 _setmodel(this.tur_head, info.head_model);
1224                 setattachment(this.tur_head, this, info.tag_head);
1225                 setattachment(this.vehicle_hudmodel, this.tur_head, info.tag_hud);
1226                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1227         }
1228         else
1229         {
1230                 setattachment(this.tur_head, this, "");
1231                 setattachment(this.vehicle_hudmodel, this, info.tag_hud);
1232                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1233         }
1234
1235         setsize(this, info.mins, info.maxs);
1236
1237         if(!nodrop)
1238         {
1239                 setorigin(this, this.origin);
1240                 tracebox(this.origin + '0 0 100', info.mins, info.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1241                 setorigin(this, trace_endpos);
1242         }
1243
1244         this.pos1 = this.origin;
1245         this.pos2 = this.angles;
1246         this.tur_head.team = this.team;
1247
1248         info.vr_setup(info, this);
1249
1250         if(this.active == ACTIVE_NOT)
1251                 this.nextthink = 0; // wait until activated
1252         else if(autocvar_g_vehicles_delayspawn)
1253                 this.nextthink = time + this.respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1254         else
1255                 this.nextthink = time + game_starttime;
1256
1257         if(MUTATOR_CALLHOOK(VehicleSpawn, this))
1258                 return false;
1259
1260         return true;
1261 }