qcsrc/common/vehicles/vehicle/racer.qc

   1 #include "racer.qh"
   2
   3 #ifdef GAMEQC
   4
   5 #ifdef SVQC
   6 #include <common/mapobjects/trigger/impulse.qh>
   7
   8 bool autocvar_g_vehicle_racer = true;
   9
  10 float autocvar_g_vehicle_racer_thinkrate = 0.05; // TODO: any higher causes it to sink in liquids
  11
  12 float autocvar_g_vehicle_racer_speed_afterburn = 3000;
  13 // energy consumed per second
  14 float autocvar_g_vehicle_racer_afterburn_cost = 130;
  15
  16 float autocvar_g_vehicle_racer_waterburn_cost = 5;
  17 float autocvar_g_vehicle_racer_waterburn_speed = 750;
  18
  19 float autocvar_g_vehicle_racer_water_speed_forward = 600;
  20 float autocvar_g_vehicle_racer_water_speed_strafe = 600;
  21
  22 float autocvar_g_vehicle_racer_pitchlimit = 30;
  23
  24 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  25 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  26
  27 float autocvar_g_vehicle_racer_anglestabilizer = 1.75;
  28 float autocvar_g_vehicle_racer_downforce = 0.01;
  29
  30 float autocvar_g_vehicle_racer_speed_forward = 650;
  31 float autocvar_g_vehicle_racer_speed_strafe = 650;
  32 float autocvar_g_vehicle_racer_springlength = 90;
  33 float autocvar_g_vehicle_racer_upforcedamper = 2;
  34 float autocvar_g_vehicle_racer_friction = 0.45;
  35
  36 float autocvar_g_vehicle_racer_water_time = 5;
  37
  38 //float autocvar_g_vehicle_racer_collision_multiplier = 0.05;
  39
  40 // 0 = hover, != 0 = maglev
  41 int autocvar_g_vehicle_racer_hovertype = 0;
  42 // NOTE!! x 4 (4 engines)
  43 float autocvar_g_vehicle_racer_hoverpower = 8000;
  44
  45 float autocvar_g_vehicle_racer_turnroll = 30;
  46 float autocvar_g_vehicle_racer_turnspeed = 220;
  47 float autocvar_g_vehicle_racer_pitchspeed = 125;
  48
  49 float autocvar_g_vehicle_racer_energy = 100;
  50 float autocvar_g_vehicle_racer_energy_regen = 90;
  51 float autocvar_g_vehicle_racer_energy_regen_pause = 0.35;
  52
  53 float autocvar_g_vehicle_racer_health = 200;
  54 float autocvar_g_vehicle_racer_health_regen = 0;
  55 float autocvar_g_vehicle_racer_health_regen_pause = 0;
  56
  57 float autocvar_g_vehicle_racer_shield = 100;
  58 float autocvar_g_vehicle_racer_shield_regen = 30;
  59 float autocvar_g_vehicle_racer_shield_regen_pause = 1;
  60
  61 bool autocvar_g_vehicle_racer_rocket_locktarget = true;
  62 float autocvar_g_vehicle_racer_rocket_locking_time = 0.35;
  63 float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5;
  64 float autocvar_g_vehicle_racer_rocket_locked_time = 4;
  65
  66 float autocvar_g_vehicle_racer_respawntime = 35;
  67
  68 float autocvar_g_vehicle_racer_blowup_radius = 250;
  69 float autocvar_g_vehicle_racer_blowup_coredamage = 250;
  70 float autocvar_g_vehicle_racer_blowup_edgedamage = 15;
  71 float autocvar_g_vehicle_racer_blowup_forceintensity = 250;
  72
  73 // Factor of old velocity to keep after collision
  74 float autocvar_g_vehicle_racer_bouncefactor = 0.25;
  75 // if != 0, New veloctiy after bounce = 0 if new velocity < this
  76 float autocvar_g_vehicle_racer_bouncestop = 0;
  77 // "minspeed_for_pain speedchange_to_pain_factor max_damage"
  78 vector autocvar_g_vehicle_racer_bouncepain = '200 0.15 150';
  79
  80 .float racer_watertime;
  81
  82 var .vector(entity this, string tag_name, float spring_length, float max_power) racer_force_from_tag;
  83
  84 void racer_align4point(entity this, entity player, float _delta)
  85 {
  86         vector push_vector;
  87         float fl_push, fr_push, bl_push, br_push;
  88
  89         push_vector  = this.racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90         fr_push   = force_fromtag_normpower;
  91         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93         push_vector += this.racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  94         fl_push   = force_fromtag_normpower;
  95         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  96
  97         push_vector += this.racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  98         br_push   = force_fromtag_normpower;
  99         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 100
 101         push_vector += this.racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 102         bl_push   = force_fromtag_normpower;
 103         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 104
 105         this.velocity += push_vector * _delta;
 106
 107         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 108
 109         int cont = pointcontents(this.origin - '0 0 64');
 110         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 111         {
 112                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 113
 114                 if(PHYS_INPUT_BUTTON_CROUCH(player) && time < this.air_finished)
 115                         this.velocity_z += 30;
 116                 else
 117                         this.velocity_z += 200;
 118         }
 119
 120
 121         // Anti ocilation
 122         if(this.velocity_z > 0)
 123                 this.velocity_z *= 1 - uforce * _delta;
 124
 125         push_vector_x =  (fl_push - bl_push);
 126         push_vector_x += (fr_push - br_push);
 127         push_vector_x *= 360;
 128
 129         push_vector_z = (fr_push - fl_push);
 130         push_vector_z += (br_push - bl_push);
 131         push_vector_z *= 360;
 132
 133         // Apply angle diffrance
 134         this.angles_z += push_vector_z * _delta;
 135         this.angles_x += push_vector_x * _delta;
 136
 137         // Apply stabilizer
 138         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 139         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 140 }
 141
 142 void racer_fire_rocket_aim(entity this, entity player, string tagname, entity trg)
 143 {
 144         vector v = gettaginfo(this, gettagindex(this, tagname));
 145         racer_fire_rocket(this, player, v, v_forward, trg);
 146 }
 147
 148 bool racer_frame(entity this, float dt)
 149 {
 150         entity player = this;
 151         entity vehic = player.vehicle;
 152         return = true;
 153
 154         if(game_stopped)
 155         {
 156                 vehic.solid = SOLID_NOT;
 157                 vehic.takedamage = DAMAGE_NO;
 158                 set_movetype(vehic, MOVETYPE_NONE);
 159                 return;
 160         }
 161
 162         vehicles_frame(vehic, player);
 163
 164         int cont = Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(vehic.origin));
 165         if(!(cont & DPCONTENTS_WATER))
 166                 vehic.air_finished = 0;
 167         else if (!vehic.air_finished)
 168                 vehic.air_finished = time + autocvar_g_vehicle_racer_water_time;
 169
 170         if(IS_DEAD(vehic))
 171         {
 172                 PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 173                 return;
 174         }
 175
 176         racer_align4point(vehic, player, dt);
 177
 178         PHYS_INPUT_BUTTON_ZOOM(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
 179
 180         vehic.angles_x *= -1;
 181
 182         // Yaw
 183         float ftmp = autocvar_g_vehicle_racer_turnspeed * dt;
 184         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - vehic.angles_y, vehic.angles_y), ftmp);
 185         vehic.angles_y = anglemods(vehic.angles_y + ftmp);
 186
 187         // Roll
 188         vehic.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * dt;
 189
 190         // Pitch
 191         ftmp = autocvar_g_vehicle_racer_pitchspeed  * dt;
 192         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - vehic.angles_x, vehic.angles_x), ftmp);
 193         vehic.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 194
 195         makevectors(vehic.angles);
 196         vehic.angles_x *= -1;
 197
 198         //ftmp = vehic.velocity_z;
 199         vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
 200         //vehic.velocity_z = ftmp;
 201
 202         if(CS(player).movement)
 203         {
 204                 if(cont & DPCONTENTS_LIQUIDSMASK)
 205                 {
 206                         if(CS(player).movement_x) { df += v_forward * ((CS(player).movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 207                         if(CS(player).movement_y) { df += v_right * ((CS(player).movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 208                 }
 209                 else
 210                 {
 211                         if(CS(player).movement_x) { df += v_forward * ((CS(player).movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 212                         if(CS(player).movement_y) { df += v_right * ((CS(player).movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 213                 }
 214
 215 #ifdef SVQC
 216                 if(vehic.sound_nexttime < time || vehic.sounds != 1)
 217                 {
 218                         vehic.sounds = 1;
 219                         vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 220                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 221                 }
 222 #endif
 223         }
 224 #ifdef SVQC
 225         else
 226         {
 227                 if(vehic.sound_nexttime < time || vehic.sounds != 0)
 228                 {
 229                         vehic.sounds = 0;
 230                         vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 231                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 232                 }
 233         }
 234 #endif
 235
 236         // Afterburn
 237         if (PHYS_INPUT_BUTTON_JUMP(player) && vehic.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * dt))
 238         {
 239 #ifdef SVQC
 240                 if(time - vehic.wait > 0.2)
 241                         pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
 242 #endif
 243
 244                 vehic.wait = time;
 245
 246                 if(cont & DPCONTENTS_LIQUIDSMASK)
 247                 {
 248                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * dt;
 249                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 250                 }
 251                 else
 252                 {
 253                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * dt;
 254                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 255                 }
 256
 257 #ifdef SVQC
 258                 // NOTE: reusing .invincible_finished here as delay counter for the smoke effect
 259                 if(vehic.invincible_finished < time)
 260                 {
 261                         traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
 262                         if(trace_fraction != 1.0)
 263                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 264
 265                         vehic.invincible_finished = time + 0.1 + (random() * 0.1);
 266                 }
 267
 268                 // NOTE: reusing .strength_finished here as a sound delay counter
 269                 if(vehic.strength_finished < time)
 270                 {
 271                         vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 272                         sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 273                 }
 274 #endif
 275         }
 276         else
 277         {
 278                 vehic.strength_finished = 0;
 279                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 280         }
 281
 282         if(cont & DPCONTENTS_LIQUIDSMASK)
 283                 vehic.racer_watertime = time;
 284
 285         float dforce = autocvar_g_vehicle_racer_downforce;
 286         if(time - vehic.racer_watertime <= 3)
 287                 dforce = autocvar_g_vehicle_racer_water_downforce;
 288
 289         df -= v_up * (vlen(vehic.velocity) * dforce);
 290         CS(player).movement = vehic.velocity += df * dt;
 291
 292 #ifdef SVQC
 293
 294         Weapon wep1 = WEP_RACER;
 295         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 296         if (!weaponLocked(player) && !weaponUseForbidden(player))
 297         if (PHYS_INPUT_BUTTON_ATCK(player))
 298         if (wep1.wr_checkammo1(wep1, vehic, weaponentity))
 299         {
 300                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 301         }
 302
 303         if(autocvar_g_vehicle_racer_rocket_locktarget)
 304         {
 305                 if(time >= vehic.vehicle_last_trace)
 306                 {
 307                         crosshair_trace(player);
 308
 309                         vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * dt,
 310                                                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * dt,
 311                                                          autocvar_g_vehicle_racer_rocket_locked_time);
 312
 313                         vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
 314                 }
 315
 316                 if(vehic.lock_target)
 317                 {
 318                         if(vehic.lock_strength == 1)
 319                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '1 0 0', 0);
 320                         else if(vehic.lock_strength > 0.5)
 321                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 1 0', 0);
 322                         else if(vehic.lock_strength < 0.5)
 323                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 0 1', 0);
 324                 }
 325         }
 326
 327         if (!weaponLocked(player) && !weaponUseForbidden(player))
 328         if(time > vehic.delay)
 329         if(PHYS_INPUT_BUTTON_ATCK2(player))
 330         {
 331                 vehic.misc_bulletcounter += 1;
 332                 vehic.delay = time + 0.3;
 333
 334                 if(vehic.misc_bulletcounter == 1)
 335                 {
 336                         racer_fire_rocket_aim(vehic, player, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 337                         player.vehicle_ammo2 = 50;
 338                 }
 339                 else if(vehic.misc_bulletcounter == 2)
 340                 {
 341                         racer_fire_rocket_aim(vehic, player, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 342                         vehic.lock_strength  = 0;
 343                         vehic.lock_target       = NULL;
 344                         vehic.misc_bulletcounter = 0;
 345                         vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 346                         vehic.lip = time;
 347                         player.vehicle_ammo2 = 0;
 348                 }
 349         }
 350         else if(vehic.misc_bulletcounter == 0)
 351                 player.vehicle_ammo2 = 100;
 352
 353         player.vehicle_reload2 = bound(0, 100 * ((time - vehic.lip) / (vehic.delay - vehic.lip)), 100);
 354
 355         if(vehic.vehicle_flags & VHF_SHIELDREGEN)
 356                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, dt, true);
 357
 358         if(vehic.vehicle_flags & VHF_HEALTHREGEN)
 359                 vehicles_regen_resource(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, dt, false, RES_HEALTH);
 360
 361         if(vehic.vehicle_flags & VHF_ENERGYREGEN)
 362                 vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, dt, false);
 363
 364         VEHICLE_UPDATE_PLAYER_RESOURCE(player, vehic, health, racer, RES_HEALTH);
 365         VEHICLE_UPDATE_PLAYER(player, vehic, energy, racer);
 366
 367         if(vehic.vehicle_flags & VHF_HASSHIELD)
 368                 VEHICLE_UPDATE_PLAYER(player, vehic, shield, racer);
 369
 370         PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 371 #endif
 372
 373         setorigin(player, vehic.origin + '0 0 32');
 374         player.oldorigin = player.origin; // negate fall damage
 375         player.velocity = vehic.velocity;
 376 }
 377
 378 void racer_think(entity this)
 379 {
 380         float dt = autocvar_g_vehicle_racer_thinkrate;
 381
 382         this.nextthink = time + dt;
 383
 384         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 385
 386         vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
 387         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 388
 389         float forced = autocvar_g_vehicle_racer_upforcedamper;
 390
 391         //int cont = pointcontents(this.origin - '0 0 64');
 392         traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
 393         //if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 394         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 395         {
 396                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 397                 this.velocity_z += 200;
 398         }
 399
 400         this.velocity += df * dt;
 401         if(this.velocity_z > 0)
 402                 this.velocity_z *= 1 - forced * dt;
 403
 404         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * dt);
 405         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * dt);
 406
 407         CSQCMODEL_AUTOUPDATE(this);
 408 }
 409
 410 void racer_exit(entity this, int eject)
 411 {
 412         vector spot;
 413
 414         setthink(this, racer_think);
 415         this.nextthink  = time;
 416         set_movetype(this, MOVETYPE_BOUNCE);
 417         sound (this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 418
 419         if(!this.owner)
 420                 return;
 421
 422         makevectors(this.angles);
 423         if(eject)
 424         {
 425                 spot = this.origin + v_forward * 100 + '0 0 64';
 426                 spot = vehicles_findgoodexit(this, this.owner, spot);
 427                 setorigin(this.owner, spot);
 428                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 429                 this.owner.oldvelocity = this.owner.velocity;
 430         }
 431         else
 432         {
 433                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 434                 {
 435                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 436                         this.owner.velocity_z += 200;
 437                         spot = this.origin + v_forward * 32 + '0 0 32';
 438                         spot = vehicles_findgoodexit(this, this.owner, spot);
 439                 }
 440                 else
 441                 {
 442                         this.owner.velocity = this.velocity * 0.5;
 443                         this.owner.velocity_z += 10;
 444                         spot = this.origin - v_forward * 200 + '0 0 32';
 445                         spot = vehicles_findgoodexit(this, this.owner, spot);
 446                 }
 447                 this.owner.oldvelocity = this.owner.velocity;
 448                 setorigin(this.owner , spot);
 449         }
 450         antilag_clear(this.owner, CS(this.owner));
 451         this.owner = NULL;
 452 }
 453
 454 void racer_blowup(entity this)
 455 {
 456         this.deadflag = DEAD_DEAD;
 457         this.vehicle_exit(this, VHEF_NORMAL);
 458
 459         RadiusDamage (this, this.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 460                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 461                                         autocvar_g_vehicle_racer_blowup_radius, NULL, NULL,
 462                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 463                                         DEATH_VH_WAKI_DEATH.m_id, DMG_NOWEP, NULL);
 464
 465         this.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 466         setthink(this, vehicles_spawn);
 467         set_movetype(this, MOVETYPE_NONE);
 468         this.effects    = EF_NODRAW;
 469         this.solid = SOLID_NOT;
 470
 471         this.colormod  = '0 0 0';
 472         this.avelocity = '0 0 0';
 473         this.velocity  = '0 0 0';
 474
 475         setorigin(this, this.pos1);
 476 }
 477
 478 void racer_blowup_think(entity this)
 479 {
 480         this.nextthink = time;
 481
 482         if(time >= this.delay)
 483                 racer_blowup(this);
 484
 485         //CSQCMODEL_AUTOUPDATE(this);
 486 }
 487
 488 void racer_deadtouch(entity this, entity toucher)
 489 {
 490         this.avelocity_x *= 0.7;
 491         this.cnt -= 1;
 492         if(this.cnt <= 0)
 493                 racer_blowup(this);
 494 }
 495
 496 spawnfunc(vehicle_racer)
 497 {
 498         if(!autocvar_g_vehicle_racer) { delete(this); return; }
 499         if(!vehicle_initialize(this, VEH_RACER, false)) { delete(this); return; }
 500 }
 501
 502 #endif // SVQC
 503
 504 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 505 {
 506 #ifdef SVQC
 507     if(autocvar_g_vehicle_racer_bouncepain)
 508         vehicles_impact(instance, autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 509 #endif
 510 }
 511
 512 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 513 {
 514     set_movetype(instance, MOVETYPE_BOUNCE);
 515 #ifdef SVQC
 516     instance.owner.vehicle_health = (GetResource(instance, RES_HEALTH) / autocvar_g_vehicle_racer_health)  * 100;
 517     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 518
 519     if(instance.owner.flagcarried)
 520        setorigin(instance.owner.flagcarried, '-190 0 96');
 521 #endif
 522 }
 523
 524 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 525 {
 526 #ifdef SVQC
 527     if(autocvar_g_vehicle_racer_hovertype != 0)
 528         instance.racer_force_from_tag = vehicles_force_fromtag_maglev;
 529     else
 530         instance.racer_force_from_tag = vehicles_force_fromtag_hover;
 531
 532     setthink(instance, racer_think);
 533     instance.nextthink    = time;
 534     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 535     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 536
 537     set_movetype(instance, MOVETYPE_TOSS);
 538     instance.solid                = SOLID_SLIDEBOX;
 539     instance.delay                = time;
 540     instance.scale                = 0.5; // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 541     instance.mass                 = 900;
 542
 543     setattachment(instance.vehicle_hudmodel, instance, "");
 544     setattachment(instance.vehicle_viewport, instance, "tag_viewport");
 545
 546     instance.PlayerPhysplug = racer_frame;
 547
 548     instance.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 549     instance.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 550     instance.damageforcescale = 0.5;
 551     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 552     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 553 #endif
 554 }
 555
 556 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 557 {
 558 #ifdef SVQC
 559     setSendEntity(instance, func_null); // stop networking this racer (for now)
 560     SetResourceExplicit(instance, RES_HEALTH, 0);
 561     instance.event_damage       = func_null;
 562     instance.solid                      = SOLID_CORPSE;
 563     instance.takedamage         = DAMAGE_NO;
 564     instance.deadflag           = DEAD_DYING;
 565     set_movetype(instance, MOVETYPE_BOUNCE);
 566     instance.wait                       = time;
 567     instance.delay                      = 2 + time + random() * 3;
 568     instance.cnt                        = 1 + random() * 2;
 569     settouch(instance, racer_deadtouch);
 570
 571     Send_Effect(EFFECT_EXPLOSION_MEDIUM, instance.origin, '0 0 0', 1);
 572
 573     if(random() < 0.5)
 574         instance.avelocity_z = 32;
 575     else
 576         instance.avelocity_z = -32;
 577
 578     instance.avelocity_x = -vlen(instance.velocity) * 0.2;
 579     instance.velocity += '0 0 700';
 580     instance.colormod = '-0.5 -0.5 -0.5';
 581
 582     setthink(instance, racer_blowup_think);
 583     instance.nextthink = time;
 584 #endif
 585 }
 586
 587 #ifdef CSQC
 588 METHOD(Racer, vr_hud, void(Racer thisveh))
 589 {
 590     Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 591                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 592                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 593 }
 594 METHOD(Racer, vr_crosshair, void(Racer thisveh, entity player))
 595 {
 596     Vehicles_drawCrosshair(vCROSS_GUIDE);
 597 }
 598 #endif
 599 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 600 {
 601 #ifdef SVQC
 602     instance.vehicle_exit = racer_exit;
 603
 604     // we have no need to network energy
 605     if(autocvar_g_vehicle_racer_energy && autocvar_g_vehicle_racer_energy_regen)
 606         instance.vehicle_flags |= VHF_ENERGYREGEN;
 607
 608     if(autocvar_g_vehicle_racer_shield)
 609         instance.vehicle_flags |= VHF_HASSHIELD;
 610
 611     if(autocvar_g_vehicle_racer_shield_regen)
 612         instance.vehicle_flags |= VHF_SHIELDREGEN;
 613
 614     if(autocvar_g_vehicle_racer_health_regen)
 615         instance.vehicle_flags |= VHF_HEALTHREGEN;
 616
 617     instance.respawntime = autocvar_g_vehicle_racer_respawntime;
 618     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 619     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 620     instance.max_health = GetResource(instance, RES_HEALTH);
 621 #endif
 622
 623 #ifdef CSQC
 624     AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 625 #endif
 626 }
 627
 628 #endif