qcsrc/common/vehicles/vehicle/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3
   4 #include "racer_weapon.qh"
   5
   6 CLASS(Racer, Vehicle)
   7 /* spawnflags */ ATTRIB(Racer, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   8 /* mins       */ ATTRIB(Racer, mins, vector, '-120 -120 -40' * 0.5);
   9 /* maxs       */ ATTRIB(Racer, maxs, vector, '120 120 40' * 0.5);
  10 /* view offset*/ ATTRIB(Racer, view_ofs, vector, '0 0 50');
  11 /* view dist  */ ATTRIB(Racer, height, float, 200);
  12 /* model          */ ATTRIB(Racer, mdl, string, "models/vehicles/wakizashi.dpm");
  13 /* model          */ ATTRIB(Racer, model, string, "models/vehicles/wakizashi.dpm");
  14 /* head_model */ ATTRIB(Racer, head_model, string, "null");
  15 /* hud_model  */ ATTRIB(Racer, hud_model, string, "models/vehicles/wakizashi_cockpit.dpm");
  16 /* tags       */ ATTRIB(Racer, tag_head, string, "");
  17 /* tags       */ ATTRIB(Racer, tag_hud, string, "");
  18 /* tags       */ ATTRIB(Racer, tag_view, string, "tag_viewport");
  19 /* netname    */ ATTRIB(Racer, netname, string, "racer");
  20 /* fullname   */ ATTRIB(Racer, vehicle_name, string, _("Racer"));
  21 /* icon       */ ATTRIB(Racer, m_icon, string, "vehicle_racer");
  22 ENDCLASS(Racer)
  23 REGISTER_VEHICLE(RACER, NEW(Racer));
  24
  25 #endif
  26
  27 #ifdef IMPLEMENTATION
  28
  29 #ifdef SVQC
  30 #include <common/triggers/trigger/impulse.qh>
  31
  32 bool autocvar_g_vehicle_racer = true;
  33
  34 float autocvar_g_vehicle_racer_thinkrate = 0.05; // TODO: any higher causes it to sink in liquids
  35
  36 float autocvar_g_vehicle_racer_speed_afterburn = 3000;
  37 // energy consumed per second
  38 float autocvar_g_vehicle_racer_afterburn_cost = 100;
  39
  40 float autocvar_g_vehicle_racer_waterburn_cost = 5;
  41 float autocvar_g_vehicle_racer_waterburn_speed = 750;
  42
  43 float autocvar_g_vehicle_racer_water_speed_forward = 600;
  44 float autocvar_g_vehicle_racer_water_speed_strafe = 600;
  45
  46 float autocvar_g_vehicle_racer_pitchlimit = 30;
  47
  48 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  49 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  50
  51 float autocvar_g_vehicle_racer_anglestabilizer = 1.75;
  52 float autocvar_g_vehicle_racer_downforce = 0.01;
  53
  54 float autocvar_g_vehicle_racer_speed_forward = 650;
  55 float autocvar_g_vehicle_racer_speed_strafe = 650;
  56 float autocvar_g_vehicle_racer_springlength = 70;
  57 float autocvar_g_vehicle_racer_upforcedamper = 10;
  58 float autocvar_g_vehicle_racer_friction = 0.45;
  59
  60 float autocvar_g_vehicle_racer_water_time = 5;
  61
  62 float autocvar_g_vehicle_racer_collision_multiplier = 0.05;
  63
  64 // 0 = hover, != 0 = maglev
  65 int autocvar_g_vehicle_racer_hovertype = 0;
  66 // NOTE!! x 4 (4 engines)
  67 float autocvar_g_vehicle_racer_hoverpower = 8000;
  68
  69 float autocvar_g_vehicle_racer_turnroll = 30;
  70 float autocvar_g_vehicle_racer_turnspeed = 220;
  71 float autocvar_g_vehicle_racer_pitchspeed = 125;
  72
  73 float autocvar_g_vehicle_racer_energy = 100;
  74 float autocvar_g_vehicle_racer_energy_regen = 50;
  75 float autocvar_g_vehicle_racer_energy_regen_pause = 1;
  76
  77 float autocvar_g_vehicle_racer_health = 200;
  78 float autocvar_g_vehicle_racer_health_regen = 0;
  79 float autocvar_g_vehicle_racer_health_regen_pause = 0;
  80
  81 float autocvar_g_vehicle_racer_shield = 100;
  82 float autocvar_g_vehicle_racer_shield_regen = 30;
  83 float autocvar_g_vehicle_racer_shield_regen_pause = 1;
  84
  85 bool autocvar_g_vehicle_racer_rocket_locktarget = true;
  86 float autocvar_g_vehicle_racer_rocket_locking_time = 0.9;
  87 float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5;
  88 float autocvar_g_vehicle_racer_rocket_locked_time = 4;
  89
  90 float autocvar_g_vehicle_racer_respawntime = 35;
  91
  92 float autocvar_g_vehicle_racer_blowup_radius = 250;
  93 float autocvar_g_vehicle_racer_blowup_coredamage = 250;
  94 float autocvar_g_vehicle_racer_blowup_edgedamage = 15;
  95 float autocvar_g_vehicle_racer_blowup_forceintensity = 250;
  96
  97 // Factor of old velocity to keep after collision
  98 float autocvar_g_vehicle_racer_bouncefactor = 0.25;
  99 // if != 0, New veloctiy after bounce = 0 if new velocity < this
 100 float autocvar_g_vehicle_racer_bouncestop = 0;
 101 // "minspeed_for_pain speedchange_to_pain_factor max_damage"
 102 vector autocvar_g_vehicle_racer_bouncepain = '60 0.75 300';
 103
 104 .float racer_watertime;
 105
 106 var vector racer_force_from_tag(entity this, string tag_name, float spring_length, float max_power);
 107
 108 void racer_align4point(entity this, float _delta)
 109 {
 110         vector push_vector;
 111         float fl_push, fr_push, bl_push, br_push;
 112
 113         push_vector  = racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 114         fr_push   = force_fromtag_normpower;
 115         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 116
 117         push_vector += racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 118         fl_push   = force_fromtag_normpower;
 119         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 120
 121         push_vector += racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 122         br_push   = force_fromtag_normpower;
 123         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 124
 125         push_vector += racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 126         bl_push   = force_fromtag_normpower;
 127         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 128
 129         this.velocity += push_vector * _delta;
 130
 131         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 132
 133         int cont = pointcontents(this.origin - '0 0 64');
 134         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 135         {
 136                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 137
 138                 if(PHYS_INPUT_BUTTON_CROUCH(this.owner) && time < this.air_finished)
 139                         this.velocity_z += 30;
 140                 else
 141                         this.velocity_z += 200;
 142         }
 143
 144
 145         // Anti ocilation
 146         if(this.velocity_z > 0)
 147                 this.velocity_z *= 1 - uforce * _delta;
 148
 149         push_vector_x =  (fl_push - bl_push);
 150         push_vector_x += (fr_push - br_push);
 151         push_vector_x *= 360;
 152
 153         push_vector_z = (fr_push - fl_push);
 154         push_vector_z += (br_push - bl_push);
 155         push_vector_z *= 360;
 156
 157         // Apply angle diffrance
 158         this.angles_z += push_vector_z * _delta;
 159         this.angles_x += push_vector_x * _delta;
 160
 161         // Apply stabilizer
 162         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 163         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 164 }
 165
 166 void racer_fire_rocket_aim(entity player, string tagname, entity trg)
 167 {
 168         entity racer = player.vehicle;
 169         vector v = gettaginfo(racer, gettagindex(racer, tagname));
 170         racer_fire_rocket(player, v, v_forward, trg);
 171 }
 172
 173 bool racer_frame(entity this)
 174 {
 175         entity vehic = this.vehicle;
 176         return = true;
 177
 178         if(intermission_running)
 179         {
 180                 vehic.velocity = '0 0 0';
 181                 vehic.avelocity = '0 0 0';
 182                 return;
 183         }
 184
 185         vehicles_frame(vehic, this);
 186
 187         traceline(vehic.origin, vehic.origin + '0 0 1', MOVE_NOMONSTERS, this);
 188         int cont = trace_dpstartcontents;
 189         if(!(cont & DPCONTENTS_WATER))
 190                 vehic.air_finished = time + autocvar_g_vehicle_racer_water_time;
 191
 192         if(IS_DEAD(vehic))
 193         {
 194                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 195                 return;
 196         }
 197
 198         racer_align4point(vehic, PHYS_INPUT_TIMELENGTH);
 199
 200         PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 201
 202         vehic.angles_x *= -1;
 203
 204         // Yaw
 205         float ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 206         ftmp = bound(-ftmp, shortangle_f(this.v_angle_y - vehic.angles_y, vehic.angles_y), ftmp);
 207         vehic.angles_y = anglemods(vehic.angles_y + ftmp);
 208
 209         // Roll
 210         vehic.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 211
 212         // Pitch
 213         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 214         ftmp = bound(-ftmp, shortangle_f(this.v_angle_x - vehic.angles_x, vehic.angles_x), ftmp);
 215         vehic.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 216
 217         makevectors(vehic.angles);
 218         vehic.angles_x *= -1;
 219
 220         //ftmp = vehic.velocity_z;
 221         vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
 222         //vehic.velocity_z = ftmp;
 223
 224         if(this.movement)
 225         {
 226                 if(cont & DPCONTENTS_LIQUIDSMASK)
 227                 {
 228                         if(this.movement_x) { df += v_forward * ((this.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 229                         if(this.movement_y) { df += v_right * ((this.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 230                 }
 231                 else
 232                 {
 233                         if(this.movement_x) { df += v_forward * ((this.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 234                         if(this.movement_y) { df += v_right * ((this.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 235                 }
 236
 237 #ifdef SVQC
 238                 if(vehic.sound_nexttime < time || vehic.sounds != 1)
 239                 {
 240                         vehic.sounds = 1;
 241                         vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 242                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 243                 }
 244 #endif
 245         }
 246 #ifdef SVQC
 247         else
 248         {
 249                 if(vehic.sound_nexttime < time || vehic.sounds != 0)
 250                 {
 251                         vehic.sounds = 0;
 252                         vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 253                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 254                 }
 255         }
 256 #endif
 257
 258         // Afterburn
 259         if (PHYS_INPUT_BUTTON_JUMP(this) && vehic.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 260         {
 261 #ifdef SVQC
 262                 if(time - vehic.wait > 0.2)
 263                         pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
 264 #endif
 265
 266                 vehic.wait = time;
 267
 268                 if(cont & DPCONTENTS_LIQUIDSMASK)
 269                 {
 270                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 271                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 272                 }
 273                 else
 274                 {
 275                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 276                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 277                 }
 278
 279 #ifdef SVQC
 280                 if(vehic.invincible_finished < time)
 281                 {
 282                         traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
 283                         if(trace_fraction != 1.0)
 284                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 285
 286                         vehic.invincible_finished = time + 0.1 + (random() * 0.1);
 287                 }
 288
 289                 if(vehic.strength_finished < time)
 290                 {
 291                         vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 292                         sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 293                 }
 294 #endif
 295         }
 296         else
 297         {
 298                 vehic.strength_finished = 0;
 299                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 300         }
 301
 302         if(cont & DPCONTENTS_LIQUIDSMASK)
 303                 vehic.racer_watertime = time;
 304
 305         float dforce = autocvar_g_vehicle_racer_downforce;
 306         if(time - vehic.racer_watertime <= 3)
 307                 dforce = autocvar_g_vehicle_racer_water_downforce;
 308
 309         df -= v_up * (vlen(vehic.velocity) * dforce);
 310         this.movement = vehic.velocity += df * PHYS_INPUT_TIMELENGTH;
 311
 312 #ifdef SVQC
 313
 314         Weapon wep1 = WEP_RACER;
 315         if (!forbidWeaponUse(this))
 316         if (PHYS_INPUT_BUTTON_ATCK(this))
 317         if (wep1.wr_checkammo1(wep1, vehic))
 318         {
 319                 string tagname = (vehic.cnt)
 320                     ? (vehic.cnt = 0, "tag_fire1")
 321                     : (vehic.cnt = 1, "tag_fire2");
 322                 vector org = gettaginfo(vehic, gettagindex(vehic, tagname));
 323                 w_shotorg = org;
 324                 w_shotdir = v_forward;
 325                 // Fix z-aim (for chase mode)
 326                 crosshair_trace(this);
 327                 w_shotdir.z = normalize(trace_endpos - org).z * 0.5;
 328                 .entity weaponentity = weaponentities[0];
 329                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 330         }
 331
 332         if(autocvar_g_vehicle_racer_rocket_locktarget)
 333         {
 334                 if(time >= vehic.vehicle_last_trace)
 335                 {
 336                         crosshair_trace(this);
 337
 338                         vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 339                                                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 340                                                          autocvar_g_vehicle_racer_rocket_locked_time);
 341
 342                         vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
 343                 }
 344
 345                 if(vehic.lock_target)
 346                 {
 347                         if(vehic.lock_strength == 1)
 348                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 0);
 349                         else if(vehic.lock_strength > 0.5)
 350                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 0);
 351                         else if(vehic.lock_strength < 0.5)
 352                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 0);
 353                 }
 354         }
 355
 356         if(!forbidWeaponUse(this))
 357         if(time > vehic.delay)
 358         if(PHYS_INPUT_BUTTON_ATCK2(this))
 359         {
 360                 vehic.misc_bulletcounter += 1;
 361                 vehic.delay = time + 0.3;
 362
 363                 if(vehic.misc_bulletcounter == 1)
 364                 {
 365                         racer_fire_rocket_aim(this, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 366                         this.vehicle_ammo2 = 50;
 367                 }
 368                 else if(vehic.misc_bulletcounter == 2)
 369                 {
 370                         racer_fire_rocket_aim(this, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 371                         vehic.lock_strength  = 0;
 372                         vehic.lock_target       = NULL;
 373                         vehic.misc_bulletcounter = 0;
 374                         vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 375                         vehic.lip = time;
 376                         this.vehicle_ammo2 = 0;
 377                 }
 378         }
 379         else if(vehic.misc_bulletcounter == 0)
 380                 this.vehicle_ammo2 = 100;
 381
 382         this.vehicle_reload2 = bound(0, 100 * ((time - vehic.lip) / (vehic.delay - vehic.lip)), 100);
 383
 384         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 385                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 386
 387         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 388                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 389
 390         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 391                 vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 392
 393         VEHICLE_UPDATE_PLAYER(this, vehic, health, racer);
 394         VEHICLE_UPDATE_PLAYER(this, vehic, energy, racer);
 395
 396         if(vehic.vehicle_flags & VHF_HASSHIELD)
 397                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, racer);
 398
 399         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 400 #endif
 401
 402         setorigin(this, vehic.origin + '0 0 32');
 403         this.velocity = vehic.velocity;
 404 }
 405
 406 void racer_think(entity this)
 407 {
 408         this.nextthink = time + autocvar_g_vehicle_racer_thinkrate;
 409
 410         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 411
 412         vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
 413         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 414
 415         float forced = autocvar_g_vehicle_racer_upforcedamper;
 416
 417         //int cont = pointcontents(this.origin - '0 0 64');
 418         traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
 419         //if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 420         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 421         {
 422                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 423                 this.velocity_z += 200;
 424         }
 425
 426         this.velocity += df * autocvar_g_vehicle_racer_thinkrate;
 427         if(this.velocity_z > 0)
 428                 this.velocity_z *= 1 - forced * autocvar_g_vehicle_racer_thinkrate;
 429
 430         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * autocvar_g_vehicle_racer_thinkrate);
 431         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * autocvar_g_vehicle_racer_thinkrate);
 432
 433         CSQCMODEL_AUTOUPDATE(this);
 434 }
 435
 436 void racer_exit(entity this, int eject)
 437 {
 438         vector spot;
 439
 440         setthink(this, racer_think);
 441         this.nextthink  = time;
 442         set_movetype(this, MOVETYPE_BOUNCE);
 443         sound (this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 444
 445         if(!this.owner)
 446                 return;
 447
 448         makevectors(this.angles);
 449         if(eject)
 450         {
 451                 spot = this.origin + v_forward * 100 + '0 0 64';
 452                 spot = vehicles_findgoodexit(this, spot);
 453                 setorigin(this.owner, spot);
 454                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 455                 this.owner.oldvelocity = this.owner.velocity;
 456         }
 457         else
 458         {
 459                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 460                 {
 461                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 462                         this.owner.velocity_z += 200;
 463                         spot = this.origin + v_forward * 32 + '0 0 32';
 464                         spot = vehicles_findgoodexit(this, spot);
 465                 }
 466                 else
 467                 {
 468                         this.owner.velocity = this.velocity * 0.5;
 469                         this.owner.velocity_z += 10;
 470                         spot = this.origin - v_forward * 200 + '0 0 32';
 471                         spot = vehicles_findgoodexit(this, spot);
 472                 }
 473                 this.owner.oldvelocity = this.owner.velocity;
 474                 setorigin(this.owner , spot);
 475         }
 476         antilag_clear(this.owner, CS(this.owner));
 477         this.owner = NULL;
 478 }
 479
 480 void racer_blowup(entity this)
 481 {
 482         this.deadflag = DEAD_DEAD;
 483         this.vehicle_exit(this, VHEF_NORMAL);
 484
 485         RadiusDamage (this, this.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 486                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 487                                         autocvar_g_vehicle_racer_blowup_radius, NULL, NULL,
 488                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 489                                         DEATH_VH_WAKI_DEATH.m_id, NULL);
 490
 491         this.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 492         setthink(this, vehicles_spawn);
 493         set_movetype(this, MOVETYPE_NONE);
 494         this.effects    = EF_NODRAW;
 495         this.solid = SOLID_NOT;
 496
 497         this.colormod  = '0 0 0';
 498         this.avelocity = '0 0 0';
 499         this.velocity  = '0 0 0';
 500
 501         setorigin(this, this.pos1);
 502 }
 503
 504 void racer_blowup_think(entity this)
 505 {
 506         this.nextthink = time;
 507
 508         if(time >= this.delay)
 509                 racer_blowup(this);
 510
 511         CSQCMODEL_AUTOUPDATE(this);
 512 }
 513
 514 void racer_deadtouch(entity this, entity toucher)
 515 {
 516         this.avelocity_x *= 0.7;
 517         this.cnt -= 1;
 518         if(this.cnt <= 0)
 519                 racer_blowup(this);
 520 }
 521
 522 spawnfunc(vehicle_racer)
 523 {
 524         if(!autocvar_g_vehicle_racer) { remove(this); return; }
 525         if(!vehicle_initialize(this, VEH_RACER, false)) { remove(this); return; }
 526 }
 527
 528 #endif // SVQC
 529
 530 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 531 {
 532 #ifdef SVQC
 533     if(autocvar_g_vehicle_racer_bouncepain)
 534         vehicles_impact(instance, autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 535 #endif
 536 }
 537
 538 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 539 {
 540 #ifdef SVQC
 541     set_movetype(instance, MOVETYPE_BOUNCE);
 542     instance.owner.vehicle_health = (instance.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 543     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 544
 545     if(instance.owner.flagcarried)
 546        setorigin(instance.owner.flagcarried, '-190 0 96');
 547 #elif defined(CSQC)
 548     instance.move_movetype = MOVETYPE_BOUNCE;
 549 #endif
 550 }
 551
 552 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 553 {
 554 #ifdef SVQC
 555     if(instance.scale != 0.5)
 556     {
 557         if(autocvar_g_vehicle_racer_hovertype != 0)
 558             racer_force_from_tag = vehicles_force_fromtag_maglev;
 559         else
 560             racer_force_from_tag = vehicles_force_fromtag_hover;
 561
 562         // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 563         instance.scale = 0.5;
 564         setattachment(instance.vehicle_hudmodel, instance, "");
 565         setattachment(instance.vehicle_viewport, instance, "tag_viewport");
 566
 567         instance.mass                      = 900;
 568     }
 569
 570     setthink(instance, racer_think);
 571     instance.nextthink    = time;
 572     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 573     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 574
 575     set_movetype(instance, MOVETYPE_TOSS);
 576     instance.solid                = SOLID_SLIDEBOX;
 577     instance.delay                = time;
 578     instance.scale                = 0.5;
 579
 580     instance.PlayerPhysplug = racer_frame;
 581
 582     instance.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 583     instance.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 584     instance.damageforcescale = 0.5;
 585     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 586     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 587 #endif
 588 }
 589
 590 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 591 {
 592 #ifdef SVQC
 593     setSendEntity(instance, func_null); // stop networking this racer (for now)
 594     instance.health                     = 0;
 595     instance.event_damage       = func_null;
 596     instance.solid                      = SOLID_CORPSE;
 597     instance.takedamage         = DAMAGE_NO;
 598     instance.deadflag           = DEAD_DYING;
 599     set_movetype(instance, MOVETYPE_BOUNCE);
 600     instance.wait                       = time;
 601     instance.delay                      = 2 + time + random() * 3;
 602     instance.cnt                        = 1 + random() * 2;
 603     settouch(instance, racer_deadtouch);
 604
 605     Send_Effect(EFFECT_EXPLOSION_MEDIUM, instance.origin, '0 0 0', 1);
 606
 607     if(random() < 0.5)
 608         instance.avelocity_z = 32;
 609     else
 610         instance.avelocity_z = -32;
 611
 612     instance.avelocity_x = -vlen(instance.velocity) * 0.2;
 613     instance.velocity += '0 0 700';
 614     instance.colormod = '-0.5 -0.5 -0.5';
 615
 616     setthink(instance, racer_blowup_think);
 617     instance.nextthink = time;
 618 #endif
 619 }
 620
 621 #ifdef CSQC
 622 METHOD(Racer, vr_hud, void(Racer thisveh))
 623 {
 624     Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 625                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 626                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 627 }
 628 METHOD(Racer, vr_crosshair, void(Racer thisveh, entity player))
 629 {
 630     Vehicles_drawCrosshair(vCROSS_GUIDE);
 631 }
 632 #endif
 633 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 634 {
 635 #ifdef SVQC
 636     instance.vehicle_exit = racer_exit;
 637
 638     // we have no need to network energy
 639     if(autocvar_g_vehicle_racer_energy)
 640     if(autocvar_g_vehicle_racer_energy_regen)
 641         instance.vehicle_flags |= VHF_ENERGYREGEN;
 642
 643     if(autocvar_g_vehicle_racer_shield)
 644         instance.vehicle_flags |= VHF_HASSHIELD;
 645
 646     if(autocvar_g_vehicle_racer_shield_regen)
 647         instance.vehicle_flags |= VHF_SHIELDREGEN;
 648
 649     if(autocvar_g_vehicle_racer_health_regen)
 650         instance.vehicle_flags |= VHF_HEALTHREGEN;
 651
 652     instance.respawntime = autocvar_g_vehicle_racer_respawntime;
 653     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 654     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 655     instance.max_health = instance.vehicle_health;
 656 #endif
 657
 658 #ifdef CSQC
 659     AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 660 #endif
 661 }
 662
 663 #endif