qcsrc/common/vehicles/vehicle/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3
   4 #include "racer_weapon.qc"
   5
   6 CLASS(Racer, Vehicle)
   7 /* spawnflags */ ATTRIB(Racer, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   8 /* mins       */ ATTRIB(Racer, mins, vector, '-120 -120 -40' * 0.5);
   9 /* maxs       */ ATTRIB(Racer, maxs, vector, '120 120 40' * 0.5);
  10 /* view offset*/ ATTRIB(Racer, view_ofs, vector, '0 0 50');
  11 /* view dist  */ ATTRIB(Racer, height, float, 200);
  12 /* model          */ ATTRIB(Racer, mdl, string, "models/vehicles/wakizashi.dpm");
  13 /* model          */ ATTRIB(Racer, model, string, "models/vehicles/wakizashi.dpm");
  14 /* head_model */ ATTRIB(Racer, head_model, string, "null");
  15 /* hud_model  */ ATTRIB(Racer, hud_model, string, "models/vehicles/wakizashi_cockpit.dpm");
  16 /* tags       */ ATTRIB(Racer, tag_head, string, "");
  17 /* tags       */ ATTRIB(Racer, tag_hud, string, "");
  18 /* tags       */ ATTRIB(Racer, tag_view, string, "tag_viewport");
  19 /* netname    */ ATTRIB(Racer, netname, string, "racer");
  20 /* fullname   */ ATTRIB(Racer, vehicle_name, string, _("Racer"));
  21 /* icon       */ ATTRIB(Racer, m_icon, string, "vehicle_racer");
  22 ENDCLASS(Racer)
  23 REGISTER_VEHICLE(RACER, NEW(Racer));
  24
  25 #endif
  26
  27 #ifdef IMPLEMENTATION
  28
  29 #include "racer_weapon.qc"
  30
  31 #ifdef SVQC
  32 #include <common/triggers/trigger/impulse.qh>
  33
  34 bool autocvar_g_vehicle_racer;
  35
  36 float autocvar_g_vehicle_racer_speed_afterburn;
  37 float autocvar_g_vehicle_racer_afterburn_cost;
  38
  39 float autocvar_g_vehicle_racer_waterburn_cost;
  40 float autocvar_g_vehicle_racer_waterburn_speed;
  41
  42 float autocvar_g_vehicle_racer_water_speed_forward;
  43 float autocvar_g_vehicle_racer_water_speed_strafe;
  44
  45 float autocvar_g_vehicle_racer_pitchlimit = 30;
  46
  47 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  48 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  49
  50 float autocvar_g_vehicle_racer_anglestabilizer;
  51 float autocvar_g_vehicle_racer_downforce;
  52
  53 float autocvar_g_vehicle_racer_speed_forward;
  54 float autocvar_g_vehicle_racer_speed_strafe;
  55 float autocvar_g_vehicle_racer_springlength;
  56 float autocvar_g_vehicle_racer_upforcedamper;
  57 float autocvar_g_vehicle_racer_friction;
  58
  59 float autocvar_g_vehicle_racer_water_time = 5;
  60
  61 float autocvar_g_vehicle_racer_hovertype;
  62 float autocvar_g_vehicle_racer_hoverpower;
  63
  64 float autocvar_g_vehicle_racer_turnroll;
  65 float autocvar_g_vehicle_racer_turnspeed;
  66 float autocvar_g_vehicle_racer_pitchspeed;
  67
  68 float autocvar_g_vehicle_racer_energy;
  69 float autocvar_g_vehicle_racer_energy_regen;
  70 float autocvar_g_vehicle_racer_energy_regen_pause;
  71
  72 float autocvar_g_vehicle_racer_health;
  73 float autocvar_g_vehicle_racer_health_regen;
  74 float autocvar_g_vehicle_racer_health_regen_pause;
  75
  76 float autocvar_g_vehicle_racer_shield;
  77 float autocvar_g_vehicle_racer_shield_regen;
  78 float autocvar_g_vehicle_racer_shield_regen_pause;
  79
  80 float autocvar_g_vehicle_racer_rocket_locktarget;
  81 float autocvar_g_vehicle_racer_rocket_locking_time;
  82 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  83 float autocvar_g_vehicle_racer_rocket_locked_time;
  84
  85 float autocvar_g_vehicle_racer_respawntime;
  86
  87 float autocvar_g_vehicle_racer_blowup_radius;
  88 float autocvar_g_vehicle_racer_blowup_coredamage;
  89 float autocvar_g_vehicle_racer_blowup_edgedamage;
  90 float autocvar_g_vehicle_racer_blowup_forceintensity;
  91
  92 float autocvar_g_vehicle_racer_bouncefactor;
  93 float autocvar_g_vehicle_racer_bouncestop;
  94 vector autocvar_g_vehicle_racer_bouncepain;
  95
  96 .float racer_watertime;
  97
  98 var vector racer_force_from_tag(entity this, string tag_name, float spring_length, float max_power);
  99
 100 void racer_align4point(entity this, float _delta)
 101 {
 102         vector push_vector;
 103         float fl_push, fr_push, bl_push, br_push;
 104
 105         push_vector  = racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 106         fr_push   = force_fromtag_normpower;
 107         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 108
 109         push_vector += racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 110         fl_push   = force_fromtag_normpower;
 111         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 112
 113         push_vector += racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 114         br_push   = force_fromtag_normpower;
 115         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 116
 117         push_vector += racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 118         bl_push   = force_fromtag_normpower;
 119         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 120
 121         this.velocity += push_vector * _delta;
 122
 123         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 124
 125         int cont = pointcontents(this.origin - '0 0 64');
 126         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 127         {
 128                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 129
 130                 if(this.owner.BUTTON_CROUCH && time < this.air_finished)
 131                         this.velocity_z += 30;
 132                 else
 133                         this.velocity_z += 200;
 134         }
 135
 136
 137         // Anti ocilation
 138         if(this.velocity_z > 0)
 139                 this.velocity_z *= 1 - uforce * _delta;
 140
 141         push_vector_x =  (fl_push - bl_push);
 142         push_vector_x += (fr_push - br_push);
 143         push_vector_x *= 360;
 144
 145         push_vector_z = (fr_push - fl_push);
 146         push_vector_z += (br_push - bl_push);
 147         push_vector_z *= 360;
 148
 149         // Apply angle diffrance
 150         this.angles_z += push_vector_z * _delta;
 151         this.angles_x += push_vector_x * _delta;
 152
 153         // Apply stabilizer
 154         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 155         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 156 }
 157
 158 void racer_fire_rocket_aim(entity player, string tagname, entity trg)
 159 {
 160         entity racer = player.vehicle;
 161         vector v = gettaginfo(racer, gettagindex(racer, tagname));
 162         racer_fire_rocket(player, v, v_forward, trg);
 163 }
 164
 165 float racer_frame()
 166 {SELFPARAM();
 167         entity player, racer;
 168         vector df;
 169         float ftmp;
 170
 171         if(intermission_running)
 172         {
 173                 self.vehicle.velocity = '0 0 0';
 174                 self.vehicle.avelocity = '0 0 0';
 175                 return 1;
 176         }
 177
 178         player  = self;
 179         racer   = self.vehicle;
 180         setself(racer);
 181
 182         vehicles_frame(racer, player);
 183
 184         if(pointcontents(racer.origin) != CONTENT_WATER)
 185                 racer.air_finished = time + autocvar_g_vehicle_racer_water_time;
 186
 187         if(IS_DEAD(racer))
 188         {
 189                 setself(player);
 190                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 191                 return 1;
 192         }
 193
 194         racer_align4point(self, PHYS_INPUT_TIMELENGTH);
 195
 196         player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 197
 198         crosshair_trace(player);
 199
 200         racer.angles_x *= -1;
 201
 202         // Yaw
 203         ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 204         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 205         racer.angles_y = anglemods(racer.angles_y + ftmp);
 206
 207         // Roll
 208         racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 209
 210         // Pitch
 211         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 212         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 213         racer.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(racer.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 214
 215         makevectors(racer.angles);
 216         racer.angles_x *= -1;
 217
 218         //ftmp = racer.velocity_z;
 219         df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 220         //racer.velocity_z = ftmp;
 221
 222         int cont = pointcontents(racer.origin);
 223         if(player.movement)
 224         {
 225                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 226                 {
 227                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 228                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 229                 }
 230                 else
 231                 {
 232                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 233                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 234                 }
 235
 236 #ifdef SVQC
 237                 if(self.sound_nexttime < time || self.sounds != 1)
 238                 {
 239                         self.sounds = 1;
 240                         self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 241                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 242                 }
 243 #endif
 244         }
 245 #ifdef SVQC
 246         else
 247         {
 248                 if(self.sound_nexttime < time || self.sounds != 0)
 249                 {
 250                         self.sounds = 0;
 251                         self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 252                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 253                 }
 254         }
 255 #endif
 256
 257         // Afterburn
 258         if (PHYS_INPUT_BUTTON_JUMP(player) && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 259         {
 260 #ifdef SVQC
 261                 if(time - racer.wait > 0.2)
 262                         pointparticles(EFFECT_RACER_BOOSTER, self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 263 #endif
 264
 265                 racer.wait = time;
 266
 267                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 268                 {
 269                         racer.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 270                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 271                 }
 272                 else
 273                 {
 274                         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 275                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 276                 }
 277
 278 #ifdef SVQC
 279                 if(racer.invincible_finished < time)
 280                 {
 281                         traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 282                         if(trace_fraction != 1.0)
 283                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 284
 285                         racer.invincible_finished = time + 0.1 + (random() * 0.1);
 286                 }
 287
 288                 if(racer.strength_finished < time)
 289                 {
 290                         racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 291                         sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 292                 }
 293 #endif
 294         }
 295         else
 296         {
 297                 racer.strength_finished = 0;
 298                 sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 299         }
 300
 301         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 302                 racer.racer_watertime = time;
 303
 304         float dforce = autocvar_g_vehicle_racer_downforce;
 305         if(time - racer.racer_watertime <= 3)
 306                 dforce = autocvar_g_vehicle_racer_water_downforce;
 307
 308         df -= v_up * (vlen(racer.velocity) * dforce);
 309         player.movement = racer.velocity += df * PHYS_INPUT_TIMELENGTH;
 310
 311 #ifdef SVQC
 312         Weapon wep1 = WEP_RACER;
 313         if (!forbidWeaponUse(player))
 314         if (player.BUTTON_ATCK)
 315         if (wep1.wr_checkammo1(wep1))
 316         {
 317                 string tagname = (racer.cnt)
 318                     ? (racer.cnt = 0, "tag_fire1")
 319                     : (racer.cnt = 1, "tag_fire2");
 320                 vector org = gettaginfo(self, gettagindex(self, tagname));
 321                 w_shotorg = org;
 322                 w_shotdir = v_forward;
 323                 // Fix z-aim (for chase mode)
 324                 crosshair_trace(player);
 325                 w_shotdir.z = normalize(trace_endpos - org).z * 0.5;
 326                 .entity weaponentity = weaponentities[0];
 327                 wep1.wr_think(wep1, self, weaponentity, 1);
 328         }
 329
 330         if(autocvar_g_vehicle_racer_rocket_locktarget)
 331         {
 332                 vehicles_locktarget(self, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 333                                                  (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 334                                                  autocvar_g_vehicle_racer_rocket_locked_time);
 335
 336                 if(self.lock_target)
 337                 {
 338                         if(racer.lock_strength == 1)
 339                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 340                         else if(self.lock_strength > 0.5)
 341                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 342                         else if(self.lock_strength < 0.5)
 343                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 344                 }
 345         }
 346
 347         if(!forbidWeaponUse(player))
 348         if(time > racer.delay)
 349         if(player.BUTTON_ATCK2)
 350         {
 351                 racer.misc_bulletcounter += 1;
 352                 racer.delay = time + 0.3;
 353
 354                 if(racer.misc_bulletcounter == 1)
 355                 {
 356                         racer_fire_rocket_aim(player, "tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 357                         player.vehicle_ammo2 = 50;
 358                 }
 359                 else if(racer.misc_bulletcounter == 2)
 360                 {
 361                         racer_fire_rocket_aim(player, "tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 362                         racer.lock_strength  = 0;
 363                         racer.lock_target       = world;
 364                         racer.misc_bulletcounter = 0;
 365                         racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 366                         racer.lip = time;
 367                         player.vehicle_ammo2 = 0;
 368                 }
 369         }
 370         else if(racer.misc_bulletcounter == 0)
 371                 player.vehicle_ammo2 = 100;
 372
 373         player.vehicle_reload2 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 374
 375         if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 376                 vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 377
 378         if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 379                 vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 380
 381         if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 382                 vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 383
 384
 385         VEHICLE_UPDATE_PLAYER(player, health, racer);
 386         VEHICLE_UPDATE_PLAYER(player, energy, racer);
 387
 388         if(racer.vehicle_flags & VHF_HASSHIELD)
 389                 VEHICLE_UPDATE_PLAYER(player, shield, racer);
 390
 391         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 392 #endif
 393
 394         setorigin(player,racer.origin + '0 0 32');
 395         player.velocity = racer.velocity;
 396
 397         setself(player);
 398         return 1;
 399 }
 400
 401 void racer_think()
 402 {SELFPARAM();
 403         self.nextthink = time;
 404
 405         float pushdeltatime = time - self.lastpushtime;
 406         if (pushdeltatime > 0.15) pushdeltatime = 0;
 407         self.lastpushtime = time;
 408         if(!pushdeltatime) return;
 409
 410         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, self);
 411
 412         vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 413         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 414
 415         float forced = autocvar_g_vehicle_racer_upforcedamper;
 416
 417         int cont = pointcontents(self.origin - '0 0 64');
 418         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 419         {
 420                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 421                 self.velocity_z += 200;
 422         }
 423
 424         self.velocity += df * pushdeltatime;
 425         if(self.velocity_z > 0)
 426                 self.velocity_z *= 1 - forced * pushdeltatime;
 427
 428         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 429         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 430
 431         CSQCMODEL_AUTOUPDATE(self);
 432 }
 433
 434 void racer_exit(float eject)
 435 {SELFPARAM();
 436         vector spot;
 437
 438         self.think        = racer_think;
 439         self.nextthink  = time;
 440         self.movetype   = MOVETYPE_BOUNCE;
 441         sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 442
 443         if(!self.owner)
 444                 return;
 445
 446         makevectors(self.angles);
 447         if(eject)
 448         {
 449                 spot = self.origin + v_forward * 100 + '0 0 64';
 450                 spot = vehicles_findgoodexit(spot);
 451                 setorigin(self.owner , spot);
 452                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 453                 self.owner.oldvelocity = self.owner.velocity;
 454         }
 455         else
 456         {
 457                 if(vdist(self.velocity, >, 2 * autocvar_sv_maxairspeed))
 458                 {
 459                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 460                         self.owner.velocity_z += 200;
 461                         spot = self.origin + v_forward * 32 + '0 0 32';
 462                         spot = vehicles_findgoodexit(spot);
 463                 }
 464                 else
 465                 {
 466                         self.owner.velocity = self.velocity * 0.5;
 467                         self.owner.velocity_z += 10;
 468                         spot = self.origin - v_forward * 200 + '0 0 32';
 469                         spot = vehicles_findgoodexit(spot);
 470                 }
 471                 self.owner.oldvelocity = self.owner.velocity;
 472                 setorigin(self.owner , spot);
 473         }
 474         antilag_clear(self.owner);
 475         self.owner = world;
 476 }
 477
 478 void racer_blowup()
 479 {SELFPARAM();
 480         self.deadflag   = DEAD_DEAD;
 481         self.vehicle_exit(VHEF_NORMAL);
 482
 483         RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 484                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 485                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 486                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 487                                         DEATH_VH_WAKI_DEATH.m_id, world);
 488
 489         self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 490         self.think        = vehicles_spawn;
 491         self.movetype   = MOVETYPE_NONE;
 492         self.effects    = EF_NODRAW;
 493         self.solid = SOLID_NOT;
 494
 495         self.colormod  = '0 0 0';
 496         self.avelocity = '0 0 0';
 497         self.velocity  = '0 0 0';
 498
 499         setorigin(self, self.pos1);
 500 }
 501
 502 void racer_blowup_think()
 503 {SELFPARAM();
 504         self.nextthink = time;
 505
 506         if(time >= self.delay)
 507                 racer_blowup();
 508
 509         CSQCMODEL_AUTOUPDATE(self);
 510 }
 511
 512 void racer_deadtouch()
 513 {SELFPARAM();
 514         self.avelocity_x *= 0.7;
 515         self.cnt -= 1;
 516         if(self.cnt <= 0)
 517                 racer_blowup();
 518 }
 519
 520 spawnfunc(vehicle_racer)
 521 {
 522         if(!autocvar_g_vehicle_racer) { remove(self); return; }
 523         if(!vehicle_initialize(VEH_RACER, false)) { remove(self); return; }
 524 }
 525
 526 #endif // SVQC
 527
 528 #ifdef CSQC
 529 #if 0
 530 void racer_draw()
 531 {SELFPARAM();
 532         float pushdeltatime = time - self.lastpushtime;
 533         if (pushdeltatime > 0.15) pushdeltatime = 0;
 534         self.lastpushtime = time;
 535         if(!pushdeltatime) return;
 536
 537         tracebox(self.move_origin, self.mins, self.maxs, self.move_origin - ('0 0 1' * STAT(VEH_RACER_SPRINGLENGTH)), MOVE_NOMONSTERS, self);
 538
 539         vector df = self.move_velocity * -STAT(VEH_RACER_FRICTION);
 540         df_z += (1 - trace_fraction) * STAT(VEH_RACER_HOVERPOWER) + sin(time * 2) * (STAT(VEH_RACER_SPRINGLENGTH) * 2);
 541
 542         float forced = STAT(VEH_RACER_UPFORCEDAMPER);
 543
 544         int cont = pointcontents(self.move_origin - '0 0 64');
 545         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 546         {
 547                 forced = STAT(VEH_RACER_WATER_UPFORCEDAMPER);
 548                 self.move_velocity_z += 200;
 549         }
 550
 551         self.move_velocity += df * pushdeltatime;
 552         if(self.move_velocity_z > 0)
 553                 self.move_velocity_z *= 1 - forced * pushdeltatime;
 554
 555         self.move_angles_x *= 1 - (STAT(VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 556         self.move_angles_z *= 1 - (STAT(VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 557
 558         Movetype_Physics_MatchServer(false);
 559 }
 560 #endif
 561 #endif
 562
 563                 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 564                 {
 565                 #ifdef SVQC
 566                         if(autocvar_g_vehicle_racer_bouncepain)
 567                                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 568                 #endif
 569                 }
 570
 571                 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 572                 {
 573                 #ifdef SVQC
 574                         self.movetype = MOVETYPE_BOUNCE;
 575                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 576                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 577
 578                         if(self.owner.flagcarried)
 579                            setorigin(self.owner.flagcarried, '-190 0 96');
 580                 #elif defined(CSQC)
 581
 582                         self.move_movetype = MOVETYPE_BOUNCE;
 583                 #endif
 584                 }
 585
 586                 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 587                 {
 588                 #ifdef SVQC
 589                         if(self.scale != 0.5)
 590                         {
 591                                 if(autocvar_g_vehicle_racer_hovertype != 0)
 592                                         racer_force_from_tag = vehicles_force_fromtag_maglev;
 593                                 else
 594                                         racer_force_from_tag = vehicles_force_fromtag_hover;
 595
 596                                 // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 597                                 self.scale = 0.5;
 598                                 setattachment(self.vehicle_hudmodel, self, "");
 599                                 setattachment(self.vehicle_viewport, self, "tag_viewport");
 600
 601                                 self.mass                          = 900;
 602                         }
 603
 604                         self.think                = racer_think;
 605                         self.nextthink    = time;
 606                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 607                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 608
 609                         self.movetype     = MOVETYPE_TOSS;
 610                         self.solid                = SOLID_SLIDEBOX;
 611                         self.delay                = time;
 612                         self.scale                = 0.5;
 613
 614                         self.PlayerPhysplug = racer_frame;
 615
 616                         self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 617                         self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 618                         self.damageforcescale = 0.5;
 619                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 620                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 621                 #endif
 622                 }
 623
 624                 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 625                 {
 626                 #ifdef SVQC
 627                         self.SendEntity         = func_null; // stop networking this racer (for now)
 628                         self.health                     = 0;
 629                         self.event_damage       = func_null;
 630                         self.solid                      = SOLID_CORPSE;
 631                         self.takedamage         = DAMAGE_NO;
 632                         self.deadflag           = DEAD_DYING;
 633                         self.movetype           = MOVETYPE_BOUNCE;
 634                         self.wait                       = time;
 635                         self.delay                      = 2 + time + random() * 3;
 636                         self.cnt                        = 1 + random() * 2;
 637                         self.touch                      = racer_deadtouch;
 638
 639                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, self.origin, '0 0 0', 1);
 640
 641                         if(random() < 0.5)
 642                                 self.avelocity_z = 32;
 643                         else
 644                                 self.avelocity_z = -32;
 645
 646                         self.avelocity_x = -vlen(self.velocity) * 0.2;
 647                         self.velocity += '0 0 700';
 648                         self.colormod = '-0.5 -0.5 -0.5';
 649
 650                         self.think = racer_blowup_think;
 651                         self.nextthink = time;
 652                 #endif
 653                 }
 654
 655 #ifdef CSQC
 656                 METHOD(Racer, vr_hud, void(Racer thisveh))
 657                 {
 658                         Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 659                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 660                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 661                 }
 662                 METHOD(Racer, vr_crosshair, void(Racer thisveh))
 663                 {
 664                         Vehicles_drawCrosshair(vCROSS_GUIDE);
 665                 }
 666 #endif
 667                 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 668                 {
 669                 #ifdef SVQC
 670                         self.vehicle_exit = racer_exit;
 671                 #endif
 672
 673                 #ifdef SVQC
 674                         // we have no need to network energy
 675                         if(autocvar_g_vehicle_racer_energy)
 676                         if(autocvar_g_vehicle_racer_energy_regen)
 677                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 678
 679                         if(autocvar_g_vehicle_racer_shield)
 680                                 self.vehicle_flags |= VHF_HASSHIELD;
 681
 682                         if(autocvar_g_vehicle_racer_shield_regen)
 683                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 684
 685                         if(autocvar_g_vehicle_racer_health_regen)
 686                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 687
 688                         self.respawntime = autocvar_g_vehicle_racer_respawntime;
 689                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 690                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 691                         self.max_health = self.vehicle_health;
 692                 #endif
 693
 694                 #ifdef CSQC
 695                         AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 696                 #endif
 697                 }
 698
 699 #endif