qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #ifndef VEHICLE_BUMBLEBEE
   2 #define VEHICLE_BUMBLEBEE
   3 #include "bumblebee.qh"
   4
   5 #include "bumblebee_weapons.qc"
   6
   7 CLASS(Bumblebee, Vehicle)
   8 /* spawnflags */ ATTRIB(Bumblebee, spawnflags, int, VHF_DMGSHAKE);
   9 /* mins       */ ATTRIB(Bumblebee, mins, vector, '-245 -130 -130');
  10 /* maxs       */ ATTRIB(Bumblebee, maxs, vector, '230 130 130');
  11 /* view offset*/ ATTRIB(Bumblebee, view_ofs, vector, '0 0 300');
  12 /* view dist  */ ATTRIB(Bumblebee, height, float, 450);
  13 /* model          */ ATTRIB(Bumblebee, mdl, string, "models/vehicles/bumblebee_body.dpm");
  14 /* model          */ ATTRIB(Bumblebee, model, string, "models/vehicles/bumblebee_body.dpm");
  15 /* head_model */ ATTRIB(Bumblebee, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Bumblebee, hud_model, string, "models/vehicles/spiderbot_cockpit.dpm");
  17 /* tags       */ ATTRIB(Bumblebee, tag_head, string, "");
  18 /* tags       */ ATTRIB(Bumblebee, tag_hud, string, "");
  19 /* tags       */ ATTRIB(Bumblebee, tag_view, string, "tag_viewport");
  20 /* netname    */ ATTRIB(Bumblebee, netname, string, "bumblebee");
  21 /* fullname   */ ATTRIB(Bumblebee, vehicle_name, string, _("Bumblebee"));
  22 /* icon       */ ATTRIB(Bumblebee, m_icon, string, "vehicle_bumble");
  23 ENDCLASS(Bumblebee)
  24 REGISTER_VEHICLE(BUMBLEBEE, NEW(Bumblebee));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 const float BRG_SETUP = 2;
  31 const float BRG_START = 4;
  32 const float BRG_END = 8;
  33
  34 #include "bumblebee_weapons.qc"
  35
  36 #ifdef SVQC
  37 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  38
  39 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  40 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  41 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  42 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  43 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  44 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  45 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  46 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  47
  48 float autocvar_g_vehicle_bumblebee_energy = 500;
  49 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  50 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  51
  52 float autocvar_g_vehicle_bumblebee_health = 1000;
  53 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  54 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  55
  56 float autocvar_g_vehicle_bumblebee_shield = 400;
  57 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  58 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  59
  60 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  61 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  62 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  63
  64 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  65
  66 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  67 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  68 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  69 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  70 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  71
  72
  73 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  74 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  75 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  76 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  77
  78 bool autocvar_g_vehicle_bumblebee_raygun = false;
  79 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  80 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  81 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  82 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  83
  84 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  85 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  86 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  87 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  88 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  89 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  90
  91 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  92 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  93 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  94 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  95 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  96
  97 bool autocvar_g_vehicle_bumblebee = true;
  98
  99 bool bumblebee_gunner_frame(entity this)
 100 {
 101         entity vehic = this.vehicle.owner;
 102         entity gun = this.vehicle;
 103         return = true;
 104
 105         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
 106         //vehicles_frame(gun, player);
 107
 108         vehic.solid = SOLID_NOT;
 109         //setorigin(this, vehic.origin);
 110         this.velocity = vehic.velocity;
 111
 112         float _in, _out;
 113         vehic.angles_x *= -1;
 114         makevectors(vehic.angles);
 115         vehic.angles_x *= -1;
 116         if(gun == vehic.gun1)
 117         {
 118                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 119                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 120                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 121         }
 122         else
 123         {
 124                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 125                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 126                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 127         }
 128
 129         crosshair_trace(this);
 130         vector _ct = trace_endpos;
 131         vector ad;
 132
 133         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 134         {
 135                 if(gun.lock_time < time)
 136                         gun.enemy = world;
 137
 138                 if(trace_ent)
 139                         if(trace_ent.movetype)
 140                                 if(trace_ent.takedamage)
 141                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 142                                         {
 143                                                 if(DIFF_TEAM(trace_ent, this))
 144                                                 {
 145                                                         gun.enemy = trace_ent;
 146                                                         gun.lock_time = time + 5;
 147                                                 }
 148                                         }
 149         }
 150
 151         if(gun.enemy)
 152         {
 153                 float distance, impact_time;
 154
 155                 vector vf = real_origin(gun.enemy);
 156                 vector _vel = gun.enemy.velocity;
 157                 if(gun.enemy.movetype == MOVETYPE_WALK)
 158                         _vel.z *= 0.1;
 159
 160
 161                 ad = vf;
 162                 distance = vlen(ad - this.origin);
 163                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 164                 ad = vf + _vel * impact_time;
 165                 trace_endpos = ad;
 166
 167
 168                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 169                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 170                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 171                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 172
 173         }
 174         else
 175                 vehicle_aimturret(vehic, _ct, gun, "fire",
 176                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 177                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 178
 179         if(!forbidWeaponUse(this))
 180         if(PHYS_INPUT_BUTTON_ATCK(this))
 181                 if(time > gun.attack_finished_single[0])
 182                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 183                         {
 184                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 185                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 186                                 gun.delay = time;
 187                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 188                         }
 189
 190         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 191
 192         if(vehic.vehicle_flags & VHF_HASSHIELD)
 193                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 194
 195         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 196         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 197
 198         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 199
 200         if(vehic.owner)
 201                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 202
 203         vehic.solid = SOLID_BBOX;
 204         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 205         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 206 }
 207
 208 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 209 {
 210         //vector exitspot;
 211         float mysize;
 212
 213         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 214         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 215                 return prefer_spot;
 216
 217         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 218         float i;
 219         vector v, v2;
 220         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 221         for(i = 0; i < 100; ++i)
 222         {
 223                 v = randomvec();
 224                 v_z = 0;
 225                 v = v2 + normalize(v) * mysize;
 226                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 227                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 228                         return v;
 229         }
 230
 231         return prefer_spot; // this should be considered a fallback?!
 232 }
 233
 234 void bumblebee_gunner_exit(int _exitflag)
 235 {SELFPARAM();
 236         entity player = self;
 237         entity gunner = player.vehicle;
 238         entity vehic = gunner.owner;
 239
 240         if(IS_REAL_CLIENT(player))
 241         {
 242                 msg_entity = player;
 243                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 244                 WriteEntity(MSG_ONE, player);
 245
 246                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 247                 WriteAngle(MSG_ONE, 0);
 248                 WriteAngle(MSG_ONE, vehic.angles.y);
 249                 WriteAngle(MSG_ONE, 0);
 250         }
 251
 252         CSQCVehicleSetup(player, HUD_NORMAL);
 253         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 254
 255         player.takedamage     = DAMAGE_AIM;
 256         player.solid          = SOLID_SLIDEBOX;
 257         player.movetype       = MOVETYPE_WALK;
 258         player.effects       &= ~EF_NODRAW;
 259         player.alpha          = 1;
 260         player.PlayerPhysplug = func_null;
 261         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 262         player.event_damage   = PlayerDamage;
 263         player.hud            = HUD_NORMAL;
 264         player.teleportable       = TELEPORT_NORMAL;
 265         PS(player).m_switchweapon = gunner.m_switchweapon;
 266         player.vehicle_enter_delay = time + 2;
 267
 268         fixedmakevectors(vehic.angles);
 269
 270         if(player == vehic.gunner1) { vehic.gunner1 = world; }
 271         if(player == vehic.gunner2) { vehic.gunner2 = world; v_right *= -1; }
 272
 273         vector spot = real_origin(gunner);
 274         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 275         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 276
 277         // TODO: figure a way to move player out of the gunner
 278
 279         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 280         player.velocity_z += 10;
 281
 282         gunner.phase = time + 5;
 283         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 284
 285         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 286
 287         player.vehicle = world;
 288 }
 289
 290 bool bumblebee_gunner_enter()
 291 {SELFPARAM();
 292         entity vehic = self;
 293         entity player = other;
 294         entity gunner = world;
 295
 296         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 297         {
 298                 // we can have some fun
 299                 if(vlen2(real_origin(vehic.gun2) - player.origin) < vlen2(real_origin(vehic.gun1) - player.origin))
 300                 {
 301                         gunner = vehic.gun2;
 302                         vehic.gunner2 = player;
 303                 }
 304                 else
 305                 {
 306                         gunner = vehic.gun1;
 307                         vehic.gunner1 = player;
 308                 }
 309         }
 310         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 311         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 312         else { LOG_TRACE("Vehicle is full, fail\n"); return false; }
 313
 314         player.vehicle                  = gunner;
 315         player.angles                   = vehic.angles;
 316         player.takedamage               = DAMAGE_NO;
 317         player.solid                    = SOLID_NOT;
 318         player.alpha                    = -1;
 319         player.movetype                 = MOVETYPE_NOCLIP;
 320         player.event_damage     = func_null;
 321         player.view_ofs                 = '0 0 0';
 322         player.hud                              = gunner.hud;
 323         player.teleportable     = false;
 324         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 325         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 326         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 327         player.vehicle_reload1  = vehic.vehicle_reload1;
 328         player.vehicle_reload2  = vehic.vehicle_reload2;
 329         player.vehicle_energy   = vehic.vehicle_energy;
 330         player.flags               &= ~FL_ONGROUND;
 331
 332         RemoveGrapplingHook(player);
 333
 334         gunner.m_switchweapon = PS(player).m_switchweapon;
 335         gunner.vehicle_exit = bumblebee_gunner_exit;
 336         gunner.vehicle_hudmodel.viewmodelforclient = player;
 337
 338         if(IS_REAL_CLIENT(player))
 339         {
 340                 msg_entity = player;
 341                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 342                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 343
 344                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 345                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 346                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 347                 WriteAngle(MSG_ONE,     0); // roll
 348         }
 349
 350         CSQCVehicleSetup(player, player.hud);
 351
 352         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 353
 354         return true;
 355 }
 356
 357 bool vehicles_valid_pilot()
 358 {SELFPARAM();
 359         if(IS_BOT_CLIENT(other) && !autocvar_g_vehicles_allow_bots)
 360                 return false;
 361
 362         if((!IS_PLAYER(other))
 363         || (IS_DEAD(other))
 364         || (other.vehicle)
 365         || (DIFF_TEAM(other, self))
 366         ) { return false; }
 367
 368         return true;
 369 }
 370
 371 void bumblebee_touch()
 372 {SELFPARAM();
 373         if(autocvar_g_vehicles_enter) { return; }
 374
 375         if(self.gunner1 != world && self.gunner2 != world)
 376         {
 377                 vehicles_touch();
 378                 return;
 379         }
 380
 381         if(vehicles_valid_pilot())
 382         {
 383                 float phase_time = (time >= self.gun1.phase) + (time >= self.gun2.phase);
 384
 385                 if(time >= other.vehicle_enter_delay && phase_time)
 386                 if(bumblebee_gunner_enter())
 387                         return;
 388         }
 389
 390         vehicles_touch();
 391 }
 392
 393 void bumblebee_regen(entity this)
 394 {
 395         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 396                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 397                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 398
 399         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 400                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 401                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 402
 403         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 404                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, true);
 405
 406         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 407                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, false);
 408
 409         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 410                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, false);
 411
 412 }
 413
 414 bool bumblebee_pilot_frame(entity this)
 415 {
 416         entity vehic = this.vehicle;
 417         return = true;
 418
 419         if(intermission_running)
 420         {
 421                 vehic.velocity = '0 0 0';
 422                 vehic.avelocity = '0 0 0';
 423                 return;
 424         }
 425
 426         vehicles_frame(vehic, this);
 427
 428         if(IS_DEAD(vehic))
 429         {
 430                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 431                 return;
 432         }
 433
 434         bumblebee_regen(vehic);
 435
 436         crosshair_trace(this);
 437
 438         vector vang = vehic.angles;
 439         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 440         vang.x *= -1;
 441         newvel.x *= -1;
 442         if(newvel.x > 180)  newvel.x -= 360;
 443         if(newvel.x < -180) newvel.x += 360;
 444         if(newvel.y > 180)  newvel.y -= 360;
 445         if(newvel.y < -180) newvel.y += 360;
 446
 447         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 448         if(ftmp > 180)  ftmp -= 360;
 449         if(ftmp < -180) ftmp += 360;
 450         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 451
 452         // Pitch
 453         ftmp = 0;
 454         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 455                 ftmp = 4;
 456         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 457                 ftmp = -8;
 458
 459         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 460         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 461         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 462
 463         vehic.angles_x = anglemods(vehic.angles.x);
 464         vehic.angles_y = anglemods(vehic.angles.y);
 465         vehic.angles_z = anglemods(vehic.angles.z);
 466
 467         makevectors('0 1 0' * vehic.angles.y);
 468         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 469
 470         if(this.movement.x != 0)
 471         {
 472                 if(this.movement.x > 0)
 473                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 474                 else if(this.movement.x < 0)
 475                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 476         }
 477
 478         if(this.movement.y != 0)
 479         {
 480                 if(this.movement.y < 0)
 481                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 482                 else if(this.movement.y > 0)
 483                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 484                 ftmp = newvel * v_right;
 485                 ftmp *= frametime * 0.1;
 486                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 487         }
 488         else
 489         {
 490                 vehic.angles_z *= 0.95;
 491                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 492                         vehic.angles_z = 0;
 493         }
 494
 495         if(PHYS_INPUT_BUTTON_CROUCH(this))
 496                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 497         else if(PHYS_INPUT_BUTTON_JUMP(this))
 498                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 499
 500         vehic.velocity  += newvel * frametime;
 501         this.velocity = this.movement  = vehic.velocity;
 502
 503
 504         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 505         {
 506                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 507                         vehic.tur_head.enemy = world;
 508
 509                 if(trace_ent)
 510                 if(trace_ent.movetype)
 511                 if(trace_ent.takedamage)
 512                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 513                 {
 514                         if(teamplay)
 515                         {
 516                                 if(trace_ent.team == this.team)
 517                                 {
 518                                         vehic.tur_head.enemy = trace_ent;
 519                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 520                                 }
 521                         }
 522                         else
 523                         {
 524                                 vehic.tur_head.enemy = trace_ent;
 525                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 526                         }
 527                 }
 528
 529                 if(vehic.tur_head.enemy)
 530                 {
 531                         trace_endpos = real_origin(vehic.tur_head.enemy);
 532                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 533                 }
 534         }
 535
 536         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 537                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 538                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 539
 540         if(!forbidWeaponUse(this))
 541         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 542         {
 543                 vehic.gun3.enemy.realowner = this;
 544                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 545
 546                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 547                 vehic.gun3.enemy.SendFlags |= BRG_START;
 548
 549                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 550
 551                 if(trace_ent)
 552                 {
 553                         if(autocvar_g_vehicle_bumblebee_raygun)
 554                         {
 555                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 556                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 557                         }
 558                         else
 559                         {
 560                                 if(!IS_DEAD(trace_ent))
 561                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 562                                         {
 563
 564                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 565                                                 {
 566                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 567                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.max_health);
 568
 569                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 570                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 571                                                 }
 572                                                 else if(IS_CLIENT(trace_ent))
 573                                                 {
 574                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 575                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 576
 577                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 578                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 579
 580                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 581                                                 }
 582                                                 else if(IS_TURRET(trace_ent))
 583                                                 {
 584                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 585                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 586                                                         //else ..hmmm what? ammo?
 587
 588                                                         trace_ent.SendFlags |= TNSF_STATUS;
 589                                                 }
 590                                         }
 591                         }
 592                 }
 593
 594                 vehic.gun3.enemy.hook_end = trace_endpos;
 595                 setorigin(vehic.gun3.enemy, trace_endpos);
 596                 vehic.gun3.enemy.SendFlags |= BRG_END;
 597
 598                 vehic.wait = time + 1;
 599         }
 600         else
 601                 vehic.gun3.enemy.effects |= EF_NODRAW;
 602         /*{
 603                 if(vehic.gun3.enemy)
 604                         remove(vehic.gun3.enemy);
 605
 606                 vehic.gun3.enemy = world;
 607         }
 608         */
 609
 610         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 611         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 612
 613         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 614         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 615
 616         if(vehic.vehicle_flags & VHF_HASSHIELD)
 617                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 618
 619         vehic.angles_x *= -1;
 620         makevectors(vehic.angles);
 621         vehic.angles_x *= -1;
 622         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 623
 624         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 625 }
 626
 627 void bumblebee_land()
 628 {SELFPARAM();
 629         float hgt;
 630
 631         hgt = raptor_altitude(512);
 632         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 633         self.angles_x *= 0.95;
 634         self.angles_z *= 0.95;
 635
 636         if(hgt < 16)
 637                 self.think      = vehicles_think;
 638
 639         self.nextthink = time;
 640
 641         CSQCMODEL_AUTOUPDATE(self);
 642 }
 643
 644 void bumblebee_exit(float eject)
 645 {SELFPARAM();
 646         if(self.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 647         {
 648                 bumblebee_gunner_exit(eject);
 649                 return;
 650         }
 651
 652         self.touch = vehicles_touch;
 653
 654         if(!IS_DEAD(self))
 655         {
 656                 self.think = bumblebee_land;
 657                 self.nextthink  = time;
 658         }
 659
 660         self.movetype = MOVETYPE_TOSS;
 661
 662         if(!self.owner)
 663                 return;
 664
 665         fixedmakevectors(self.angles);
 666         vector spot;
 667         if(vdist(self.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 668                 spot = self.origin + v_up * 128 + v_forward * 300;
 669         else
 670                 spot = self.origin + v_up * 128 - v_forward * 300;
 671
 672         spot = vehicles_findgoodexit(spot);
 673
 674         // Hide beam
 675         if(self.gun3.enemy || !wasfreed(self.gun3.enemy)) {
 676                 self.gun3.enemy.effects |= EF_NODRAW;
 677         }
 678
 679         self.owner.velocity = 0.75 * self.vehicle.velocity + normalize(spot - self.vehicle.origin) * 200;
 680         self.owner.velocity_z += 10;
 681         setorigin(self.owner, spot);
 682
 683         antilag_clear(self.owner, CS(self.owner));
 684         self.owner = world;
 685 }
 686
 687 void bumblebee_blowup()
 688 {SELFPARAM();
 689         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 690                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 691                                  autocvar_g_vehicle_bumblebee_blowup_radius, self, world,
 692                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 693                                  DEATH_VH_BUMB_DEATH.m_id, world);
 694
 695         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 696         Send_Effect(EFFECT_EXPLOSION_BIG, (self.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 697
 698         if(self.owner.deadflag == DEAD_DYING)
 699                 self.owner.deadflag = DEAD_DEAD;
 700
 701         remove(self);
 702 }
 703
 704 void bumblebee_diethink()
 705 {SELFPARAM();
 706         if(time >= self.wait)
 707                 self.think = bumblebee_blowup;
 708
 709         if(random() < 0.1)
 710         {
 711                 sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 712                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 713         }
 714
 715         self.nextthink = time + 0.1;
 716 }
 717
 718 spawnfunc(vehicle_bumblebee)
 719 {
 720         if(!autocvar_g_vehicle_bumblebee) { remove(self); return; }
 721         if(!vehicle_initialize(VEH_BUMBLEBEE, false)) { remove(self); return; }
 722 }
 723
 724 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 725 {
 726     if(autocvar_g_vehicle_bumblebee_bouncepain)
 727         vehicles_impact(autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 728 }
 729 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 730 {
 731     SELFPARAM();
 732     self.touch = bumblebee_touch;
 733     self.nextthink = 0;
 734     self.movetype = MOVETYPE_BOUNCEMISSILE;
 735 }
 736 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 737 {
 738     SELFPARAM();
 739     self.angles_z *= 0.8;
 740     self.angles_x *= 0.8;
 741
 742     self.nextthink = time;
 743
 744     if(!self.owner)
 745     {
 746         entity oldself = self;
 747         if(self.gunner1)
 748         {
 749             setself(self.gunner1);
 750             oldself.gun1.vehicle_exit(VHEF_EJECT);
 751             entity oldother = other;
 752             other = self;
 753             setself(oldself);
 754             self.phase = 0;
 755             self.touch();
 756             other = oldother;
 757             return;
 758         }
 759
 760         if(self.gunner2)
 761         {
 762             setself(self.gunner2);
 763             oldself.gun2.vehicle_exit(VHEF_EJECT);
 764             entity oldother = other;
 765             other = self;
 766             setself(oldself);
 767             self.phase = 0;
 768             self.touch();
 769             other = oldother;
 770             return;
 771         }
 772     }
 773 }
 774 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 775 {
 776     SELFPARAM();
 777     entity oldself = self;
 778     setself(instance);
 779
 780     CSQCModel_UnlinkEntity(self);
 781
 782     // Hide beam
 783     if(self.gun3.enemy || !wasfreed(self.gun3.enemy))
 784         self.gun3.enemy.effects |= EF_NODRAW;
 785
 786     if(self.gunner1)
 787     {
 788         setself(self.gunner1);
 789         oldself.gun1.vehicle_exit(VHEF_EJECT);
 790         setself(oldself);
 791     }
 792
 793     if(self.gunner2)
 794     {
 795         setself(self.gunner2);
 796         oldself.gun2.vehicle_exit(VHEF_EJECT);
 797         setself(oldself);
 798     }
 799
 800     self.vehicle_exit(VHEF_EJECT);
 801
 802     fixedmakevectors(self.angles);
 803     vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 804     vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 805     vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 806
 807     entity _body = vehicle_tossgib(self, self.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 808
 809     if(random() > 0.5)
 810         _body.touch = bumblebee_blowup;
 811     else
 812         _body.touch = func_null;
 813
 814     _body.think = bumblebee_diethink;
 815     _body.nextthink = time;
 816     _body.wait = time + 2 + (random() * 8);
 817     _body.owner = self;
 818     _body.enemy = self.enemy;
 819     _body.scale = 1.5;
 820     _body.angles = self.angles;
 821
 822     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(self.origin, 16), '0 0 0', 1);
 823
 824     self.health                 = 0;
 825     self.event_damage   = func_null;
 826     self.solid                  = SOLID_NOT;
 827     self.takedamage             = DAMAGE_NO;
 828     self.deadflag               = DEAD_DYING;
 829     self.movetype               = MOVETYPE_NONE;
 830     self.effects                = EF_NODRAW;
 831     self.colormod               = '0 0 0';
 832     self.avelocity              = '0 0 0';
 833     self.velocity               = '0 0 0';
 834     self.touch                  = func_null;
 835     self.nextthink              = 0;
 836
 837     setorigin(self, self.pos1);
 838
 839     setself(oldself);
 840 }
 841 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 842 {
 843     SELFPARAM();
 844     if(!self.gun1)
 845     {
 846         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 847         self.vehicle_shieldent = spawn();
 848         self.vehicle_shieldent.effects = EF_LOWPRECISION;
 849         setmodel(self.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 850         setattachment(self.vehicle_shieldent, self, "");
 851         setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 852         self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 853         self.vehicle_shieldent.think       = shieldhit_think;
 854         self.vehicle_shieldent.alpha = -1;
 855         self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 856
 857         self.gun1 = new(vehicle_playerslot);
 858         self.gun2 = new(vehicle_playerslot);
 859         self.gun3 = new(bumblebee_raygun);
 860
 861         self.vehicle_flags |= VHF_MULTISLOT;
 862
 863         self.gun1.owner = self;
 864         self.gun2.owner = self;
 865         self.gun3.owner = self;
 866
 867         setmodel(self.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 868         setmodel(self.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 869         setmodel(self.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 870
 871         setattachment(self.gun1, self, "cannon_right");
 872         setattachment(self.gun2, self, "cannon_left");
 873
 874         // Angled bones are no fun, messes up gun-aim; so work arround it.
 875         self.gun3.pos1 = self.angles;
 876         self.angles = '0 0 0';
 877         vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 878         ofs -= self.origin;
 879         setattachment(self.gun3, self, "");
 880         setorigin(self.gun3, ofs);
 881         self.angles = self.gun3.pos1;
 882
 883         vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 884         vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 885
 886         setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 887         setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 888
 889         //fixme-model-bones
 890         setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 891         setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 892         //fixme-model-bones
 893         setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 894         setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 895
 896         self.scale = 1.5;
 897
 898         // Raygun beam
 899         if(self.gun3.enemy == world)
 900         {
 901             self.gun3.enemy = spawn();
 902             Net_LinkEntity(self.gun3.enemy, true, 0, bumble_raygun_send);
 903             self.gun3.enemy.SendFlags = BRG_SETUP;
 904             self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 905             self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 906         }
 907     }
 908
 909     self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 910     self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 911     self.solid = SOLID_BBOX;
 912     self.movetype = MOVETYPE_TOSS;
 913     self.damageforcescale = 0.025;
 914
 915     self.PlayerPhysplug = bumblebee_pilot_frame;
 916
 917     setorigin(self, self.origin + '0 0 25');
 918 }
 919 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 920 {
 921     SELFPARAM();
 922     if(autocvar_g_vehicle_bumblebee_energy)
 923     if(autocvar_g_vehicle_bumblebee_energy_regen)
 924         self.vehicle_flags |= VHF_ENERGYREGEN;
 925
 926     if(autocvar_g_vehicle_bumblebee_shield)
 927         self.vehicle_flags |= VHF_HASSHIELD;
 928
 929     if(autocvar_g_vehicle_bumblebee_shield_regen)
 930         self.vehicle_flags |= VHF_SHIELDREGEN;
 931
 932     if(autocvar_g_vehicle_bumblebee_health_regen)
 933         self.vehicle_flags |= VHF_HEALTHREGEN;
 934
 935     self.vehicle_exit = bumblebee_exit;
 936     self.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 937     self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 938     self.max_health = self.vehicle_health;
 939     self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 940 }
 941
 942 #endif // SVQC
 943 #ifdef CSQC
 944
 945 void CSQC_BUMBLE_GUN_HUD()
 946 {
 947         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 948                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 949                                          string_null, '0 0 0');
 950 }
 951
 952 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 953 {
 954     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 955                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 956                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 957
 958     float hudAlpha = autocvar_hud_panel_fg_alpha;
 959     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 960     vector tmpPos  = '0 0 0';
 961     vector tmpSize = '1 1 1' * hud_fontsize;
 962     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 963
 964     if(!AuxiliaryXhair[1].draw2d)
 965     {
 966         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 967         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 968     }
 969
 970     if(!AuxiliaryXhair[2].draw2d)
 971     {
 972         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 973         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 974     }
 975 }
 976 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh))
 977 {
 978     Vehicles_drawCrosshair(vCROSS_HEAL);
 979 }
 980 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 981 {
 982     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 983     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 984     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 985 }
 986
 987 #endif
 988 #endif