qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #ifndef VEHICLE_BUMBLEBEE
   2 #define VEHICLE_BUMBLEBEE
   3 #include "bumblebee.qh"
   4
   5 #include "bumblebee_weapons.qh"
   6
   7 CLASS(Bumblebee, Vehicle)
   8 /* spawnflags */ ATTRIB(Bumblebee, spawnflags, int, VHF_DMGSHAKE);
   9 /* mins       */ ATTRIB(Bumblebee, mins, vector, '-245 -130 -130');
  10 /* maxs       */ ATTRIB(Bumblebee, maxs, vector, '230 130 130');
  11 /* view offset*/ ATTRIB(Bumblebee, view_ofs, vector, '0 0 300');
  12 /* view dist  */ ATTRIB(Bumblebee, height, float, 450);
  13 /* model          */ ATTRIB(Bumblebee, mdl, string, "models/vehicles/bumblebee_body.dpm");
  14 /* model          */ ATTRIB(Bumblebee, model, string, "models/vehicles/bumblebee_body.dpm");
  15 /* head_model */ ATTRIB(Bumblebee, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Bumblebee, hud_model, string, "models/vehicles/spiderbot_cockpit.dpm");
  17 /* tags       */ ATTRIB(Bumblebee, tag_head, string, "");
  18 /* tags       */ ATTRIB(Bumblebee, tag_hud, string, "");
  19 /* tags       */ ATTRIB(Bumblebee, tag_view, string, "tag_viewport");
  20 /* netname    */ ATTRIB(Bumblebee, netname, string, "bumblebee");
  21 /* fullname   */ ATTRIB(Bumblebee, vehicle_name, string, _("Bumblebee"));
  22 /* icon       */ ATTRIB(Bumblebee, m_icon, string, "vehicle_bumble");
  23 ENDCLASS(Bumblebee)
  24 REGISTER_VEHICLE(BUMBLEBEE, NEW(Bumblebee));
  25
  26 #ifndef MENUQC
  27         MODEL(VEH_BUMBLEBEE_GUNCOCKPIT, "models/vehicles/wakizashi_cockpit.dpm");
  28 #endif
  29
  30 #endif
  31
  32 #ifdef IMPLEMENTATION
  33
  34 const float BRG_SETUP = 2;
  35 const float BRG_START = 4;
  36 const float BRG_END = 8;
  37
  38 #ifdef SVQC
  39 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  40
  41 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  42 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  43 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  44 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  45 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  46 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  47 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  48 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  49
  50 float autocvar_g_vehicle_bumblebee_energy = 500;
  51 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  52 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  53
  54 float autocvar_g_vehicle_bumblebee_health = 1000;
  55 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  56 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  57
  58 float autocvar_g_vehicle_bumblebee_shield = 400;
  59 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  60 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  61
  62 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  63 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  64 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  65
  66 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  67
  68 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  69 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  70 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  71 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  72 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  73
  74
  75 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  76 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  77 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  78 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  79
  80 bool autocvar_g_vehicle_bumblebee_raygun = false;
  81 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  82 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  83 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  84 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  85
  86 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  87 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  88 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  89 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  90 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  91 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  92
  93 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  94 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  95 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  96 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  97 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  98
  99 bool autocvar_g_vehicle_bumblebee = true;
 100
 101 bool bumblebee_gunner_frame(entity this)
 102 {
 103         entity vehic = this.vehicle.owner;
 104         entity gun = this.vehicle;
 105         return = true;
 106
 107         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
 108         //vehicles_frame(gun, player);
 109
 110         vehic.solid = SOLID_NOT;
 111         //setorigin(this, vehic.origin);
 112         this.velocity = vehic.velocity;
 113
 114         float _in, _out;
 115         vehic.angles_x *= -1;
 116         makevectors(vehic.angles);
 117         vehic.angles_x *= -1;
 118         if(gun == vehic.gun1)
 119         {
 120                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 121                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 122                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 123         }
 124         else
 125         {
 126                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 127                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 128                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 129         }
 130
 131         crosshair_trace(this);
 132         vector _ct = trace_endpos;
 133         vector ad;
 134
 135         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 136         {
 137                 if(gun.lock_time < time)
 138                         gun.enemy = NULL;
 139
 140                 if(trace_ent)
 141                         if(trace_ent.move_movetype)
 142                                 if(trace_ent.takedamage)
 143                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 144                                         {
 145                                                 if(DIFF_TEAM(trace_ent, this))
 146                                                 {
 147                                                         gun.enemy = trace_ent;
 148                                                         gun.lock_time = time + 5;
 149                                                 }
 150                                         }
 151         }
 152
 153         if(gun.enemy)
 154         {
 155                 float distance, impact_time;
 156
 157                 vector vf = real_origin(gun.enemy);
 158                 vector _vel = gun.enemy.velocity;
 159                 if(gun.enemy.move_movetype == MOVETYPE_WALK)
 160                         _vel.z *= 0.1;
 161
 162
 163                 ad = vf;
 164                 distance = vlen(ad - this.origin);
 165                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 166                 ad = vf + _vel * impact_time;
 167                 trace_endpos = ad;
 168
 169
 170                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 171                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 172                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 173                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 174
 175         }
 176         else
 177                 vehicle_aimturret(vehic, _ct, gun, "fire",
 178                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 179                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 180
 181         if(!forbidWeaponUse(this))
 182         if(PHYS_INPUT_BUTTON_ATCK(this))
 183                 if(time > gun.attack_finished_single[0])
 184                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 185                         {
 186                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 187                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 188                                 gun.delay = time;
 189                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 190                         }
 191
 192         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 193
 194         if(vehic.vehicle_flags & VHF_HASSHIELD)
 195                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 196
 197         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 198         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 199
 200         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 201
 202         if(vehic.owner)
 203                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 204
 205         vehic.solid = SOLID_BBOX;
 206         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 207         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 208 }
 209
 210 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 211 {
 212         //vector exitspot;
 213         float mysize;
 214
 215         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 216         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 217                 return prefer_spot;
 218
 219         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 220         float i;
 221         vector v, v2;
 222         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 223         for(i = 0; i < 100; ++i)
 224         {
 225                 v = randomvec();
 226                 v_z = 0;
 227                 v = v2 + normalize(v) * mysize;
 228                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 229                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 230                         return v;
 231         }
 232
 233         return prefer_spot; // this should be considered a fallback?!
 234 }
 235
 236 void bumblebee_gunner_exit(entity this, int _exitflag)
 237 {
 238         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 239         entity gunner = this;
 240         entity vehic = gunner.owner;
 241
 242         if(IS_REAL_CLIENT(player))
 243         {
 244                 msg_entity = player;
 245                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 246                 WriteEntity(MSG_ONE, player);
 247
 248                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 249                 WriteAngle(MSG_ONE, 0);
 250                 WriteAngle(MSG_ONE, vehic.angles.y);
 251                 WriteAngle(MSG_ONE, 0);
 252         }
 253
 254         CSQCVehicleSetup(player, HUD_NORMAL);
 255         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 256
 257         player.takedamage     = DAMAGE_AIM;
 258         player.solid          = SOLID_SLIDEBOX;
 259         set_movetype(player, MOVETYPE_WALK);
 260         player.effects       &= ~EF_NODRAW;
 261         player.alpha          = 1;
 262         player.PlayerPhysplug = func_null;
 263         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 264         player.event_damage   = PlayerDamage;
 265         player.hud            = HUD_NORMAL;
 266         player.teleportable       = TELEPORT_NORMAL;
 267         PS(player).m_switchweapon = gunner.m_switchweapon;
 268         player.vehicle_enter_delay = time + 2;
 269
 270         fixedmakevectors(vehic.angles);
 271
 272         if(player == vehic.gunner1) { vehic.gunner1 = NULL; }
 273         if(player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 274
 275         vector spot = real_origin(gunner);
 276         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 277         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 278
 279         // TODO: figure a way to move player out of the gunner
 280
 281         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 282         player.velocity_z += 10;
 283
 284         gunner.phase = time + 5;
 285         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 286
 287         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 288
 289         player.vehicle = NULL;
 290 }
 291
 292 bool bumblebee_gunner_enter(entity this, entity player)
 293 {
 294         entity vehic = this;
 295         entity gunner = NULL;
 296
 297         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 298         {
 299                 // we can have some fun
 300                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 301                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 302                 if(vlen2(player.origin - v1) < vlen2(player.origin - v2))
 303                 {
 304                         gunner = vehic.gun1;
 305                         vehic.gunner1 = player;
 306                 }
 307                 else
 308                 {
 309                         gunner = vehic.gun2;
 310                         vehic.gunner2 = player;
 311                 }
 312         }
 313         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 314         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 315         else { LOG_TRACE("Vehicle is full, fail\n"); return false; }
 316
 317         player.vehicle                  = gunner;
 318         player.angles                   = vehic.angles;
 319         player.takedamage               = DAMAGE_NO;
 320         player.solid                    = SOLID_NOT;
 321         player.alpha                    = -1;
 322         set_movetype(player, MOVETYPE_NOCLIP);
 323         player.event_damage     = func_null;
 324         player.view_ofs                 = '0 0 0';
 325         player.hud                              = gunner.hud;
 326         player.teleportable     = false;
 327         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 328         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 329         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 330         player.vehicle_reload1  = vehic.vehicle_reload1;
 331         player.vehicle_reload2  = vehic.vehicle_reload2;
 332         player.vehicle_energy   = vehic.vehicle_energy;
 333         UNSET_ONGROUND(player);
 334
 335         RemoveGrapplingHook(player);
 336
 337         gunner.m_switchweapon = PS(player).m_switchweapon;
 338         gunner.vehicle_exit = bumblebee_gunner_exit;
 339         gunner.vehicle_hudmodel.viewmodelforclient = player;
 340
 341         if(IS_REAL_CLIENT(player))
 342         {
 343                 msg_entity = player;
 344                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 345                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 346
 347                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 348                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 349                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 350                 WriteAngle(MSG_ONE,     0); // roll
 351         }
 352
 353         CSQCVehicleSetup(player, player.hud);
 354
 355         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 356
 357         return true;
 358 }
 359
 360 bool vehicles_valid_pilot(entity this, entity toucher)
 361 {
 362         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 363                 return false;
 364
 365         if((!IS_PLAYER(toucher))
 366         || (IS_DEAD(toucher))
 367         || (toucher.vehicle)
 368         || (DIFF_TEAM(toucher, this))
 369         ) { return false; }
 370
 371         return true;
 372 }
 373
 374 void bumblebee_touch(entity this, entity toucher)
 375 {
 376         if(autocvar_g_vehicles_enter) { return; }
 377
 378         if(this.gunner1 != NULL && this.gunner2 != NULL)
 379         {
 380                 vehicles_touch(this, toucher);
 381                 return;
 382         }
 383
 384         if(vehicles_valid_pilot(this, toucher))
 385         {
 386                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 387
 388                 if(time >= toucher.vehicle_enter_delay && phase_time)
 389                 if(bumblebee_gunner_enter(this, toucher))
 390                         return;
 391         }
 392
 393         vehicles_touch(this, toucher);
 394 }
 395
 396 void bumblebee_regen(entity this)
 397 {
 398         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 399                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 400                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 401
 402         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 403                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 404                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 405
 406         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 407                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, true);
 408
 409         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 410                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, false);
 411
 412         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 413                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, false);
 414
 415 }
 416
 417 bool bumblebee_pilot_frame(entity this)
 418 {
 419         entity vehic = this.vehicle;
 420         return = true;
 421
 422         if(intermission_running)
 423         {
 424                 vehic.velocity = '0 0 0';
 425                 vehic.avelocity = '0 0 0';
 426                 return;
 427         }
 428
 429         vehicles_frame(vehic, this);
 430
 431         if(IS_DEAD(vehic))
 432         {
 433                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 434                 return;
 435         }
 436
 437         bumblebee_regen(vehic);
 438
 439         crosshair_trace(this);
 440
 441         vector vang = vehic.angles;
 442         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 443         vang.x *= -1;
 444         newvel.x *= -1;
 445         if(newvel.x > 180)  newvel.x -= 360;
 446         if(newvel.x < -180) newvel.x += 360;
 447         if(newvel.y > 180)  newvel.y -= 360;
 448         if(newvel.y < -180) newvel.y += 360;
 449
 450         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 451         if(ftmp > 180)  ftmp -= 360;
 452         if(ftmp < -180) ftmp += 360;
 453         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 454
 455         // Pitch
 456         ftmp = 0;
 457         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 458                 ftmp = 4;
 459         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 460                 ftmp = -8;
 461
 462         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 463         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 464         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 465
 466         vehic.angles_x = anglemods(vehic.angles.x);
 467         vehic.angles_y = anglemods(vehic.angles.y);
 468         vehic.angles_z = anglemods(vehic.angles.z);
 469
 470         makevectors('0 1 0' * vehic.angles.y);
 471         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 472
 473         if(this.movement.x != 0)
 474         {
 475                 if(this.movement.x > 0)
 476                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 477                 else if(this.movement.x < 0)
 478                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 479         }
 480
 481         if(this.movement.y != 0)
 482         {
 483                 if(this.movement.y < 0)
 484                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 485                 else if(this.movement.y > 0)
 486                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 487                 ftmp = newvel * v_right;
 488                 ftmp *= frametime * 0.1;
 489                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 490         }
 491         else
 492         {
 493                 vehic.angles_z *= 0.95;
 494                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 495                         vehic.angles_z = 0;
 496         }
 497
 498         if(PHYS_INPUT_BUTTON_CROUCH(this))
 499                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 500         else if(PHYS_INPUT_BUTTON_JUMP(this))
 501                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 502
 503         vehic.velocity  += newvel * frametime;
 504         this.velocity = this.movement  = vehic.velocity;
 505
 506
 507         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 508         {
 509                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 510                         vehic.tur_head.enemy = NULL;
 511
 512                 if(trace_ent)
 513                 if(trace_ent.move_movetype)
 514                 if(trace_ent.takedamage)
 515                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 516                 {
 517                         if(teamplay)
 518                         {
 519                                 if(trace_ent.team == this.team)
 520                                 {
 521                                         vehic.tur_head.enemy = trace_ent;
 522                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 523                                 }
 524                         }
 525                         else
 526                         {
 527                                 vehic.tur_head.enemy = trace_ent;
 528                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 529                         }
 530                 }
 531
 532                 if(vehic.tur_head.enemy)
 533                 {
 534                         trace_endpos = real_origin(vehic.tur_head.enemy);
 535                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 536                 }
 537         }
 538
 539         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 540                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 541                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 542
 543         if(!forbidWeaponUse(this))
 544         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 545         {
 546                 vehic.gun3.enemy.realowner = this;
 547                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 548
 549                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 550                 vehic.gun3.enemy.SendFlags |= BRG_START;
 551
 552                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 553
 554                 if(trace_ent)
 555                 {
 556                         if(autocvar_g_vehicle_bumblebee_raygun)
 557                         {
 558                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 559                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 560                         }
 561                         else
 562                         {
 563                                 if(!IS_DEAD(trace_ent))
 564                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 565                                         {
 566
 567                                                 if(IS_VEHICLE(trace_ent))
 568                                                 {
 569                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 570                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.max_health);
 571
 572                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 573                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 574                                                 }
 575                                                 else if(IS_CLIENT(trace_ent))
 576                                                 {
 577                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 578                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 579
 580                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 581                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 582
 583                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 584                                                 }
 585                                                 else if(IS_TURRET(trace_ent))
 586                                                 {
 587                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 588                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 589                                                         //else ..hmmm what? ammo?
 590
 591                                                         trace_ent.SendFlags |= TNSF_STATUS;
 592                                                 }
 593                                         }
 594                         }
 595                 }
 596
 597                 vehic.gun3.enemy.hook_end = trace_endpos;
 598                 setorigin(vehic.gun3.enemy, trace_endpos);
 599                 vehic.gun3.enemy.SendFlags |= BRG_END;
 600
 601                 vehic.wait = time + 1;
 602         }
 603         else
 604                 vehic.gun3.enemy.effects |= EF_NODRAW;
 605         /*{
 606                 if(vehic.gun3.enemy)
 607                         remove(vehic.gun3.enemy);
 608
 609                 vehic.gun3.enemy = NULL;
 610         }
 611         */
 612
 613         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 614         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 615
 616         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 617         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 618
 619         if(vehic.vehicle_flags & VHF_HASSHIELD)
 620                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 621
 622         vehic.angles_x *= -1;
 623         makevectors(vehic.angles);
 624         vehic.angles_x *= -1;
 625         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 626
 627         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 628 }
 629
 630 void bumblebee_land(entity this)
 631 {
 632         float hgt;
 633
 634         hgt = vehicle_altitude(this, 512);
 635         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 636         this.angles_x *= 0.95;
 637         this.angles_z *= 0.95;
 638
 639         if(hgt < 16)
 640                 setthink(this, vehicles_think);
 641
 642         this.nextthink = time;
 643
 644         CSQCMODEL_AUTOUPDATE(this);
 645 }
 646
 647 void bumblebee_exit(entity this, int eject)
 648 {
 649         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 650         {
 651                 bumblebee_gunner_exit(this, eject);
 652                 return;
 653         }
 654
 655         settouch(this, vehicles_touch);
 656
 657         if(!IS_DEAD(this))
 658         {
 659                 setthink(this, bumblebee_land);
 660                 this.nextthink  = time;
 661         }
 662
 663         set_movetype(this, MOVETYPE_TOSS);
 664
 665         if(!this.owner)
 666                 return;
 667
 668         fixedmakevectors(this.angles);
 669         vector spot;
 670         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 671                 spot = this.origin + v_up * 128 + v_forward * 300;
 672         else
 673                 spot = this.origin + v_up * 128 - v_forward * 300;
 674
 675         spot = vehicles_findgoodexit(this, spot);
 676
 677         // Hide beam
 678         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 679                 this.gun3.enemy.effects |= EF_NODRAW;
 680
 681         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 682         this.owner.velocity_z += 10;
 683         setorigin(this.owner, spot);
 684
 685         antilag_clear(this.owner, CS(this.owner));
 686         this.owner = NULL;
 687 }
 688
 689 void bumblebee_blowup(entity this)
 690 {
 691         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 692                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 693                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 694                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 695                                  DEATH_VH_BUMB_DEATH.m_id, NULL);
 696
 697         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 698         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 699
 700         if(this.owner.deadflag == DEAD_DYING)
 701                 this.owner.deadflag = DEAD_DEAD;
 702
 703         remove(this);
 704 }
 705
 706 void bumblebee_dead_touch(entity this, entity toucher)
 707 {
 708         bumblebee_blowup(this);
 709 }
 710
 711 void bumblebee_diethink(entity this)
 712 {
 713         if(time >= this.wait)
 714                 setthink(this, bumblebee_blowup);
 715
 716         if(random() < 0.1)
 717         {
 718                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 719                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 720         }
 721
 722         this.nextthink = time + 0.1;
 723 }
 724
 725 spawnfunc(vehicle_bumblebee)
 726 {
 727         if(!autocvar_g_vehicle_bumblebee) { remove(this); return; }
 728         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { remove(this); return; }
 729 }
 730
 731 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 732 {
 733     if(autocvar_g_vehicle_bumblebee_bouncepain)
 734         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 735 }
 736 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 737 {
 738     settouch(instance, bumblebee_touch);
 739     instance.nextthink = 0;
 740     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 741 }
 742 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 743 {
 744         if(!instance.gunner1)
 745         if(time >= instance.gun1.phase)
 746         if(instance.gun1.vehicle_enter)
 747         if(instance.gun1.vehicle_enter(instance, actor))
 748                 return;
 749
 750         if(!instance.gunner2)
 751         if(time >= instance.gun2.phase)
 752         if(instance.gun2.vehicle_enter)
 753         if(instance.gun2.vehicle_enter(instance, actor))
 754                 return;
 755 }
 756 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 757 {
 758     instance.angles_z *= 0.8;
 759     instance.angles_x *= 0.8;
 760
 761     instance.nextthink = time;
 762
 763     if(!instance.owner)
 764     {
 765         if(instance.gunner1)
 766         {
 767                 entity e = instance.gunner1;
 768                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 769                 instance.phase = 0;
 770                 gettouch(instance)(instance, e);
 771                 return;
 772         }
 773
 774         if(instance.gunner2)
 775         {
 776                 entity e = instance.gunner2;
 777                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 778                 instance.phase = 0;
 779                 gettouch(instance)(instance, e);
 780             return;
 781         }
 782     }
 783 }
 784 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 785 {
 786         CSQCModel_UnlinkEntity(instance);
 787
 788         // hide beam
 789         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 790                 instance.gun3.enemy.effects |= EF_NODRAW;
 791
 792         if(instance.gunner1)
 793                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 794
 795         if(instance.gunner2)
 796                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 797
 798         instance.vehicle_exit(instance, VHEF_EJECT);
 799
 800     fixedmakevectors(instance.angles);
 801     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 802     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 803     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 804
 805     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 806
 807     if(random() > 0.5)
 808         settouch(_body, bumblebee_dead_touch);
 809     else
 810         settouch(_body, func_null);
 811
 812     setthink(_body, bumblebee_diethink);
 813     _body.nextthink = time;
 814     _body.wait = time + 2 + (random() * 8);
 815     _body.owner = instance;
 816     _body.enemy = instance.enemy;
 817     _body.scale = 1.5;
 818     _body.angles = instance.angles;
 819
 820     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 821
 822     instance.health                     = 0;
 823     instance.event_damage       = func_null;
 824     instance.solid                      = SOLID_NOT;
 825     instance.takedamage         = DAMAGE_NO;
 826     instance.deadflag           = DEAD_DYING;
 827     set_movetype(instance, MOVETYPE_NONE);
 828     instance.effects            = EF_NODRAW;
 829     instance.colormod           = '0 0 0';
 830     instance.avelocity          = '0 0 0';
 831     instance.velocity           = '0 0 0';
 832     settouch(instance, func_null);
 833     instance.nextthink          = 0;
 834
 835     setorigin(instance, instance.pos1);
 836 }
 837 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 838 {
 839     if(!instance.gun1)
 840     {
 841         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 842         instance.vehicle_shieldent = spawn();
 843         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 844         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 845         setattachment(instance.vehicle_shieldent, instance, "");
 846         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 847         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 848         setthink(instance.vehicle_shieldent, shieldhit_think);
 849         instance.vehicle_shieldent.alpha = -1;
 850         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 851
 852         instance.gun1 = new(vehicle_playerslot);
 853         instance.gun2 = new(vehicle_playerslot);
 854         instance.gun3 = new(bumblebee_raygun);
 855
 856         instance.vehicle_flags |= VHF_MULTISLOT;
 857
 858         instance.gun1.owner = instance;
 859         instance.gun2.owner = instance;
 860         instance.gun3.owner = instance;
 861
 862         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 863         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 864         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 865
 866         setattachment(instance.gun1, instance, "cannon_right");
 867         setattachment(instance.gun2, instance, "cannon_left");
 868
 869         // Angled bones are no fun, messes up gun-aim; so work arround it.
 870         instance.gun3.pos1 = instance.angles;
 871         instance.angles = '0 0 0';
 872         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 873         ofs -= instance.origin;
 874         setattachment(instance.gun3, instance, "");
 875         setorigin(instance.gun3, ofs);
 876         instance.angles = instance.gun3.pos1;
 877
 878         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 879         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 880
 881         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 882         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 883
 884         //fixme-model-bones
 885         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 886         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 887         //fixme-model-bones
 888         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 889         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 890
 891         instance.scale = 1.5;
 892
 893         // Raygun beam
 894         if(instance.gun3.enemy == NULL)
 895         {
 896             instance.gun3.enemy = spawn();
 897             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 898             instance.gun3.enemy.SendFlags = BRG_SETUP;
 899             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 900             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 901         }
 902     }
 903
 904     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 905     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 906     instance.solid = SOLID_BBOX;
 907     set_movetype(instance, MOVETYPE_TOSS);
 908     instance.damageforcescale = 0.025;
 909
 910     instance.PlayerPhysplug = bumblebee_pilot_frame;
 911
 912     setorigin(instance, instance.origin + '0 0 25');
 913 }
 914 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 915 {
 916     if(autocvar_g_vehicle_bumblebee_energy)
 917     if(autocvar_g_vehicle_bumblebee_energy_regen)
 918         instance.vehicle_flags |= VHF_ENERGYREGEN;
 919
 920     if(autocvar_g_vehicle_bumblebee_shield)
 921         instance.vehicle_flags |= VHF_HASSHIELD;
 922
 923     if(autocvar_g_vehicle_bumblebee_shield_regen)
 924         instance.vehicle_flags |= VHF_SHIELDREGEN;
 925
 926     if(autocvar_g_vehicle_bumblebee_health_regen)
 927         instance.vehicle_flags |= VHF_HEALTHREGEN;
 928
 929     instance.vehicle_exit = bumblebee_exit;
 930     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 931     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 932     instance.max_health = instance.vehicle_health;
 933     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 934 }
 935
 936 #endif // SVQC
 937 #ifdef CSQC
 938
 939 void CSQC_BUMBLE_GUN_HUD()
 940 {
 941         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 942                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 943                                          string_null, '0 0 0');
 944 }
 945
 946 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 947 {
 948     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 949                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 950                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 951
 952     float hudAlpha = autocvar_hud_panel_fg_alpha;
 953     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 954     vector tmpPos  = '0 0 0';
 955     vector tmpSize = '1 1 1' * hud_fontsize;
 956     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 957
 958     if(!AuxiliaryXhair[1].draw2d)
 959     {
 960         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 961         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 962     }
 963
 964     if(!AuxiliaryXhair[2].draw2d)
 965     {
 966         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 967         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 968     }
 969 }
 970 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 971 {
 972     Vehicles_drawCrosshair(vCROSS_HEAL);
 973 }
 974 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 975 {
 976     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 977     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 978     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 979 }
 980
 981 #endif
 982 #endif