qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #ifndef VEHICLE_BUMBLEBEE
   2 #define VEHICLE_BUMBLEBEE
   3 #include "bumblebee.qh"
   4
   5 #include "bumblebee_weapons.qh"
   6
   7 CLASS(Bumblebee, Vehicle)
   8 /* spawnflags */ ATTRIB(Bumblebee, spawnflags, int, VHF_DMGSHAKE);
   9 /* mins       */ ATTRIB(Bumblebee, mins, vector, '-245 -130 -130');
  10 /* maxs       */ ATTRIB(Bumblebee, maxs, vector, '230 130 130');
  11 /* view offset*/ ATTRIB(Bumblebee, view_ofs, vector, '0 0 300');
  12 /* view dist  */ ATTRIB(Bumblebee, height, float, 450);
  13 /* model          */ ATTRIB(Bumblebee, mdl, string, "models/vehicles/bumblebee_body.dpm");
  14 /* model          */ ATTRIB(Bumblebee, model, string, "models/vehicles/bumblebee_body.dpm");
  15 /* head_model */ ATTRIB(Bumblebee, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Bumblebee, hud_model, string, "models/vehicles/spiderbot_cockpit.dpm");
  17 /* tags       */ ATTRIB(Bumblebee, tag_head, string, "");
  18 /* tags       */ ATTRIB(Bumblebee, tag_hud, string, "");
  19 /* tags       */ ATTRIB(Bumblebee, tag_view, string, "tag_viewport");
  20 /* netname    */ ATTRIB(Bumblebee, netname, string, "bumblebee");
  21 /* fullname   */ ATTRIB(Bumblebee, vehicle_name, string, _("Bumblebee"));
  22 /* icon       */ ATTRIB(Bumblebee, m_icon, string, "vehicle_bumble");
  23 ENDCLASS(Bumblebee)
  24 REGISTER_VEHICLE(BUMBLEBEE, NEW(Bumblebee));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 const float BRG_SETUP = 2;
  31 const float BRG_START = 4;
  32 const float BRG_END = 8;
  33
  34 #ifdef SVQC
  35 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  36
  37 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  38 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  39 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  40 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  41 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  42 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  43 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  44 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  45
  46 float autocvar_g_vehicle_bumblebee_energy = 500;
  47 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  48 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  49
  50 float autocvar_g_vehicle_bumblebee_health = 1000;
  51 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  52 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  53
  54 float autocvar_g_vehicle_bumblebee_shield = 400;
  55 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  56 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  57
  58 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  59 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  60 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  61
  62 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  63
  64 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  65 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  66 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  67 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  68 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  69
  70
  71 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  72 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  73 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  74 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  75
  76 bool autocvar_g_vehicle_bumblebee_raygun = false;
  77 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  78 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  79 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  80 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  81
  82 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  83 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  84 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  85 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  86 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  87 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  88
  89 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  90 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  91 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  92 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  93 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  94
  95 bool autocvar_g_vehicle_bumblebee = true;
  96
  97 bool bumblebee_gunner_frame(entity this)
  98 {
  99         entity vehic = this.vehicle.owner;
 100         entity gun = this.vehicle;
 101         return = true;
 102
 103         setself(vehic);
 104
 105         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
 106         //vehicles_frame(gun, player);
 107
 108         vehic.solid = SOLID_NOT;
 109         //setorigin(this, vehic.origin);
 110         this.velocity = vehic.velocity;
 111
 112         float _in, _out;
 113         vehic.angles_x *= -1;
 114         makevectors(vehic.angles);
 115         vehic.angles_x *= -1;
 116         if(gun == vehic.gun1)
 117         {
 118                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 119                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 120                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 121         }
 122         else
 123         {
 124                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 125                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 126                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 127         }
 128
 129         crosshair_trace(this);
 130         vector _ct = trace_endpos;
 131         vector ad;
 132
 133         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 134         {
 135                 if(gun.lock_time < time)
 136                         gun.enemy = world;
 137
 138                 if(trace_ent)
 139                         if(trace_ent.movetype)
 140                                 if(trace_ent.takedamage)
 141                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 142                                         {
 143                                                 if(DIFF_TEAM(trace_ent, this))
 144                                                 {
 145                                                         gun.enemy = trace_ent;
 146                                                         gun.lock_time = time + 5;
 147                                                 }
 148                                         }
 149         }
 150
 151         if(gun.enemy)
 152         {
 153                 float distance, impact_time;
 154
 155                 vector vf = real_origin(gun.enemy);
 156                 vector _vel = gun.enemy.velocity;
 157                 if(gun.enemy.movetype == MOVETYPE_WALK)
 158                         _vel.z *= 0.1;
 159
 160
 161                 ad = vf;
 162                 distance = vlen(ad - this.origin);
 163                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 164                 ad = vf + _vel * impact_time;
 165                 trace_endpos = ad;
 166
 167
 168                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 169                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 170                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 171                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 172
 173         }
 174         else
 175                 vehicle_aimturret(vehic, _ct, gun, "fire",
 176                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 177                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 178
 179         if(!forbidWeaponUse(this))
 180         if(PHYS_INPUT_BUTTON_ATCK(this))
 181                 if(time > gun.attack_finished_single[0])
 182                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 183                         {
 184                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 185                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 186                                 gun.delay = time;
 187                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 188                         }
 189
 190         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 191
 192         if(vehic.vehicle_flags & VHF_HASSHIELD)
 193                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 194
 195         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 196         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 197
 198         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 199
 200         if(vehic.owner)
 201                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 202
 203         vehic.solid = SOLID_BBOX;
 204         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 205         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 206
 207         setself(this);
 208 }
 209
 210 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 211 {
 212         //vector exitspot;
 213         float mysize;
 214
 215         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 216         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 217                 return prefer_spot;
 218
 219         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 220         float i;
 221         vector v, v2;
 222         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 223         for(i = 0; i < 100; ++i)
 224         {
 225                 v = randomvec();
 226                 v_z = 0;
 227                 v = v2 + normalize(v) * mysize;
 228                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 229                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 230                         return v;
 231         }
 232
 233         return prefer_spot; // this should be considered a fallback?!
 234 }
 235
 236 void bumblebee_gunner_exit(int _exitflag)
 237 {SELFPARAM();
 238         entity player = self;
 239         entity gunner = player.vehicle;
 240         entity vehic = gunner.owner;
 241
 242         if(IS_REAL_CLIENT(player))
 243         {
 244                 msg_entity = player;
 245                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 246                 WriteEntity(MSG_ONE, player);
 247
 248                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 249                 WriteAngle(MSG_ONE, 0);
 250                 WriteAngle(MSG_ONE, vehic.angles.y);
 251                 WriteAngle(MSG_ONE, 0);
 252         }
 253
 254         CSQCVehicleSetup(player, HUD_NORMAL);
 255         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 256
 257         player.takedamage     = DAMAGE_AIM;
 258         player.solid          = SOLID_SLIDEBOX;
 259         player.movetype       = MOVETYPE_WALK;
 260         player.effects       &= ~EF_NODRAW;
 261         player.alpha          = 1;
 262         player.PlayerPhysplug = func_null;
 263         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 264         player.event_damage   = PlayerDamage;
 265         player.hud            = HUD_NORMAL;
 266         player.teleportable       = TELEPORT_NORMAL;
 267         PS(player).m_switchweapon = gunner.m_switchweapon;
 268         player.vehicle_enter_delay = time + 2;
 269
 270         fixedmakevectors(vehic.angles);
 271
 272         if(player == vehic.gunner1) { vehic.gunner1 = world; }
 273         if(player == vehic.gunner2) { vehic.gunner2 = world; v_right *= -1; }
 274
 275         vector spot = real_origin(gunner);
 276         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 277         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 278
 279         // TODO: figure a way to move player out of the gunner
 280
 281         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 282         player.velocity_z += 10;
 283
 284         gunner.phase = time + 5;
 285         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 286
 287         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 288
 289         player.vehicle = world;
 290 }
 291
 292 bool bumblebee_gunner_enter()
 293 {SELFPARAM();
 294         entity vehic = self;
 295         entity player = other;
 296         entity gunner = world;
 297
 298         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 299         {
 300                 // we can have some fun
 301                 if(vlen2(real_origin(vehic.gun2) - player.origin) < vlen2(real_origin(vehic.gun1) - player.origin))
 302                 {
 303                         gunner = vehic.gun2;
 304                         vehic.gunner2 = player;
 305                 }
 306                 else
 307                 {
 308                         gunner = vehic.gun1;
 309                         vehic.gunner1 = player;
 310                 }
 311         }
 312         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 313         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 314         else { LOG_TRACE("Vehicle is full, fail\n"); return false; }
 315
 316         player.vehicle                  = gunner;
 317         player.angles                   = vehic.angles;
 318         player.takedamage               = DAMAGE_NO;
 319         player.solid                    = SOLID_NOT;
 320         player.alpha                    = -1;
 321         player.movetype                 = MOVETYPE_NOCLIP;
 322         player.event_damage     = func_null;
 323         player.view_ofs                 = '0 0 0';
 324         player.hud                              = gunner.hud;
 325         player.teleportable     = false;
 326         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 327         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 328         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 329         player.vehicle_reload1  = vehic.vehicle_reload1;
 330         player.vehicle_reload2  = vehic.vehicle_reload2;
 331         player.vehicle_energy   = vehic.vehicle_energy;
 332         player.flags               &= ~FL_ONGROUND;
 333
 334         RemoveGrapplingHook(player);
 335
 336         gunner.m_switchweapon = PS(player).m_switchweapon;
 337         gunner.vehicle_exit = bumblebee_gunner_exit;
 338         gunner.vehicle_hudmodel.viewmodelforclient = player;
 339
 340         if(IS_REAL_CLIENT(player))
 341         {
 342                 msg_entity = player;
 343                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 344                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 345
 346                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 347                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 348                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 349                 WriteAngle(MSG_ONE,     0); // roll
 350         }
 351
 352         CSQCVehicleSetup(player, player.hud);
 353
 354         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 355
 356         return true;
 357 }
 358
 359 bool vehicles_valid_pilot()
 360 {SELFPARAM();
 361         if(IS_BOT_CLIENT(other) && !autocvar_g_vehicles_allow_bots)
 362                 return false;
 363
 364         if((!IS_PLAYER(other))
 365         || (IS_DEAD(other))
 366         || (other.vehicle)
 367         || (DIFF_TEAM(other, self))
 368         ) { return false; }
 369
 370         return true;
 371 }
 372
 373 void bumblebee_touch()
 374 {SELFPARAM();
 375         if(autocvar_g_vehicles_enter) { return; }
 376
 377         if(self.gunner1 != world && self.gunner2 != world)
 378         {
 379                 vehicles_touch();
 380                 return;
 381         }
 382
 383         if(vehicles_valid_pilot())
 384         {
 385                 float phase_time = (time >= self.gun1.phase) + (time >= self.gun2.phase);
 386
 387                 if(time >= other.vehicle_enter_delay && phase_time)
 388                 if(bumblebee_gunner_enter())
 389                         return;
 390         }
 391
 392         vehicles_touch();
 393 }
 394
 395 void bumblebee_regen(entity this)
 396 {
 397         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 398                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 399                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 400
 401         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 402                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 403                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 404
 405         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 406                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, true);
 407
 408         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 409                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, false);
 410
 411         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 412                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, false);
 413
 414 }
 415
 416 bool bumblebee_pilot_frame(entity this)
 417 {
 418         entity vehic = this.vehicle;
 419         return = true;
 420
 421         if(intermission_running)
 422         {
 423                 vehic.velocity = '0 0 0';
 424                 vehic.avelocity = '0 0 0';
 425                 return;
 426         }
 427
 428         vehicles_frame(vehic, this);
 429
 430         if(IS_DEAD(vehic))
 431         {
 432                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 433                 return;
 434         }
 435
 436         setself(vehic);
 437
 438         bumblebee_regen(vehic);
 439
 440         crosshair_trace(this);
 441
 442         vector vang = vehic.angles;
 443         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 444         vang.x *= -1;
 445         newvel.x *= -1;
 446         if(newvel.x > 180)  newvel.x -= 360;
 447         if(newvel.x < -180) newvel.x += 360;
 448         if(newvel.y > 180)  newvel.y -= 360;
 449         if(newvel.y < -180) newvel.y += 360;
 450
 451         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 452         if(ftmp > 180)  ftmp -= 360;
 453         if(ftmp < -180) ftmp += 360;
 454         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 455
 456         // Pitch
 457         ftmp = 0;
 458         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 459                 ftmp = 4;
 460         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 461                 ftmp = -8;
 462
 463         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 464         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 465         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 466
 467         vehic.angles_x = anglemods(vehic.angles.x);
 468         vehic.angles_y = anglemods(vehic.angles.y);
 469         vehic.angles_z = anglemods(vehic.angles.z);
 470
 471         makevectors('0 1 0' * vehic.angles.y);
 472         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 473
 474         if(this.movement.x != 0)
 475         {
 476                 if(this.movement.x > 0)
 477                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 478                 else if(this.movement.x < 0)
 479                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 480         }
 481
 482         if(this.movement.y != 0)
 483         {
 484                 if(this.movement.y < 0)
 485                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 486                 else if(this.movement.y > 0)
 487                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 488                 ftmp = newvel * v_right;
 489                 ftmp *= frametime * 0.1;
 490                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 491         }
 492         else
 493         {
 494                 vehic.angles_z *= 0.95;
 495                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 496                         vehic.angles_z = 0;
 497         }
 498
 499         if(PHYS_INPUT_BUTTON_CROUCH(this))
 500                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 501         else if(PHYS_INPUT_BUTTON_JUMP(this))
 502                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 503
 504         vehic.velocity  += newvel * frametime;
 505         this.velocity = this.movement  = vehic.velocity;
 506
 507
 508         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 509         {
 510                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 511                         vehic.tur_head.enemy = world;
 512
 513                 if(trace_ent)
 514                 if(trace_ent.movetype)
 515                 if(trace_ent.takedamage)
 516                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 517                 {
 518                         if(teamplay)
 519                         {
 520                                 if(trace_ent.team == this.team)
 521                                 {
 522                                         vehic.tur_head.enemy = trace_ent;
 523                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 524                                 }
 525                         }
 526                         else
 527                         {
 528                                 vehic.tur_head.enemy = trace_ent;
 529                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 530                         }
 531                 }
 532
 533                 if(vehic.tur_head.enemy)
 534                 {
 535                         trace_endpos = real_origin(vehic.tur_head.enemy);
 536                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 537                 }
 538         }
 539
 540         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 541                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 542                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 543
 544         if(!forbidWeaponUse(this))
 545         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 546         {
 547                 vehic.gun3.enemy.realowner = this;
 548                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 549
 550                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 551                 vehic.gun3.enemy.SendFlags |= BRG_START;
 552
 553                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 554
 555                 if(trace_ent)
 556                 {
 557                         if(autocvar_g_vehicle_bumblebee_raygun)
 558                         {
 559                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 560                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 561                         }
 562                         else
 563                         {
 564                                 if(!IS_DEAD(trace_ent))
 565                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 566                                         {
 567
 568                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 569                                                 {
 570                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 571                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.max_health);
 572
 573                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 574                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 575                                                 }
 576                                                 else if(IS_CLIENT(trace_ent))
 577                                                 {
 578                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 579                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 580
 581                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 582                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 583
 584                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 585                                                 }
 586                                                 else if(IS_TURRET(trace_ent))
 587                                                 {
 588                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 589                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 590                                                         //else ..hmmm what? ammo?
 591
 592                                                         trace_ent.SendFlags |= TNSF_STATUS;
 593                                                 }
 594                                         }
 595                         }
 596                 }
 597
 598                 vehic.gun3.enemy.hook_end = trace_endpos;
 599                 setorigin(vehic.gun3.enemy, trace_endpos);
 600                 vehic.gun3.enemy.SendFlags |= BRG_END;
 601
 602                 vehic.wait = time + 1;
 603         }
 604         else
 605                 vehic.gun3.enemy.effects |= EF_NODRAW;
 606         /*{
 607                 if(vehic.gun3.enemy)
 608                         remove(vehic.gun3.enemy);
 609
 610                 vehic.gun3.enemy = world;
 611         }
 612         */
 613
 614         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 615         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 616
 617         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 618         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 619
 620         if(vehic.vehicle_flags & VHF_HASSHIELD)
 621                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 622
 623         vehic.angles_x *= -1;
 624         makevectors(vehic.angles);
 625         vehic.angles_x *= -1;
 626         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 627
 628         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 629
 630         setself(this);
 631 }
 632
 633 void bumblebee_land()
 634 {SELFPARAM();
 635         float hgt;
 636
 637         hgt = raptor_altitude(512);
 638         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 639         self.angles_x *= 0.95;
 640         self.angles_z *= 0.95;
 641
 642         if(hgt < 16)
 643                 self.think      = vehicles_think;
 644
 645         self.nextthink = time;
 646
 647         CSQCMODEL_AUTOUPDATE(self);
 648 }
 649
 650 void bumblebee_exit(float eject)
 651 {SELFPARAM();
 652         if(self.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 653         {
 654                 bumblebee_gunner_exit(eject);
 655                 return;
 656         }
 657
 658         self.touch = vehicles_touch;
 659
 660         if(!IS_DEAD(self))
 661         {
 662                 self.think = bumblebee_land;
 663                 self.nextthink  = time;
 664         }
 665
 666         self.movetype = MOVETYPE_TOSS;
 667
 668         if(!self.owner)
 669                 return;
 670
 671         fixedmakevectors(self.angles);
 672         vector spot;
 673         if(vdist(self.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 674                 spot = self.origin + v_up * 128 + v_forward * 300;
 675         else
 676                 spot = self.origin + v_up * 128 - v_forward * 300;
 677
 678         spot = vehicles_findgoodexit(spot);
 679
 680         // Hide beam
 681         if(self.gun3.enemy || !wasfreed(self.gun3.enemy)) {
 682                 self.gun3.enemy.effects |= EF_NODRAW;
 683         }
 684
 685         self.owner.velocity = 0.75 * self.vehicle.velocity + normalize(spot - self.vehicle.origin) * 200;
 686         self.owner.velocity_z += 10;
 687         setorigin(self.owner, spot);
 688
 689         antilag_clear(self.owner, CS(self.owner));
 690         self.owner = world;
 691 }
 692
 693 void bumblebee_blowup()
 694 {SELFPARAM();
 695         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 696                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 697                                  autocvar_g_vehicle_bumblebee_blowup_radius, self, world,
 698                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 699                                  DEATH_VH_BUMB_DEATH.m_id, world);
 700
 701         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 702         Send_Effect(EFFECT_EXPLOSION_BIG, (self.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 703
 704         if(self.owner.deadflag == DEAD_DYING)
 705                 self.owner.deadflag = DEAD_DEAD;
 706
 707         remove(self);
 708 }
 709
 710 void bumblebee_diethink()
 711 {SELFPARAM();
 712         if(time >= self.wait)
 713                 self.think = bumblebee_blowup;
 714
 715         if(random() < 0.1)
 716         {
 717                 sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 718                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 719         }
 720
 721         self.nextthink = time + 0.1;
 722 }
 723
 724 spawnfunc(vehicle_bumblebee)
 725 {
 726         if(!autocvar_g_vehicle_bumblebee) { remove(self); return; }
 727         if(!vehicle_initialize(VEH_BUMBLEBEE, false)) { remove(self); return; }
 728 }
 729
 730 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 731 {
 732     if(autocvar_g_vehicle_bumblebee_bouncepain)
 733         vehicles_impact(autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 734 }
 735 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 736 {
 737     SELFPARAM();
 738     self.touch = bumblebee_touch;
 739     self.nextthink = 0;
 740     self.movetype = MOVETYPE_BOUNCEMISSILE;
 741 }
 742 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 743 {
 744     SELFPARAM();
 745     self.angles_z *= 0.8;
 746     self.angles_x *= 0.8;
 747
 748     self.nextthink = time;
 749
 750     if(!self.owner)
 751     {
 752         entity oldself = self;
 753         if(self.gunner1)
 754         {
 755             setself(self.gunner1);
 756             oldself.gun1.vehicle_exit(VHEF_EJECT);
 757             entity oldother = other;
 758             other = self;
 759             setself(oldself);
 760             self.phase = 0;
 761             self.touch();
 762             other = oldother;
 763             return;
 764         }
 765
 766         if(self.gunner2)
 767         {
 768             setself(self.gunner2);
 769             oldself.gun2.vehicle_exit(VHEF_EJECT);
 770             entity oldother = other;
 771             other = self;
 772             setself(oldself);
 773             self.phase = 0;
 774             self.touch();
 775             other = oldother;
 776             return;
 777         }
 778     }
 779 }
 780 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 781 {
 782     SELFPARAM();
 783     entity oldself = self;
 784     setself(instance);
 785
 786     CSQCModel_UnlinkEntity(self);
 787
 788     // Hide beam
 789     if(self.gun3.enemy || !wasfreed(self.gun3.enemy))
 790         self.gun3.enemy.effects |= EF_NODRAW;
 791
 792     if(self.gunner1)
 793     {
 794         setself(self.gunner1);
 795         oldself.gun1.vehicle_exit(VHEF_EJECT);
 796         setself(oldself);
 797     }
 798
 799     if(self.gunner2)
 800     {
 801         setself(self.gunner2);
 802         oldself.gun2.vehicle_exit(VHEF_EJECT);
 803         setself(oldself);
 804     }
 805
 806     self.vehicle_exit(VHEF_EJECT);
 807
 808     fixedmakevectors(self.angles);
 809     vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 810     vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 811     vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 812
 813     entity _body = vehicle_tossgib(self, self.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 814
 815     if(random() > 0.5)
 816         _body.touch = bumblebee_blowup;
 817     else
 818         _body.touch = func_null;
 819
 820     _body.think = bumblebee_diethink;
 821     _body.nextthink = time;
 822     _body.wait = time + 2 + (random() * 8);
 823     _body.owner = self;
 824     _body.enemy = self.enemy;
 825     _body.scale = 1.5;
 826     _body.angles = self.angles;
 827
 828     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(self.origin, 16), '0 0 0', 1);
 829
 830     self.health                 = 0;
 831     self.event_damage   = func_null;
 832     self.solid                  = SOLID_NOT;
 833     self.takedamage             = DAMAGE_NO;
 834     self.deadflag               = DEAD_DYING;
 835     self.movetype               = MOVETYPE_NONE;
 836     self.effects                = EF_NODRAW;
 837     self.colormod               = '0 0 0';
 838     self.avelocity              = '0 0 0';
 839     self.velocity               = '0 0 0';
 840     self.touch                  = func_null;
 841     self.nextthink              = 0;
 842
 843     setorigin(self, self.pos1);
 844
 845     setself(oldself);
 846 }
 847 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 848 {
 849     SELFPARAM();
 850     if(!self.gun1)
 851     {
 852         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 853         self.vehicle_shieldent = spawn();
 854         self.vehicle_shieldent.effects = EF_LOWPRECISION;
 855         setmodel(self.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 856         setattachment(self.vehicle_shieldent, self, "");
 857         setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 858         self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 859         self.vehicle_shieldent.think       = shieldhit_think;
 860         self.vehicle_shieldent.alpha = -1;
 861         self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 862
 863         self.gun1 = new(vehicle_playerslot);
 864         self.gun2 = new(vehicle_playerslot);
 865         self.gun3 = new(bumblebee_raygun);
 866
 867         self.vehicle_flags |= VHF_MULTISLOT;
 868
 869         self.gun1.owner = self;
 870         self.gun2.owner = self;
 871         self.gun3.owner = self;
 872
 873         setmodel(self.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 874         setmodel(self.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 875         setmodel(self.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 876
 877         setattachment(self.gun1, self, "cannon_right");
 878         setattachment(self.gun2, self, "cannon_left");
 879
 880         // Angled bones are no fun, messes up gun-aim; so work arround it.
 881         self.gun3.pos1 = self.angles;
 882         self.angles = '0 0 0';
 883         vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 884         ofs -= self.origin;
 885         setattachment(self.gun3, self, "");
 886         setorigin(self.gun3, ofs);
 887         self.angles = self.gun3.pos1;
 888
 889         vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 890         vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 891
 892         setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 893         setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 894
 895         //fixme-model-bones
 896         setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 897         setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 898         //fixme-model-bones
 899         setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 900         setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 901
 902         self.scale = 1.5;
 903
 904         // Raygun beam
 905         if(self.gun3.enemy == world)
 906         {
 907             self.gun3.enemy = spawn();
 908             Net_LinkEntity(self.gun3.enemy, true, 0, bumble_raygun_send);
 909             self.gun3.enemy.SendFlags = BRG_SETUP;
 910             self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 911             self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 912         }
 913     }
 914
 915     self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 916     self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 917     self.solid = SOLID_BBOX;
 918     self.movetype = MOVETYPE_TOSS;
 919     self.damageforcescale = 0.025;
 920
 921     self.PlayerPhysplug = bumblebee_pilot_frame;
 922
 923     setorigin(self, self.origin + '0 0 25');
 924 }
 925 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 926 {
 927     SELFPARAM();
 928     if(autocvar_g_vehicle_bumblebee_energy)
 929     if(autocvar_g_vehicle_bumblebee_energy_regen)
 930         self.vehicle_flags |= VHF_ENERGYREGEN;
 931
 932     if(autocvar_g_vehicle_bumblebee_shield)
 933         self.vehicle_flags |= VHF_HASSHIELD;
 934
 935     if(autocvar_g_vehicle_bumblebee_shield_regen)
 936         self.vehicle_flags |= VHF_SHIELDREGEN;
 937
 938     if(autocvar_g_vehicle_bumblebee_health_regen)
 939         self.vehicle_flags |= VHF_HEALTHREGEN;
 940
 941     self.vehicle_exit = bumblebee_exit;
 942     self.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 943     self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 944     self.max_health = self.vehicle_health;
 945     self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 946 }
 947
 948 #endif // SVQC
 949 #ifdef CSQC
 950
 951 void CSQC_BUMBLE_GUN_HUD()
 952 {
 953         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 954                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 955                                          string_null, '0 0 0');
 956 }
 957
 958 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 959 {
 960     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 961                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 962                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 963
 964     float hudAlpha = autocvar_hud_panel_fg_alpha;
 965     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 966     vector tmpPos  = '0 0 0';
 967     vector tmpSize = '1 1 1' * hud_fontsize;
 968     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 969
 970     if(!AuxiliaryXhair[1].draw2d)
 971     {
 972         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 973         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 974     }
 975
 976     if(!AuxiliaryXhair[2].draw2d)
 977     {
 978         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 979         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 980     }
 981 }
 982 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh))
 983 {
 984     Vehicles_drawCrosshair(vCROSS_HEAL);
 985 }
 986 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 987 {
 988     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 989     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 990     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 991 }
 992
 993 #endif
 994 #endif