qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #include "bumblebee.qh"
   2
   3 const float BRG_SETUP = 2;
   4 const float BRG_START = 4;
   5 const float BRG_END = 8;
   6
   7 #ifdef SVQC
   8 float autocvar_g_vehicle_bumblebee_respawntime = 60;
   9
  10 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  11 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  12 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  13 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  14 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  15 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  16 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  17 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  18 bool autocvar_g_vehicle_bumblebee_swim = false;
  19
  20 float autocvar_g_vehicle_bumblebee_energy = 500;
  21 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  22 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  23
  24 float autocvar_g_vehicle_bumblebee_health = 1000;
  25 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  26 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  27
  28 float autocvar_g_vehicle_bumblebee_shield = 400;
  29 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  30 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  31
  32 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  33 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  34 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  37
  38 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  39 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  40 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  41 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  42 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  43
  44
  45 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  46 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  47 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  48 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  49
  50 bool autocvar_g_vehicle_bumblebee_raygun = false;
  51 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  52 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  53 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  54 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  55
  56 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  57 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  58 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  59 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  60 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  61 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  62
  63 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  64 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  65 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  66 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  67 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  68
  69 bool autocvar_g_vehicle_bumblebee = true;
  70
  71 bool bumblebee_gunner_frame(entity this, float dt)
  72 {
  73         entity vehic = this.vehicle.owner;
  74         entity gun = this.vehicle;
  75         return = true;
  76
  77         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
  78         //vehicles_frame(gun, player);
  79
  80         vehic.solid = SOLID_NOT;
  81         //setorigin(this, vehic.origin);
  82         this.velocity = vehic.velocity;
  83
  84         float _in, _out;
  85         vehic.angles_x *= -1;
  86         makevectors(vehic.angles);
  87         vehic.angles_x *= -1;
  88         if(gun == vehic.gun1)
  89         {
  90                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  91                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  92                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
  93         }
  94         else
  95         {
  96                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  97                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  98                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
  99         }
 100         this.oldorigin = this.origin; // negate fall damage
 101
 102         crosshair_trace(this);
 103         vector _ct = trace_endpos;
 104         vector ad;
 105
 106         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 107         {
 108                 if(gun.lock_time < time)
 109                         gun.enemy = NULL;
 110
 111                 if(trace_ent)
 112                         if(trace_ent.move_movetype)
 113                                 if(trace_ent.takedamage)
 114                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 115                                         {
 116                                                 if(DIFF_TEAM(trace_ent, this))
 117                                                 {
 118                                                         gun.enemy = trace_ent;
 119                                                         gun.lock_time = time + 5;
 120                                                 }
 121                                         }
 122         }
 123
 124         if(gun.enemy)
 125         {
 126                 float distance, impact_time;
 127
 128                 vector vf = real_origin(gun.enemy);
 129                 vector _vel = gun.enemy.velocity;
 130                 if(gun.enemy.move_movetype == MOVETYPE_WALK)
 131                         _vel.z *= 0.1;
 132
 133
 134                 ad = vf;
 135                 distance = vlen(ad - this.origin);
 136                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 137                 ad = vf + _vel * impact_time;
 138                 trace_endpos = ad;
 139
 140
 141                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 142                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 143                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 144                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 145
 146         }
 147         else
 148                 vehicle_aimturret(vehic, _ct, gun, "fire",
 149                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 150                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 151
 152         if(!forbidWeaponUse(this))
 153         if(PHYS_INPUT_BUTTON_ATCK(this))
 154                 if(time > gun.attack_finished_single[0])
 155                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 156                         {
 157                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 158                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 159                                 gun.delay = time;
 160                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 161                         }
 162
 163         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 164
 165         if(vehic.vehicle_flags & VHF_HASSHIELD)
 166                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 167
 168         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 169         traceline(ad, ad + v_forward * max_shot_distance, MOVE_NORMAL, gun);
 170
 171         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 172
 173         if(vehic.owner)
 174                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 175
 176         vehic.solid = SOLID_BBOX;
 177         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 178         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 179 }
 180
 181 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 182 {
 183         //vector exitspot;
 184         float mysize;
 185
 186         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, player), STAT(PL_MAX, player), prefer_spot, MOVE_NORMAL, player);
 187         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 188                 return prefer_spot;
 189
 190         mysize = 1.5 * vlen(STAT(PL_MAX, player) - STAT(PL_MIN, player)); // can't use gunner's size, as they don't have a size
 191         float i;
 192         vector v, v2;
 193         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 194         for(i = 0; i < 100; ++i)
 195         {
 196                 v = randomvec();
 197                 v_z = 0;
 198                 v = v2 + normalize(v) * mysize;
 199                 tracebox(v2, STAT(PL_MIN, player), STAT(PL_MAX, player), v, MOVE_NORMAL, player);
 200                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 201                         return v;
 202         }
 203
 204         return prefer_spot; // this should be considered a fallback?!
 205 }
 206
 207 void bumblebee_gunner_exit(entity this, int _exitflag)
 208 {
 209         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 210         entity gunner = this;
 211         entity vehic = gunner.owner;
 212
 213         if(IS_REAL_CLIENT(player))
 214         {
 215                 msg_entity = player;
 216                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 217                 WriteEntity(MSG_ONE, player);
 218
 219                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 220                 WriteAngle(MSG_ONE, 0);
 221                 WriteAngle(MSG_ONE, vehic.angles.y);
 222                 WriteAngle(MSG_ONE, 0);
 223         }
 224
 225         CSQCVehicleSetup(player, HUD_NORMAL);
 226         setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
 227
 228         player.takedamage     = DAMAGE_AIM;
 229         player.solid          = SOLID_SLIDEBOX;
 230         set_movetype(player, MOVETYPE_WALK);
 231         player.effects       &= ~EF_NODRAW;
 232         player.alpha          = 1;
 233         player.PlayerPhysplug = func_null;
 234         player.view_ofs       = STAT(PL_VIEW_OFS, player);
 235         player.event_damage   = PlayerDamage;
 236         player.hud            = HUD_NORMAL;
 237         player.teleportable       = TELEPORT_NORMAL;
 238         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 239         {
 240                 .entity weaponentity = weaponentities[slot];
 241                 player.(weaponentity).m_switchweapon = gunner.(weaponentity).m_switchweapon;
 242                 delete(gunner.(weaponentity));
 243         }
 244         player.vehicle_enter_delay = time + 2;
 245
 246         fixedmakevectors(vehic.angles);
 247
 248         if(player == vehic.gunner1) { vehic.gunner1 = NULL; }
 249         if(player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 250
 251         vector spot = real_origin(gunner);
 252         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 253         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 254
 255         // TODO: figure a way to move player out of the gunner
 256
 257         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 258         player.velocity_z += 10;
 259
 260         gunner.phase = time + 5;
 261         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 262
 263         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 264
 265         player.vehicle = NULL;
 266 }
 267
 268 bool bumblebee_gunner_enter(entity this, entity player)
 269 {
 270         entity vehic = this;
 271         entity gunner = NULL;
 272
 273         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 274         {
 275                 // we can have some fun
 276                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 277                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 278                 if(vlen2(player.origin - v1) < vlen2(player.origin - v2))
 279                 {
 280                         gunner = vehic.gun1;
 281                         vehic.gunner1 = player;
 282                 }
 283                 else
 284                 {
 285                         gunner = vehic.gun2;
 286                         vehic.gunner2 = player;
 287                 }
 288         }
 289         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 290         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 291         else { LOG_TRACE("Vehicle is full, fail"); return false; }
 292
 293         player.vehicle                  = gunner;
 294         player.angles                   = vehic.angles;
 295         player.takedamage               = DAMAGE_NO;
 296         player.solid                    = SOLID_NOT;
 297         player.alpha                    = -1;
 298         set_movetype(player, MOVETYPE_NOCLIP);
 299         player.event_damage     = func_null;
 300         player.view_ofs                 = '0 0 0';
 301         player.hud                              = gunner.hud;
 302         player.teleportable     = false;
 303         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 304         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 305         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 306         player.vehicle_reload1  = vehic.vehicle_reload1;
 307         player.vehicle_reload2  = vehic.vehicle_reload2;
 308         player.vehicle_energy   = vehic.vehicle_energy;
 309         UNSET_ONGROUND(player);
 310
 311         RemoveGrapplingHooks(player);
 312
 313         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 314         {
 315                 .entity weaponentity = weaponentities[slot];
 316
 317                 gunner.(weaponentity) = new(temp_wepent);
 318                 gunner.(weaponentity).m_switchweapon = player.(weaponentity).m_switchweapon;
 319         }
 320         gunner.vehicle_exit = bumblebee_gunner_exit;
 321         gunner.vehicle_hudmodel.viewmodelforclient = player;
 322
 323         if(IS_REAL_CLIENT(player))
 324         {
 325                 msg_entity = player;
 326                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 327                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 328
 329                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 330                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 331                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 332                 WriteAngle(MSG_ONE,     0); // roll
 333         }
 334
 335         CSQCVehicleSetup(player, player.hud);
 336
 337         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 338
 339         return true;
 340 }
 341
 342 bool vehicles_valid_pilot(entity this, entity toucher)
 343 {
 344         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 345                 return false;
 346
 347         if((!IS_PLAYER(toucher))
 348         || (IS_DEAD(toucher))
 349         || (toucher.vehicle)
 350         || (DIFF_TEAM(toucher, this))
 351         ) { return false; }
 352
 353         return true;
 354 }
 355
 356 void bumblebee_touch(entity this, entity toucher)
 357 {
 358         if(autocvar_g_vehicles_enter) { return; }
 359
 360         if(this.gunner1 != NULL && this.gunner2 != NULL)
 361         {
 362                 vehicles_touch(this, toucher);
 363                 return;
 364         }
 365
 366         if(vehicles_valid_pilot(this, toucher))
 367         {
 368                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 369
 370                 if(time >= toucher.vehicle_enter_delay && phase_time)
 371                 if(bumblebee_gunner_enter(this, toucher))
 372                         return;
 373         }
 374
 375         vehicles_touch(this, toucher);
 376 }
 377
 378 void bumblebee_regen(entity this, float dt)
 379 {
 380         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 381                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 382                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 383
 384         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 385                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 386                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 387
 388         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 389                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, dt, true);
 390
 391         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 392                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, dt, false);
 393
 394         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 395                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, dt, false);
 396
 397 }
 398
 399 bool bumblebee_pilot_frame(entity this, float dt)
 400 {
 401         entity vehic = this.vehicle;
 402         return = true;
 403
 404         if(game_stopped)
 405         {
 406                 vehic.solid = SOLID_NOT;
 407                 vehic.takedamage = DAMAGE_NO;
 408                 set_movetype(vehic, MOVETYPE_NONE);
 409                 return;
 410         }
 411
 412         vehicles_frame(vehic, this);
 413
 414         if(IS_DEAD(vehic))
 415         {
 416                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 417                 return;
 418         }
 419
 420         bumblebee_regen(vehic, dt);
 421
 422         crosshair_trace(this);
 423
 424         vector vang = vehic.angles;
 425         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 426         vang.x *= -1;
 427         newvel.x *= -1;
 428         if(newvel.x > 180)  newvel.x -= 360;
 429         if(newvel.x < -180) newvel.x += 360;
 430         if(newvel.y > 180)  newvel.y -= 360;
 431         if(newvel.y < -180) newvel.y += 360;
 432
 433         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 434         if(ftmp > 180)  ftmp -= 360;
 435         if(ftmp < -180) ftmp += 360;
 436         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 437
 438         // Pitch
 439         ftmp = 0;
 440         if(CS(this).movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 441                 ftmp = 4;
 442         else if(CS(this).movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 443                 ftmp = -8;
 444
 445         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 446         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 447         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 448
 449         vehic.angles_x = anglemods(vehic.angles.x);
 450         vehic.angles_y = anglemods(vehic.angles.y);
 451         vehic.angles_z = anglemods(vehic.angles.z);
 452
 453         makevectors('0 1 0' * vehic.angles.y);
 454         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 455
 456         if(CS(this).movement.x != 0)
 457         {
 458                 if(CS(this).movement.x > 0)
 459                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 460                 else if(CS(this).movement.x < 0)
 461                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 462         }
 463
 464         if(CS(this).movement.y != 0)
 465         {
 466                 if(CS(this).movement.y < 0)
 467                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 468                 else if(CS(this).movement.y > 0)
 469                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 470                 ftmp = newvel * v_right;
 471                 ftmp *= dt * 0.1;
 472                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 473         }
 474         else
 475         {
 476                 vehic.angles_z *= 0.95;
 477                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 478                         vehic.angles_z = 0;
 479         }
 480
 481         if(PHYS_INPUT_BUTTON_CROUCH(this))
 482                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 483         else if(PHYS_INPUT_BUTTON_JUMP(this))
 484                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 485
 486         vehic.velocity  += newvel * dt;
 487         this.velocity = CS(this).movement  = vehic.velocity;
 488
 489
 490         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 491         {
 492                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 493                         vehic.tur_head.enemy = NULL;
 494
 495                 if(trace_ent)
 496                 if(trace_ent.move_movetype)
 497                 if(trace_ent.takedamage)
 498                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 499                 {
 500                         if(teamplay)
 501                         {
 502                                 if(trace_ent.team == this.team)
 503                                 {
 504                                         vehic.tur_head.enemy = trace_ent;
 505                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 506                                 }
 507                         }
 508                         else
 509                         {
 510                                 vehic.tur_head.enemy = trace_ent;
 511                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 512                         }
 513                 }
 514
 515                 if(vehic.tur_head.enemy)
 516                 {
 517                         trace_endpos = real_origin(vehic.tur_head.enemy);
 518                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 519                 }
 520         }
 521
 522         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 523                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 524                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 525
 526         if(!forbidWeaponUse(this))
 527         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME || autocvar_g_vehicle_bumblebee_raygun == 0))
 528         {
 529                 vehic.gun3.enemy.realowner = this;
 530                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 531
 532                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 533                 vehic.gun3.enemy.SendFlags |= BRG_START;
 534
 535                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 536
 537                 if(trace_ent)
 538                 {
 539                         if(autocvar_g_vehicle_bumblebee_raygun)
 540                         {
 541                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME, DEATH_GENERIC.m_id, DMG_NOWEP, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * PHYS_INPUT_FRAMETIME);
 542                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * PHYS_INPUT_FRAMETIME;
 543                         }
 544                         else
 545                         {
 546                                 if(!IS_DEAD(trace_ent))
 547                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 548                                         {
 549
 550                                                 if(IS_VEHICLE(trace_ent))
 551                                                 {
 552                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 553                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * dt, trace_ent.tur_head.max_health);
 554
 555                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 556                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 557                                                 }
 558                                                 else if(IS_CLIENT(trace_ent))
 559                                                 {
 560                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 561                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 562
 563                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 564                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * dt, autocvar_g_vehicle_bumblebee_healgun_amax);
 565
 566                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 567                                                 }
 568                                                 else if(IS_TURRET(trace_ent))
 569                                                 {
 570                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 571                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 572                                                         //else ..hmmm what? ammo?
 573
 574                                                         trace_ent.SendFlags |= TNSF_STATUS;
 575                                                 }
 576                                         }
 577                         }
 578                 }
 579
 580                 vehic.gun3.enemy.hook_end = trace_endpos;
 581                 setorigin(vehic.gun3.enemy, trace_endpos);
 582                 vehic.gun3.enemy.SendFlags |= BRG_END;
 583
 584                 vehic.wait = time + 1;
 585         }
 586         else
 587                 vehic.gun3.enemy.effects |= EF_NODRAW;
 588         /*{
 589                 if(vehic.gun3.enemy)
 590                         remove(vehic.gun3.enemy);
 591
 592                 vehic.gun3.enemy = NULL;
 593         }
 594         */
 595
 596         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 597         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 598
 599         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 600         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 601
 602         if(vehic.vehicle_flags & VHF_HASSHIELD)
 603                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 604
 605         vehic.angles_x *= -1;
 606         makevectors(vehic.angles);
 607         vehic.angles_x *= -1;
 608         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 609         this.oldorigin = this.origin; // negate fall damage
 610
 611         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 612 }
 613
 614 void bumblebee_land(entity this)
 615 {
 616         float hgt;
 617
 618         hgt = vehicle_altitude(this, 512);
 619         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
 620         this.angles_x *= 0.95;
 621         this.angles_z *= 0.95;
 622
 623         if(hgt < 16)
 624                 setthink(this, vehicles_think);
 625
 626         this.nextthink = time;
 627
 628         CSQCMODEL_AUTOUPDATE(this);
 629 }
 630
 631 void bumblebee_exit(entity this, int eject)
 632 {
 633         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 634         {
 635                 bumblebee_gunner_exit(this, eject);
 636                 return;
 637         }
 638
 639         settouch(this, vehicles_touch);
 640
 641         if(!IS_DEAD(this))
 642         {
 643                 setthink(this, bumblebee_land);
 644                 this.nextthink  = time;
 645         }
 646
 647         set_movetype(this, MOVETYPE_TOSS);
 648
 649         if(!this.owner)
 650                 return;
 651
 652         fixedmakevectors(this.angles);
 653         vector spot;
 654         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 655                 spot = this.origin + v_up * 128 + v_forward * 300;
 656         else
 657                 spot = this.origin + v_up * 128 - v_forward * 300;
 658
 659         spot = vehicles_findgoodexit(this, this.owner, spot);
 660
 661         // Hide beam
 662         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 663                 this.gun3.enemy.effects |= EF_NODRAW;
 664
 665         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 666         this.owner.velocity_z += 10;
 667         setorigin(this.owner, spot);
 668
 669         antilag_clear(this.owner, CS(this.owner));
 670         this.owner = NULL;
 671 }
 672
 673 void bumblebee_blowup(entity this)
 674 {
 675         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 676                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 677                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 678                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 679                                  DEATH_VH_BUMB_DEATH.m_id, DMG_NOWEP, NULL);
 680
 681         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 682         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 683
 684         if(this.owner.deadflag == DEAD_DYING)
 685                 this.owner.deadflag = DEAD_DEAD;
 686
 687         delete(this);
 688 }
 689
 690 void bumblebee_dead_touch(entity this, entity toucher)
 691 {
 692         bumblebee_blowup(this);
 693 }
 694
 695 void bumblebee_diethink(entity this)
 696 {
 697         if(time >= this.wait)
 698                 setthink(this, bumblebee_blowup);
 699
 700         if(random() < 0.1)
 701         {
 702                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 703                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 704         }
 705
 706         this.nextthink = time + 0.1;
 707 }
 708
 709 spawnfunc(vehicle_bumblebee)
 710 {
 711         if(!autocvar_g_vehicle_bumblebee) { delete(this); return; }
 712         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { delete(this); return; }
 713 }
 714
 715 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 716 {
 717     if(autocvar_g_vehicle_bumblebee_bouncepain)
 718         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 719 }
 720 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 721 {
 722     settouch(instance, bumblebee_touch);
 723     instance.nextthink = 0;
 724     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 725 }
 726 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 727 {
 728         if(!instance.gunner1)
 729         if(time >= instance.gun1.phase)
 730         if(instance.gun1.vehicle_enter)
 731         if(instance.gun1.vehicle_enter(instance, actor))
 732                 return;
 733
 734         if(!instance.gunner2)
 735         if(time >= instance.gun2.phase)
 736         if(instance.gun2.vehicle_enter)
 737         if(instance.gun2.vehicle_enter(instance, actor))
 738                 return;
 739 }
 740 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 741 {
 742     instance.angles_z *= 0.8;
 743     instance.angles_x *= 0.8;
 744
 745     instance.nextthink = time;
 746
 747     if(!instance.owner)
 748     {
 749         if(instance.gunner1)
 750         {
 751                 entity e = instance.gunner1;
 752                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 753                 instance.phase = 0;
 754                 gettouch(instance)(instance, e);
 755                 return;
 756         }
 757
 758         if(instance.gunner2)
 759         {
 760                 entity e = instance.gunner2;
 761                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 762                 instance.phase = 0;
 763                 gettouch(instance)(instance, e);
 764             return;
 765         }
 766     }
 767 }
 768 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 769 {
 770         CSQCModel_UnlinkEntity(instance);
 771
 772         // hide beam
 773         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 774                 instance.gun3.enemy.effects |= EF_NODRAW;
 775
 776         if(instance.gunner1)
 777                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 778
 779         if(instance.gunner2)
 780                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 781
 782         instance.vehicle_exit(instance, VHEF_EJECT);
 783
 784     fixedmakevectors(instance.angles);
 785     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 786     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 787     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 788
 789     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 790
 791     if(random() > 0.5)
 792         settouch(_body, bumblebee_dead_touch);
 793     else
 794         settouch(_body, func_null);
 795
 796     setthink(_body, bumblebee_diethink);
 797     _body.nextthink = time;
 798     _body.wait = time + 2 + (random() * 8);
 799     _body.owner = instance;
 800     _body.enemy = instance.enemy;
 801     _body.scale = 1.5;
 802     _body.angles = instance.angles;
 803
 804     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 805
 806     instance.health                     = 0;
 807     instance.event_damage       = func_null;
 808     instance.solid                      = SOLID_NOT;
 809     instance.takedamage         = DAMAGE_NO;
 810     instance.deadflag           = DEAD_DYING;
 811     set_movetype(instance, MOVETYPE_NONE);
 812     instance.effects            = EF_NODRAW;
 813     instance.colormod           = '0 0 0';
 814     instance.avelocity          = '0 0 0';
 815     instance.velocity           = '0 0 0';
 816     settouch(instance, func_null);
 817     instance.nextthink          = 0;
 818
 819     setorigin(instance, instance.pos1);
 820 }
 821 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 822 {
 823     if(!instance.gun1)
 824     {
 825         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 826         instance.vehicle_shieldent = spawn();
 827         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 828         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 829         setattachment(instance.vehicle_shieldent, instance, "");
 830         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 831         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 832         setthink(instance.vehicle_shieldent, shieldhit_think);
 833         instance.vehicle_shieldent.alpha = -1;
 834         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 835
 836         instance.gun1 = new(vehicle_playerslot);
 837         instance.gun2 = new(vehicle_playerslot);
 838         instance.gun3 = new(bumblebee_raygun);
 839
 840         instance.vehicle_flags |= VHF_MULTISLOT;
 841
 842         instance.gun1.owner = instance;
 843         instance.gun2.owner = instance;
 844         instance.gun3.owner = instance;
 845
 846         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 847         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 848         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 849
 850         setattachment(instance.gun1, instance, "cannon_right");
 851         setattachment(instance.gun2, instance, "cannon_left");
 852
 853         // Angled bones are no fun, messes up gun-aim; so work arround it.
 854         instance.gun3.pos1 = instance.angles;
 855         instance.angles = '0 0 0';
 856         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 857         ofs -= instance.origin;
 858         setattachment(instance.gun3, instance, "");
 859         setorigin(instance.gun3, ofs);
 860         instance.angles = instance.gun3.pos1;
 861
 862         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 863         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 864
 865         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 866         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 867
 868         //fixme-model-bones
 869         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 870         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 871         //fixme-model-bones
 872         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 873         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 874
 875         instance.scale = 1.5;
 876
 877         // Raygun beam
 878         if(instance.gun3.enemy == NULL)
 879         {
 880             instance.gun3.enemy = spawn();
 881             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 882             instance.gun3.enemy.SendFlags = BRG_SETUP;
 883             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 884             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 885         }
 886     }
 887
 888     if(!autocvar_g_vehicle_bumblebee_swim)
 889         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 890
 891     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 892     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 893     instance.solid = SOLID_BBOX;
 894     set_movetype(instance, MOVETYPE_TOSS);
 895     instance.damageforcescale = 0.025;
 896
 897     instance.PlayerPhysplug = bumblebee_pilot_frame;
 898
 899     setorigin(instance, instance.origin + '0 0 25');
 900 }
 901 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 902 {
 903     if(autocvar_g_vehicle_bumblebee_energy)
 904     if(autocvar_g_vehicle_bumblebee_energy_regen)
 905         instance.vehicle_flags |= VHF_ENERGYREGEN;
 906
 907     if(autocvar_g_vehicle_bumblebee_shield)
 908         instance.vehicle_flags |= VHF_HASSHIELD;
 909
 910     if(autocvar_g_vehicle_bumblebee_shield_regen)
 911         instance.vehicle_flags |= VHF_SHIELDREGEN;
 912
 913     if(autocvar_g_vehicle_bumblebee_health_regen)
 914         instance.vehicle_flags |= VHF_HEALTHREGEN;
 915
 916     instance.vehicle_exit = bumblebee_exit;
 917     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 918     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 919     instance.max_health = instance.vehicle_health;
 920     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 921 }
 922
 923 #endif // SVQC
 924 #ifdef CSQC
 925
 926 void CSQC_BUMBLE_GUN_HUD()
 927 {
 928         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 929                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 930                                          string_null, '0 0 0');
 931 }
 932
 933 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 934 {
 935     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 936                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 937                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 938
 939     float hudAlpha = autocvar_hud_panel_fg_alpha;
 940     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 941     vector tmpPos  = '0 0 0';
 942     vector tmpSize = '1 1 1' * hud_fontsize;
 943     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 944
 945     if(!AuxiliaryXhair[1].draw2d)
 946     {
 947         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 948         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 949     }
 950
 951     if(!AuxiliaryXhair[2].draw2d)
 952     {
 953         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 954         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 955     }
 956 }
 957 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 958 {
 959     Vehicles_drawCrosshair(vCROSS_HEAL);
 960 }
 961 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 962 {
 963     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 964     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 965     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 966 }
 967
 968 #endif