qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #include "bumblebee.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 const float BRG_SETUP = 2;
   6 const float BRG_START = 4;
   7 const float BRG_END = 8;
   8
   9 #ifdef SVQC
  10 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  11
  12 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  13 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  14 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  15 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  16 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  17 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  18 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  19 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  20 bool autocvar_g_vehicle_bumblebee_swim = false;
  21
  22 float autocvar_g_vehicle_bumblebee_energy = 500;
  23 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  24 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  25
  26 float autocvar_g_vehicle_bumblebee_health = 1000;
  27 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  28 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  29
  30 float autocvar_g_vehicle_bumblebee_shield = 400;
  31 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  32 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  33
  34 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  35 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  37
  38 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  39
  40 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  41 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  42 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  43 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  44 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  45
  46
  47 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  48 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  49 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  50 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  51
  52 bool autocvar_g_vehicle_bumblebee_raygun = false;
  53 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  54 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  55 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  56 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  57
  58 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  59 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  60 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  61 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  62 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  63 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  64
  65 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  66 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  67 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  68 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  69 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  70
  71 bool autocvar_g_vehicle_bumblebee = true;
  72
  73 bool bumblebee_gunner_frame(entity this, float dt)
  74 {
  75         entity vehic = this.vehicle.owner;
  76         entity gun = this.vehicle;
  77         return = true;
  78
  79         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
  80         //vehicles_frame(gun, player);
  81
  82         vehic.solid = SOLID_NOT;
  83         //setorigin(this, vehic.origin);
  84         this.velocity = vehic.velocity;
  85
  86         float _in, _out;
  87         vehic.angles_x *= -1;
  88         makevectors(vehic.angles);
  89         vehic.angles_x *= -1;
  90         if(gun == vehic.gun1)
  91         {
  92                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  93                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  94                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
  95         }
  96         else
  97         {
  98                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  99                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 100                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 101         }
 102
 103         crosshair_trace(this);
 104         vector _ct = trace_endpos;
 105         vector ad;
 106
 107         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 108         {
 109                 if(gun.lock_time < time)
 110                         gun.enemy = NULL;
 111
 112                 if(trace_ent)
 113                         if(trace_ent.move_movetype)
 114                                 if(trace_ent.takedamage)
 115                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 116                                         {
 117                                                 if(DIFF_TEAM(trace_ent, this))
 118                                                 {
 119                                                         gun.enemy = trace_ent;
 120                                                         gun.lock_time = time + 5;
 121                                                 }
 122                                         }
 123         }
 124
 125         if(gun.enemy)
 126         {
 127                 float distance, impact_time;
 128
 129                 vector vf = real_origin(gun.enemy);
 130                 vector _vel = gun.enemy.velocity;
 131                 if(gun.enemy.move_movetype == MOVETYPE_WALK)
 132                         _vel.z *= 0.1;
 133
 134
 135                 ad = vf;
 136                 distance = vlen(ad - this.origin);
 137                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 138                 ad = vf + _vel * impact_time;
 139                 trace_endpos = ad;
 140
 141
 142                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 143                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 144                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 145                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 146
 147         }
 148         else
 149                 vehicle_aimturret(vehic, _ct, gun, "fire",
 150                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 151                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 152
 153         if(!forbidWeaponUse(this))
 154         if(PHYS_INPUT_BUTTON_ATCK(this))
 155                 if(time > gun.attack_finished_single[0])
 156                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 157                         {
 158                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 159                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 160                                 gun.delay = time;
 161                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 162                         }
 163
 164         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 165
 166         if(vehic.vehicle_flags & VHF_HASSHIELD)
 167                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 168
 169         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 170         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 171
 172         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 173
 174         if(vehic.owner)
 175                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 176
 177         vehic.solid = SOLID_BBOX;
 178         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 179         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 180 }
 181
 182 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 183 {
 184         //vector exitspot;
 185         float mysize;
 186
 187         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 188         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 189                 return prefer_spot;
 190
 191         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 192         float i;
 193         vector v, v2;
 194         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 195         for(i = 0; i < 100; ++i)
 196         {
 197                 v = randomvec();
 198                 v_z = 0;
 199                 v = v2 + normalize(v) * mysize;
 200                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 201                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 202                         return v;
 203         }
 204
 205         return prefer_spot; // this should be considered a fallback?!
 206 }
 207
 208 void bumblebee_gunner_exit(entity this, int _exitflag)
 209 {
 210         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 211         entity gunner = this;
 212         entity vehic = gunner.owner;
 213
 214         if(IS_REAL_CLIENT(player))
 215         {
 216                 msg_entity = player;
 217                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 218                 WriteEntity(MSG_ONE, player);
 219
 220                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 221                 WriteAngle(MSG_ONE, 0);
 222                 WriteAngle(MSG_ONE, vehic.angles.y);
 223                 WriteAngle(MSG_ONE, 0);
 224         }
 225
 226         CSQCVehicleSetup(player, HUD_NORMAL);
 227         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 228
 229         player.takedamage     = DAMAGE_AIM;
 230         player.solid          = SOLID_SLIDEBOX;
 231         set_movetype(player, MOVETYPE_WALK);
 232         player.effects       &= ~EF_NODRAW;
 233         player.alpha          = 1;
 234         player.PlayerPhysplug = func_null;
 235         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 236         player.event_damage   = PlayerDamage;
 237         player.hud            = HUD_NORMAL;
 238         player.teleportable       = TELEPORT_NORMAL;
 239         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 240         {
 241                 .entity weaponentity = weaponentities[slot];
 242                 player.(weaponentity).m_switchweapon = gunner.(weaponentity).m_switchweapon;
 243                 delete(gunner.(weaponentity));
 244         }
 245         player.vehicle_enter_delay = time + 2;
 246
 247         fixedmakevectors(vehic.angles);
 248
 249         if(player == vehic.gunner1) { vehic.gunner1 = NULL; }
 250         if(player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 251
 252         vector spot = real_origin(gunner);
 253         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 254         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 255
 256         // TODO: figure a way to move player out of the gunner
 257
 258         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 259         player.velocity_z += 10;
 260
 261         gunner.phase = time + 5;
 262         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 263
 264         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 265
 266         player.vehicle = NULL;
 267 }
 268
 269 bool bumblebee_gunner_enter(entity this, entity player)
 270 {
 271         entity vehic = this;
 272         entity gunner = NULL;
 273
 274         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 275         {
 276                 // we can have some fun
 277                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 278                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 279                 if(vlen2(player.origin - v1) < vlen2(player.origin - v2))
 280                 {
 281                         gunner = vehic.gun1;
 282                         vehic.gunner1 = player;
 283                 }
 284                 else
 285                 {
 286                         gunner = vehic.gun2;
 287                         vehic.gunner2 = player;
 288                 }
 289         }
 290         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 291         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 292         else { LOG_TRACE("Vehicle is full, fail"); return false; }
 293
 294         player.vehicle                  = gunner;
 295         player.angles                   = vehic.angles;
 296         player.takedamage               = DAMAGE_NO;
 297         player.solid                    = SOLID_NOT;
 298         player.alpha                    = -1;
 299         set_movetype(player, MOVETYPE_NOCLIP);
 300         player.event_damage     = func_null;
 301         player.view_ofs                 = '0 0 0';
 302         player.hud                              = gunner.hud;
 303         player.teleportable     = false;
 304         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 305         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 306         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 307         player.vehicle_reload1  = vehic.vehicle_reload1;
 308         player.vehicle_reload2  = vehic.vehicle_reload2;
 309         player.vehicle_energy   = vehic.vehicle_energy;
 310         UNSET_ONGROUND(player);
 311
 312         RemoveGrapplingHooks(player);
 313
 314         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 315         {
 316                 .entity weaponentity = weaponentities[slot];
 317
 318                 gunner.(weaponentity) = new(temp_wepent);
 319                 gunner.(weaponentity).m_switchweapon = player.(weaponentity).m_switchweapon;
 320         }
 321         gunner.vehicle_exit = bumblebee_gunner_exit;
 322         gunner.vehicle_hudmodel.viewmodelforclient = player;
 323
 324         if(IS_REAL_CLIENT(player))
 325         {
 326                 msg_entity = player;
 327                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 328                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 329
 330                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 331                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 332                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 333                 WriteAngle(MSG_ONE,     0); // roll
 334         }
 335
 336         CSQCVehicleSetup(player, player.hud);
 337
 338         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 339
 340         return true;
 341 }
 342
 343 bool vehicles_valid_pilot(entity this, entity toucher)
 344 {
 345         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 346                 return false;
 347
 348         if((!IS_PLAYER(toucher))
 349         || (IS_DEAD(toucher))
 350         || (toucher.vehicle)
 351         || (DIFF_TEAM(toucher, this))
 352         ) { return false; }
 353
 354         return true;
 355 }
 356
 357 void bumblebee_touch(entity this, entity toucher)
 358 {
 359         if(autocvar_g_vehicles_enter) { return; }
 360
 361         if(this.gunner1 != NULL && this.gunner2 != NULL)
 362         {
 363                 vehicles_touch(this, toucher);
 364                 return;
 365         }
 366
 367         if(vehicles_valid_pilot(this, toucher))
 368         {
 369                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 370
 371                 if(time >= toucher.vehicle_enter_delay && phase_time)
 372                 if(bumblebee_gunner_enter(this, toucher))
 373                         return;
 374         }
 375
 376         vehicles_touch(this, toucher);
 377 }
 378
 379 void bumblebee_regen(entity this, float dt)
 380 {
 381         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 382                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 383                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 384
 385         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 386                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 387                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 388
 389         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 390                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, dt, true);
 391
 392         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 393                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, dt, false);
 394
 395         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 396                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, dt, false);
 397
 398 }
 399
 400 bool bumblebee_pilot_frame(entity this, float dt)
 401 {
 402         entity vehic = this.vehicle;
 403         return = true;
 404
 405         if(intermission_running)
 406         {
 407                 vehic.solid = SOLID_NOT;
 408                 vehic.takedamage = DAMAGE_NO;
 409                 set_movetype(vehic, MOVETYPE_NONE);
 410                 return;
 411         }
 412
 413         vehicles_frame(vehic, this);
 414
 415         if(IS_DEAD(vehic))
 416         {
 417                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 418                 return;
 419         }
 420
 421         bumblebee_regen(vehic, dt);
 422
 423         crosshair_trace(this);
 424
 425         vector vang = vehic.angles;
 426         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 427         vang.x *= -1;
 428         newvel.x *= -1;
 429         if(newvel.x > 180)  newvel.x -= 360;
 430         if(newvel.x < -180) newvel.x += 360;
 431         if(newvel.y > 180)  newvel.y -= 360;
 432         if(newvel.y < -180) newvel.y += 360;
 433
 434         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 435         if(ftmp > 180)  ftmp -= 360;
 436         if(ftmp < -180) ftmp += 360;
 437         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 438
 439         // Pitch
 440         ftmp = 0;
 441         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 442                 ftmp = 4;
 443         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 444                 ftmp = -8;
 445
 446         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 447         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 448         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 449
 450         vehic.angles_x = anglemods(vehic.angles.x);
 451         vehic.angles_y = anglemods(vehic.angles.y);
 452         vehic.angles_z = anglemods(vehic.angles.z);
 453
 454         makevectors('0 1 0' * vehic.angles.y);
 455         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 456
 457         if(this.movement.x != 0)
 458         {
 459                 if(this.movement.x > 0)
 460                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 461                 else if(this.movement.x < 0)
 462                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 463         }
 464
 465         if(this.movement.y != 0)
 466         {
 467                 if(this.movement.y < 0)
 468                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 469                 else if(this.movement.y > 0)
 470                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 471                 ftmp = newvel * v_right;
 472                 ftmp *= dt * 0.1;
 473                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 474         }
 475         else
 476         {
 477                 vehic.angles_z *= 0.95;
 478                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 479                         vehic.angles_z = 0;
 480         }
 481
 482         if(PHYS_INPUT_BUTTON_CROUCH(this))
 483                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 484         else if(PHYS_INPUT_BUTTON_JUMP(this))
 485                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 486
 487         vehic.velocity  += newvel * dt;
 488         this.velocity = this.movement  = vehic.velocity;
 489
 490
 491         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 492         {
 493                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 494                         vehic.tur_head.enemy = NULL;
 495
 496                 if(trace_ent)
 497                 if(trace_ent.move_movetype)
 498                 if(trace_ent.takedamage)
 499                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 500                 {
 501                         if(teamplay)
 502                         {
 503                                 if(trace_ent.team == this.team)
 504                                 {
 505                                         vehic.tur_head.enemy = trace_ent;
 506                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 507                                 }
 508                         }
 509                         else
 510                         {
 511                                 vehic.tur_head.enemy = trace_ent;
 512                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 513                         }
 514                 }
 515
 516                 if(vehic.tur_head.enemy)
 517                 {
 518                         trace_endpos = real_origin(vehic.tur_head.enemy);
 519                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 520                 }
 521         }
 522
 523         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 524                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 525                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 526
 527         if(!forbidWeaponUse(this))
 528         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME || autocvar_g_vehicle_bumblebee_raygun == 0))
 529         {
 530                 vehic.gun3.enemy.realowner = this;
 531                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 532
 533                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 534                 vehic.gun3.enemy.SendFlags |= BRG_START;
 535
 536                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 537
 538                 if(trace_ent)
 539                 {
 540                         if(autocvar_g_vehicle_bumblebee_raygun)
 541                         {
 542                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * PHYS_INPUT_FRAMETIME);
 543                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * PHYS_INPUT_FRAMETIME;
 544                         }
 545                         else
 546                         {
 547                                 if(!IS_DEAD(trace_ent))
 548                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 549                                         {
 550
 551                                                 if(IS_VEHICLE(trace_ent))
 552                                                 {
 553                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 554                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * dt, trace_ent.tur_head.max_health);
 555
 556                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 557                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 558                                                 }
 559                                                 else if(IS_CLIENT(trace_ent))
 560                                                 {
 561                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 562                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 563
 564                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 565                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * dt, autocvar_g_vehicle_bumblebee_healgun_amax);
 566
 567                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 568                                                 }
 569                                                 else if(IS_TURRET(trace_ent))
 570                                                 {
 571                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 572                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 573                                                         //else ..hmmm what? ammo?
 574
 575                                                         trace_ent.SendFlags |= TNSF_STATUS;
 576                                                 }
 577                                         }
 578                         }
 579                 }
 580
 581                 vehic.gun3.enemy.hook_end = trace_endpos;
 582                 setorigin(vehic.gun3.enemy, trace_endpos);
 583                 vehic.gun3.enemy.SendFlags |= BRG_END;
 584
 585                 vehic.wait = time + 1;
 586         }
 587         else
 588                 vehic.gun3.enemy.effects |= EF_NODRAW;
 589         /*{
 590                 if(vehic.gun3.enemy)
 591                         remove(vehic.gun3.enemy);
 592
 593                 vehic.gun3.enemy = NULL;
 594         }
 595         */
 596
 597         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 598         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 599
 600         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 601         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 602
 603         if(vehic.vehicle_flags & VHF_HASSHIELD)
 604                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 605
 606         vehic.angles_x *= -1;
 607         makevectors(vehic.angles);
 608         vehic.angles_x *= -1;
 609         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 610
 611         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 612 }
 613
 614 void bumblebee_land(entity this)
 615 {
 616         float hgt;
 617
 618         hgt = vehicle_altitude(this, 512);
 619         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
 620         this.angles_x *= 0.95;
 621         this.angles_z *= 0.95;
 622
 623         if(hgt < 16)
 624                 setthink(this, vehicles_think);
 625
 626         this.nextthink = time;
 627
 628         CSQCMODEL_AUTOUPDATE(this);
 629 }
 630
 631 void bumblebee_exit(entity this, int eject)
 632 {
 633         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 634         {
 635                 bumblebee_gunner_exit(this, eject);
 636                 return;
 637         }
 638
 639         settouch(this, vehicles_touch);
 640
 641         if(!IS_DEAD(this))
 642         {
 643                 setthink(this, bumblebee_land);
 644                 this.nextthink  = time;
 645         }
 646
 647         set_movetype(this, MOVETYPE_TOSS);
 648
 649         if(!this.owner)
 650                 return;
 651
 652         fixedmakevectors(this.angles);
 653         vector spot;
 654         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 655                 spot = this.origin + v_up * 128 + v_forward * 300;
 656         else
 657                 spot = this.origin + v_up * 128 - v_forward * 300;
 658
 659         spot = vehicles_findgoodexit(this, spot);
 660
 661         // Hide beam
 662         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 663                 this.gun3.enemy.effects |= EF_NODRAW;
 664
 665         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 666         this.owner.velocity_z += 10;
 667         setorigin(this.owner, spot);
 668
 669         antilag_clear(this.owner, CS(this.owner));
 670         this.owner = NULL;
 671 }
 672
 673 void bumblebee_blowup(entity this)
 674 {
 675         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 676                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 677                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 678                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 679                                  DEATH_VH_BUMB_DEATH.m_id, NULL);
 680
 681         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 682         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 683
 684         if(this.owner.deadflag == DEAD_DYING)
 685                 this.owner.deadflag = DEAD_DEAD;
 686
 687         delete(this);
 688 }
 689
 690 void bumblebee_dead_touch(entity this, entity toucher)
 691 {
 692         bumblebee_blowup(this);
 693 }
 694
 695 void bumblebee_diethink(entity this)
 696 {
 697         if(time >= this.wait)
 698                 setthink(this, bumblebee_blowup);
 699
 700         if(random() < 0.1)
 701         {
 702                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 703                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 704         }
 705
 706         this.nextthink = time + 0.1;
 707 }
 708
 709 spawnfunc(vehicle_bumblebee)
 710 {
 711         if(!autocvar_g_vehicle_bumblebee) { delete(this); return; }
 712         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { delete(this); return; }
 713 }
 714
 715 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 716 {
 717     if(autocvar_g_vehicle_bumblebee_bouncepain)
 718         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 719 }
 720 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 721 {
 722     settouch(instance, bumblebee_touch);
 723     instance.nextthink = 0;
 724     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 725 }
 726 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 727 {
 728         if(!instance.gunner1)
 729         if(time >= instance.gun1.phase)
 730         if(instance.gun1.vehicle_enter)
 731         if(instance.gun1.vehicle_enter(instance, actor))
 732                 return;
 733
 734         if(!instance.gunner2)
 735         if(time >= instance.gun2.phase)
 736         if(instance.gun2.vehicle_enter)
 737         if(instance.gun2.vehicle_enter(instance, actor))
 738                 return;
 739 }
 740 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 741 {
 742     instance.angles_z *= 0.8;
 743     instance.angles_x *= 0.8;
 744
 745     instance.nextthink = time;
 746
 747     if(!instance.owner)
 748     {
 749         if(instance.gunner1)
 750         {
 751                 entity e = instance.gunner1;
 752                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 753                 instance.phase = 0;
 754                 gettouch(instance)(instance, e);
 755                 return;
 756         }
 757
 758         if(instance.gunner2)
 759         {
 760                 entity e = instance.gunner2;
 761                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 762                 instance.phase = 0;
 763                 gettouch(instance)(instance, e);
 764             return;
 765         }
 766     }
 767 }
 768 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 769 {
 770         CSQCModel_UnlinkEntity(instance);
 771
 772         // hide beam
 773         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 774                 instance.gun3.enemy.effects |= EF_NODRAW;
 775
 776         if(instance.gunner1)
 777                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 778
 779         if(instance.gunner2)
 780                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 781
 782         instance.vehicle_exit(instance, VHEF_EJECT);
 783
 784     fixedmakevectors(instance.angles);
 785     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 786     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 787     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 788
 789     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 790
 791     if(random() > 0.5)
 792         settouch(_body, bumblebee_dead_touch);
 793     else
 794         settouch(_body, func_null);
 795
 796     setthink(_body, bumblebee_diethink);
 797     _body.nextthink = time;
 798     _body.wait = time + 2 + (random() * 8);
 799     _body.owner = instance;
 800     _body.enemy = instance.enemy;
 801     _body.scale = 1.5;
 802     _body.angles = instance.angles;
 803
 804     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 805
 806     instance.health                     = 0;
 807     instance.event_damage       = func_null;
 808     instance.solid                      = SOLID_NOT;
 809     instance.takedamage         = DAMAGE_NO;
 810     instance.deadflag           = DEAD_DYING;
 811     set_movetype(instance, MOVETYPE_NONE);
 812     instance.effects            = EF_NODRAW;
 813     instance.colormod           = '0 0 0';
 814     instance.avelocity          = '0 0 0';
 815     instance.velocity           = '0 0 0';
 816     settouch(instance, func_null);
 817     instance.nextthink          = 0;
 818
 819     setorigin(instance, instance.pos1);
 820 }
 821 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 822 {
 823     if(!instance.gun1)
 824     {
 825         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 826         instance.vehicle_shieldent = spawn();
 827         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 828         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 829         setattachment(instance.vehicle_shieldent, instance, "");
 830         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 831         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 832         setthink(instance.vehicle_shieldent, shieldhit_think);
 833         instance.vehicle_shieldent.alpha = -1;
 834         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 835
 836         instance.gun1 = new(vehicle_playerslot);
 837         instance.gun2 = new(vehicle_playerslot);
 838         instance.gun3 = new(bumblebee_raygun);
 839
 840         instance.vehicle_flags |= VHF_MULTISLOT;
 841
 842         instance.gun1.owner = instance;
 843         instance.gun2.owner = instance;
 844         instance.gun3.owner = instance;
 845
 846         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 847         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 848         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 849
 850         setattachment(instance.gun1, instance, "cannon_right");
 851         setattachment(instance.gun2, instance, "cannon_left");
 852
 853         // Angled bones are no fun, messes up gun-aim; so work arround it.
 854         instance.gun3.pos1 = instance.angles;
 855         instance.angles = '0 0 0';
 856         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 857         ofs -= instance.origin;
 858         setattachment(instance.gun3, instance, "");
 859         setorigin(instance.gun3, ofs);
 860         instance.angles = instance.gun3.pos1;
 861
 862         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 863         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 864
 865         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 866         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 867
 868         //fixme-model-bones
 869         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 870         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 871         //fixme-model-bones
 872         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 873         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 874
 875         instance.scale = 1.5;
 876
 877         // Raygun beam
 878         if(instance.gun3.enemy == NULL)
 879         {
 880             instance.gun3.enemy = spawn();
 881             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 882             instance.gun3.enemy.SendFlags = BRG_SETUP;
 883             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 884             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 885         }
 886     }
 887
 888     if(!autocvar_g_vehicle_bumblebee_swim)
 889         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 890
 891     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 892     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 893     instance.solid = SOLID_BBOX;
 894     set_movetype(instance, MOVETYPE_TOSS);
 895     instance.damageforcescale = 0.025;
 896
 897     instance.PlayerPhysplug = bumblebee_pilot_frame;
 898
 899     setorigin(instance, instance.origin + '0 0 25');
 900 }
 901 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 902 {
 903     if(autocvar_g_vehicle_bumblebee_energy)
 904     if(autocvar_g_vehicle_bumblebee_energy_regen)
 905         instance.vehicle_flags |= VHF_ENERGYREGEN;
 906
 907     if(autocvar_g_vehicle_bumblebee_shield)
 908         instance.vehicle_flags |= VHF_HASSHIELD;
 909
 910     if(autocvar_g_vehicle_bumblebee_shield_regen)
 911         instance.vehicle_flags |= VHF_SHIELDREGEN;
 912
 913     if(autocvar_g_vehicle_bumblebee_health_regen)
 914         instance.vehicle_flags |= VHF_HEALTHREGEN;
 915
 916     instance.vehicle_exit = bumblebee_exit;
 917     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 918     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 919     instance.max_health = instance.vehicle_health;
 920     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 921 }
 922
 923 #endif // SVQC
 924 #ifdef CSQC
 925
 926 void CSQC_BUMBLE_GUN_HUD()
 927 {
 928         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 929                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 930                                          string_null, '0 0 0');
 931 }
 932
 933 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 934 {
 935     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 936                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 937                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 938
 939     float hudAlpha = autocvar_hud_panel_fg_alpha;
 940     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 941     vector tmpPos  = '0 0 0';
 942     vector tmpSize = '1 1 1' * hud_fontsize;
 943     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 944
 945     if(!AuxiliaryXhair[1].draw2d)
 946     {
 947         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 948         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 949     }
 950
 951     if(!AuxiliaryXhair[2].draw2d)
 952     {
 953         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 954         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 955     }
 956 }
 957 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 958 {
 959     Vehicles_drawCrosshair(vCROSS_HEAL);
 960 }
 961 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 962 {
 963     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 964     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 965     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 966 }
 967
 968 #endif
 969 #endif