qcsrc/common/vehicles/vehicle/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3
   4 CLASS(Racer, Vehicle)
   5 /* spawnflags */ ATTRIB(Racer, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   6 /* mins       */ ATTRIB(Racer, mins, vector, '-120 -120 -40' * 0.5);
   7 /* maxs       */ ATTRIB(Racer, maxs, vector, '120 120 40' * 0.5);
   8 /* model          */ ATTRIB(Racer, mdl, string, "models/vehicles/wakizashi.dpm");
   9 /* model          */ ATTRIB(Racer, model, string, "models/vehicles/wakizashi.dpm");
  10 /* head_model */ ATTRIB(Racer, head_model, string, "null");
  11 /* hud_model  */ ATTRIB(Racer, hud_model, string, "models/vehicles/wakizashi_cockpit.dpm");
  12 /* tags       */ ATTRIB(Racer, tag_head, string, "");
  13 /* tags       */ ATTRIB(Racer, tag_hud, string, "");
  14 /* tags       */ ATTRIB(Racer, tag_hview, string, "tag_viewport");
  15 /* netname    */ ATTRIB(Racer, netname, string, "racer");
  16 /* fullname   */ ATTRIB(Racer, vehicle_name, string, _("Racer"));
  17 /* icon       */ ATTRIB(Racer, m_icon, string, "vehicle_racer");
  18 ENDCLASS(Racer)
  19
  20 REGISTER_VEHICLE(RACER, NEW(Racer));
  21
  22 #include "../../weapons/all.qh"
  23
  24 CLASS(RacerAttack, PortoLaunch)
  25 /* flags     */ ATTRIB(RacerAttack, spawnflags, int, WEP_TYPE_OTHER);
  26 /* impulse   */ ATTRIB(RacerAttack, impulse, int, 3);
  27 /* refname   */ ATTRIB(RacerAttack, netname, string, "racercannon");
  28 /* wepname   */ ATTRIB(RacerAttack, message, string, _("Racer cannon"));
  29 ENDCLASS(RacerAttack)
  30 REGISTER_WEAPON(RACER, NEW(RacerAttack));
  31
  32 #endif
  33
  34 #ifdef IMPLEMENTATION
  35 #ifdef SVQC
  36 #include "../../effects/effects.qh"
  37 #include "../../triggers/trigger/impulse.qh"
  38
  39 float autocvar_g_vehicle_racer_cannon_cost;
  40 float autocvar_g_vehicle_racer_cannon_damage;
  41 float autocvar_g_vehicle_racer_cannon_radius;
  42 float autocvar_g_vehicle_racer_cannon_refire;
  43 float autocvar_g_vehicle_racer_cannon_speed;
  44 float autocvar_g_vehicle_racer_cannon_spread;
  45 float autocvar_g_vehicle_racer_cannon_force;
  46
  47 void racer_fire_rocket(vector org, vector dir, entity trg);
  48 METHOD(RacerAttack, wr_think, bool(entity thiswep, bool fire1, bool fire2)) {
  49         SELFPARAM();
  50         bool isPlayer = IS_PLAYER(self);
  51         if (fire1)
  52         if (!isPlayer || weapon_prepareattack(false, autocvar_g_vehicle_racer_cannon_refire)) {
  53                 if (isPlayer) W_SetupShot_Dir(self, v_forward, false, 0, "", CH_WEAPON_B, 0);
  54                 vector org = w_shotorg;
  55                 vector dir = w_shotdir;
  56                 entity bolt = vehicles_projectile(EFFECT_RACER_MUZZLEFLASH.eent_eff_name, SND(LASERGUN_FIRE),
  57                                                            org, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
  58                                                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
  59                                                            DEATH_VH_WAKI_GUN, PROJECTILE_WAKICANNON, 0, true, true, self.owner);
  60                 bolt.velocity = normalize(dir) * autocvar_g_vehicle_racer_cannon_speed;
  61                 weapon_thinkf(WFRAME_FIRE1, 0, w_ready);
  62         }
  63         if (fire2)
  64         if (!isPlayer || weapon_prepareattack(false, 0.2)) {
  65                 if (isPlayer) W_SetupShot_Dir(self, v_forward, false, 0, "", CH_WEAPON_B, 0);
  66                 racer_fire_rocket(w_shotorg, w_shotdir, NULL);
  67                 weapon_thinkf(WFRAME_FIRE2, 0, w_ready);
  68         }
  69         return true;
  70 }
  71
  72 bool autocvar_g_vehicle_racer;
  73
  74 float autocvar_g_vehicle_racer_speed_afterburn;
  75 float autocvar_g_vehicle_racer_afterburn_cost;
  76
  77 float autocvar_g_vehicle_racer_waterburn_cost;
  78 float autocvar_g_vehicle_racer_waterburn_speed;
  79
  80 float autocvar_g_vehicle_racer_water_speed_forward;
  81 float autocvar_g_vehicle_racer_water_speed_strafe;
  82
  83 float autocvar_g_vehicle_racer_pitchlimit = 30;
  84
  85 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  86 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  87
  88 float autocvar_g_vehicle_racer_anglestabilizer;
  89 float autocvar_g_vehicle_racer_downforce;
  90
  91 float autocvar_g_vehicle_racer_speed_forward;
  92 float autocvar_g_vehicle_racer_speed_strafe;
  93 float autocvar_g_vehicle_racer_springlength;
  94 float autocvar_g_vehicle_racer_upforcedamper;
  95 float autocvar_g_vehicle_racer_friction;
  96
  97 float autocvar_g_vehicle_racer_water_time = 5;
  98
  99 float autocvar_g_vehicle_racer_hovertype;
 100 float autocvar_g_vehicle_racer_hoverpower;
 101
 102 float autocvar_g_vehicle_racer_turnroll;
 103 float autocvar_g_vehicle_racer_turnspeed;
 104 float autocvar_g_vehicle_racer_pitchspeed;
 105
 106 float autocvar_g_vehicle_racer_energy;
 107 float autocvar_g_vehicle_racer_energy_regen;
 108 float autocvar_g_vehicle_racer_energy_regen_pause;
 109
 110 float autocvar_g_vehicle_racer_health;
 111 float autocvar_g_vehicle_racer_health_regen;
 112 float autocvar_g_vehicle_racer_health_regen_pause;
 113
 114 float autocvar_g_vehicle_racer_shield;
 115 float autocvar_g_vehicle_racer_shield_regen;
 116 float autocvar_g_vehicle_racer_shield_regen_pause;
 117
 118 float autocvar_g_vehicle_racer_rocket_accel;
 119 float autocvar_g_vehicle_racer_rocket_damage;
 120 float autocvar_g_vehicle_racer_rocket_radius;
 121 float autocvar_g_vehicle_racer_rocket_force;
 122 float autocvar_g_vehicle_racer_rocket_refire;
 123 float autocvar_g_vehicle_racer_rocket_speed;
 124 float autocvar_g_vehicle_racer_rocket_turnrate;
 125
 126 float autocvar_g_vehicle_racer_rocket_locktarget;
 127 float autocvar_g_vehicle_racer_rocket_locking_time;
 128 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
 129 float autocvar_g_vehicle_racer_rocket_locked_time;
 130 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
 131 float autocvar_g_vehicle_racer_rocket_climbspeed;
 132
 133 float autocvar_g_vehicle_racer_respawntime;
 134
 135 float autocvar_g_vehicle_racer_blowup_radius;
 136 float autocvar_g_vehicle_racer_blowup_coredamage;
 137 float autocvar_g_vehicle_racer_blowup_edgedamage;
 138 float autocvar_g_vehicle_racer_blowup_forceintensity;
 139
 140 float autocvar_g_vehicle_racer_bouncefactor;
 141 float autocvar_g_vehicle_racer_bouncestop;
 142 vector autocvar_g_vehicle_racer_bouncepain;
 143
 144 .float racer_watertime;
 145
 146 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
 147
 148 void racer_align4point(float _delta)
 149 {SELFPARAM();
 150         vector push_vector;
 151         float fl_push, fr_push, bl_push, br_push;
 152
 153         push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 154         fr_push   = force_fromtag_normpower;
 155         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 156
 157         push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 158         fl_push   = force_fromtag_normpower;
 159         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 160
 161         push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 162         br_push   = force_fromtag_normpower;
 163         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 164
 165         push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 166         bl_push   = force_fromtag_normpower;
 167         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 168
 169         self.velocity += push_vector * _delta;
 170
 171         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 172
 173         int cont = pointcontents(self.origin - '0 0 64');
 174         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 175         {
 176                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 177
 178                 if(self.owner.BUTTON_CROUCH && time < self.air_finished)
 179                         self.velocity_z += 30;
 180                 else
 181                         self.velocity_z += 200;
 182         }
 183
 184
 185         // Anti ocilation
 186         if(self.velocity_z > 0)
 187                 self.velocity_z *= 1 - uforce * _delta;
 188
 189         push_vector_x =  (fl_push - bl_push);
 190         push_vector_x += (fr_push - br_push);
 191         push_vector_x *= 360;
 192
 193         push_vector_z = (fr_push - fl_push);
 194         push_vector_z += (br_push - bl_push);
 195         push_vector_z *= 360;
 196
 197         // Apply angle diffrance
 198         self.angles_z += push_vector_z * _delta;
 199         self.angles_x += push_vector_x * _delta;
 200
 201         // Apply stabilizer
 202         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 203         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 204 }
 205
 206 void racer_rocket_groundhugger()
 207 {SELFPARAM();
 208         vector olddir, newdir;
 209         float oldvel, newvel;
 210
 211         self.nextthink  = time;
 212
 213         if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 214         {
 215                 self.use();
 216                 return;
 217         }
 218
 219         if(!self.realowner.vehicle)
 220         {
 221                 UpdateCSQCProjectile(self);
 222                 return;
 223         }
 224
 225         olddir = normalize(self.velocity);
 226         oldvel = vlen(self.velocity);
 227         newvel = oldvel + self.lip;
 228
 229         tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 230         if(trace_fraction <= 0.5)
 231         {
 232                 // Hitting somethign soon, just speed ahead
 233                 self.velocity = olddir * newvel;
 234                 UpdateCSQCProjectile(self);
 235                 return;
 236         }
 237
 238         traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 239         if(trace_fraction != 1.0)
 240         {
 241                 newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 242                 self.velocity = normalize(olddir + newdir) * newvel;
 243         }
 244         else
 245         {
 246                 self.velocity = olddir * newvel;
 247                 self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 248         }
 249
 250         int cont = pointcontents(self.origin - '0 0 32');
 251         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 252                 self.velocity_z += 200;
 253
 254         UpdateCSQCProjectile(self);
 255         return;
 256 }
 257
 258 void racer_rocket_tracker()
 259 {SELFPARAM();
 260         vector olddir, newdir;
 261         float oldvel, newvel;
 262
 263         self.nextthink  = time;
 264
 265         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 266         {
 267                 self.use();
 268                 return;
 269         }
 270
 271         if(!self.realowner.vehicle)
 272         {
 273                 UpdateCSQCProjectile(self);
 274                 return;
 275         }
 276
 277         olddir = normalize(self.velocity);
 278         oldvel = vlen(self.velocity);
 279         newvel = oldvel + self.lip;
 280         makevectors(vectoangles(olddir));
 281
 282         float time_to_impact = min(vlen(self.enemy.origin - self.origin) / vlen(self.velocity), 1);
 283         vector predicted_origin = self.enemy.origin + self.enemy.velocity * time_to_impact;
 284
 285         traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 286         newdir = normalize(predicted_origin - self.origin);
 287
 288         //vector
 289         float height_diff = predicted_origin_z - self.origin_z;
 290
 291         if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 292         {
 293                 //bprint("Target lost!\n");
 294                 //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 295                 self.think = racer_rocket_groundhugger;
 296                 return;
 297         }
 298
 299         if(trace_fraction != 1.0 && trace_ent != self.enemy)
 300                 newdir_z += 16 * sys_frametime;
 301
 302         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 303         self.velocity_z -= 800 * sys_frametime;
 304         self.velocity_z += max(height_diff, autocvar_g_vehicle_racer_rocket_climbspeed) * sys_frametime ;
 305
 306         UpdateCSQCProjectile(self);
 307         return;
 308 }
 309
 310 void racer_fire_rocket(vector org, vector dir, entity trg)
 311 {SELFPARAM();
 312         entity rocket = vehicles_projectile(EFFECT_RACER_ROCKETLAUNCH.eent_eff_name, SND(ROCKET_FIRE),
 313                                                    org, dir * autocvar_g_vehicle_racer_rocket_speed,
 314                                                    autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 315                                                    DEATH_VH_WAKI_ROCKET, PROJECTILE_WAKIROCKET, 20, false, false, self.owner);
 316
 317         rocket.lip                        = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 318         rocket.wait                      = autocvar_g_vehicle_racer_rocket_turnrate;
 319         rocket.nextthink                = time;
 320         rocket.enemy                    = trg;
 321         rocket.cnt                        = time + 15;
 322
 323         if(trg)
 324                 rocket.think                    = racer_rocket_tracker;
 325         else
 326                 rocket.think                    = racer_rocket_groundhugger;
 327 }
 328
 329 void racer_fire_rocket_aim(string tagname, entity trg)
 330 {
 331         SELFPARAM();
 332         vector v = gettaginfo(self, gettagindex(self, tagname));
 333         racer_fire_rocket(v, v_forward, trg);
 334 }
 335
 336 float racer_frame()
 337 {SELFPARAM();
 338         entity player, racer;
 339         vector df;
 340         float ftmp;
 341
 342         if(intermission_running)
 343         {
 344                 self.vehicle.velocity = '0 0 0';
 345                 self.vehicle.avelocity = '0 0 0';
 346                 return 1;
 347         }
 348
 349         player  = self;
 350         racer   = self.vehicle;
 351         setself(racer);
 352
 353         vehicles_painframe();
 354
 355         if(pointcontents(racer.origin) != CONTENT_WATER)
 356                 racer.air_finished = time + autocvar_g_vehicle_racer_water_time;
 357
 358         if(racer.deadflag != DEAD_NO)
 359         {
 360                 setself(player);
 361                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 362                 return 1;
 363         }
 364
 365         racer_align4point(PHYS_INPUT_TIMELENGTH);
 366
 367         player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 368
 369         crosshair_trace(player);
 370
 371         racer.angles_x *= -1;
 372
 373         // Yaw
 374         ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 375         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 376         racer.angles_y = anglemods(racer.angles_y + ftmp);
 377
 378         // Roll
 379         racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 380
 381         // Pitch
 382         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 383         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 384         racer.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(racer.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 385
 386         makevectors(racer.angles);
 387         racer.angles_x *= -1;
 388
 389         //ftmp = racer.velocity_z;
 390         df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 391         //racer.velocity_z = ftmp;
 392
 393         int cont = pointcontents(racer.origin);
 394         if(vlen(player.movement) != 0)
 395         {
 396                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 397                 {
 398                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 399                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 400                 }
 401                 else
 402                 {
 403                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 404                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 405                 }
 406
 407 #ifdef SVQC
 408                 if(self.sound_nexttime < time || self.sounds != 1)
 409                 {
 410                         self.sounds = 1;
 411                         self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 412                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 413                 }
 414 #endif
 415         }
 416 #ifdef SVQC
 417         else
 418         {
 419                 if(self.sound_nexttime < time || self.sounds != 0)
 420                 {
 421                         self.sounds = 0;
 422                         self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 423                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 424                 }
 425         }
 426 #endif
 427
 428         // Afterburn
 429         if (PHYS_INPUT_BUTTON_JUMP(player) && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 430         {
 431 #ifdef SVQC
 432                 if(time - racer.wait > 0.2)
 433                         pointparticles(particleeffectnum(EFFECT_RACER_BOOSTER), self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 434 #endif
 435
 436                 racer.wait = time;
 437
 438                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 439                 {
 440                         racer.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 441                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 442                 }
 443                 else
 444                 {
 445                         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 446                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 447                 }
 448
 449 #ifdef SVQC
 450                 if(racer.invincible_finished < time)
 451                 {
 452                         traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 453                         if(trace_fraction != 1.0)
 454                                 pointparticles(particleeffectnum(EFFECT_SMOKE_SMALL), trace_endpos, '0 0 0', 1);
 455
 456                         racer.invincible_finished = time + 0.1 + (random() * 0.1);
 457                 }
 458
 459                 if(racer.strength_finished < time)
 460                 {
 461                         racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 462                         sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 463                 }
 464 #endif
 465         }
 466         else
 467         {
 468                 racer.strength_finished = 0;
 469                 sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 470         }
 471
 472         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 473                 racer.racer_watertime = time;
 474
 475         float dforce = autocvar_g_vehicle_racer_downforce;
 476         if(time - racer.racer_watertime <= 3)
 477                 dforce = autocvar_g_vehicle_racer_water_downforce;
 478
 479         df -= v_up * (vlen(racer.velocity) * dforce);
 480         player.movement = racer.velocity += df * PHYS_INPUT_TIMELENGTH;
 481
 482 #ifdef SVQC
 483         if(!forbidWeaponUse(player))
 484         if(player.BUTTON_ATCK)
 485         if(time > racer.attack_finished_single)
 486         if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 487         {
 488                 racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 489                 racer.wait = time;
 490
 491                 crosshair_trace(player);
 492                 string tagname = (racer.cnt)
 493                     ? (racer.cnt = 0, "tag_fire1")
 494                     : (racer.cnt = 1, "tag_fire2");
 495                 vector org = gettaginfo(self, gettagindex(self, tagname));
 496                 // Fix z-aim (for chase mode)
 497                 vector dir = normalize(trace_endpos - org);
 498                 v_forward.z = dir.z * 0.5;
 499                 w_shotorg = org;
 500                 w_shotdir = v_forward;
 501                 Weapon wep = WEP_RACER;
 502                 wep.wr_think(wep, true, false);
 503                 racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 504         }
 505
 506         if(autocvar_g_vehicle_racer_rocket_locktarget)
 507         {
 508                 vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 509                                                  (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 510                                                  autocvar_g_vehicle_racer_rocket_locked_time);
 511
 512                 if(self.lock_target)
 513                 {
 514                         if(racer.lock_strength == 1)
 515                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 516                         else if(self.lock_strength > 0.5)
 517                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 518                         else if(self.lock_strength < 0.5)
 519                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 520                 }
 521         }
 522
 523         if(!forbidWeaponUse(player))
 524         if(time > racer.delay)
 525         if(player.BUTTON_ATCK2)
 526         {
 527                 racer.misc_bulletcounter += 1;
 528                 racer.delay = time + 0.3;
 529
 530                 if(racer.misc_bulletcounter == 1)
 531                 {
 532                         racer_fire_rocket_aim("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 533                         player.vehicle_ammo2 = 50;
 534                 }
 535                 else if(racer.misc_bulletcounter == 2)
 536                 {
 537                         racer_fire_rocket_aim("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 538                         racer.lock_strength  = 0;
 539                         racer.lock_target       = world;
 540                         racer.misc_bulletcounter = 0;
 541                         racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 542                         racer.lip = time;
 543                         player.vehicle_ammo2 = 0;
 544                 }
 545         }
 546         else if(racer.misc_bulletcounter == 0)
 547                 player.vehicle_ammo2 = 100;
 548
 549         player.vehicle_reload2 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 550
 551         if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 552                 vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 553
 554         if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 555                 vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 556
 557         if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 558                 vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 559
 560
 561         VEHICLE_UPDATE_PLAYER(player, health, racer);
 562         VEHICLE_UPDATE_PLAYER(player, energy, racer);
 563
 564         if(racer.vehicle_flags & VHF_HASSHIELD)
 565                 VEHICLE_UPDATE_PLAYER(player, shield, racer);
 566
 567         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 568 #endif
 569
 570         setorigin(player,racer.origin + '0 0 32');
 571         player.velocity = racer.velocity;
 572
 573         setself(player);
 574         return 1;
 575 }
 576
 577 void racer_think()
 578 {SELFPARAM();
 579         self.nextthink = time;
 580
 581         float pushdeltatime = time - self.lastpushtime;
 582         if (pushdeltatime > 0.15) pushdeltatime = 0;
 583         self.lastpushtime = time;
 584         if(!pushdeltatime) return;
 585
 586         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, self);
 587
 588         vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 589         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 590
 591         float forced = autocvar_g_vehicle_racer_upforcedamper;
 592
 593         int cont = pointcontents(self.origin - '0 0 64');
 594         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 595         {
 596                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 597                 self.velocity_z += 200;
 598         }
 599
 600         self.velocity += df * pushdeltatime;
 601         if(self.velocity_z > 0)
 602                 self.velocity_z *= 1 - forced * pushdeltatime;
 603
 604         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 605         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 606
 607         CSQCMODEL_AUTOUPDATE(self);
 608 }
 609
 610 void racer_exit(float eject)
 611 {SELFPARAM();
 612         vector spot;
 613
 614         self.think        = racer_think;
 615         self.nextthink  = time;
 616         self.movetype   = MOVETYPE_BOUNCE;
 617         sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 618
 619         if(!self.owner)
 620                 return;
 621
 622         makevectors(self.angles);
 623         if(eject)
 624         {
 625                 spot = self.origin + v_forward * 100 + '0 0 64';
 626                 spot = vehicles_findgoodexit(spot);
 627                 setorigin(self.owner , spot);
 628                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 629                 self.owner.oldvelocity = self.owner.velocity;
 630         }
 631         else
 632         {
 633                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 634                 {
 635                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 636                         self.owner.velocity_z += 200;
 637                         spot = self.origin + v_forward * 32 + '0 0 32';
 638                         spot = vehicles_findgoodexit(spot);
 639                 }
 640                 else
 641                 {
 642                         self.owner.velocity = self.velocity * 0.5;
 643                         self.owner.velocity_z += 10;
 644                         spot = self.origin - v_forward * 200 + '0 0 32';
 645                         spot = vehicles_findgoodexit(spot);
 646                 }
 647                 self.owner.oldvelocity = self.owner.velocity;
 648                 setorigin(self.owner , spot);
 649         }
 650         antilag_clear(self.owner);
 651         self.owner = world;
 652 }
 653
 654 void racer_blowup()
 655 {SELFPARAM();
 656         self.deadflag   = DEAD_DEAD;
 657         self.vehicle_exit(VHEF_NORMAL);
 658
 659         RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 660                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 661                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 662                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 663                                         DEATH_VH_WAKI_DEATH, world);
 664
 665         self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 666         self.think        = vehicles_spawn;
 667         self.movetype   = MOVETYPE_NONE;
 668         self.effects    = EF_NODRAW;
 669
 670         self.colormod  = '0 0 0';
 671         self.avelocity = '0 0 0';
 672         self.velocity  = '0 0 0';
 673
 674         setorigin(self, self.pos1);
 675 }
 676
 677 void racer_blowup_think()
 678 {SELFPARAM();
 679         self.nextthink = time;
 680
 681         if(time >= self.delay)
 682                 racer_blowup();
 683
 684         CSQCMODEL_AUTOUPDATE(self);
 685 }
 686
 687 void racer_deadtouch()
 688 {SELFPARAM();
 689         self.avelocity_x *= 0.7;
 690         self.cnt -= 1;
 691         if(self.cnt <= 0)
 692                 racer_blowup();
 693 }
 694
 695 void spawnfunc_vehicle_racer()
 696 {SELFPARAM();
 697         if(!autocvar_g_vehicle_racer) { remove(self); return; }
 698         if(!vehicle_initialize(VEH_RACER, false)) { remove(self); return; }
 699 }
 700
 701 #endif // SVQC
 702
 703 #ifdef CSQC
 704 #if 0
 705 void racer_draw()
 706 {SELFPARAM();
 707         float pushdeltatime = time - self.lastpushtime;
 708         if (pushdeltatime > 0.15) pushdeltatime = 0;
 709         self.lastpushtime = time;
 710         if(!pushdeltatime) return;
 711
 712         tracebox(self.move_origin, self.mins, self.maxs, self.move_origin - ('0 0 1' * getstatf(STAT_VEH_RACER_SPRINGLENGTH)), MOVE_NOMONSTERS, self);
 713
 714         vector df = self.move_velocity * -getstatf(STAT_VEH_RACER_FRICTION);
 715         df_z += (1 - trace_fraction) * getstatf(STAT_VEH_RACER_HOVERPOWER) + sin(time * 2) * (getstatf(STAT_VEH_RACER_SPRINGLENGTH) * 2);
 716
 717         float forced = getstatf(STAT_VEH_RACER_UPFORCEDAMPER);
 718
 719         int cont = pointcontents(self.move_origin - '0 0 64');
 720         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 721         {
 722                 forced = getstatf(STAT_VEH_RACER_WATER_UPFORCEDAMPER);
 723                 self.move_velocity_z += 200;
 724         }
 725
 726         self.move_velocity += df * pushdeltatime;
 727         if(self.move_velocity_z > 0)
 728                 self.move_velocity_z *= 1 - forced * pushdeltatime;
 729
 730         self.move_angles_x *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 731         self.move_angles_z *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 732
 733         Movetype_Physics_MatchServer(false);
 734 }
 735 #endif
 736 #endif
 737
 738                 METHOD(Racer, vr_impact, bool(Racer thisveh))
 739                 {
 740                 #ifdef SVQC
 741                         if(autocvar_g_vehicle_racer_bouncepain)
 742                                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 743                 #endif
 744                         return true;
 745                 }
 746
 747                 METHOD(Racer, vr_enter, bool(Racer thisveh))
 748                 {
 749                 #ifdef SVQC
 750                         self.movetype = MOVETYPE_BOUNCE;
 751                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 752                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 753
 754                         if(self.owner.flagcarried)
 755                            setorigin(self.owner.flagcarried, '-190 0 96');
 756                 #elif defined(CSQC)
 757
 758                         self.move_movetype = MOVETYPE_BOUNCE;
 759                 #endif
 760
 761                         return true;
 762                 }
 763
 764                 METHOD(Racer, vr_spawn, bool(Racer thisveh))
 765                 {
 766                 #ifdef SVQC
 767                         if(self.scale != 0.5)
 768                         {
 769                                 if(autocvar_g_vehicle_racer_hovertype != 0)
 770                                         racer_force_from_tag = vehicles_force_fromtag_maglev;
 771                                 else
 772                                         racer_force_from_tag = vehicles_force_fromtag_hover;
 773
 774                                 // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 775                                 self.scale = 0.5;
 776                                 setattachment(self.vehicle_hudmodel, self, "");
 777                                 setattachment(self.vehicle_viewport, self, "tag_viewport");
 778
 779                                 self.mass                          = 900;
 780                         }
 781
 782                         self.think                = racer_think;
 783                         self.nextthink    = time;
 784                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 785                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 786
 787                         self.movetype     = MOVETYPE_TOSS;
 788                         self.solid                = SOLID_SLIDEBOX;
 789                         self.delay                = time;
 790                         self.scale                = 0.5;
 791
 792                         self.PlayerPhysplug = racer_frame;
 793
 794                         self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 795                         self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 796                         self.damageforcescale = 0.5;
 797                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 798                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 799                 #endif
 800                         return true;
 801                 }
 802
 803                 METHOD(Racer, vr_death, bool(Racer thisveh))
 804                 {
 805                 #ifdef SVQC
 806                         self.SendEntity         = func_null; // stop networking this racer (for now)
 807                         self.health                     = 0;
 808                         self.event_damage       = func_null;
 809                         self.solid                      = SOLID_CORPSE;
 810                         self.takedamage         = DAMAGE_NO;
 811                         self.deadflag           = DEAD_DYING;
 812                         self.movetype           = MOVETYPE_BOUNCE;
 813                         self.wait                       = time;
 814                         self.delay                      = 2 + time + random() * 3;
 815                         self.cnt                        = 1 + random() * 2;
 816                         self.touch                      = racer_deadtouch;
 817
 818                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, self.origin, '0 0 0', 1);
 819
 820                         if(random() < 0.5)
 821                                 self.avelocity_z = 32;
 822                         else
 823                                 self.avelocity_z = -32;
 824
 825                         self.avelocity_x = -vlen(self.velocity) * 0.2;
 826                         self.velocity += '0 0 700';
 827                         self.colormod = '-0.5 -0.5 -0.5';
 828
 829                         self.think = racer_blowup_think;
 830                         self.nextthink = time;
 831                 #endif
 832                         return true;
 833                 }
 834
 835 #ifdef CSQC
 836                 METHOD(Racer, vr_hud, bool(Racer thisveh))
 837                 {
 838                         Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 839                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 840                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color,
 841                                                          vCROSS_GUIDE);
 842                         return true;
 843                 }
 844 #endif
 845                 METHOD(Racer, vr_setup, bool(Racer thisveh))
 846                 {
 847                 #ifdef SVQC
 848                         self.vehicle_exit = racer_exit;
 849                 #endif
 850
 851                 #ifdef SVQC
 852                         // we have no need to network energy
 853                         if(autocvar_g_vehicle_racer_energy)
 854                         if(autocvar_g_vehicle_racer_energy_regen)
 855                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 856
 857                         if(autocvar_g_vehicle_racer_shield)
 858                                 self.vehicle_flags |= VHF_HASSHIELD;
 859
 860                         if(autocvar_g_vehicle_racer_shield_regen)
 861                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 862
 863                         if(autocvar_g_vehicle_racer_health_regen)
 864                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 865
 866                         self.respawntime = autocvar_g_vehicle_racer_respawntime;
 867                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 868                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 869                         self.max_health = self.vehicle_health;
 870                 #endif
 871
 872                 #ifdef CSQC
 873                         AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 874                 #endif
 875                         return true;
 876                 }
 877
 878                 METHOD(Racer, vr_precache, bool(Racer thisveh))
 879                 {
 880                         return true;
 881                 }
 882
 883 #endif // REGISTER_VEHICLE