qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #ifndef VEHICLE_BUMBLEBEE
   2 #define VEHICLE_BUMBLEBEE
   3 #include "bumblebee.qh"
   4
   5 #include "bumblebee_weapons.qh"
   6
   7 CLASS(Bumblebee, Vehicle)
   8 /* spawnflags */ ATTRIB(Bumblebee, spawnflags, int, VHF_DMGSHAKE);
   9 /* mins       */ ATTRIB(Bumblebee, mins, vector, '-245 -130 -130');
  10 /* maxs       */ ATTRIB(Bumblebee, maxs, vector, '230 130 130');
  11 /* view offset*/ ATTRIB(Bumblebee, view_ofs, vector, '0 0 300');
  12 /* view dist  */ ATTRIB(Bumblebee, height, float, 450);
  13 /* model          */ ATTRIB(Bumblebee, mdl, string, "models/vehicles/bumblebee_body.dpm");
  14 /* model          */ ATTRIB(Bumblebee, model, string, "models/vehicles/bumblebee_body.dpm");
  15 /* head_model */ ATTRIB(Bumblebee, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Bumblebee, hud_model, string, "models/vehicles/spiderbot_cockpit.dpm");
  17 /* tags       */ ATTRIB(Bumblebee, tag_head, string, "");
  18 /* tags       */ ATTRIB(Bumblebee, tag_hud, string, "");
  19 /* tags       */ ATTRIB(Bumblebee, tag_view, string, "tag_viewport");
  20 /* netname    */ ATTRIB(Bumblebee, netname, string, "bumblebee");
  21 /* fullname   */ ATTRIB(Bumblebee, vehicle_name, string, _("Bumblebee"));
  22 /* icon       */ ATTRIB(Bumblebee, m_icon, string, "vehicle_bumble");
  23 ENDCLASS(Bumblebee)
  24 REGISTER_VEHICLE(BUMBLEBEE, NEW(Bumblebee));
  25
  26 #ifndef MENUQC
  27         MODEL(VEH_BUMBLEBEE_GUNCOCKPIT, "models/vehicles/wakizashi_cockpit.dpm");
  28 #endif
  29
  30 #endif
  31
  32 #ifdef IMPLEMENTATION
  33
  34 const float BRG_SETUP = 2;
  35 const float BRG_START = 4;
  36 const float BRG_END = 8;
  37
  38 #ifdef SVQC
  39 float autocvar_g_vehicle_bumblebee_respawntime = 60;
  40
  41 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  42 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  43 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  44 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  45 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  46 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  47 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  48 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  49
  50 float autocvar_g_vehicle_bumblebee_energy = 500;
  51 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  52 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  53
  54 float autocvar_g_vehicle_bumblebee_health = 1000;
  55 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  56 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  57
  58 float autocvar_g_vehicle_bumblebee_shield = 400;
  59 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  60 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  61
  62 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  63 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  64 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  65
  66 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  67
  68 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  69 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  70 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  71 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  72 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  73
  74
  75 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  76 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  77 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  78 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  79
  80 bool autocvar_g_vehicle_bumblebee_raygun = false;
  81 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  82 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  83 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  84 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  85
  86 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  87 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  88 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  89 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  90 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  91 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  92
  93 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  94 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  95 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  96 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  97 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  98
  99 bool autocvar_g_vehicle_bumblebee = true;
 100
 101 bool bumblebee_gunner_frame(entity this)
 102 {
 103         entity vehic = this.vehicle.owner;
 104         entity gun = this.vehicle;
 105         return = true;
 106
 107         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
 108         //vehicles_frame(gun, player);
 109
 110         vehic.solid = SOLID_NOT;
 111         //setorigin(this, vehic.origin);
 112         this.velocity = vehic.velocity;
 113
 114         float _in, _out;
 115         vehic.angles_x *= -1;
 116         makevectors(vehic.angles);
 117         vehic.angles_x *= -1;
 118         if(gun == vehic.gun1)
 119         {
 120                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 121                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 122                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 123         }
 124         else
 125         {
 126                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 127                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 128                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 129         }
 130
 131         crosshair_trace(this);
 132         vector _ct = trace_endpos;
 133         vector ad;
 134
 135         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 136         {
 137                 if(gun.lock_time < time)
 138                         gun.enemy = world;
 139
 140                 if(trace_ent)
 141                         if(trace_ent.movetype)
 142                                 if(trace_ent.takedamage)
 143                                         if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 144                                         {
 145                                                 if(DIFF_TEAM(trace_ent, this))
 146                                                 {
 147                                                         gun.enemy = trace_ent;
 148                                                         gun.lock_time = time + 5;
 149                                                 }
 150                                         }
 151         }
 152
 153         if(gun.enemy)
 154         {
 155                 float distance, impact_time;
 156
 157                 vector vf = real_origin(gun.enemy);
 158                 vector _vel = gun.enemy.velocity;
 159                 if(gun.enemy.movetype == MOVETYPE_WALK)
 160                         _vel.z *= 0.1;
 161
 162
 163                 ad = vf;
 164                 distance = vlen(ad - this.origin);
 165                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 166                 ad = vf + _vel * impact_time;
 167                 trace_endpos = ad;
 168
 169
 170                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 171                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 172                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 173                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 174
 175         }
 176         else
 177                 vehicle_aimturret(vehic, _ct, gun, "fire",
 178                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 179                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 180
 181         if(!forbidWeaponUse(this))
 182         if(PHYS_INPUT_BUTTON_ATCK(this))
 183                 if(time > gun.attack_finished_single[0])
 184                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 185                         {
 186                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 187                                 bumblebee_fire_cannon(vehic, gun, "fire", this);
 188                                 gun.delay = time;
 189                                 gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 190                         }
 191
 192         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 193
 194         if(vehic.vehicle_flags & VHF_HASSHIELD)
 195                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 196
 197         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 198         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 199
 200         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), 0);
 201
 202         if(vehic.owner)
 203                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' *(1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 204
 205         vehic.solid = SOLID_BBOX;
 206         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 207         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 208 }
 209
 210 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 211 {
 212         //vector exitspot;
 213         float mysize;
 214
 215         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), prefer_spot, MOVE_NORMAL, player);
 216         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 217                 return prefer_spot;
 218
 219         mysize = 1.5 * vlen(STAT(PL_MAX, NULL) - STAT(PL_MIN, NULL)); // can't use gunner's size, as they don't have a size
 220         float i;
 221         vector v, v2;
 222         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 223         for(i = 0; i < 100; ++i)
 224         {
 225                 v = randomvec();
 226                 v_z = 0;
 227                 v = v2 + normalize(v) * mysize;
 228                 tracebox(v2, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v, MOVE_NORMAL, player);
 229                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 230                         return v;
 231         }
 232
 233         return prefer_spot; // this should be considered a fallback?!
 234 }
 235
 236 void bumblebee_gunner_exit(entity this, int _exitflag)
 237 {
 238         entity player = this;
 239         entity gunner = player.vehicle;
 240         entity vehic = gunner.owner;
 241
 242         if(IS_REAL_CLIENT(player))
 243         {
 244                 msg_entity = player;
 245                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 246                 WriteEntity(MSG_ONE, player);
 247
 248                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 249                 WriteAngle(MSG_ONE, 0);
 250                 WriteAngle(MSG_ONE, vehic.angles.y);
 251                 WriteAngle(MSG_ONE, 0);
 252         }
 253
 254         CSQCVehicleSetup(player, HUD_NORMAL);
 255         setsize(player, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 256
 257         player.takedamage     = DAMAGE_AIM;
 258         player.solid          = SOLID_SLIDEBOX;
 259         player.movetype       = MOVETYPE_WALK;
 260         player.effects       &= ~EF_NODRAW;
 261         player.alpha          = 1;
 262         player.PlayerPhysplug = func_null;
 263         player.view_ofs       = STAT(PL_VIEW_OFS, NULL);
 264         player.event_damage   = PlayerDamage;
 265         player.hud            = HUD_NORMAL;
 266         player.teleportable       = TELEPORT_NORMAL;
 267         PS(player).m_switchweapon = gunner.m_switchweapon;
 268         player.vehicle_enter_delay = time + 2;
 269
 270         fixedmakevectors(vehic.angles);
 271
 272         if(player == vehic.gunner1) { vehic.gunner1 = world; }
 273         if(player == vehic.gunner2) { vehic.gunner2 = world; v_right *= -1; }
 274
 275         vector spot = real_origin(gunner);
 276         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 277         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 278
 279         // TODO: figure a way to move player out of the gunner
 280
 281         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 282         player.velocity_z += 10;
 283
 284         gunner.phase = time + 5;
 285         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 286
 287         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 288
 289         player.vehicle = world;
 290 }
 291
 292 bool bumblebee_gunner_enter(entity this, entity player)
 293 {
 294         entity vehic = this;
 295         entity gunner = world;
 296
 297         if(!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2)
 298         {
 299                 // we can have some fun
 300                 if(vlen2(real_origin(vehic.gun2) - player.origin) < vlen2(real_origin(vehic.gun1) - player.origin))
 301                 {
 302                         gunner = vehic.gun2;
 303                         vehic.gunner2 = player;
 304                 }
 305                 else
 306                 {
 307                         gunner = vehic.gun1;
 308                         vehic.gunner1 = player;
 309                 }
 310         }
 311         else if(!vehic.gunner1 && time >= vehic.gun1.phase)     { gunner = vehic.gun1; vehic.gunner1 = player; }
 312         else if(!vehic.gunner2 && time >= vehic.gun2.phase)             { gunner = vehic.gun2; vehic.gunner2 = player; }
 313         else { LOG_TRACE("Vehicle is full, fail\n"); return false; }
 314
 315         player.vehicle                  = gunner;
 316         player.angles                   = vehic.angles;
 317         player.takedamage               = DAMAGE_NO;
 318         player.solid                    = SOLID_NOT;
 319         player.alpha                    = -1;
 320         player.movetype                 = MOVETYPE_NOCLIP;
 321         player.event_damage     = func_null;
 322         player.view_ofs                 = '0 0 0';
 323         player.hud                              = gunner.hud;
 324         player.teleportable     = false;
 325         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 326         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 327         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 328         player.vehicle_reload1  = vehic.vehicle_reload1;
 329         player.vehicle_reload2  = vehic.vehicle_reload2;
 330         player.vehicle_energy   = vehic.vehicle_energy;
 331         player.flags               &= ~FL_ONGROUND;
 332
 333         RemoveGrapplingHook(player);
 334
 335         gunner.m_switchweapon = PS(player).m_switchweapon;
 336         gunner.vehicle_exit = bumblebee_gunner_exit;
 337         gunner.vehicle_hudmodel.viewmodelforclient = player;
 338
 339         if(IS_REAL_CLIENT(player))
 340         {
 341                 msg_entity = player;
 342                 WriteByte(MSG_ONE,              SVC_SETVIEWPORT);
 343                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 344
 345                 WriteByte(MSG_ONE,              SVC_SETVIEWANGLES);
 346                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 347                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 348                 WriteAngle(MSG_ONE,     0); // roll
 349         }
 350
 351         CSQCVehicleSetup(player, player.hud);
 352
 353         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 354
 355         return true;
 356 }
 357
 358 bool vehicles_valid_pilot(entity this, entity toucher)
 359 {
 360         if(IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots)
 361                 return false;
 362
 363         if((!IS_PLAYER(toucher))
 364         || (IS_DEAD(toucher))
 365         || (toucher.vehicle)
 366         || (DIFF_TEAM(toucher, this))
 367         ) { return false; }
 368
 369         return true;
 370 }
 371
 372 void bumblebee_touch(entity this)
 373 {
 374         if(autocvar_g_vehicles_enter) { return; }
 375
 376         if(this.gunner1 != world && this.gunner2 != world)
 377         {
 378                 vehicles_touch(this);
 379                 return;
 380         }
 381
 382         if(vehicles_valid_pilot(this, other))
 383         {
 384                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 385
 386                 if(time >= other.vehicle_enter_delay && phase_time)
 387                 if(bumblebee_gunner_enter(this, other))
 388                         return;
 389         }
 390
 391         vehicles_touch(this);
 392 }
 393
 394 void bumblebee_regen(entity this)
 395 {
 396         if(this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 397                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 398                                                                            this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 399
 400         if(this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 401                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 402                                                                            this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 403
 404         if(this.vehicle_flags  & VHF_SHIELDREGEN)
 405                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, true);
 406
 407         if(this.vehicle_flags  & VHF_HEALTHREGEN)
 408                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, false);
 409
 410         if(this.vehicle_flags  & VHF_ENERGYREGEN)
 411                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, false);
 412
 413 }
 414
 415 bool bumblebee_pilot_frame(entity this)
 416 {
 417         entity vehic = this.vehicle;
 418         return = true;
 419
 420         if(intermission_running)
 421         {
 422                 vehic.velocity = '0 0 0';
 423                 vehic.avelocity = '0 0 0';
 424                 return;
 425         }
 426
 427         vehicles_frame(vehic, this);
 428
 429         if(IS_DEAD(vehic))
 430         {
 431                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 432                 return;
 433         }
 434
 435         bumblebee_regen(vehic);
 436
 437         crosshair_trace(this);
 438
 439         vector vang = vehic.angles;
 440         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 441         vang.x *= -1;
 442         newvel.x *= -1;
 443         if(newvel.x > 180)  newvel.x -= 360;
 444         if(newvel.x < -180) newvel.x += 360;
 445         if(newvel.y > 180)  newvel.y -= 360;
 446         if(newvel.y < -180) newvel.y += 360;
 447
 448         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 449         if(ftmp > 180)  ftmp -= 360;
 450         if(ftmp < -180) ftmp += 360;
 451         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 452
 453         // Pitch
 454         ftmp = 0;
 455         if(this.movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit)
 456                 ftmp = 4;
 457         else if(this.movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 458                 ftmp = -8;
 459
 460         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x , autocvar_g_vehicle_bumblebee_pitchlimit);
 461         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 462         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 463
 464         vehic.angles_x = anglemods(vehic.angles.x);
 465         vehic.angles_y = anglemods(vehic.angles.y);
 466         vehic.angles_z = anglemods(vehic.angles.z);
 467
 468         makevectors('0 1 0' * vehic.angles.y);
 469         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 470
 471         if(this.movement.x != 0)
 472         {
 473                 if(this.movement.x > 0)
 474                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 475                 else if(this.movement.x < 0)
 476                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 477         }
 478
 479         if(this.movement.y != 0)
 480         {
 481                 if(this.movement.y < 0)
 482                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 483                 else if(this.movement.y > 0)
 484                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 485                 ftmp = newvel * v_right;
 486                 ftmp *= frametime * 0.1;
 487                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 488         }
 489         else
 490         {
 491                 vehic.angles_z *= 0.95;
 492                 if(vehic.angles.z >= -1 && vehic.angles.z <= -1)
 493                         vehic.angles_z = 0;
 494         }
 495
 496         if(PHYS_INPUT_BUTTON_CROUCH(this))
 497                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 498         else if(PHYS_INPUT_BUTTON_JUMP(this))
 499                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 500
 501         vehic.velocity  += newvel * frametime;
 502         this.velocity = this.movement  = vehic.velocity;
 503
 504
 505         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 506         {
 507                 if(vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy))
 508                         vehic.tur_head.enemy = world;
 509
 510                 if(trace_ent)
 511                 if(trace_ent.movetype)
 512                 if(trace_ent.takedamage)
 513                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 514                 {
 515                         if(teamplay)
 516                         {
 517                                 if(trace_ent.team == this.team)
 518                                 {
 519                                         vehic.tur_head.enemy = trace_ent;
 520                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 521                                 }
 522                         }
 523                         else
 524                         {
 525                                 vehic.tur_head.enemy = trace_ent;
 526                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 527                         }
 528                 }
 529
 530                 if(vehic.tur_head.enemy)
 531                 {
 532                         trace_endpos = real_origin(vehic.tur_head.enemy);
 533                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 534                 }
 535         }
 536
 537         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 538                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 539                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 540
 541         if(!forbidWeaponUse(this))
 542         if((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 543         {
 544                 vehic.gun3.enemy.realowner = this;
 545                 vehic.gun3.enemy.effects &= ~EF_NODRAW;
 546
 547                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 548                 vehic.gun3.enemy.SendFlags |= BRG_START;
 549
 550                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 551
 552                 if(trace_ent)
 553                 {
 554                         if(autocvar_g_vehicle_bumblebee_raygun)
 555                         {
 556                                 Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 557                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 558                         }
 559                         else
 560                         {
 561                                 if(!IS_DEAD(trace_ent))
 562                                         if((teamplay && trace_ent.team == this.team) || !teamplay)
 563                                         {
 564
 565                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 566                                                 {
 567                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health)
 568                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.max_health);
 569
 570                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 571                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 572                                                 }
 573                                                 else if(IS_CLIENT(trace_ent))
 574                                                 {
 575                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 576                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 577
 578                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 579                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 580
 581                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 582                                                 }
 583                                                 else if(IS_TURRET(trace_ent))
 584                                                 {
 585                                                         if(trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 586                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.max_health);
 587                                                         //else ..hmmm what? ammo?
 588
 589                                                         trace_ent.SendFlags |= TNSF_STATUS;
 590                                                 }
 591                                         }
 592                         }
 593                 }
 594
 595                 vehic.gun3.enemy.hook_end = trace_endpos;
 596                 setorigin(vehic.gun3.enemy, trace_endpos);
 597                 vehic.gun3.enemy.SendFlags |= BRG_END;
 598
 599                 vehic.wait = time + 1;
 600         }
 601         else
 602                 vehic.gun3.enemy.effects |= EF_NODRAW;
 603         /*{
 604                 if(vehic.gun3.enemy)
 605                         remove(vehic.gun3.enemy);
 606
 607                 vehic.gun3.enemy = world;
 608         }
 609         */
 610
 611         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 612         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 613
 614         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 615         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 616
 617         if(vehic.vehicle_flags & VHF_HASSHIELD)
 618                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 619
 620         vehic.angles_x *= -1;
 621         makevectors(vehic.angles);
 622         vehic.angles_x *= -1;
 623         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 624
 625         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 626 }
 627
 628 void bumblebee_land(entity this)
 629 {
 630         float hgt;
 631
 632         hgt = raptor_altitude(this, 512);
 633         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 634         this.angles_x *= 0.95;
 635         this.angles_z *= 0.95;
 636
 637         if(hgt < 16)
 638                 setthink(this, vehicles_think);
 639
 640         this.nextthink = time;
 641
 642         CSQCMODEL_AUTOUPDATE(this);
 643 }
 644
 645 void bumblebee_exit(entity this, int eject)
 646 {
 647         if(this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid)
 648         {
 649                 bumblebee_gunner_exit(this, eject);
 650                 return;
 651         }
 652
 653         settouch(this, vehicles_touch);
 654
 655         if(!IS_DEAD(this))
 656         {
 657                 setthink(this, bumblebee_land);
 658                 this.nextthink  = time;
 659         }
 660
 661         this.movetype = MOVETYPE_TOSS;
 662
 663         if(!this.owner)
 664                 return;
 665
 666         fixedmakevectors(this.angles);
 667         vector spot;
 668         if(vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5))
 669                 spot = this.origin + v_up * 128 + v_forward * 300;
 670         else
 671                 spot = this.origin + v_up * 128 - v_forward * 300;
 672
 673         spot = vehicles_findgoodexit(this, spot);
 674
 675         // Hide beam
 676         if(this.gun3.enemy || !wasfreed(this.gun3.enemy))
 677                 this.gun3.enemy.effects |= EF_NODRAW;
 678
 679         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 680         this.owner.velocity_z += 10;
 681         setorigin(this.owner, spot);
 682
 683         antilag_clear(this.owner, CS(this.owner));
 684         this.owner = world;
 685 }
 686
 687 void bumblebee_blowup(entity this)
 688 {
 689         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 690                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 691                                  autocvar_g_vehicle_bumblebee_blowup_radius, this, world,
 692                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 693                                  DEATH_VH_BUMB_DEATH.m_id, world);
 694
 695         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 696         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 697
 698         if(this.owner.deadflag == DEAD_DYING)
 699                 this.owner.deadflag = DEAD_DEAD;
 700
 701         remove(this);
 702 }
 703
 704 void bumblebee_diethink(entity this)
 705 {
 706         if(time >= this.wait)
 707                 setthink(this, bumblebee_blowup);
 708
 709         if(random() < 0.1)
 710         {
 711                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 712                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 713         }
 714
 715         this.nextthink = time + 0.1;
 716 }
 717
 718 spawnfunc(vehicle_bumblebee)
 719 {
 720         if(!autocvar_g_vehicle_bumblebee) { remove(this); return; }
 721         if(!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { remove(this); return; }
 722 }
 723
 724 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 725 {
 726     if(autocvar_g_vehicle_bumblebee_bouncepain)
 727         vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 728 }
 729 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 730 {
 731     settouch(instance, bumblebee_touch);
 732     instance.nextthink = 0;
 733     instance.movetype = MOVETYPE_BOUNCEMISSILE;
 734 }
 735 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 736 {
 737     instance.angles_z *= 0.8;
 738     instance.angles_x *= 0.8;
 739
 740     instance.nextthink = time;
 741
 742     if(!instance.owner)
 743     {
 744         if(instance.gunner1)
 745         {
 746                 entity e = instance.gunner1;
 747                 instance.gun1.vehicle_exit(e, VHEF_EJECT);
 748                 entity oldother = other;
 749                 other = e;
 750                 instance.phase = 0;
 751                 gettouch(instance)(instance);
 752                 other = oldother;
 753                 return;
 754         }
 755
 756         if(instance.gunner2)
 757         {
 758                 entity e = instance.gunner2;
 759                 instance.gun2.vehicle_exit(e, VHEF_EJECT);
 760                 entity oldother = other;
 761                 other = e;
 762                 instance.phase = 0;
 763                 gettouch(instance)(instance);
 764                 other = oldother;
 765             return;
 766         }
 767     }
 768 }
 769 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 770 {
 771         CSQCModel_UnlinkEntity(instance);
 772
 773         // hide beam
 774         if(instance.gun3.enemy || !wasfreed(instance.gun3.enemy))
 775                 instance.gun3.enemy.effects |= EF_NODRAW;
 776
 777         if(instance.gunner1)
 778                 instance.gun1.vehicle_exit(instance.gunner1, VHEF_EJECT);
 779
 780         if(instance.gunner2)
 781                 instance.gun2.vehicle_exit(instance.gunner2, VHEF_EJECT);
 782
 783         instance.vehicle_exit(instance, VHEF_EJECT);
 784
 785     fixedmakevectors(instance.angles);
 786     vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 787     vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 788     vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 789
 790     entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 791
 792     if(random() > 0.5)
 793         settouch(_body, bumblebee_blowup);
 794     else
 795         settouch(_body, func_null);
 796
 797     setthink(_body, bumblebee_diethink);
 798     _body.nextthink = time;
 799     _body.wait = time + 2 + (random() * 8);
 800     _body.owner = instance;
 801     _body.enemy = instance.enemy;
 802     _body.scale = 1.5;
 803     _body.angles = instance.angles;
 804
 805     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 806
 807     instance.health                     = 0;
 808     instance.event_damage       = func_null;
 809     instance.solid                      = SOLID_NOT;
 810     instance.takedamage         = DAMAGE_NO;
 811     instance.deadflag           = DEAD_DYING;
 812     instance.movetype           = MOVETYPE_NONE;
 813     instance.effects            = EF_NODRAW;
 814     instance.colormod           = '0 0 0';
 815     instance.avelocity          = '0 0 0';
 816     instance.velocity           = '0 0 0';
 817     settouch(instance, func_null);
 818     instance.nextthink          = 0;
 819
 820     setorigin(instance, instance.pos1);
 821 }
 822 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 823 {
 824     if(!instance.gun1)
 825     {
 826         // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 827         instance.vehicle_shieldent = spawn();
 828         instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 829         setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 830         setattachment(instance.vehicle_shieldent, instance, "");
 831         setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 832         instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 833         setthink(instance.vehicle_shieldent, shieldhit_think);
 834         instance.vehicle_shieldent.alpha = -1;
 835         instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 836
 837         instance.gun1 = new(vehicle_playerslot);
 838         instance.gun2 = new(vehicle_playerslot);
 839         instance.gun3 = new(bumblebee_raygun);
 840
 841         instance.vehicle_flags |= VHF_MULTISLOT;
 842
 843         instance.gun1.owner = instance;
 844         instance.gun2.owner = instance;
 845         instance.gun3.owner = instance;
 846
 847         setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 848         setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 849         setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 850
 851         setattachment(instance.gun1, instance, "cannon_right");
 852         setattachment(instance.gun2, instance, "cannon_left");
 853
 854         // Angled bones are no fun, messes up gun-aim; so work arround it.
 855         instance.gun3.pos1 = instance.angles;
 856         instance.angles = '0 0 0';
 857         vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 858         ofs -= instance.origin;
 859         setattachment(instance.gun3, instance, "");
 860         setorigin(instance.gun3, ofs);
 861         instance.angles = instance.gun3.pos1;
 862
 863         vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 864         vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 865
 866         setorigin(instance.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 867         setorigin(instance.vehicle_viewport, '5 0 2');    // Move camera forward up
 868
 869         //fixme-model-bones
 870         setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 871         setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 872         //fixme-model-bones
 873         setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 874         setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 875
 876         instance.scale = 1.5;
 877
 878         // Raygun beam
 879         if(instance.gun3.enemy == world)
 880         {
 881             instance.gun3.enemy = spawn();
 882             Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 883             instance.gun3.enemy.SendFlags = BRG_SETUP;
 884             instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 885             instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 886         }
 887     }
 888
 889     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 890     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 891     instance.solid = SOLID_BBOX;
 892     instance.movetype = MOVETYPE_TOSS;
 893     instance.damageforcescale = 0.025;
 894
 895     instance.PlayerPhysplug = bumblebee_pilot_frame;
 896
 897     setorigin(instance, instance.origin + '0 0 25');
 898 }
 899 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 900 {
 901     if(autocvar_g_vehicle_bumblebee_energy)
 902     if(autocvar_g_vehicle_bumblebee_energy_regen)
 903         instance.vehicle_flags |= VHF_ENERGYREGEN;
 904
 905     if(autocvar_g_vehicle_bumblebee_shield)
 906         instance.vehicle_flags |= VHF_HASSHIELD;
 907
 908     if(autocvar_g_vehicle_bumblebee_shield_regen)
 909         instance.vehicle_flags |= VHF_SHIELDREGEN;
 910
 911     if(autocvar_g_vehicle_bumblebee_health_regen)
 912         instance.vehicle_flags |= VHF_HEALTHREGEN;
 913
 914     instance.vehicle_exit = bumblebee_exit;
 915     instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 916     instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 917     instance.max_health = instance.vehicle_health;
 918     instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 919 }
 920
 921 #endif // SVQC
 922 #ifdef CSQC
 923
 924 void CSQC_BUMBLE_GUN_HUD()
 925 {
 926         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 927                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 928                                          string_null, '0 0 0');
 929 }
 930
 931 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 932 {
 933     Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 934                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 935                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 936
 937     float hudAlpha = autocvar_hud_panel_fg_alpha;
 938     float blinkValue = 0.55 + sin(time * 7) * 0.45;
 939     vector tmpPos  = '0 0 0';
 940     vector tmpSize = '1 1 1' * hud_fontsize;
 941     tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520/768);
 942
 943     if(!AuxiliaryXhair[1].draw2d)
 944     {
 945         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96/256) - tmpSize.y;
 946         drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 947     }
 948
 949     if(!AuxiliaryXhair[2].draw2d)
 950     {
 951         tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160/256);
 952         drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 953     }
 954 }
 955 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 956 {
 957     Vehicles_drawCrosshair(vCROSS_HEAL);
 958 }
 959 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 960 {
 961     AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 962     AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 963     AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 964 }
 965
 966 #endif
 967 #endif