qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #include "bumblebee.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 const float BRG_SETUP = 2;
   6 const float BRG_START = 4;
   7 const float BRG_END = 8;
   8
   9 #ifdef SVQC
  10 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  11
  12 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  13 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  14 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  15 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  16 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  17 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  18 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  19 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  20 bool autocvar_g_vehicle_bumblebee_swim = false;
  21
  22 float autocvar_g_vehicle_bumblebee_energy = 500;
  23 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  24 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  25
  26 float autocvar_g_vehicle_bumblebee_health = 1000;
  27 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  28 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  29
  30 float autocvar_g_vehicle_bumblebee_shield = 400;
  31 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  32 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  33
  34 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  35 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  37
  38 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  39
  40 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  41 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  42 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  43 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  44 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  45
  46
  47 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  48 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  49 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  50 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  51
  52 bool autocvar_g_vehicle_bumblebee_raygun = false;
  53 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  54 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  55 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  56 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  57
  58 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  59 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  60 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  61 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  62 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  63 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  64
  65 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  66 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  67 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  68 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  69 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  70
  71 bool autocvar_g_vehicle_bumblebee = true;
  72
  73 bool bumblebee_gunner_frame(entity this, float dt)
  74 {
  75         entity vehic = this.vehicle.owner;
  76         entity gun = this.vehicle;
  77         return = true;
  78
  79         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
  80         //vehicles_frame(gun, player);
  81
  82         vehic.solid = SOLID_NOT;
  83         //setorigin(this, vehic.origin);
  84         this.velocity = vehic.velocity;
  85
  86         float _in, _out;
  87         vehic.angles_x *= -1;
  88         makevectors(vehic.angles);
  89         vehic.angles_x *= -1;
  90         if(gun == vehic.gun1)
  91         {
  92                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  93                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  94                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
  95         }
  96         else
  97         {
  98                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  99                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 100                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 101         }
 102         this.oldorigin = this.origin; // negate fall damage
 103
 104         crosshair_trace(this);
 105         vector _ct = trace_endpos;
 106         vector ad;
 107
 108         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 109         {
 110                 if(gun.lock_time < time)
 111                         gun.enemy = NULL;
 112
 113                 if(trace_ent)
 114                         if(trace_ent.move_movetype)
 115                                 if(trace_ent.takedamage)
 116                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 117                                         {
 118                                                 if(DIFF_TEAM(trace_ent, this))
 119                                                 {
 120                                                         gun.enemy = trace_ent;
 121                                                         gun.lock_time = time + 5;
 122                                                 }
 123                                         }
 124         }
 125
 126         if(gun.enemy)
 127         {
 128                 float distance, impact_time;
 129
 130                 vector vf = real_origin(gun.enemy);
 131                 vector _vel = gun.enemy.velocity;
 132                 if(gun.enemy.move_movetype == MOVETYPE_WALK)
 133                         _vel.z *= 0.1;
 134
 135
 136                 ad = vf;
 137                 distance = vlen(ad - this.origin);
 138                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 139                 ad = vf + _vel * impact_time;
 140                 trace_endpos = ad;
 141
 142
 143                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 144                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 145                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 146                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 147
 148         }
 149         else
 150                 vehicle_aimturret(vehic, _ct, gun, "fire",
 151                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 152                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 153
 154         if(!forbidWeaponUse(this))
 155         if(PHYS_INPUT_BUTTON_ATCK(this))
 156                 if(time > gun.attack_finished_single[0])
 157                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 158                         {
 159                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 160                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 161                                 gun.delay = time;
 162                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 163                         }
 164
 165         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 166
 167         if(vehic.vehicle_flags & VHF_HASSHIELD)
 168                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 169
 170         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 171         traceline(ad, ad + v_forward * max_shot_distance, MOVE_NORMAL, gun);
 172
 173         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 174
 175         if(vehic.owner)
 176                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 177
 178         vehic.solid = SOLID_BBOX;
 179         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 180         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 181 }
 182
 183 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 184 {
 185         //vector exitspot;
 186         float mysize;
 187
 188         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, player), STAT(PL_MAX, player), prefer_spot, MOVE_NORMAL, player);
 189         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 190                 return prefer_spot;
 191
 192         mysize = 1.5 * vlen(STAT(PL_MAX, player) - STAT(PL_MIN, player)); // can't use gunner's size, as they don't have a size
 193         float i;
 194         vector v, v2;
 195         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 196         for(i = 0; i < 100; ++i)
 197         {
 198                 v = randomvec();
 199                 v_z = 0;
 200                 v = v2 + normalize(v) * mysize;
 201                 tracebox(v2, STAT(PL_MIN, player), STAT(PL_MAX, player), v, MOVE_NORMAL, player);
 202                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 203                         return v;
 204         }
 205
 206         return prefer_spot; // this should be considered a fallback?!
 207 }
 208
 209 void bumblebee_gunner_exit(entity this, int _exitflag)
 210 {
 211         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 212         entity gunner = this;
 213         entity vehic = gunner.owner;
 214
 215         if(IS_REAL_CLIENT(player))
 216         {
 217                 msg_entity = player;
 218                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 219                 WriteEntity(MSG_ONE, player);
 220
 221                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 222                 WriteAngle(MSG_ONE, 0);
 223                 WriteAngle(MSG_ONE, vehic.angles.y);
 224                 WriteAngle(MSG_ONE, 0);
 225         }
 226
 227         CSQCVehicleSetup(player, HUD_NORMAL);
 228         setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
 229
 230         player.takedamage     = DAMAGE_AIM;
 231         player.solid          = SOLID_SLIDEBOX;
 232         set_movetype(player, MOVETYPE_WALK);
 233         player.effects       &= ~EF_NODRAW;
 234         player.alpha          = 1;
 235         player.PlayerPhysplug = func_null;
 236         player.view_ofs       = STAT(PL_VIEW_OFS, player);
 237         player.event_damage   = PlayerDamage;
 238         player.hud            = HUD_NORMAL;
 239         player.teleportable       = TELEPORT_NORMAL;
 240         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 241         {
 242                 .entity weaponentity = weaponentities[slot];
 243                 player.(weaponentity).m_switchweapon = gunner.(weaponentity).m_switchweapon;
 244                 delete(gunner.(weaponentity));
 245         }
 246         player.vehicle_enter_delay = time + 2;
 247
 248         fixedmakevectors(vehic.angles);
 249
 250         if(player == vehic.gunner1) { vehic.gunner1 = NULL; }
 251         if(player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 252
 253         vector spot = real_origin(gunner);
 254         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 255         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 256
 257         // TODO: figure a way to move player out of the gunner
 258
 259         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 260         player.velocity_z += 10;
 261
 262         gunner.phase = time + 5;
 263         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 264
 265         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 266
 267         player.vehicle = NULL;
 268 }
 269
 270 bool bumblebee_gunner_enter(entity this, entity player)
 271 {
 272         entity vehic = this;
 273         entity gunner = NULL;
 274
 275         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 276         {
 277                 // we can have some fun
 278                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 279                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 280                 if(vlen2(player.origin - v1) < vlen2(player.origin - v2))
 281                 {
 282                         gunner = vehic.gun1;
 283                         vehic.gunner1 = player;
 284                 }
 285                 else
 286                 {
 287                         gunner = vehic.gun2;
 288                         vehic.gunner2 = player;
 289                 }
 290         }
 291         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 292         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 293         else { LOG_TRACE("Vehicle is full, fail"); return false; }
 294
 295         player.vehicle                  = gunner;
 296         player.angles                   = vehic.angles;
 297         player.takedamage               = DAMAGE_NO;
 298         player.solid                    = SOLID_NOT;
 299         player.alpha                    = -1;
 300         set_movetype(player, MOVETYPE_NOCLIP);
 301         player.event_damage     = func_null;
 302         player.view_ofs                 = '0 0 0';
 303         player.hud                              = gunner.hud;
 304         player.teleportable     = false;
 305         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 306         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 307         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 308         player.vehicle_reload1  = vehic.vehicle_reload1;
 309         player.vehicle_reload2  = vehic.vehicle_reload2;
 310         player.vehicle_energy   = vehic.vehicle_energy;
 311         UNSET_ONGROUND(player);
 312
 313         RemoveGrapplingHooks(player);
 314
 315         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 316         {
 317                 .entity weaponentity = weaponentities[slot];
 318
 319                 gunner.(weaponentity) = new(temp_wepent);
 320                 gunner.(weaponentity).m_switchweapon = player.(weaponentity).m_switchweapon;
 321         }
 322         gunner.vehicle_exit = bumblebee_gunner_exit;
 323         gunner.vehicle_hudmodel.viewmodelforclient = player;
 324
 325         if(IS_REAL_CLIENT(player))
 326         {
 327                 msg_entity = player;
 328                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 329                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 330
 331                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 332                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 333                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 334                 WriteAngle(MSG_ONE,     0); // roll
 335         }
 336
 337         CSQCVehicleSetup(player, player.hud);
 338
 339         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 340
 341         return true;
 342 }
 343
 344 bool vehicles_valid_pilot(entity this, entity toucher)
 345 {
 346         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 347                 return false;
 348
 349         if((!IS_PLAYER(toucher))
 350         || (IS_DEAD(toucher))
 351         || (toucher.vehicle)
 352         || (DIFF_TEAM(toucher, this))
 353         ) { return false; }
 354
 355         return true;
 356 }
 357
 358 void bumblebee_touch(entity this, entity toucher)
 359 {
 360         if(autocvar_g_vehicles_enter) { return; }
 361
 362         if(this.gunner1 != NULL && this.gunner2 != NULL)
 363         {
 364                 vehicles_touch(this, toucher);
 365                 return;
 366         }
 367
 368         if(vehicles_valid_pilot(this, toucher))
 369         {
 370                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 371
 372                 if(time >= toucher.vehicle_enter_delay && phase_time)
 373                 if(bumblebee_gunner_enter(this, toucher))
 374                         return;
 375         }
 376
 377         vehicles_touch(this, toucher);
 378 }
 379
 380 void bumblebee_regen(entity this, float dt)
 381 {
 382         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 383                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 384                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 385
 386         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 387                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 388                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 389
 390         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 391                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, dt, true);
 392
 393         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 394                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, dt, false);
 395
 396         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 397                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, dt, false);
 398
 399 }
 400
 401 bool bumblebee_pilot_frame(entity this, float dt)
 402 {
 403         entity vehic = this.vehicle;
 404         return = true;
 405
 406         if(game_stopped)
 407         {
 408                 vehic.solid = SOLID_NOT;
 409                 vehic.takedamage = DAMAGE_NO;
 410                 set_movetype(vehic, MOVETYPE_NONE);
 411                 return;
 412         }
 413
 414         vehicles_frame(vehic, this);
 415
 416         if(IS_DEAD(vehic))
 417         {
 418                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 419                 return;
 420         }
 421
 422         bumblebee_regen(vehic, dt);
 423
 424         crosshair_trace(this);
 425
 426         vector vang = vehic.angles;
 427         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 428         vang.x *= -1;
 429         newvel.x *= -1;
 430         if(newvel.x > 180)  newvel.x -= 360;
 431         if(newvel.x < -180) newvel.x += 360;
 432         if(newvel.y > 180)  newvel.y -= 360;
 433         if(newvel.y < -180) newvel.y += 360;
 434
 435         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 436         if(ftmp > 180)  ftmp -= 360;
 437         if(ftmp < -180) ftmp += 360;
 438         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 439
 440         // Pitch
 441         ftmp = 0;
 442         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 443                 ftmp = 4;
 444         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 445                 ftmp = -8;
 446
 447         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 448         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 449         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 450
 451         vehic.angles_x = anglemods(vehic.angles.x);
 452         vehic.angles_y = anglemods(vehic.angles.y);
 453         vehic.angles_z = anglemods(vehic.angles.z);
 454
 455         makevectors('0 1 0' * vehic.angles.y);
 456         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 457
 458         if(this.movement.x != 0)
 459         {
 460                 if(this.movement.x > 0)
 461                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 462                 else if(this.movement.x < 0)
 463                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 464         }
 465
 466         if(this.movement.y != 0)
 467         {
 468                 if(this.movement.y < 0)
 469                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 470                 else if(this.movement.y > 0)
 471                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 472                 ftmp = newvel * v_right;
 473                 ftmp *= dt * 0.1;
 474                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 475         }
 476         else
 477         {
 478                 vehic.angles_z *= 0.95;
 479                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 480                         vehic.angles_z = 0;
 481         }
 482
 483         if(PHYS_INPUT_BUTTON_CROUCH(this))
 484                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 485         else if(PHYS_INPUT_BUTTON_JUMP(this))
 486                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 487
 488         vehic.velocity  += newvel * dt;
 489         this.velocity = this.movement  = vehic.velocity;
 490
 491
 492         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 493         {
 494                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 495                         vehic.tur_head.enemy = NULL;
 496
 497                 if(trace_ent)
 498                 if(trace_ent.move_movetype)
 499                 if(trace_ent.takedamage)
 500                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 501                 {
 502                         if(teamplay)
 503                         {
 504                                 if(trace_ent.team == this.team)
 505                                 {
 506                                         vehic.tur_head.enemy = trace_ent;
 507                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 508                                 }
 509                         }
 510                         else
 511                         {
 512                                 vehic.tur_head.enemy = trace_ent;
 513                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 514                         }
 515                 }
 516
 517                 if(vehic.tur_head.enemy)
 518                 {
 519                         trace_endpos = real_origin(vehic.tur_head.enemy);
 520                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 521                 }
 522         }
 523
 524         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 525                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 526                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 527
 528         if(!forbidWeaponUse(this))
 529         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME || autocvar_g_vehicle_bumblebee_raygun == 0))
 530         {
 531                 vehic.gun3.enemy.realowner = this;
 532                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 533
 534                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 535                 vehic.gun3.enemy.SendFlags |= BRG_START;
 536
 537                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 538
 539                 if(trace_ent)
 540                 {
 541                         if(autocvar_g_vehicle_bumblebee_raygun)
 542                         {
 543                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * PHYS_INPUT_FRAMETIME);
 544                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * PHYS_INPUT_FRAMETIME;
 545                         }
 546                         else
 547                         {
 548                                 if(!IS_DEAD(trace_ent))
 549                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 550                                         {
 551
 552                                                 if(IS_VEHICLE(trace_ent))
 553                                                 {
 554                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 555                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * dt, trace_ent.tur_head.max_health);
 556
 557                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 558                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 559                                                 }
 560                                                 else if(IS_CLIENT(trace_ent))
 561                                                 {
 562                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 563                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 564
 565                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 566                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * dt, autocvar_g_vehicle_bumblebee_healgun_amax);
 567
 568                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 569                                                 }
 570                                                 else if(IS_TURRET(trace_ent))
 571                                                 {
 572                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 573                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 574                                                         //else ..hmmm what? ammo?
 575
 576                                                         trace_ent.SendFlags |= TNSF_STATUS;
 577                                                 }
 578                                         }
 579                         }
 580                 }
 581
 582                 vehic.gun3.enemy.hook_end = trace_endpos;
 583                 setorigin(vehic.gun3.enemy, trace_endpos);
 584                 vehic.gun3.enemy.SendFlags |= BRG_END;
 585
 586                 vehic.wait = time + 1;
 587         }
 588         else
 589                 vehic.gun3.enemy.effects |= EF_NODRAW;
 590         /*{
 591                 if(vehic.gun3.enemy)
 592                         remove(vehic.gun3.enemy);
 593
 594                 vehic.gun3.enemy = NULL;
 595         }
 596         */
 597
 598         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 599         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 600
 601         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 602         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 603
 604         if(vehic.vehicle_flags & VHF_HASSHIELD)
 605                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 606
 607         vehic.angles_x *= -1;
 608         makevectors(vehic.angles);
 609         vehic.angles_x *= -1;
 610         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 611         this.oldorigin = this.origin; // negate fall damage
 612
 613         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 614 }
 615
 616 void bumblebee_land(entity this)
 617 {
 618         float hgt;
 619
 620         hgt = vehicle_altitude(this, 512);
 621         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
 622         this.angles_x *= 0.95;
 623         this.angles_z *= 0.95;
 624
 625         if(hgt < 16)
 626                 setthink(this, vehicles_think);
 627
 628         this.nextthink = time;
 629
 630         CSQCMODEL_AUTOUPDATE(this);
 631 }
 632
 633 void bumblebee_exit(entity this, int eject)
 634 {
 635         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 636         {
 637                 bumblebee_gunner_exit(this, eject);
 638                 return;
 639         }
 640
 641         settouch(this, vehicles_touch);
 642
 643         if(!IS_DEAD(this))
 644         {
 645                 setthink(this, bumblebee_land);
 646                 this.nextthink  = time;
 647         }
 648
 649         set_movetype(this, MOVETYPE_TOSS);
 650
 651         if(!this.owner)
 652                 return;
 653
 654         fixedmakevectors(this.angles);
 655         vector spot;
 656         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 657                 spot = this.origin + v_up * 128 + v_forward * 300;
 658         else
 659                 spot = this.origin + v_up * 128 - v_forward * 300;
 660
 661         spot = vehicles_findgoodexit(this, this.owner, spot);
 662
 663         // Hide beam
 664         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 665                 this.gun3.enemy.effects |= EF_NODRAW;
 666
 667         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 668         this.owner.velocity_z += 10;
 669         setorigin(this.owner, spot);
 670
 671         antilag_clear(this.owner, CS(this.owner));
 672         this.owner = NULL;
 673 }
 674
 675 void bumblebee_blowup(entity this)
 676 {
 677         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 678                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 679                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 680                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 681                                  DEATH_VH_BUMB_DEATH.m_id, NULL);
 682
 683         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 684         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 685
 686         if(this.owner.deadflag == DEAD_DYING)
 687                 this.owner.deadflag = DEAD_DEAD;
 688
 689         delete(this);
 690 }
 691
 692 void bumblebee_dead_touch(entity this, entity toucher)
 693 {
 694         bumblebee_blowup(this);
 695 }
 696
 697 void bumblebee_diethink(entity this)
 698 {
 699         if(time >= this.wait)
 700                 setthink(this, bumblebee_blowup);
 701
 702         if(random() < 0.1)
 703         {
 704                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 705                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 706         }
 707
 708         this.nextthink = time + 0.1;
 709 }
 710
 711 spawnfunc(vehicle_bumblebee)
 712 {
 713         if(!autocvar_g_vehicle_bumblebee) { delete(this); return; }
 714         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { delete(this); return; }
 715 }
 716
 717 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 718 {
 719     if(autocvar_g_vehicle_bumblebee_bouncepain)
 720         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 721 }
 722 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 723 {
 724     settouch(instance, bumblebee_touch);
 725     instance.nextthink = 0;
 726     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 727 }
 728 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 729 {
 730         if(!instance.gunner1)
 731         if(time >= instance.gun1.phase)
 732         if(instance.gun1.vehicle_enter)
 733         if(instance.gun1.vehicle_enter(instance, actor))
 734                 return;
 735
 736         if(!instance.gunner2)
 737         if(time >= instance.gun2.phase)
 738         if(instance.gun2.vehicle_enter)
 739         if(instance.gun2.vehicle_enter(instance, actor))
 740                 return;
 741 }
 742 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 743 {
 744     instance.angles_z *= 0.8;
 745     instance.angles_x *= 0.8;
 746
 747     instance.nextthink = time;
 748
 749     if(!instance.owner)
 750     {
 751         if(instance.gunner1)
 752         {
 753                 entity e = instance.gunner1;
 754                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 755                 instance.phase = 0;
 756                 gettouch(instance)(instance, e);
 757                 return;
 758         }
 759
 760         if(instance.gunner2)
 761         {
 762                 entity e = instance.gunner2;
 763                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 764                 instance.phase = 0;
 765                 gettouch(instance)(instance, e);
 766             return;
 767         }
 768     }
 769 }
 770 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 771 {
 772         CSQCModel_UnlinkEntity(instance);
 773
 774         // hide beam
 775         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 776                 instance.gun3.enemy.effects |= EF_NODRAW;
 777
 778         if(instance.gunner1)
 779                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 780
 781         if(instance.gunner2)
 782                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 783
 784         instance.vehicle_exit(instance, VHEF_EJECT);
 785
 786     fixedmakevectors(instance.angles);
 787     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 788     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 789     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 790
 791     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 792
 793     if(random() > 0.5)
 794         settouch(_body, bumblebee_dead_touch);
 795     else
 796         settouch(_body, func_null);
 797
 798     setthink(_body, bumblebee_diethink);
 799     _body.nextthink = time;
 800     _body.wait = time + 2 + (random() * 8);
 801     _body.owner = instance;
 802     _body.enemy = instance.enemy;
 803     _body.scale = 1.5;
 804     _body.angles = instance.angles;
 805
 806     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 807
 808     instance.health                     = 0;
 809     instance.event_damage       = func_null;
 810     instance.solid                      = SOLID_NOT;
 811     instance.takedamage         = DAMAGE_NO;
 812     instance.deadflag           = DEAD_DYING;
 813     set_movetype(instance, MOVETYPE_NONE);
 814     instance.effects            = EF_NODRAW;
 815     instance.colormod           = '0 0 0';
 816     instance.avelocity          = '0 0 0';
 817     instance.velocity           = '0 0 0';
 818     settouch(instance, func_null);
 819     instance.nextthink          = 0;
 820
 821     setorigin(instance, instance.pos1);
 822 }
 823 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 824 {
 825     if(!instance.gun1)
 826     {
 827         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 828         instance.vehicle_shieldent = spawn();
 829         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 830         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 831         setattachment(instance.vehicle_shieldent, instance, "");
 832         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 833         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 834         setthink(instance.vehicle_shieldent, shieldhit_think);
 835         instance.vehicle_shieldent.alpha = -1;
 836         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 837
 838         instance.gun1 = new(vehicle_playerslot);
 839         instance.gun2 = new(vehicle_playerslot);
 840         instance.gun3 = new(bumblebee_raygun);
 841
 842         instance.vehicle_flags |= VHF_MULTISLOT;
 843
 844         instance.gun1.owner = instance;
 845         instance.gun2.owner = instance;
 846         instance.gun3.owner = instance;
 847
 848         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 849         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 850         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 851
 852         setattachment(instance.gun1, instance, "cannon_right");
 853         setattachment(instance.gun2, instance, "cannon_left");
 854
 855         // Angled bones are no fun, messes up gun-aim; so work arround it.
 856         instance.gun3.pos1 = instance.angles;
 857         instance.angles = '0 0 0';
 858         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 859         ofs -= instance.origin;
 860         setattachment(instance.gun3, instance, "");
 861         setorigin(instance.gun3, ofs);
 862         instance.angles = instance.gun3.pos1;
 863
 864         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 865         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 866
 867         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 868         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 869
 870         //fixme-model-bones
 871         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 872         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 873         //fixme-model-bones
 874         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 875         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 876
 877         instance.scale = 1.5;
 878
 879         // Raygun beam
 880         if(instance.gun3.enemy == NULL)
 881         {
 882             instance.gun3.enemy = spawn();
 883             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 884             instance.gun3.enemy.SendFlags = BRG_SETUP;
 885             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 886             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 887         }
 888     }
 889
 890     if(!autocvar_g_vehicle_bumblebee_swim)
 891         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 892
 893     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 894     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 895     instance.solid = SOLID_BBOX;
 896     set_movetype(instance, MOVETYPE_TOSS);
 897     instance.damageforcescale = 0.025;
 898
 899     instance.PlayerPhysplug = bumblebee_pilot_frame;
 900
 901     setorigin(instance, instance.origin + '0 0 25');
 902 }
 903 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 904 {
 905     if(autocvar_g_vehicle_bumblebee_energy)
 906     if(autocvar_g_vehicle_bumblebee_energy_regen)
 907         instance.vehicle_flags |= VHF_ENERGYREGEN;
 908
 909     if(autocvar_g_vehicle_bumblebee_shield)
 910         instance.vehicle_flags |= VHF_HASSHIELD;
 911
 912     if(autocvar_g_vehicle_bumblebee_shield_regen)
 913         instance.vehicle_flags |= VHF_SHIELDREGEN;
 914
 915     if(autocvar_g_vehicle_bumblebee_health_regen)
 916         instance.vehicle_flags |= VHF_HEALTHREGEN;
 917
 918     instance.vehicle_exit = bumblebee_exit;
 919     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 920     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 921     instance.max_health = instance.vehicle_health;
 922     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 923 }
 924
 925 #endif // SVQC
 926 #ifdef CSQC
 927
 928 void CSQC_BUMBLE_GUN_HUD()
 929 {
 930         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 931                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 932                                          string_null, '0 0 0');
 933 }
 934
 935 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 936 {
 937     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 938                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 939                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 940
 941     float hudAlpha = autocvar_hud_panel_fg_alpha;
 942     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 943     vector tmpPos  = '0 0 0';
 944     vector tmpSize = '1 1 1' * hud_fontsize;
 945     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 946
 947     if(!AuxiliaryXhair[1].draw2d)
 948     {
 949         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 950         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 951     }
 952
 953     if(!AuxiliaryXhair[2].draw2d)
 954     {
 955         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 956         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 957     }
 958 }
 959 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 960 {
 961     Vehicles_drawCrosshair(vCROSS_HEAL);
 962 }
 963 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 964 {
 965     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 966     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 967     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 968 }
 969
 970 #endif
 971 #endif