qcsrc/common/vehicles/vehicle/racer.qc

   1 #include "racer.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6 #include <common/triggers/trigger/impulse.qh>
   7
   8 bool autocvar_g_vehicle_racer = true;
   9
  10 float autocvar_g_vehicle_racer_thinkrate = 0.05; // TODO: any higher causes it to sink in liquids
  11
  12 float autocvar_g_vehicle_racer_speed_afterburn = 3000;
  13 // energy consumed per second
  14 float autocvar_g_vehicle_racer_afterburn_cost = 100;
  15
  16 float autocvar_g_vehicle_racer_waterburn_cost = 5;
  17 float autocvar_g_vehicle_racer_waterburn_speed = 750;
  18
  19 float autocvar_g_vehicle_racer_water_speed_forward = 600;
  20 float autocvar_g_vehicle_racer_water_speed_strafe = 600;
  21
  22 float autocvar_g_vehicle_racer_pitchlimit = 30;
  23
  24 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  25 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  26
  27 float autocvar_g_vehicle_racer_anglestabilizer = 1.75;
  28 float autocvar_g_vehicle_racer_downforce = 0.01;
  29
  30 float autocvar_g_vehicle_racer_speed_forward = 650;
  31 float autocvar_g_vehicle_racer_speed_strafe = 650;
  32 float autocvar_g_vehicle_racer_springlength = 70;
  33 float autocvar_g_vehicle_racer_upforcedamper = 10;
  34 float autocvar_g_vehicle_racer_friction = 0.45;
  35
  36 float autocvar_g_vehicle_racer_water_time = 5;
  37
  38 float autocvar_g_vehicle_racer_collision_multiplier = 0.05;
  39
  40 // 0 = hover, != 0 = maglev
  41 int autocvar_g_vehicle_racer_hovertype = 0;
  42 // NOTE!! x 4 (4 engines)
  43 float autocvar_g_vehicle_racer_hoverpower = 8000;
  44
  45 float autocvar_g_vehicle_racer_turnroll = 30;
  46 float autocvar_g_vehicle_racer_turnspeed = 220;
  47 float autocvar_g_vehicle_racer_pitchspeed = 125;
  48
  49 float autocvar_g_vehicle_racer_energy = 100;
  50 float autocvar_g_vehicle_racer_energy_regen = 50;
  51 float autocvar_g_vehicle_racer_energy_regen_pause = 1;
  52
  53 float autocvar_g_vehicle_racer_health = 200;
  54 float autocvar_g_vehicle_racer_health_regen = 0;
  55 float autocvar_g_vehicle_racer_health_regen_pause = 0;
  56
  57 float autocvar_g_vehicle_racer_shield = 100;
  58 float autocvar_g_vehicle_racer_shield_regen = 30;
  59 float autocvar_g_vehicle_racer_shield_regen_pause = 1;
  60
  61 bool autocvar_g_vehicle_racer_rocket_locktarget = true;
  62 float autocvar_g_vehicle_racer_rocket_locking_time = 0.9;
  63 float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5;
  64 float autocvar_g_vehicle_racer_rocket_locked_time = 4;
  65
  66 float autocvar_g_vehicle_racer_respawntime = 35;
  67
  68 float autocvar_g_vehicle_racer_blowup_radius = 250;
  69 float autocvar_g_vehicle_racer_blowup_coredamage = 250;
  70 float autocvar_g_vehicle_racer_blowup_edgedamage = 15;
  71 float autocvar_g_vehicle_racer_blowup_forceintensity = 250;
  72
  73 // Factor of old velocity to keep after collision
  74 float autocvar_g_vehicle_racer_bouncefactor = 0.25;
  75 // if != 0, New veloctiy after bounce = 0 if new velocity < this
  76 float autocvar_g_vehicle_racer_bouncestop = 0;
  77 // "minspeed_for_pain speedchange_to_pain_factor max_damage"
  78 vector autocvar_g_vehicle_racer_bouncepain = '60 0.75 300';
  79
  80 .float racer_watertime;
  81
  82 var vector racer_force_from_tag(entity this, string tag_name, float spring_length, float max_power);
  83
  84 void racer_align4point(entity this, float _delta)
  85 {
  86         vector push_vector;
  87         float fl_push, fr_push, bl_push, br_push;
  88
  89         push_vector  = racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90         fr_push   = force_fromtag_normpower;
  91         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93         push_vector += racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  94         fl_push   = force_fromtag_normpower;
  95         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  96
  97         push_vector += racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  98         br_push   = force_fromtag_normpower;
  99         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 100
 101         push_vector += racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 102         bl_push   = force_fromtag_normpower;
 103         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 104
 105         this.velocity += push_vector * _delta;
 106
 107         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 108
 109         int cont = pointcontents(this.origin - '0 0 64');
 110         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 111         {
 112                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 113
 114                 if(PHYS_INPUT_BUTTON_CROUCH(this.owner) && time < this.air_finished)
 115                         this.velocity_z += 30;
 116                 else
 117                         this.velocity_z += 200;
 118         }
 119
 120
 121         // Anti ocilation
 122         if(this.velocity_z > 0)
 123                 this.velocity_z *= 1 - uforce * _delta;
 124
 125         push_vector_x =  (fl_push - bl_push);
 126         push_vector_x += (fr_push - br_push);
 127         push_vector_x *= 360;
 128
 129         push_vector_z = (fr_push - fl_push);
 130         push_vector_z += (br_push - bl_push);
 131         push_vector_z *= 360;
 132
 133         // Apply angle diffrance
 134         this.angles_z += push_vector_z * _delta;
 135         this.angles_x += push_vector_x * _delta;
 136
 137         // Apply stabilizer
 138         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 139         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 140 }
 141
 142 void racer_fire_rocket_aim(entity player, string tagname, entity trg)
 143 {
 144         entity racer = player.vehicle;
 145         vector v = gettaginfo(racer, gettagindex(racer, tagname));
 146         racer_fire_rocket(player, v, v_forward, trg);
 147 }
 148
 149 bool racer_frame(entity this, float dt)
 150 {
 151         entity vehic = this.vehicle;
 152         return = true;
 153
 154         if(intermission_running)
 155         {
 156                 vehic.velocity = '0 0 0';
 157                 vehic.avelocity = '0 0 0';
 158                 return;
 159         }
 160
 161         vehicles_frame(vehic, this);
 162
 163         traceline(vehic.origin, vehic.origin + '0 0 1', MOVE_NOMONSTERS, this);
 164         int cont = trace_dpstartcontents;
 165         if(!(cont & DPCONTENTS_WATER))
 166                 vehic.air_finished = time + autocvar_g_vehicle_racer_water_time;
 167
 168         if(IS_DEAD(vehic))
 169         {
 170                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 171                 return;
 172         }
 173
 174         racer_align4point(vehic, dt);
 175
 176         PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 177
 178         vehic.angles_x *= -1;
 179
 180         // Yaw
 181         float ftmp = autocvar_g_vehicle_racer_turnspeed * dt;
 182         ftmp = bound(-ftmp, shortangle_f(this.v_angle_y - vehic.angles_y, vehic.angles_y), ftmp);
 183         vehic.angles_y = anglemods(vehic.angles_y + ftmp);
 184
 185         // Roll
 186         vehic.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * dt;
 187
 188         // Pitch
 189         ftmp = autocvar_g_vehicle_racer_pitchspeed  * dt;
 190         ftmp = bound(-ftmp, shortangle_f(this.v_angle_x - vehic.angles_x, vehic.angles_x), ftmp);
 191         vehic.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 192
 193         makevectors(vehic.angles);
 194         vehic.angles_x *= -1;
 195
 196         //ftmp = vehic.velocity_z;
 197         vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
 198         //vehic.velocity_z = ftmp;
 199
 200         if(this.movement)
 201         {
 202                 if(cont & DPCONTENTS_LIQUIDSMASK)
 203                 {
 204                         if(this.movement_x) { df += v_forward * ((this.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 205                         if(this.movement_y) { df += v_right * ((this.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 206                 }
 207                 else
 208                 {
 209                         if(this.movement_x) { df += v_forward * ((this.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 210                         if(this.movement_y) { df += v_right * ((this.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 211                 }
 212
 213 #ifdef SVQC
 214                 if(vehic.sound_nexttime < time || vehic.sounds != 1)
 215                 {
 216                         vehic.sounds = 1;
 217                         vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 218                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 219                 }
 220 #endif
 221         }
 222 #ifdef SVQC
 223         else
 224         {
 225                 if(vehic.sound_nexttime < time || vehic.sounds != 0)
 226                 {
 227                         vehic.sounds = 0;
 228                         vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 229                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 230                 }
 231         }
 232 #endif
 233
 234         // Afterburn
 235         if (PHYS_INPUT_BUTTON_JUMP(this) && vehic.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * dt))
 236         {
 237 #ifdef SVQC
 238                 if(time - vehic.wait > 0.2)
 239                         pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
 240 #endif
 241
 242                 vehic.wait = time;
 243
 244                 if(cont & DPCONTENTS_LIQUIDSMASK)
 245                 {
 246                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * dt;
 247                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 248                 }
 249                 else
 250                 {
 251                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * dt;
 252                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 253                 }
 254
 255 #ifdef SVQC
 256                 if(vehic.invincible_finished < time)
 257                 {
 258                         traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
 259                         if(trace_fraction != 1.0)
 260                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 261
 262                         vehic.invincible_finished = time + 0.1 + (random() * 0.1);
 263                 }
 264
 265                 if(vehic.strength_finished < time)
 266                 {
 267                         vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 268                         sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 269                 }
 270 #endif
 271         }
 272         else
 273         {
 274                 vehic.strength_finished = 0;
 275                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 276         }
 277
 278         if(cont & DPCONTENTS_LIQUIDSMASK)
 279                 vehic.racer_watertime = time;
 280
 281         float dforce = autocvar_g_vehicle_racer_downforce;
 282         if(time - vehic.racer_watertime <= 3)
 283                 dforce = autocvar_g_vehicle_racer_water_downforce;
 284
 285         df -= v_up * (vlen(vehic.velocity) * dforce);
 286         this.movement = vehic.velocity += df * dt;
 287
 288 #ifdef SVQC
 289
 290         Weapon wep1 = WEP_RACER;
 291         if (!forbidWeaponUse(this))
 292         if (PHYS_INPUT_BUTTON_ATCK(this))
 293         if (wep1.wr_checkammo1(wep1, vehic))
 294         {
 295                 string tagname = (vehic.cnt)
 296                     ? (vehic.cnt = 0, "tag_fire1")
 297                     : (vehic.cnt = 1, "tag_fire2");
 298                 vector org = gettaginfo(vehic, gettagindex(vehic, tagname));
 299                 w_shotorg = org;
 300                 w_shotdir = v_forward;
 301                 // Fix z-aim (for chase mode)
 302                 crosshair_trace(this);
 303                 w_shotdir.z = normalize(trace_endpos - org).z * 0.5;
 304                 .entity weaponentity = weaponentities[0];
 305                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 306         }
 307
 308         if(autocvar_g_vehicle_racer_rocket_locktarget)
 309         {
 310                 if(time >= vehic.vehicle_last_trace)
 311                 {
 312                         crosshair_trace(this);
 313
 314                         vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * dt,
 315                                                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * dt,
 316                                                          autocvar_g_vehicle_racer_rocket_locked_time);
 317
 318                         vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
 319                 }
 320
 321                 if(vehic.lock_target)
 322                 {
 323                         if(vehic.lock_strength == 1)
 324                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 0);
 325                         else if(vehic.lock_strength > 0.5)
 326                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 0);
 327                         else if(vehic.lock_strength < 0.5)
 328                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 0);
 329                 }
 330         }
 331
 332         if(!forbidWeaponUse(this))
 333         if(time > vehic.delay)
 334         if(PHYS_INPUT_BUTTON_ATCK2(this))
 335         {
 336                 vehic.misc_bulletcounter += 1;
 337                 vehic.delay = time + 0.3;
 338
 339                 if(vehic.misc_bulletcounter == 1)
 340                 {
 341                         racer_fire_rocket_aim(this, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 342                         this.vehicle_ammo2 = 50;
 343                 }
 344                 else if(vehic.misc_bulletcounter == 2)
 345                 {
 346                         racer_fire_rocket_aim(this, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 347                         vehic.lock_strength  = 0;
 348                         vehic.lock_target       = NULL;
 349                         vehic.misc_bulletcounter = 0;
 350                         vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 351                         vehic.lip = time;
 352                         this.vehicle_ammo2 = 0;
 353                 }
 354         }
 355         else if(vehic.misc_bulletcounter == 0)
 356                 this.vehicle_ammo2 = 100;
 357
 358         this.vehicle_reload2 = bound(0, 100 * ((time - vehic.lip) / (vehic.delay - vehic.lip)), 100);
 359
 360         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 361                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, dt, true);
 362
 363         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 364                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, dt, false);
 365
 366         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 367                 vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, dt, false);
 368
 369         VEHICLE_UPDATE_PLAYER(this, vehic, health, racer);
 370         VEHICLE_UPDATE_PLAYER(this, vehic, energy, racer);
 371
 372         if(vehic.vehicle_flags & VHF_HASSHIELD)
 373                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, racer);
 374
 375         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 376 #endif
 377
 378         setorigin(this, vehic.origin + '0 0 32');
 379         this.velocity = vehic.velocity;
 380 }
 381
 382 void racer_think(entity this)
 383 {
 384         this.nextthink = time + autocvar_g_vehicle_racer_thinkrate;
 385
 386         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 387
 388         vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
 389         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 390
 391         float forced = autocvar_g_vehicle_racer_upforcedamper;
 392
 393         //int cont = pointcontents(this.origin - '0 0 64');
 394         traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
 395         //if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 396         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 397         {
 398                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 399                 this.velocity_z += 200;
 400         }
 401
 402         this.velocity += df * autocvar_g_vehicle_racer_thinkrate;
 403         if(this.velocity_z > 0)
 404                 this.velocity_z *= 1 - forced * autocvar_g_vehicle_racer_thinkrate;
 405
 406         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * autocvar_g_vehicle_racer_thinkrate);
 407         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * autocvar_g_vehicle_racer_thinkrate);
 408
 409         CSQCMODEL_AUTOUPDATE(this);
 410 }
 411
 412 void racer_exit(entity this, int eject)
 413 {
 414         vector spot;
 415
 416         setthink(this, racer_think);
 417         this.nextthink  = time;
 418         set_movetype(this, MOVETYPE_BOUNCE);
 419         sound (this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 420
 421         if(!this.owner)
 422                 return;
 423
 424         makevectors(this.angles);
 425         if(eject)
 426         {
 427                 spot = this.origin + v_forward * 100 + '0 0 64';
 428                 spot = vehicles_findgoodexit(this, spot);
 429                 setorigin(this.owner, spot);
 430                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 431                 this.owner.oldvelocity = this.owner.velocity;
 432         }
 433         else
 434         {
 435                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 436                 {
 437                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 438                         this.owner.velocity_z += 200;
 439                         spot = this.origin + v_forward * 32 + '0 0 32';
 440                         spot = vehicles_findgoodexit(this, spot);
 441                 }
 442                 else
 443                 {
 444                         this.owner.velocity = this.velocity * 0.5;
 445                         this.owner.velocity_z += 10;
 446                         spot = this.origin - v_forward * 200 + '0 0 32';
 447                         spot = vehicles_findgoodexit(this, spot);
 448                 }
 449                 this.owner.oldvelocity = this.owner.velocity;
 450                 setorigin(this.owner , spot);
 451         }
 452         antilag_clear(this.owner, CS(this.owner));
 453         this.owner = NULL;
 454 }
 455
 456 void racer_blowup(entity this)
 457 {
 458         this.deadflag = DEAD_DEAD;
 459         this.vehicle_exit(this, VHEF_NORMAL);
 460
 461         RadiusDamage (this, this.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 462                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 463                                         autocvar_g_vehicle_racer_blowup_radius, NULL, NULL,
 464                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 465                                         DEATH_VH_WAKI_DEATH.m_id, NULL);
 466
 467         this.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 468         setthink(this, vehicles_spawn);
 469         set_movetype(this, MOVETYPE_NONE);
 470         this.effects    = EF_NODRAW;
 471         this.solid = SOLID_NOT;
 472
 473         this.colormod  = '0 0 0';
 474         this.avelocity = '0 0 0';
 475         this.velocity  = '0 0 0';
 476
 477         setorigin(this, this.pos1);
 478 }
 479
 480 void racer_blowup_think(entity this)
 481 {
 482         this.nextthink = time;
 483
 484         if(time >= this.delay)
 485                 racer_blowup(this);
 486
 487         CSQCMODEL_AUTOUPDATE(this);
 488 }
 489
 490 void racer_deadtouch(entity this, entity toucher)
 491 {
 492         this.avelocity_x *= 0.7;
 493         this.cnt -= 1;
 494         if(this.cnt <= 0)
 495                 racer_blowup(this);
 496 }
 497
 498 spawnfunc(vehicle_racer)
 499 {
 500         if(!autocvar_g_vehicle_racer) { delete(this); return; }
 501         if(!vehicle_initialize(this, VEH_RACER, false)) { delete(this); return; }
 502 }
 503
 504 #endif // SVQC
 505
 506 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 507 {
 508 #ifdef SVQC
 509     if(autocvar_g_vehicle_racer_bouncepain)
 510         vehicles_impact(instance, autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 511 #endif
 512 }
 513
 514 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 515 {
 516 #ifdef SVQC
 517     set_movetype(instance, MOVETYPE_BOUNCE);
 518     instance.owner.vehicle_health = (instance.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 519     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 520
 521     if(instance.owner.flagcarried)
 522        setorigin(instance.owner.flagcarried, '-190 0 96');
 523 #elif defined(CSQC)
 524     set_movetype(instance, MOVETYPE_BOUNCE);
 525 #endif
 526 }
 527
 528 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 529 {
 530 #ifdef SVQC
 531     if(instance.scale != 0.5)
 532     {
 533         if(autocvar_g_vehicle_racer_hovertype != 0)
 534             racer_force_from_tag = vehicles_force_fromtag_maglev;
 535         else
 536             racer_force_from_tag = vehicles_force_fromtag_hover;
 537
 538         // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 539         instance.scale = 0.5;
 540         setattachment(instance.vehicle_hudmodel, instance, "");
 541         setattachment(instance.vehicle_viewport, instance, "tag_viewport");
 542
 543         instance.mass                      = 900;
 544     }
 545
 546     setthink(instance, racer_think);
 547     instance.nextthink    = time;
 548     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 549     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 550
 551     set_movetype(instance, MOVETYPE_TOSS);
 552     instance.solid                = SOLID_SLIDEBOX;
 553     instance.delay                = time;
 554     instance.scale                = 0.5;
 555
 556     instance.PlayerPhysplug = racer_frame;
 557
 558     instance.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 559     instance.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 560     instance.damageforcescale = 0.5;
 561     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 562     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 563 #endif
 564 }
 565
 566 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 567 {
 568 #ifdef SVQC
 569     setSendEntity(instance, func_null); // stop networking this racer (for now)
 570     instance.health                     = 0;
 571     instance.event_damage       = func_null;
 572     instance.solid                      = SOLID_CORPSE;
 573     instance.takedamage         = DAMAGE_NO;
 574     instance.deadflag           = DEAD_DYING;
 575     set_movetype(instance, MOVETYPE_BOUNCE);
 576     instance.wait                       = time;
 577     instance.delay                      = 2 + time + random() * 3;
 578     instance.cnt                        = 1 + random() * 2;
 579     settouch(instance, racer_deadtouch);
 580
 581     Send_Effect(EFFECT_EXPLOSION_MEDIUM, instance.origin, '0 0 0', 1);
 582
 583     if(random() < 0.5)
 584         instance.avelocity_z = 32;
 585     else
 586         instance.avelocity_z = -32;
 587
 588     instance.avelocity_x = -vlen(instance.velocity) * 0.2;
 589     instance.velocity += '0 0 700';
 590     instance.colormod = '-0.5 -0.5 -0.5';
 591
 592     setthink(instance, racer_blowup_think);
 593     instance.nextthink = time;
 594 #endif
 595 }
 596
 597 #ifdef CSQC
 598 METHOD(Racer, vr_hud, void(Racer thisveh))
 599 {
 600     Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 601                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 602                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 603 }
 604 METHOD(Racer, vr_crosshair, void(Racer thisveh, entity player))
 605 {
 606     Vehicles_drawCrosshair(vCROSS_GUIDE);
 607 }
 608 #endif
 609 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 610 {
 611 #ifdef SVQC
 612     instance.vehicle_exit = racer_exit;
 613
 614     // we have no need to network energy
 615     if(autocvar_g_vehicle_racer_energy)
 616     if(autocvar_g_vehicle_racer_energy_regen)
 617         instance.vehicle_flags |= VHF_ENERGYREGEN;
 618
 619     if(autocvar_g_vehicle_racer_shield)
 620         instance.vehicle_flags |= VHF_HASSHIELD;
 621
 622     if(autocvar_g_vehicle_racer_shield_regen)
 623         instance.vehicle_flags |= VHF_SHIELDREGEN;
 624
 625     if(autocvar_g_vehicle_racer_health_regen)
 626         instance.vehicle_flags |= VHF_HEALTHREGEN;
 627
 628     instance.respawntime = autocvar_g_vehicle_racer_respawntime;
 629     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 630     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 631     instance.max_health = instance.vehicle_health;
 632 #endif
 633
 634 #ifdef CSQC
 635     AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 636 #endif
 637 }
 638
 639 #endif