qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #ifndef VEHICLE_BUMBLEBEE
   2 #define VEHICLE_BUMBLEBEE
   3 #include "bumblebee.qh"
   4
   5 #include "bumblebee_weapons.qh"
   6
   7 CLASS(Bumblebee, Vehicle)
   8 /* spawnflags */ ATTRIB(Bumblebee, spawnflags, int, VHF_DMGSHAKE);
   9 /* mins       */ ATTRIB(Bumblebee, mins, vector, '-245 -130 -130');
  10 /* maxs       */ ATTRIB(Bumblebee, maxs, vector, '230 130 130');
  11 /* view offset*/ ATTRIB(Bumblebee, view_ofs, vector, '0 0 300');
  12 /* view dist  */ ATTRIB(Bumblebee, height, float, 450);
  13 /* model          */ ATTRIB(Bumblebee, mdl, string, "models/vehicles/bumblebee_body.dpm");
  14 /* model          */ ATTRIB(Bumblebee, model, string, "models/vehicles/bumblebee_body.dpm");
  15 /* head_model */ ATTRIB(Bumblebee, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Bumblebee, hud_model, string, "models/vehicles/spiderbot_cockpit.dpm");
  17 /* tags       */ ATTRIB(Bumblebee, tag_head, string, "");
  18 /* tags       */ ATTRIB(Bumblebee, tag_hud, string, "");
  19 /* tags       */ ATTRIB(Bumblebee, tag_view, string, "tag_viewport");
  20 /* netname    */ ATTRIB(Bumblebee, netname, string, "bumblebee");
  21 /* fullname   */ ATTRIB(Bumblebee, vehicle_name, string, _("Bumblebee"));
  22 /* icon       */ ATTRIB(Bumblebee, m_icon, string, "vehicle_bumble");
  23 ENDCLASS(Bumblebee)
  24 REGISTER_VEHICLE(BUMBLEBEE, NEW(Bumblebee));
  25
  26 #ifndef MENUQC
  27         MODEL(VEH_BUMBLEBEE_GUNCOCKPIT, "models/vehicles/wakizashi_cockpit.dpm");
  28 #endif
  29
  30 #endif
  31
  32 #ifdef IMPLEMENTATION
  33
  34 const float BRG_SETUP = 2;
  35 const float BRG_START = 4;
  36 const float BRG_END = 8;
  37
  38 #ifdef SVQC
  39 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  40
  41 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  42 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  43 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  44 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  45 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  46 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  47 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  48 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  49 bool autocvar_g_vehicle_bumblebee_swim = false;
  50
  51 float autocvar_g_vehicle_bumblebee_energy = 500;
  52 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  53 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  54
  55 float autocvar_g_vehicle_bumblebee_health = 1000;
  56 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  57 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  58
  59 float autocvar_g_vehicle_bumblebee_shield = 400;
  60 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  61 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  62
  63 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  64 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  65 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  66
  67 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  68
  69 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  70 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  71 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  72 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  73 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  74
  75
  76 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  77 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  78 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  79 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  80
  81 bool autocvar_g_vehicle_bumblebee_raygun = false;
  82 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  83 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  84 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  85 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  86
  87 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  88 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  89 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  90 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  91 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  92 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  93
  94 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  95 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  96 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  97 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  98 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  99
 100 bool autocvar_g_vehicle_bumblebee = true;
 101
 102 bool bumblebee_gunner_frame(entity this, float dt)
 103 {
 104         entity vehic = this.vehicle.owner;
 105         entity gun = this.vehicle;
 106         return = true;
 107
 108         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
 109         //vehicles_frame(gun, player);
 110
 111         vehic.solid = SOLID_NOT;
 112         //setorigin(this, vehic.origin);
 113         this.velocity = vehic.velocity;
 114
 115         float _in, _out;
 116         vehic.angles_x *= -1;
 117         makevectors(vehic.angles);
 118         vehic.angles_x *= -1;
 119         if(gun == vehic.gun1)
 120         {
 121                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 122                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 123                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 124         }
 125         else
 126         {
 127                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 128                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 129                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 130         }
 131
 132         crosshair_trace(this);
 133         vector _ct = trace_endpos;
 134         vector ad;
 135
 136         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 137         {
 138                 if(gun.lock_time < time)
 139                         gun.enemy = NULL;
 140
 141                 if(trace_ent)
 142                         if(trace_ent.move_movetype)
 143                                 if(trace_ent.takedamage)
 144                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 145                                         {
 146                                                 if(DIFF_TEAM(trace_ent, this))
 147                                                 {
 148                                                         gun.enemy = trace_ent;
 149                                                         gun.lock_time = time + 5;
 150                                                 }
 151                                         }
 152         }
 153
 154         if(gun.enemy)
 155         {
 156                 float distance, impact_time;
 157
 158                 vector vf = real_origin(gun.enemy);
 159                 vector _vel = gun.enemy.velocity;
 160                 if(gun.enemy.move_movetype == MOVETYPE_WALK)
 161                         _vel.z *= 0.1;
 162
 163
 164                 ad = vf;
 165                 distance = vlen(ad - this.origin);
 166                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 167                 ad = vf + _vel * impact_time;
 168                 trace_endpos = ad;
 169
 170
 171                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 172                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 173                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 174                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 175
 176         }
 177         else
 178                 vehicle_aimturret(vehic, _ct, gun, "fire",
 179                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 180                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 181
 182         if(!forbidWeaponUse(this))
 183         if(PHYS_INPUT_BUTTON_ATCK(this))
 184                 if(time > gun.attack_finished_single[0])
 185                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 186                         {
 187                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 188                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 189                                 gun.delay = time;
 190                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 191                         }
 192
 193         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 194
 195         if(vehic.vehicle_flags & VHF_HASSHIELD)
 196                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 197
 198         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 199         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 200
 201         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 202
 203         if(vehic.owner)
 204                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 205
 206         vehic.solid = SOLID_BBOX;
 207         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 208         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 209 }
 210
 211 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 212 {
 213         //vector exitspot;
 214         float mysize;
 215
 216         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 217         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 218                 return prefer_spot;
 219
 220         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 221         float i;
 222         vector v, v2;
 223         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 224         for(i = 0; i < 100; ++i)
 225         {
 226                 v = randomvec();
 227                 v_z = 0;
 228                 v = v2 + normalize(v) * mysize;
 229                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 230                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 231                         return v;
 232         }
 233
 234         return prefer_spot; // this should be considered a fallback?!
 235 }
 236
 237 void bumblebee_gunner_exit(entity this, int _exitflag)
 238 {
 239         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 240         entity gunner = this;
 241         entity vehic = gunner.owner;
 242
 243         if(IS_REAL_CLIENT(player))
 244         {
 245                 msg_entity = player;
 246                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 247                 WriteEntity(MSG_ONE, player);
 248
 249                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 250                 WriteAngle(MSG_ONE, 0);
 251                 WriteAngle(MSG_ONE, vehic.angles.y);
 252                 WriteAngle(MSG_ONE, 0);
 253         }
 254
 255         CSQCVehicleSetup(player, HUD_NORMAL);
 256         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 257
 258         player.takedamage     = DAMAGE_AIM;
 259         player.solid          = SOLID_SLIDEBOX;
 260         set_movetype(player, MOVETYPE_WALK);
 261         player.effects       &= ~EF_NODRAW;
 262         player.alpha          = 1;
 263         player.PlayerPhysplug = func_null;
 264         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 265         player.event_damage   = PlayerDamage;
 266         player.hud            = HUD_NORMAL;
 267         player.teleportable       = TELEPORT_NORMAL;
 268         PS(player).m_switchweapon = gunner.m_switchweapon;
 269         player.vehicle_enter_delay = time + 2;
 270
 271         fixedmakevectors(vehic.angles);
 272
 273         if(player == vehic.gunner1) { vehic.gunner1 = NULL; }
 274         if(player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 275
 276         vector spot = real_origin(gunner);
 277         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 278         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 279
 280         // TODO: figure a way to move player out of the gunner
 281
 282         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 283         player.velocity_z += 10;
 284
 285         gunner.phase = time + 5;
 286         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 287
 288         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 289
 290         player.vehicle = NULL;
 291 }
 292
 293 bool bumblebee_gunner_enter(entity this, entity player)
 294 {
 295         entity vehic = this;
 296         entity gunner = NULL;
 297
 298         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 299         {
 300                 // we can have some fun
 301                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 302                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 303                 if(vlen2(player.origin - v1) < vlen2(player.origin - v2))
 304                 {
 305                         gunner = vehic.gun1;
 306                         vehic.gunner1 = player;
 307                 }
 308                 else
 309                 {
 310                         gunner = vehic.gun2;
 311                         vehic.gunner2 = player;
 312                 }
 313         }
 314         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 315         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 316         else { LOG_TRACE("Vehicle is full, fail"); return false; }
 317
 318         player.vehicle                  = gunner;
 319         player.angles                   = vehic.angles;
 320         player.takedamage               = DAMAGE_NO;
 321         player.solid                    = SOLID_NOT;
 322         player.alpha                    = -1;
 323         set_movetype(player, MOVETYPE_NOCLIP);
 324         player.event_damage     = func_null;
 325         player.view_ofs                 = '0 0 0';
 326         player.hud                              = gunner.hud;
 327         player.teleportable     = false;
 328         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 329         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 330         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 331         player.vehicle_reload1  = vehic.vehicle_reload1;
 332         player.vehicle_reload2  = vehic.vehicle_reload2;
 333         player.vehicle_energy   = vehic.vehicle_energy;
 334         UNSET_ONGROUND(player);
 335
 336         RemoveGrapplingHook(player);
 337
 338         gunner.m_switchweapon = PS(player).m_switchweapon;
 339         gunner.vehicle_exit = bumblebee_gunner_exit;
 340         gunner.vehicle_hudmodel.viewmodelforclient = player;
 341
 342         if(IS_REAL_CLIENT(player))
 343         {
 344                 msg_entity = player;
 345                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 346                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 347
 348                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 349                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 350                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 351                 WriteAngle(MSG_ONE,     0); // roll
 352         }
 353
 354         CSQCVehicleSetup(player, player.hud);
 355
 356         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 357
 358         return true;
 359 }
 360
 361 bool vehicles_valid_pilot(entity this, entity toucher)
 362 {
 363         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 364                 return false;
 365
 366         if((!IS_PLAYER(toucher))
 367         || (IS_DEAD(toucher))
 368         || (toucher.vehicle)
 369         || (DIFF_TEAM(toucher, this))
 370         ) { return false; }
 371
 372         return true;
 373 }
 374
 375 void bumblebee_touch(entity this, entity toucher)
 376 {
 377         if(autocvar_g_vehicles_enter) { return; }
 378
 379         if(this.gunner1 != NULL && this.gunner2 != NULL)
 380         {
 381                 vehicles_touch(this, toucher);
 382                 return;
 383         }
 384
 385         if(vehicles_valid_pilot(this, toucher))
 386         {
 387                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 388
 389                 if(time >= toucher.vehicle_enter_delay && phase_time)
 390                 if(bumblebee_gunner_enter(this, toucher))
 391                         return;
 392         }
 393
 394         vehicles_touch(this, toucher);
 395 }
 396
 397 void bumblebee_regen(entity this, float dt)
 398 {
 399         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 400                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 401                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 402
 403         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 404                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 405                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 406
 407         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 408                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, dt, true);
 409
 410         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 411                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, dt, false);
 412
 413         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 414                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, dt, false);
 415
 416 }
 417
 418 bool bumblebee_pilot_frame(entity this, float dt)
 419 {
 420         entity vehic = this.vehicle;
 421         return = true;
 422
 423         if(intermission_running)
 424         {
 425                 vehic.velocity = '0 0 0';
 426                 vehic.avelocity = '0 0 0';
 427                 return;
 428         }
 429
 430         vehicles_frame(vehic, this);
 431
 432         if(IS_DEAD(vehic))
 433         {
 434                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 435                 return;
 436         }
 437
 438         bumblebee_regen(vehic, dt);
 439
 440         crosshair_trace(this);
 441
 442         vector vang = vehic.angles;
 443         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 444         vang.x *= -1;
 445         newvel.x *= -1;
 446         if(newvel.x > 180)  newvel.x -= 360;
 447         if(newvel.x < -180) newvel.x += 360;
 448         if(newvel.y > 180)  newvel.y -= 360;
 449         if(newvel.y < -180) newvel.y += 360;
 450
 451         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 452         if(ftmp > 180)  ftmp -= 360;
 453         if(ftmp < -180) ftmp += 360;
 454         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 455
 456         // Pitch
 457         ftmp = 0;
 458         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 459                 ftmp = 4;
 460         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 461                 ftmp = -8;
 462
 463         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 464         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 465         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 466
 467         vehic.angles_x = anglemods(vehic.angles.x);
 468         vehic.angles_y = anglemods(vehic.angles.y);
 469         vehic.angles_z = anglemods(vehic.angles.z);
 470
 471         makevectors('0 1 0' * vehic.angles.y);
 472         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 473
 474         if(this.movement.x != 0)
 475         {
 476                 if(this.movement.x > 0)
 477                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 478                 else if(this.movement.x < 0)
 479                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 480         }
 481
 482         if(this.movement.y != 0)
 483         {
 484                 if(this.movement.y < 0)
 485                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 486                 else if(this.movement.y > 0)
 487                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 488                 ftmp = newvel * v_right;
 489                 ftmp *= dt * 0.1;
 490                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 491         }
 492         else
 493         {
 494                 vehic.angles_z *= 0.95;
 495                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 496                         vehic.angles_z = 0;
 497         }
 498
 499         if(PHYS_INPUT_BUTTON_CROUCH(this))
 500                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 501         else if(PHYS_INPUT_BUTTON_JUMP(this))
 502                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 503
 504         vehic.velocity  += newvel * dt;
 505         this.velocity = this.movement  = vehic.velocity;
 506
 507
 508         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 509         {
 510                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 511                         vehic.tur_head.enemy = NULL;
 512
 513                 if(trace_ent)
 514                 if(trace_ent.move_movetype)
 515                 if(trace_ent.takedamage)
 516                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 517                 {
 518                         if(teamplay)
 519                         {
 520                                 if(trace_ent.team == this.team)
 521                                 {
 522                                         vehic.tur_head.enemy = trace_ent;
 523                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 524                                 }
 525                         }
 526                         else
 527                         {
 528                                 vehic.tur_head.enemy = trace_ent;
 529                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 530                         }
 531                 }
 532
 533                 if(vehic.tur_head.enemy)
 534                 {
 535                         trace_endpos = real_origin(vehic.tur_head.enemy);
 536                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 537                 }
 538         }
 539
 540         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 541                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 542                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 543
 544         if(!forbidWeaponUse(this))
 545         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME || autocvar_g_vehicle_bumblebee_raygun == 0))
 546         {
 547                 vehic.gun3.enemy.realowner = this;
 548                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 549
 550                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 551                 vehic.gun3.enemy.SendFlags |= BRG_START;
 552
 553                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 554
 555                 if(trace_ent)
 556                 {
 557                         if(autocvar_g_vehicle_bumblebee_raygun)
 558                         {
 559                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * PHYS_INPUT_FRAMETIME);
 560                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * PHYS_INPUT_FRAMETIME;
 561                         }
 562                         else
 563                         {
 564                                 if(!IS_DEAD(trace_ent))
 565                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 566                                         {
 567
 568                                                 if(IS_VEHICLE(trace_ent))
 569                                                 {
 570                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 571                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * dt, trace_ent.tur_head.max_health);
 572
 573                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 574                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 575                                                 }
 576                                                 else if(IS_CLIENT(trace_ent))
 577                                                 {
 578                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 579                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 580
 581                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 582                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * dt, autocvar_g_vehicle_bumblebee_healgun_amax);
 583
 584                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 585                                                 }
 586                                                 else if(IS_TURRET(trace_ent))
 587                                                 {
 588                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 589                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 590                                                         //else ..hmmm what? ammo?
 591
 592                                                         trace_ent.SendFlags |= TNSF_STATUS;
 593                                                 }
 594                                         }
 595                         }
 596                 }
 597
 598                 vehic.gun3.enemy.hook_end = trace_endpos;
 599                 setorigin(vehic.gun3.enemy, trace_endpos);
 600                 vehic.gun3.enemy.SendFlags |= BRG_END;
 601
 602                 vehic.wait = time + 1;
 603         }
 604         else
 605                 vehic.gun3.enemy.effects |= EF_NODRAW;
 606         /*{
 607                 if(vehic.gun3.enemy)
 608                         remove(vehic.gun3.enemy);
 609
 610                 vehic.gun3.enemy = NULL;
 611         }
 612         */
 613
 614         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 615         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 616
 617         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 618         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 619
 620         if(vehic.vehicle_flags & VHF_HASSHIELD)
 621                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 622
 623         vehic.angles_x *= -1;
 624         makevectors(vehic.angles);
 625         vehic.angles_x *= -1;
 626         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 627
 628         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 629 }
 630
 631 void bumblebee_land(entity this)
 632 {
 633         float hgt;
 634
 635         hgt = vehicle_altitude(this, 512);
 636         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
 637         this.angles_x *= 0.95;
 638         this.angles_z *= 0.95;
 639
 640         if(hgt < 16)
 641                 setthink(this, vehicles_think);
 642
 643         this.nextthink = time;
 644
 645         CSQCMODEL_AUTOUPDATE(this);
 646 }
 647
 648 void bumblebee_exit(entity this, int eject)
 649 {
 650         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 651         {
 652                 bumblebee_gunner_exit(this, eject);
 653                 return;
 654         }
 655
 656         settouch(this, vehicles_touch);
 657
 658         if(!IS_DEAD(this))
 659         {
 660                 setthink(this, bumblebee_land);
 661                 this.nextthink  = time;
 662         }
 663
 664         set_movetype(this, MOVETYPE_TOSS);
 665
 666         if(!this.owner)
 667                 return;
 668
 669         fixedmakevectors(this.angles);
 670         vector spot;
 671         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 672                 spot = this.origin + v_up * 128 + v_forward * 300;
 673         else
 674                 spot = this.origin + v_up * 128 - v_forward * 300;
 675
 676         spot = vehicles_findgoodexit(this, spot);
 677
 678         // Hide beam
 679         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 680                 this.gun3.enemy.effects |= EF_NODRAW;
 681
 682         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 683         this.owner.velocity_z += 10;
 684         setorigin(this.owner, spot);
 685
 686         antilag_clear(this.owner, CS(this.owner));
 687         this.owner = NULL;
 688 }
 689
 690 void bumblebee_blowup(entity this)
 691 {
 692         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 693                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 694                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 695                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 696                                  DEATH_VH_BUMB_DEATH.m_id, NULL);
 697
 698         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 699         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 700
 701         if(this.owner.deadflag == DEAD_DYING)
 702                 this.owner.deadflag = DEAD_DEAD;
 703
 704         delete(this);
 705 }
 706
 707 void bumblebee_dead_touch(entity this, entity toucher)
 708 {
 709         bumblebee_blowup(this);
 710 }
 711
 712 void bumblebee_diethink(entity this)
 713 {
 714         if(time >= this.wait)
 715                 setthink(this, bumblebee_blowup);
 716
 717         if(random() < 0.1)
 718         {
 719                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 720                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 721         }
 722
 723         this.nextthink = time + 0.1;
 724 }
 725
 726 spawnfunc(vehicle_bumblebee)
 727 {
 728         if(!autocvar_g_vehicle_bumblebee) { delete(this); return; }
 729         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { delete(this); return; }
 730 }
 731
 732 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 733 {
 734     if(autocvar_g_vehicle_bumblebee_bouncepain)
 735         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 736 }
 737 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 738 {
 739     settouch(instance, bumblebee_touch);
 740     instance.nextthink = 0;
 741     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 742 }
 743 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 744 {
 745         if(!instance.gunner1)
 746         if(time >= instance.gun1.phase)
 747         if(instance.gun1.vehicle_enter)
 748         if(instance.gun1.vehicle_enter(instance, actor))
 749                 return;
 750
 751         if(!instance.gunner2)
 752         if(time >= instance.gun2.phase)
 753         if(instance.gun2.vehicle_enter)
 754         if(instance.gun2.vehicle_enter(instance, actor))
 755                 return;
 756 }
 757 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 758 {
 759     instance.angles_z *= 0.8;
 760     instance.angles_x *= 0.8;
 761
 762     instance.nextthink = time;
 763
 764     if(!instance.owner)
 765     {
 766         if(instance.gunner1)
 767         {
 768                 entity e = instance.gunner1;
 769                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 770                 instance.phase = 0;
 771                 gettouch(instance)(instance, e);
 772                 return;
 773         }
 774
 775         if(instance.gunner2)
 776         {
 777                 entity e = instance.gunner2;
 778                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 779                 instance.phase = 0;
 780                 gettouch(instance)(instance, e);
 781             return;
 782         }
 783     }
 784 }
 785 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 786 {
 787         CSQCModel_UnlinkEntity(instance);
 788
 789         // hide beam
 790         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 791                 instance.gun3.enemy.effects |= EF_NODRAW;
 792
 793         if(instance.gunner1)
 794                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 795
 796         if(instance.gunner2)
 797                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 798
 799         instance.vehicle_exit(instance, VHEF_EJECT);
 800
 801     fixedmakevectors(instance.angles);
 802     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 803     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 804     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 805
 806     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 807
 808     if(random() > 0.5)
 809         settouch(_body, bumblebee_dead_touch);
 810     else
 811         settouch(_body, func_null);
 812
 813     setthink(_body, bumblebee_diethink);
 814     _body.nextthink = time;
 815     _body.wait = time + 2 + (random() * 8);
 816     _body.owner = instance;
 817     _body.enemy = instance.enemy;
 818     _body.scale = 1.5;
 819     _body.angles = instance.angles;
 820
 821     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 822
 823     instance.health                     = 0;
 824     instance.event_damage       = func_null;
 825     instance.solid                      = SOLID_NOT;
 826     instance.takedamage         = DAMAGE_NO;
 827     instance.deadflag           = DEAD_DYING;
 828     set_movetype(instance, MOVETYPE_NONE);
 829     instance.effects            = EF_NODRAW;
 830     instance.colormod           = '0 0 0';
 831     instance.avelocity          = '0 0 0';
 832     instance.velocity           = '0 0 0';
 833     settouch(instance, func_null);
 834     instance.nextthink          = 0;
 835
 836     setorigin(instance, instance.pos1);
 837 }
 838 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 839 {
 840     if(!instance.gun1)
 841     {
 842         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 843         instance.vehicle_shieldent = spawn();
 844         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 845         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 846         setattachment(instance.vehicle_shieldent, instance, "");
 847         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 848         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 849         setthink(instance.vehicle_shieldent, shieldhit_think);
 850         instance.vehicle_shieldent.alpha = -1;
 851         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 852
 853         instance.gun1 = new(vehicle_playerslot);
 854         instance.gun2 = new(vehicle_playerslot);
 855         instance.gun3 = new(bumblebee_raygun);
 856
 857         instance.vehicle_flags |= VHF_MULTISLOT;
 858
 859         instance.gun1.owner = instance;
 860         instance.gun2.owner = instance;
 861         instance.gun3.owner = instance;
 862
 863         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 864         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 865         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 866
 867         setattachment(instance.gun1, instance, "cannon_right");
 868         setattachment(instance.gun2, instance, "cannon_left");
 869
 870         // Angled bones are no fun, messes up gun-aim; so work arround it.
 871         instance.gun3.pos1 = instance.angles;
 872         instance.angles = '0 0 0';
 873         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 874         ofs -= instance.origin;
 875         setattachment(instance.gun3, instance, "");
 876         setorigin(instance.gun3, ofs);
 877         instance.angles = instance.gun3.pos1;
 878
 879         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 880         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 881
 882         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 883         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 884
 885         //fixme-model-bones
 886         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 887         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 888         //fixme-model-bones
 889         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 890         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 891
 892         instance.scale = 1.5;
 893
 894         // Raygun beam
 895         if(instance.gun3.enemy == NULL)
 896         {
 897             instance.gun3.enemy = spawn();
 898             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 899             instance.gun3.enemy.SendFlags = BRG_SETUP;
 900             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 901             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 902         }
 903     }
 904
 905     if(!autocvar_g_vehicle_bumblebee_swim)
 906         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 907
 908     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 909     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 910     instance.solid = SOLID_BBOX;
 911     set_movetype(instance, MOVETYPE_TOSS);
 912     instance.damageforcescale = 0.025;
 913
 914     instance.PlayerPhysplug = bumblebee_pilot_frame;
 915
 916     setorigin(instance, instance.origin + '0 0 25');
 917 }
 918 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 919 {
 920     if(autocvar_g_vehicle_bumblebee_energy)
 921     if(autocvar_g_vehicle_bumblebee_energy_regen)
 922         instance.vehicle_flags |= VHF_ENERGYREGEN;
 923
 924     if(autocvar_g_vehicle_bumblebee_shield)
 925         instance.vehicle_flags |= VHF_HASSHIELD;
 926
 927     if(autocvar_g_vehicle_bumblebee_shield_regen)
 928         instance.vehicle_flags |= VHF_SHIELDREGEN;
 929
 930     if(autocvar_g_vehicle_bumblebee_health_regen)
 931         instance.vehicle_flags |= VHF_HEALTHREGEN;
 932
 933     instance.vehicle_exit = bumblebee_exit;
 934     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 935     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 936     instance.max_health = instance.vehicle_health;
 937     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 938 }
 939
 940 #endif // SVQC
 941 #ifdef CSQC
 942
 943 void CSQC_BUMBLE_GUN_HUD()
 944 {
 945         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 946                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 947                                          string_null, '0 0 0');
 948 }
 949
 950 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 951 {
 952     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 953                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 954                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 955
 956     float hudAlpha = autocvar_hud_panel_fg_alpha;
 957     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 958     vector tmpPos  = '0 0 0';
 959     vector tmpSize = '1 1 1' * hud_fontsize;
 960     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 961
 962     if(!AuxiliaryXhair[1].draw2d)
 963     {
 964         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 965         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 966     }
 967
 968     if(!AuxiliaryXhair[2].draw2d)
 969     {
 970         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 971         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 972     }
 973 }
 974 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 975 {
 976     Vehicles_drawCrosshair(vCROSS_HEAL);
 977 }
 978 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 979 {
 980     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 981     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 982     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 983 }
 984
 985 #endif
 986 #endif