qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #include "bumblebee.qh"
   2
   3 const float BRG_SETUP = 2;
   4 const float BRG_START = 4;
   5 const float BRG_END = 8;
   6
   7 #ifdef SVQC
   8 float autocvar_g_vehicle_bumblebee_respawntime = 60;
   9
  10 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  11 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  12 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  13 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  14 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  15 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  16 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  17 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  18 bool autocvar_g_vehicle_bumblebee_swim = false;
  19
  20 float autocvar_g_vehicle_bumblebee_energy = 500;
  21 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  22 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  23
  24 float autocvar_g_vehicle_bumblebee_health = 1000;
  25 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  26 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  27
  28 float autocvar_g_vehicle_bumblebee_shield = 400;
  29 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  30 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  31
  32 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  33 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  34 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  37
  38 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  39 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  40 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  41 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  42 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  43
  44
  45 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  46 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  47 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  48 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  49
  50 bool autocvar_g_vehicle_bumblebee_raygun = false;
  51 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  52 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  53 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  54 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  55
  56 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  57 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  58 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  59 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  60 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  61 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  62
  63 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  64 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  65 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  66 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  67 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  68
  69 bool autocvar_g_vehicle_bumblebee = true;
  70
  71 bool bumblebee_gunner_frame(entity this, float dt)
  72 {
  73         entity vehic = this.vehicle.owner;
  74         entity gun = this.vehicle;
  75         return = true;
  76
  77         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
  78         //vehicles_frame(gun, player);
  79
  80         vehic.solid = SOLID_NOT;
  81         //setorigin(this, vehic.origin);
  82         this.velocity = vehic.velocity;
  83
  84         float _in, _out;
  85         vehic.angles_x *= -1;
  86         makevectors(vehic.angles);
  87         vehic.angles_x *= -1;
  88         if(gun == vehic.gun1)
  89         {
  90                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  91                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  92                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
  93         }
  94         else
  95         {
  96                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  97                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  98                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
  99         }
 100         this.oldorigin = this.origin; // negate fall damage
 101
 102         crosshair_trace(this);
 103         vector _ct = trace_endpos;
 104         vector ad;
 105
 106         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 107         {
 108                 if(gun.lock_time < time)
 109                         gun.enemy = NULL;
 110
 111                 if(trace_ent)
 112                         if(trace_ent.move_movetype)
 113                                 if(trace_ent.takedamage)
 114                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 115                                         {
 116                                                 if(DIFF_TEAM(trace_ent, this))
 117                                                 {
 118                                                         gun.enemy = trace_ent;
 119                                                         gun.lock_time = time + 5;
 120                                                 }
 121                                         }
 122         }
 123
 124         if(gun.enemy)
 125         {
 126                 float distance, impact_time;
 127
 128                 vector vf = real_origin(gun.enemy);
 129                 vector _vel = gun.enemy.velocity;
 130                 if(gun.enemy.move_movetype == MOVETYPE_WALK)
 131                         _vel.z *= 0.1;
 132
 133
 134                 ad = vf;
 135                 distance = vlen(ad - this.origin);
 136                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 137                 ad = vf + _vel * impact_time;
 138                 trace_endpos = ad;
 139
 140
 141                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 142                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 143                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 144                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 145
 146         }
 147         else
 148                 vehicle_aimturret(vehic, _ct, gun, "fire",
 149                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 150                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 151
 152         if(!forbidWeaponUse(this))
 153         if(PHYS_INPUT_BUTTON_ATCK(this))
 154                 if(time > gun.attack_finished_single[0])
 155                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 156                         {
 157                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 158                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 159                                 gun.delay = time;
 160                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 161                         }
 162
 163         VEHICLE_UPDATE_PLAYER_RESOURCE(this, vehic, health, bumblebee, RESOURCE_HEALTH);
 164
 165         if(vehic.vehicle_flags & VHF_HASSHIELD)
 166                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 167
 168         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 169         traceline(ad, ad + v_forward * max_shot_distance, MOVE_NORMAL, gun);
 170
 171         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 172
 173         if(vehic.owner)
 174                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 175
 176         vehic.solid = SOLID_BBOX;
 177         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 178         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 179 }
 180
 181 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 182 {
 183         //vector exitspot;
 184         float mysize;
 185
 186         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, player), STAT(PL_MAX, player), prefer_spot, MOVE_NORMAL, player);
 187         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 188                 return prefer_spot;
 189
 190         mysize = 1.5 * vlen(STAT(PL_MAX, player) - STAT(PL_MIN, player)); // can't use gunner's size, as they don't have a size
 191         float i;
 192         vector v, v2;
 193         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 194         for(i = 0; i < 100; ++i)
 195         {
 196                 v = randomvec();
 197                 v_z = 0;
 198                 v = v2 + normalize(v) * mysize;
 199                 tracebox(v2, STAT(PL_MIN, player), STAT(PL_MAX, player), v, MOVE_NORMAL, player);
 200                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 201                         return v;
 202         }
 203
 204         return prefer_spot; // this should be considered a fallback?!
 205 }
 206
 207 void bumblebee_gunner_exit(entity this, int _exitflag)
 208 {
 209         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 210         entity gunner = this;
 211         entity vehic = gunner.owner;
 212
 213         if(IS_REAL_CLIENT(player))
 214         {
 215                 msg_entity = player;
 216                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 217                 WriteEntity(MSG_ONE, player);
 218
 219                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 220                 WriteAngle(MSG_ONE, 0);
 221                 WriteAngle(MSG_ONE, vehic.angles.y);
 222                 WriteAngle(MSG_ONE, 0);
 223         }
 224
 225         CSQCVehicleSetup(player, HUD_NORMAL);
 226         setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
 227
 228         player.takedamage     = DAMAGE_AIM;
 229         player.solid          = SOLID_SLIDEBOX;
 230         set_movetype(player, MOVETYPE_WALK);
 231         player.effects       &= ~EF_NODRAW;
 232         player.alpha          = 1;
 233         player.PlayerPhysplug = func_null;
 234         player.view_ofs       = STAT(PL_VIEW_OFS, player);
 235         player.event_damage   = PlayerDamage;
 236         STAT(HUD, player)     = HUD_NORMAL;
 237         player.teleportable       = TELEPORT_NORMAL;
 238         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 239         {
 240                 .entity weaponentity = weaponentities[slot];
 241                 player.(weaponentity).m_switchweapon = gunner.(weaponentity).m_switchweapon;
 242                 delete(gunner.(weaponentity));
 243         }
 244         player.vehicle_enter_delay = time + 2;
 245
 246         fixedmakevectors(vehic.angles);
 247
 248         if(player == vehic.gunner1) { vehic.gunner1 = NULL; }
 249         if(player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 250
 251         vector spot = real_origin(gunner);
 252         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 253         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 254
 255         // TODO: figure a way to move player out of the gunner
 256
 257         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 258         player.velocity_z += 10;
 259
 260         gunner.phase = time + 5;
 261         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 262
 263         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 264
 265         player.vehicle = NULL;
 266 }
 267
 268 bool bumblebee_gunner_enter(entity this, entity player)
 269 {
 270         entity vehic = this;
 271         entity gunner = NULL;
 272
 273         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 274         {
 275                 // we can have some fun
 276                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 277                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 278                 if(vlen2(player.origin - v1) < vlen2(player.origin - v2))
 279                 {
 280                         gunner = vehic.gun1;
 281                         vehic.gunner1 = player;
 282                 }
 283                 else
 284                 {
 285                         gunner = vehic.gun2;
 286                         vehic.gunner2 = player;
 287                 }
 288         }
 289         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 290         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 291         else { LOG_TRACE("Vehicle is full, fail"); return false; }
 292
 293         player.vehicle                  = gunner;
 294         player.angles                   = vehic.angles;
 295         player.takedamage               = DAMAGE_NO;
 296         player.solid                    = SOLID_NOT;
 297         player.alpha                    = -1;
 298         set_movetype(player, MOVETYPE_NOCLIP);
 299         player.event_damage     = func_null;
 300         player.view_ofs                 = '0 0 0';
 301         STAT(HUD, player)               = STAT(HUD, gunner);
 302         player.teleportable     = false;
 303         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 304         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 305         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 306         player.vehicle_reload1  = vehic.vehicle_reload1;
 307         player.vehicle_reload2  = vehic.vehicle_reload2;
 308         player.vehicle_energy   = vehic.vehicle_energy;
 309         UNSET_ONGROUND(player);
 310
 311         RemoveGrapplingHooks(player);
 312
 313         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 314         {
 315                 .entity weaponentity = weaponentities[slot];
 316
 317                 gunner.(weaponentity) = new(temp_wepent);
 318                 gunner.(weaponentity).m_switchweapon = player.(weaponentity).m_switchweapon;
 319         }
 320         gunner.vehicle_exit = bumblebee_gunner_exit;
 321         gunner.vehicle_hudmodel.viewmodelforclient = player;
 322
 323         if(IS_REAL_CLIENT(player))
 324         {
 325                 msg_entity = player;
 326                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 327                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 328
 329                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 330                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 331                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 332                 WriteAngle(MSG_ONE,     0); // roll
 333         }
 334
 335         CSQCVehicleSetup(player, STAT(HUD, player));
 336
 337         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 338
 339         return true;
 340 }
 341
 342 bool vehicles_valid_pilot(entity this, entity toucher)
 343 {
 344         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 345                 return false;
 346
 347         if((!IS_PLAYER(toucher))
 348         || (IS_DEAD(toucher))
 349         || (toucher.vehicle)
 350         || (DIFF_TEAM(toucher, this))
 351         ) { return false; }
 352
 353         return true;
 354 }
 355
 356 void bumblebee_touch(entity this, entity toucher)
 357 {
 358         if(autocvar_g_vehicles_enter) { return; }
 359
 360         if(this.gunner1 != NULL && this.gunner2 != NULL)
 361         {
 362                 vehicles_touch(this, toucher);
 363                 return;
 364         }
 365
 366         if(vehicles_valid_pilot(this, toucher))
 367         {
 368                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 369
 370                 if(time >= toucher.vehicle_enter_delay && phase_time)
 371                 if(bumblebee_gunner_enter(this, toucher))
 372                         return;
 373         }
 374
 375         vehicles_touch(this, toucher);
 376 }
 377
 378 void bumblebee_regen(entity this, float dt)
 379 {
 380         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 381                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 382                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 383
 384         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 385                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 386                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 387
 388         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 389                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, dt, true);
 390
 391         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 392                 vehicles_regen_resource(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, dt, false, RESOURCE_HEALTH);
 393
 394         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 395                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, dt, false);
 396
 397 }
 398
 399 bool bumblebee_pilot_frame(entity this, float dt)
 400 {
 401         entity vehic = this.vehicle;
 402         return = true;
 403
 404         if(game_stopped)
 405         {
 406                 vehic.solid = SOLID_NOT;
 407                 vehic.takedamage = DAMAGE_NO;
 408                 set_movetype(vehic, MOVETYPE_NONE);
 409                 return;
 410         }
 411
 412         vehicles_frame(vehic, this);
 413
 414         if(IS_DEAD(vehic))
 415         {
 416                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 417                 return;
 418         }
 419
 420         bumblebee_regen(vehic, dt);
 421
 422         crosshair_trace(this);
 423
 424         vector vang = vehic.angles;
 425         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 426         vang.x *= -1;
 427         newvel.x *= -1;
 428         if(newvel.x > 180)  newvel.x -= 360;
 429         if(newvel.x < -180) newvel.x += 360;
 430         if(newvel.y > 180)  newvel.y -= 360;
 431         if(newvel.y < -180) newvel.y += 360;
 432
 433         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 434         if(ftmp > 180)  ftmp -= 360;
 435         if(ftmp < -180) ftmp += 360;
 436         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 437
 438         // Pitch
 439         ftmp = 0;
 440         if(CS(this).movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 441                 ftmp = 4;
 442         else if(CS(this).movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 443                 ftmp = -8;
 444
 445         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 446         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 447         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 448
 449         vehic.angles_x = anglemods(vehic.angles.x);
 450         vehic.angles_y = anglemods(vehic.angles.y);
 451         vehic.angles_z = anglemods(vehic.angles.z);
 452
 453         makevectors('0 1 0' * vehic.angles.y);
 454         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 455
 456         if(CS(this).movement.x != 0)
 457         {
 458                 if(CS(this).movement.x > 0)
 459                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 460                 else if(CS(this).movement.x < 0)
 461                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 462         }
 463
 464         if(CS(this).movement.y != 0)
 465         {
 466                 if(CS(this).movement.y < 0)
 467                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 468                 else if(CS(this).movement.y > 0)
 469                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 470                 ftmp = newvel * v_right;
 471                 ftmp *= dt * 0.1;
 472                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 473         }
 474         else
 475         {
 476                 vehic.angles_z *= 0.95;
 477                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 478                         vehic.angles_z = 0;
 479         }
 480
 481         if(PHYS_INPUT_BUTTON_CROUCH(this))
 482                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 483         else if(PHYS_INPUT_BUTTON_JUMP(this))
 484                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 485
 486         vehic.velocity  += newvel * dt;
 487         this.velocity = CS(this).movement  = vehic.velocity;
 488
 489
 490         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 491         {
 492                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 493                         vehic.tur_head.enemy = NULL;
 494
 495                 if(trace_ent)
 496                 if(trace_ent.move_movetype)
 497                 if(trace_ent.takedamage)
 498                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 499                 {
 500                         if(teamplay)
 501                         {
 502                                 if(trace_ent.team == this.team)
 503                                 {
 504                                         vehic.tur_head.enemy = trace_ent;
 505                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 506                                 }
 507                         }
 508                         else
 509                         {
 510                                 vehic.tur_head.enemy = trace_ent;
 511                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 512                         }
 513                 }
 514
 515                 if(vehic.tur_head.enemy)
 516                 {
 517                         trace_endpos = real_origin(vehic.tur_head.enemy);
 518                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 519                 }
 520         }
 521
 522         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 523                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 524                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 525
 526         if(!forbidWeaponUse(this))
 527         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME || autocvar_g_vehicle_bumblebee_raygun == 0))
 528         {
 529                 vehic.gun3.enemy.realowner = this;
 530                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 531
 532                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 533                 vehic.gun3.enemy.SendFlags |= BRG_START;
 534
 535                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 536
 537                 if(trace_ent)
 538                 {
 539                         if(autocvar_g_vehicle_bumblebee_raygun)
 540                         {
 541                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME, DEATH_GENERIC.m_id, DMG_NOWEP, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * PHYS_INPUT_FRAMETIME);
 542                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * PHYS_INPUT_FRAMETIME;
 543                         }
 544                         else
 545                         {
 546                                 if(!IS_DEAD(trace_ent))
 547                                 {
 548                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 549                                         {
 550                                                 if(autocvar_g_vehicle_bumblebee_healgun_hps)
 551                                                 {
 552                                                         float hplimit = ((IS_PLAYER(trace_ent)) ? autocvar_g_vehicle_bumblebee_healgun_hmax : RESOURCE_LIMIT_NONE);
 553                                                         Heal(trace_ent, this, autocvar_g_vehicle_bumblebee_healgun_hps * dt, hplimit);
 554                                                 }
 555
 556                                                 if(IS_VEHICLE(trace_ent))
 557                                                 {
 558                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && GetResourceAmount(trace_ent, RESOURCE_HEALTH) <= trace_ent.max_health)
 559                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * dt, trace_ent.tur_head.max_health);
 560                                                 }
 561                                                 else if(IS_CLIENT(trace_ent))
 562                                                 {
 563                                                         if(GetResourceAmount(trace_ent, RESOURCE_ARMOR) <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 564                                                                 GiveResourceWithLimit(trace_ent, RESOURCE_ARMOR, autocvar_g_vehicle_bumblebee_healgun_aps * dt, autocvar_g_vehicle_bumblebee_healgun_amax);
 565                                                 }
 566                                         }
 567                                 }
 568                         }
 569                 }
 570
 571                 vehic.gun3.enemy.hook_end = trace_endpos;
 572                 setorigin(vehic.gun3.enemy, trace_endpos);
 573                 vehic.gun3.enemy.SendFlags |= BRG_END;
 574
 575                 vehic.wait = time + 1;
 576         }
 577         else
 578                 vehic.gun3.enemy.effects |= EF_NODRAW;
 579         /*{
 580                 if(vehic.gun3.enemy)
 581                         remove(vehic.gun3.enemy);
 582
 583                 vehic.gun3.enemy = NULL;
 584         }
 585         */
 586
 587         VEHICLE_UPDATE_PLAYER_RESOURCE(this, vehic, health, bumblebee, RESOURCE_HEALTH);
 588         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 589
 590         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 591         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 592
 593         if(vehic.vehicle_flags & VHF_HASSHIELD)
 594                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 595
 596         vehic.angles_x *= -1;
 597         makevectors(vehic.angles);
 598         vehic.angles_x *= -1;
 599         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 600         this.oldorigin = this.origin; // negate fall damage
 601
 602         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 603 }
 604
 605 void bumblebee_land(entity this)
 606 {
 607         float hgt;
 608
 609         hgt = vehicle_altitude(this, 512);
 610         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
 611         this.angles_x *= 0.95;
 612         this.angles_z *= 0.95;
 613
 614         if(hgt < 16)
 615                 setthink(this, vehicles_think);
 616
 617         this.nextthink = time;
 618
 619         CSQCMODEL_AUTOUPDATE(this);
 620 }
 621
 622 void bumblebee_exit(entity this, int eject)
 623 {
 624         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 625         {
 626                 bumblebee_gunner_exit(this, eject);
 627                 return;
 628         }
 629
 630         settouch(this, vehicles_touch);
 631
 632         if(!IS_DEAD(this))
 633         {
 634                 setthink(this, bumblebee_land);
 635                 this.nextthink  = time;
 636         }
 637
 638         set_movetype(this, MOVETYPE_TOSS);
 639
 640         if(!this.owner)
 641                 return;
 642
 643         fixedmakevectors(this.angles);
 644         vector spot;
 645         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 646                 spot = this.origin + v_up * 128 + v_forward * 300;
 647         else
 648                 spot = this.origin + v_up * 128 - v_forward * 300;
 649
 650         spot = vehicles_findgoodexit(this, this.owner, spot);
 651
 652         // Hide beam
 653         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 654                 this.gun3.enemy.effects |= EF_NODRAW;
 655
 656         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 657         this.owner.velocity_z += 10;
 658         setorigin(this.owner, spot);
 659
 660         antilag_clear(this.owner, CS(this.owner));
 661         this.owner = NULL;
 662 }
 663
 664 void bumblebee_blowup(entity this)
 665 {
 666         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 667                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 668                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 669                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 670                                  DEATH_VH_BUMB_DEATH.m_id, DMG_NOWEP, NULL);
 671
 672         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 673         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 674
 675         if(this.owner.deadflag == DEAD_DYING)
 676                 this.owner.deadflag = DEAD_DEAD;
 677
 678         delete(this);
 679 }
 680
 681 void bumblebee_dead_touch(entity this, entity toucher)
 682 {
 683         bumblebee_blowup(this);
 684 }
 685
 686 void bumblebee_diethink(entity this)
 687 {
 688         if(time >= this.wait)
 689                 setthink(this, bumblebee_blowup);
 690
 691         if(random() < 0.1)
 692         {
 693                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 694                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 695         }
 696
 697         this.nextthink = time + 0.1;
 698 }
 699
 700 spawnfunc(vehicle_bumblebee)
 701 {
 702         if(!autocvar_g_vehicle_bumblebee) { delete(this); return; }
 703         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { delete(this); return; }
 704 }
 705
 706 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 707 {
 708     if(autocvar_g_vehicle_bumblebee_bouncepain)
 709         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 710 }
 711 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 712 {
 713     settouch(instance, bumblebee_touch);
 714     instance.nextthink = 0;
 715     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 716 }
 717 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 718 {
 719         if(!instance.gunner1)
 720         if(time >= instance.gun1.phase)
 721         if(instance.gun1.vehicle_enter)
 722         if(instance.gun1.vehicle_enter(instance, actor))
 723                 return;
 724
 725         if(!instance.gunner2)
 726         if(time >= instance.gun2.phase)
 727         if(instance.gun2.vehicle_enter)
 728         if(instance.gun2.vehicle_enter(instance, actor))
 729                 return;
 730 }
 731 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 732 {
 733     instance.angles_z *= 0.8;
 734     instance.angles_x *= 0.8;
 735
 736     instance.nextthink = time;
 737
 738     if(!instance.owner)
 739     {
 740         if(instance.gunner1)
 741         {
 742                 entity e = instance.gunner1;
 743                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 744                 instance.phase = 0;
 745                 gettouch(instance)(instance, e);
 746                 return;
 747         }
 748
 749         if(instance.gunner2)
 750         {
 751                 entity e = instance.gunner2;
 752                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 753                 instance.phase = 0;
 754                 gettouch(instance)(instance, e);
 755             return;
 756         }
 757     }
 758 }
 759 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 760 {
 761         CSQCModel_UnlinkEntity(instance);
 762
 763         // hide beam
 764         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 765                 instance.gun3.enemy.effects |= EF_NODRAW;
 766
 767         if(instance.gunner1)
 768                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 769
 770         if(instance.gunner2)
 771                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 772
 773         instance.vehicle_exit(instance, VHEF_EJECT);
 774
 775     fixedmakevectors(instance.angles);
 776     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 777     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 778     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 779
 780     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 781
 782     if(random() > 0.5)
 783         settouch(_body, bumblebee_dead_touch);
 784     else
 785         settouch(_body, func_null);
 786
 787     setthink(_body, bumblebee_diethink);
 788     _body.nextthink = time;
 789     _body.wait = time + 2 + (random() * 8);
 790     _body.owner = instance;
 791     _body.enemy = instance.enemy;
 792     _body.scale = 1.5;
 793     _body.angles = instance.angles;
 794
 795     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 796
 797     SetResourceAmountExplicit(instance, RESOURCE_HEALTH, 0);
 798     instance.event_damage       = func_null;
 799     instance.solid                      = SOLID_NOT;
 800     instance.takedamage         = DAMAGE_NO;
 801     instance.deadflag           = DEAD_DYING;
 802     set_movetype(instance, MOVETYPE_NONE);
 803     instance.effects            = EF_NODRAW;
 804     instance.colormod           = '0 0 0';
 805     instance.avelocity          = '0 0 0';
 806     instance.velocity           = '0 0 0';
 807     settouch(instance, func_null);
 808     instance.nextthink          = 0;
 809
 810     setorigin(instance, instance.pos1);
 811 }
 812 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 813 {
 814     if(!instance.gun1)
 815     {
 816         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 817         instance.vehicle_shieldent = spawn();
 818         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 819         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 820         setattachment(instance.vehicle_shieldent, instance, "");
 821         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 822         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 823         setthink(instance.vehicle_shieldent, shieldhit_think);
 824         instance.vehicle_shieldent.alpha = -1;
 825         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 826
 827         instance.gun1 = new(vehicle_playerslot);
 828         instance.gun2 = new(vehicle_playerslot);
 829         instance.gun3 = new(bumblebee_raygun);
 830
 831         instance.vehicle_flags |= VHF_MULTISLOT;
 832
 833         instance.gun1.owner = instance;
 834         instance.gun2.owner = instance;
 835         instance.gun3.owner = instance;
 836
 837         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 838         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 839         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 840
 841         setattachment(instance.gun1, instance, "cannon_right");
 842         setattachment(instance.gun2, instance, "cannon_left");
 843
 844         // Angled bones are no fun, messes up gun-aim; so work arround it.
 845         instance.gun3.pos1 = instance.angles;
 846         instance.angles = '0 0 0';
 847         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 848         ofs -= instance.origin;
 849         setattachment(instance.gun3, instance, "");
 850         setorigin(instance.gun3, ofs);
 851         instance.angles = instance.gun3.pos1;
 852
 853         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 854         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 855
 856         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 857         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 858
 859         //fixme-model-bones
 860         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 861         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 862         //fixme-model-bones
 863         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 864         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 865
 866         instance.scale = 1.5;
 867
 868         // Raygun beam
 869         if(instance.gun3.enemy == NULL)
 870         {
 871             instance.gun3.enemy = spawn();
 872             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 873             instance.gun3.enemy.SendFlags = BRG_SETUP;
 874             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 875             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 876         }
 877     }
 878
 879     if(!autocvar_g_vehicle_bumblebee_swim)
 880         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 881
 882     SetResourceAmountExplicit(instance, RESOURCE_HEALTH, autocvar_g_vehicle_bumblebee_health);
 883     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 884     instance.solid = SOLID_BBOX;
 885     set_movetype(instance, MOVETYPE_TOSS);
 886     instance.damageforcescale = 0.025;
 887
 888     instance.PlayerPhysplug = bumblebee_pilot_frame;
 889
 890     setorigin(instance, instance.origin + '0 0 25');
 891 }
 892 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 893 {
 894     if(autocvar_g_vehicle_bumblebee_energy)
 895     if(autocvar_g_vehicle_bumblebee_energy_regen)
 896         instance.vehicle_flags |= VHF_ENERGYREGEN;
 897
 898     if(autocvar_g_vehicle_bumblebee_shield)
 899         instance.vehicle_flags |= VHF_HASSHIELD;
 900
 901     if(autocvar_g_vehicle_bumblebee_shield_regen)
 902         instance.vehicle_flags |= VHF_SHIELDREGEN;
 903
 904     if(autocvar_g_vehicle_bumblebee_health_regen)
 905         instance.vehicle_flags |= VHF_HEALTHREGEN;
 906
 907     instance.vehicle_exit = bumblebee_exit;
 908     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 909     SetResourceAmountExplicit(instance, RESOURCE_HEALTH, autocvar_g_vehicle_bumblebee_health);
 910     instance.max_health = GetResourceAmount(instance, RESOURCE_HEALTH);
 911     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 912 }
 913
 914 #endif // SVQC
 915 #ifdef CSQC
 916
 917 void CSQC_BUMBLE_GUN_HUD()
 918 {
 919         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 920                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 921                                          string_null, '0 0 0');
 922 }
 923
 924 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 925 {
 926     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 927                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 928                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 929
 930     float hudAlpha = autocvar_hud_panel_fg_alpha;
 931     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 932     vector tmpPos  = '0 0 0';
 933     vector tmpSize = '1 1 1' * hud_fontsize;
 934     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 935
 936     if(!AuxiliaryXhair[1].draw2d)
 937     {
 938         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 939         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 940     }
 941
 942     if(!AuxiliaryXhair[2].draw2d)
 943     {
 944         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 945         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 946     }
 947 }
 948 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 949 {
 950     Vehicles_drawCrosshair(vCROSS_HEAL);
 951 }
 952 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 953 {
 954     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 955     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 956     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 957 }
 958
 959 #endif