qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qh"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* view offset*/ ATTRIB(Raptor, view_ofs, vector, '0 0 160');
  12 /* view dist  */ ATTRIB(Raptor, height, float, 200);
  13 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  14 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  15 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  17 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  18 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  19 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  20 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  21 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  22 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  23 ENDCLASS(Raptor)
  24 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 #ifdef SVQC
  31
  32 bool autocvar_g_vehicle_raptor = true;
  33
  34 float autocvar_g_vehicle_raptor_respawntime = 40;
  35 float autocvar_g_vehicle_raptor_takeofftime = 1.5;
  36
  37 // 0: go where player aims, +forward etc relative to aim angles
  38 // 1: ignore aim for up/down movement. +forward always moved forward, +jump always moves up
  39 int autocvar_g_vehicle_raptor_movestyle = 1;
  40 float autocvar_g_vehicle_raptor_turnspeed = 200;
  41 float autocvar_g_vehicle_raptor_pitchspeed = 50;
  42 float autocvar_g_vehicle_raptor_pitchlimit = 45;
  43
  44 float autocvar_g_vehicle_raptor_speed_forward = 1700;
  45 float autocvar_g_vehicle_raptor_speed_strafe = 900;
  46 float autocvar_g_vehicle_raptor_speed_up = 1700;
  47 float autocvar_g_vehicle_raptor_speed_down = 1700;
  48 float autocvar_g_vehicle_raptor_friction = 2;
  49
  50 float autocvar_g_vehicle_raptor_cannon_turnspeed = 120;
  51 float autocvar_g_vehicle_raptor_cannon_turnlimit = 20;
  52 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up = 12;
  53 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down = 32;
  54
  55 float autocvar_g_vehicle_raptor_cannon_locktarget = 0;
  56 float autocvar_g_vehicle_raptor_cannon_locking_time = 0.2;
  57 float autocvar_g_vehicle_raptor_cannon_locking_releasetime = 0.45;
  58 float autocvar_g_vehicle_raptor_cannon_locked_time = 1;
  59 float autocvar_g_vehicle_raptor_cannon_predicttarget = 1;
  60
  61 float autocvar_g_vehicle_raptor_energy = 100;
  62 float autocvar_g_vehicle_raptor_energy_regen = 25;
  63 float autocvar_g_vehicle_raptor_energy_regen_pause = 0.25;
  64
  65 float autocvar_g_vehicle_raptor_health = 150;
  66 float autocvar_g_vehicle_raptor_health_regen = 0;
  67 float autocvar_g_vehicle_raptor_health_regen_pause = 0;
  68
  69 float autocvar_g_vehicle_raptor_shield = 75;
  70 float autocvar_g_vehicle_raptor_shield_regen = 25;
  71 float autocvar_g_vehicle_raptor_shield_regen_pause = 1.5;
  72
  73 float autocvar_g_vehicle_raptor_bouncefactor = 0.2;
  74 float autocvar_g_vehicle_raptor_bouncestop = 0;
  75 vector autocvar_g_vehicle_raptor_bouncepain = '1 4 1000';
  76
  77 .entity bomb1;
  78 .entity bomb2;
  79
  80 float raptor_altitude(float amax)
  81 {SELFPARAM();
  82         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  83         return vlen(self.origin - trace_endpos);
  84 }
  85
  86 void raptor_land(entity this)
  87 {
  88         float hgt;
  89
  90         hgt = raptor_altitude(512);
  91         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  92         self.angles_x *= 0.95;
  93         self.angles_z *= 0.95;
  94
  95         if(hgt < 128)
  96         if(hgt > 0)
  97                 self.frame = (hgt / 128) * 25;
  98
  99         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 100         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 101
 102         if(hgt < 16)
 103         {
 104                 self.movetype = MOVETYPE_TOSS;
 105                 setthink(self, vehicles_think);
 106                 self.frame      = 0;
 107         }
 108
 109         self.nextthink  = time;
 110
 111         CSQCMODEL_AUTOUPDATE(self);
 112 }
 113
 114 void raptor_exit(float eject)
 115 {SELFPARAM();
 116         vector spot;
 117         self.tur_head.exteriormodeltoclient = world;
 118
 119         if(!IS_DEAD(self))
 120         {
 121                 setthink(self, raptor_land);
 122                 self.nextthink  = time;
 123         }
 124
 125         if(!self.owner)
 126                 return;
 127
 128         makevectors(self.angles);
 129         if(eject)
 130         {
 131                 spot = self.origin + v_forward * 100 + '0 0 64';
 132                 spot = vehicles_findgoodexit(spot);
 133                 setorigin(self.owner , spot);
 134                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 135                 self.owner.oldvelocity = self.owner.velocity;
 136         }
 137         else
 138         {
 139                 if(vdist(self.velocity, >, 2 * autocvar_sv_maxairspeed))
 140                 {
 141                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 142                         self.owner.velocity_z += 200;
 143                         spot = self.origin + v_forward * 32 + '0 0 64';
 144                         spot = vehicles_findgoodexit(spot);
 145                 }
 146                 else
 147                 {
 148                         self.owner.velocity = self.velocity * 0.5;
 149                         self.owner.velocity_z += 10;
 150                         spot = self.origin - v_forward * 200 + '0 0 64';
 151                         spot = vehicles_findgoodexit(spot);
 152                 }
 153                 self.owner.oldvelocity = self.owner.velocity;
 154                 setorigin(self.owner , spot);
 155         }
 156
 157         antilag_clear(self.owner, CS(self.owner));
 158         self.owner = world;
 159 }
 160
 161 bool raptor_frame(entity this)
 162 {
 163         entity vehic = this.vehicle;
 164         return = true;
 165
 166         if(intermission_running)
 167         {
 168                 vehic.velocity = '0 0 0';
 169                 vehic.avelocity = '0 0 0';
 170                 return;
 171         }
 172
 173         vehicles_frame(vehic, this);
 174
 175         float ftmp = 0;
 176         /*
 177         ftmp = vlen(vehic.velocity);
 178         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 179                 ftmp = 1;
 180         else
 181                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 182         */
 183
 184         if(vehic.sound_nexttime < time)
 185         {
 186                 vehic.sound_nexttime = time + 7.955812;
 187                 //sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 188                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 189                 vehic.wait = ftmp;
 190         }
 191         /*
 192         else if(fabs(ftmp - vehic.wait) > 0.2)
 193         {
 194                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 195                 sound (vehic, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 196                 vehic.wait = ftmp;
 197         }
 198         */
 199
 200         if(IS_DEAD(vehic))
 201         {
 202                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 203                 return;
 204         }
 205         crosshair_trace(this);
 206
 207         //if(time - vehic.lastteleporttime < 1)
 208         //{
 209                 if(vehic.angles_z > 50 || vehic.angles_z < -50)
 210                 {
 211                         if(PHYS_INPUT_BUTTON_JUMP(this))
 212                         {
 213                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 214                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 215                         }
 216                 }
 217         //}
 218
 219         vector vang;
 220         vang = vehic.angles;
 221         vector df = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 222         vang_x *= -1;
 223         df_x *= -1;
 224         if(df_x > 180)  df_x -= 360;
 225         if(df_x < -180) df_x += 360;
 226         if(df_y > 180)  df_y -= 360;
 227         if(df_y < -180) df_y += 360;
 228
 229         ftmp = shortangle_f(this.v_angle_y - vang_y, vang_y);
 230         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 231         vehic.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 232
 233         // Pitch
 234         ftmp = 0;
 235         if(this.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 236         else if(this.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 237
 238         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 239         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 240         vehic.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 241
 242         vehic.angles_x = anglemods(vehic.angles_x);
 243         vehic.angles_y = anglemods(vehic.angles_y);
 244         vehic.angles_z = anglemods(vehic.angles_z);
 245
 246         if(autocvar_g_vehicle_raptor_movestyle == 1)
 247                 makevectors('0 1 0' * vehic.angles_y);
 248         else
 249                 makevectors(this.v_angle);
 250
 251         df = vehic.velocity * -autocvar_g_vehicle_raptor_friction;
 252
 253         if(this.movement_x != 0)
 254         {
 255                 if(this.movement_x > 0)
 256                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 257                 else if(this.movement_x < 0)
 258                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 259         }
 260
 261         if(this.movement_y != 0)
 262         {
 263                 if(this.movement_y < 0)
 264                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 265                 else if(this.movement_y > 0)
 266                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 267
 268                 vehic.angles_z = bound(-30,vehic.angles_z + (this.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 269         }
 270         else
 271         {
 272                 vehic.angles_z *= 0.95;
 273                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 274                         vehic.angles_z = 0;
 275         }
 276
 277         if(PHYS_INPUT_BUTTON_CROUCH(this))
 278                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 279         else if (PHYS_INPUT_BUTTON_JUMP(this))
 280                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 281
 282         vehic.velocity  += df * frametime;
 283         this.velocity = this.movement  = vehic.velocity;
 284         setorigin(this, vehic.origin + '0 0 32');
 285
 286         this.vehicle_weapon2mode = vehic.vehicle_weapon2mode;
 287
 288         vector vf, ad;
 289         // Target lock & predict
 290         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 291         {
 292                 if(vehic.gun1.lock_time < time || IS_DEAD(vehic.gun1.enemy) || STAT(FROZEN, vehic.gun1.enemy))
 293                         vehic.gun1.enemy = world;
 294
 295                 if(trace_ent)
 296                 if(trace_ent.movetype)
 297                 if(trace_ent.takedamage)
 298                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 299                 {
 300                         if(teamplay)
 301                         {
 302                                 if(trace_ent.team != this.team)
 303                                 {
 304                                         vehic.gun1.enemy = trace_ent;
 305                                         vehic.gun1.lock_time = time + 5;
 306                                 }
 307                         }
 308                         else
 309                         {
 310                                 vehic.gun1.enemy = trace_ent;
 311                                 vehic.gun1.lock_time = time + 0.5;
 312                         }
 313                 }
 314
 315                 if(vehic.gun1.enemy)
 316                 {
 317                         float distance, impact_time;
 318
 319                         vf = real_origin(vehic.gun1.enemy);
 320                         UpdateAuxiliaryXhair(this, vf, '1 0 0', 1);
 321                         vector _vel = vehic.gun1.enemy.velocity;
 322                         if(vehic.gun1.enemy.movetype == MOVETYPE_WALK)
 323                                 _vel_z *= 0.1;
 324
 325                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 326                         {
 327                                 ad = vf;
 328                                 distance = vlen(ad - this.origin);
 329                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 330                                 ad = vf + _vel * impact_time;
 331                                 trace_endpos = ad;
 332                         }
 333                         else
 334                                 trace_endpos = vf;
 335                 }
 336         }
 337         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 338         {
 339
 340                 vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 341                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 342                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 343
 344                 if(vehic.lock_target != world)
 345                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 346                 if(vehic.lock_strength == 1)
 347                 {
 348                         float i, distance, impact_time;
 349
 350                         vf = real_origin(vehic.lock_target);
 351                         ad = vf;
 352                         for(i = 0; i < 4; ++i)
 353                         {
 354                                 distance = vlen(ad - vehic.origin);
 355                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 356                                 ad = vf + vehic.lock_target.velocity * impact_time;
 357                         }
 358                         trace_endpos = ad;
 359                 }
 360
 361                 if(vehic.lock_target)
 362                 {
 363                         if(vehic.lock_strength == 1)
 364                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 1);
 365                         else if(vehic.lock_strength > 0.5)
 366                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 1);
 367                         else if(vehic.lock_strength < 0.5)
 368                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 1);
 369                 }
 370         }
 371
 372
 373         vehicle_aimturret(vehic, trace_endpos, vehic.gun1, "fire1",
 374                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 375                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 376
 377         vehicle_aimturret(vehic, trace_endpos, vehic.gun2, "fire1",
 378                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 379                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 380
 381         /*
 382         ad = ad * 0.5;
 383         v_forward = vf * 0.5;
 384         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, vehic);
 385         UpdateAuxiliaryXhair(this, trace_endpos, '0 1 0', 0);
 386         */
 387
 388         setself(vehic);
 389
 390         Weapon wep1 = WEP_RAPTOR;
 391         if(!forbidWeaponUse(this))
 392         if(PHYS_INPUT_BUTTON_ATCK(this))
 393         if (wep1.wr_checkammo1(wep1, vehic))
 394         {
 395             .entity weaponentity = weaponentities[0];
 396                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 397         }
 398
 399         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 400                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 401
 402         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 403                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 404
 405         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 406                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 407
 408         Weapon wep2a = WEP_RAPTOR_BOMB;
 409         if(!forbidWeaponUse(this))
 410         if(vehic.vehicle_weapon2mode == RSM_BOMB)
 411         {
 412                 if(time > vehic.lip + autocvar_g_vehicle_raptor_bombs_refire)
 413                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 414                 {
 415                     .entity weaponentity = weaponentities[1];
 416                         wep2a.wr_think(wep2a, vehic, weaponentity, 2);
 417                         vehic.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 418                         vehic.lip   = time;
 419                 }
 420         }
 421         else
 422         {
 423                 Weapon wep2b = WEP_RAPTOR_FLARE;
 424                 if(time > vehic.lip + autocvar_g_vehicle_raptor_flare_refire)
 425                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 426                 {
 427                     .entity weaponentity = weaponentities[1];
 428                         wep2b.wr_think(wep2b, vehic, weaponentity, 2);
 429                         vehic.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 430                         vehic.lip   = time;
 431                 }
 432         }
 433
 434         setself(this);
 435
 436         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 437         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 438         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 439
 440         if(vehic.bomb1.cnt < time)
 441         {
 442                 bool incoming = false;
 443                 FOREACH_ENTITY_ENT(enemy, vehic,
 444                 {
 445                         if(it.flags & FL_PROJECTILE)
 446                         if(MISSILE_IS_TRACKING(it))
 447                         if(vdist(vehic.origin - it.origin, <, 2 * autocvar_g_vehicle_raptor_flare_range))
 448                         {
 449                                 incoming = true;
 450                                 break;
 451                         }
 452                 });
 453
 454                 if(incoming)
 455                 {
 456                         msg_entity = this;
 457                         soundto(MSG_ONE, vehic, CH_PAIN_SINGLE, SND(VEH_MISSILE_ALARM), VOL_BASE, ATTEN_NONE);
 458                 }
 459
 460                 vehic.bomb1.cnt = time + 1;
 461         }
 462
 463
 464         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 465         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 466         if(vehic.vehicle_flags & VHF_HASSHIELD)
 467                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 468
 469         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 470 }
 471
 472 bool raptor_takeoff(entity this)
 473 {
 474         entity vehic = this.vehicle;
 475         return = true;
 476
 477         vehic.nextthink = time;
 478         CSQCMODEL_AUTOUPDATE(vehic);
 479         vehic.nextthink = 0; // will this work?
 480
 481         if(vehic.sound_nexttime < time)
 482         {
 483                 vehic.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 484                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 485         }
 486
 487         // Takeoff sequense
 488         if(vehic.frame < 25)
 489         {
 490                 vehic.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 491                 vehic.velocity_z = min(vehic.velocity_z * 1.5, 256);
 492                 vehic.bomb1.gun1.avelocity_y = 90 + ((vehic.frame / 25) * 25000);
 493                 vehic.bomb1.gun2.avelocity_y = -vehic.bomb1.gun1.avelocity_y;
 494                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 495
 496                 setorigin(this, vehic.origin + '0 0 32');
 497         }
 498         else
 499                 this.PlayerPhysplug = raptor_frame;
 500
 501         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 502                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 503
 504         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 505                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 506
 507         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 508                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 509
 510
 511         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 512         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 513         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 514
 515         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 516         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 517         if(vehic.vehicle_flags & VHF_HASSHIELD)
 518                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 519
 520         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 521 }
 522
 523 void raptor_blowup(entity this)
 524 {
 525         self.deadflag   = DEAD_DEAD;
 526         self.vehicle_exit(VHEF_NORMAL);
 527         RadiusDamage (self, self.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 528
 529         self.alpha                = -1;
 530         self.movetype      = MOVETYPE_NONE;
 531         self.effects            = EF_NODRAW;
 532         self.colormod      = '0 0 0';
 533         self.avelocity    = '0 0 0';
 534         self.velocity      = '0 0 0';
 535
 536         setorigin(self, self.pos1);
 537         settouch(self, func_null);
 538         self.nextthink = 0;
 539 }
 540
 541 void raptor_diethink(entity this)
 542 {
 543         if(time >= self.wait)
 544                 setthink(self, raptor_blowup);
 545
 546         if(random() < 0.05)
 547         {
 548                 sound (self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 549                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 550         }
 551         self.nextthink = time;
 552
 553         CSQCMODEL_AUTOUPDATE(self);
 554 }
 555
 556 // If we dont do this ever now and then, the raptors rotors
 557 // stop working, presumably due to angle overflow. cute.
 558 void raptor_rotor_anglefix(entity this)
 559 {
 560         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 561         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 562         self.nextthink = time + 15;
 563 }
 564
 565 float raptor_impulse(float _imp)
 566 {SELFPARAM();
 567         switch(_imp)
 568         {
 569                 case IMP_weapon_group_1.impulse:
 570                         self.vehicle.vehicle_weapon2mode = RSM_BOMB;
 571                         CSQCVehicleSetup(self, 0);
 572                         return true;
 573                 case IMP_weapon_group_2.impulse:
 574                         self.vehicle.vehicle_weapon2mode = RSM_FLARE;
 575                         CSQCVehicleSetup(self, 0);
 576                         return true;
 577
 578                 case IMP_weapon_next_byid.impulse:
 579                 case IMP_weapon_next_bypriority.impulse:
 580                 case IMP_weapon_next_bygroup.impulse:
 581                         self.vehicle.vehicle_weapon2mode += 1;
 582                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 583                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 584
 585                         CSQCVehicleSetup(self, 0);
 586                         return true;
 587                 case IMP_weapon_last.impulse:
 588                 case IMP_weapon_prev_byid.impulse:
 589                 case IMP_weapon_prev_bypriority.impulse:
 590                 case IMP_weapon_prev_bygroup.impulse:
 591                         self.vehicle.vehicle_weapon2mode -= 1;
 592                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 593                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 594
 595                         CSQCVehicleSetup(self, 0);
 596                         return true;
 597
 598                 /*
 599                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 600                         break;
 601                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 602                         break;
 603                 */
 604         }
 605         return false;
 606 }
 607
 608 spawnfunc(vehicle_raptor)
 609 {
 610         if(!autocvar_g_vehicle_raptor) { remove(this); return; }
 611         if(!vehicle_initialize(this, VEH_RAPTOR, false)) { remove(this); return; }
 612 }
 613
 614 METHOD(Raptor, vr_impact, void(Raptor thisveh, entity instance))
 615 {
 616     if(autocvar_g_vehicle_raptor_bouncepain)
 617         vehicles_impact(instance, autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 618 }
 619 METHOD(Raptor, vr_enter, void(Raptor thisveh, entity instance))
 620 {
 621     SELFPARAM();
 622     self.vehicle_weapon2mode = RSM_BOMB;
 623     self.owner.PlayerPhysplug = raptor_takeoff;
 624     self.movetype          = MOVETYPE_BOUNCEMISSILE;
 625     self.solid            = SOLID_SLIDEBOX;
 626     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 627     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 628     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 629     self.tur_head.exteriormodeltoclient = self.owner;
 630
 631     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 632     self.lip   = time;
 633
 634     if(self.owner.flagcarried)
 635        setorigin(self.owner.flagcarried, '-20 0 96');
 636
 637     CSQCVehicleSetup(self.owner, 0);
 638 }
 639 METHOD(Raptor, vr_death, void(Raptor thisveh, entity instance))
 640 {
 641     instance.health                             = 0;
 642     instance.event_damage               = func_null;
 643     instance.solid                              = SOLID_CORPSE;
 644     instance.takedamage                 = DAMAGE_NO;
 645     instance.deadflag                   = DEAD_DYING;
 646     instance.movetype                   = MOVETYPE_BOUNCE;
 647     setthink(instance, raptor_diethink);
 648     instance.nextthink                  = time;
 649     instance.wait                               = time + 5 + (random() * 5);
 650
 651     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (instance.origin, 16), '0 0 0', 1);
 652
 653     instance.velocity_z += 600;
 654
 655     instance.avelocity = '0 0.5 1' * (random() * 400);
 656     instance.avelocity -= '0 0.5 1' * (random() * 400);
 657
 658     instance.colormod = '-0.5 -0.5 -0.5';
 659     settouch(instance, raptor_blowup);
 660 }
 661 METHOD(Raptor, vr_spawn, void(Raptor thisveh, entity instance))
 662 {
 663     SELFPARAM();
 664     if(!self.gun1)
 665     {
 666         entity spinner;
 667         vector ofs;
 668
 669         //FIXME: Camera is in a bad place in HUD model.
 670         //setorigin(self.vehicle_viewport, '25 0 5');
 671
 672         self.vehicles_impulse   = raptor_impulse;
 673
 674         self.frame = 0;
 675
 676         self.bomb1 = new(raptor_bomb);
 677         self.bomb2 = new(raptor_bomb);
 678         self.gun1  = new(raptor_gun);
 679         self.gun2  = new(raptor_gun);
 680
 681         setmodel(self.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 682         setmodel(self.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 683         setmodel(self.gun1, MDL_VEH_RAPTOR_GUN);
 684         setmodel(self.gun2, MDL_VEH_RAPTOR_GUN);
 685         setmodel(self.tur_head, MDL_VEH_RAPTOR_TAIL);
 686
 687         setattachment(self.bomb1, self, "bombmount_left");
 688         setattachment(self.bomb2, self, "bombmount_right");
 689         setattachment(self.tur_head, self,"root");
 690
 691         // FIXMODEL Guns mounts to angled bones
 692         self.bomb1.angles = self.angles;
 693         self.angles = '0 0 0';
 694         // This messes up gun-aim, so work arround it.
 695         //setattachment(self.gun1, self, "gunmount_left");
 696         ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 697         ofs -= self.origin;
 698         setattachment(self.gun1, self, "");
 699         setorigin(self.gun1, ofs);
 700
 701         //setattachment(self.gun2, self, "gunmount_right");
 702         ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 703         ofs -= self.origin;
 704         setattachment(self.gun2, self, "");
 705         setorigin(self.gun2, ofs);
 706
 707         self.angles = self.bomb1.angles;
 708         self.bomb1.angles = '0 0 0';
 709
 710         spinner = new(raptor_spinner);
 711         spinner.owner = self;
 712         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 713         setattachment(spinner, self, "engine_left");
 714         spinner.movetype = MOVETYPE_NOCLIP;
 715         spinner.avelocity = '0 90 0';
 716         self.bomb1.gun1 = spinner;
 717
 718         spinner = new(raptor_spinner);
 719         spinner.owner = self;
 720         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 721         setattachment(spinner, self, "engine_right");
 722         spinner.movetype = MOVETYPE_NOCLIP;
 723         spinner.avelocity = '0 -90 0';
 724         self.bomb1.gun2 = spinner;
 725
 726         // Sigh.
 727         setthink(self.bomb1, raptor_rotor_anglefix);
 728         self.bomb1.nextthink = time;
 729
 730         self.mass                          = 1 ;
 731     }
 732
 733     self.frame            = 0;
 734     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 735     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 736     self.movetype          = MOVETYPE_TOSS;
 737     self.solid            = SOLID_SLIDEBOX;
 738     self.vehicle_energy = 1;
 739
 740     self.PlayerPhysplug = raptor_frame;
 741
 742     self.bomb1.gun1.avelocity_y = 90;
 743     self.bomb1.gun2.avelocity_y = -90;
 744
 745     self.delay = time;
 746
 747     self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 748     self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 749     self.damageforcescale = 0.25;
 750     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 751     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 752 }
 753 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 754 {
 755     if(autocvar_g_vehicle_raptor_shield)
 756         instance.vehicle_flags |= VHF_HASSHIELD;
 757
 758     if(autocvar_g_vehicle_raptor_shield_regen)
 759         instance.vehicle_flags |= VHF_SHIELDREGEN;
 760
 761     if(autocvar_g_vehicle_raptor_health_regen)
 762         instance.vehicle_flags |= VHF_HEALTHREGEN;
 763
 764     if(autocvar_g_vehicle_raptor_energy_regen)
 765         instance.vehicle_flags |= VHF_ENERGYREGEN;
 766
 767     instance.vehicle_exit = raptor_exit;
 768     instance.respawntime = autocvar_g_vehicle_raptor_respawntime;
 769     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 770     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 771     instance.max_health = instance.vehicle_health;
 772 }
 773
 774 #endif
 775 #ifdef CSQC
 776
 777 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 778 {
 779     Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 780                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 781                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 782 }
 783 METHOD(Raptor, vr_crosshair, void(Raptor thisveh))
 784 {
 785     SELFPARAM();
 786     string crosshair;
 787
 788     switch(weapon2mode)
 789     {
 790         case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 791         case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 792         default:        crosshair = vCROSS_BURST;
 793     }
 794
 795     vector tmpSize = '0 0 0';
 796     if(weapon2mode != RSM_FLARE)
 797     {
 798         vector where;
 799
 800         if(!dropmark)
 801         {
 802             dropmark = spawn();
 803             dropmark.owner = self;
 804             dropmark.gravity = 1;
 805         }
 806
 807         float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 808         if(reload2 == 1)
 809         {
 810             setorigin(dropmark, pmove_org);
 811             dropmark.velocity = pmove_vel;
 812             tracetoss(dropmark, self);
 813
 814             where = project_3d_to_2d(trace_endpos);
 815
 816             setorigin(dropmark, trace_endpos);
 817             tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 818
 819             if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 820             {
 821                 where.x -= tmpSize.x * 0.5;
 822                 where.y -= tmpSize.y * 0.5;
 823                 where.z = 0;
 824                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 825                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 826             }
 827             dropmark.cnt = time + 5;
 828         }
 829         else
 830         {
 831             if(dropmark.cnt > time)
 832             {
 833                 where = project_3d_to_2d(dropmark.origin);
 834                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 835
 836                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 837                 {
 838                     where.x -= tmpSize.x * 0.5;
 839                     where.y -= tmpSize.y * 0.5;
 840                     where.z = 0;
 841                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 842                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 843                 }
 844             }
 845         }
 846     }
 847
 848     Vehicles_drawCrosshair(crosshair);
 849 }
 850 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 851 {
 852     AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 853 }
 854
 855 #endif
 856 #endif