qcsrc/common/vehicles/vehicle/raptor.qc

   1 #include "raptor.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6
   7 bool autocvar_g_vehicle_raptor = true;
   8
   9 float autocvar_g_vehicle_raptor_respawntime = 40;
  10 float autocvar_g_vehicle_raptor_takeofftime = 1.5;
  11
  12 // 0: go where player aims, +forward etc relative to aim angles
  13 // 1: ignore aim for up/down movement. +forward always moved forward, +jump always moves up
  14 int autocvar_g_vehicle_raptor_movestyle = 1;
  15 float autocvar_g_vehicle_raptor_turnspeed = 200;
  16 float autocvar_g_vehicle_raptor_pitchspeed = 50;
  17 float autocvar_g_vehicle_raptor_pitchlimit = 45;
  18
  19 float autocvar_g_vehicle_raptor_speed_forward = 1700;
  20 float autocvar_g_vehicle_raptor_speed_strafe = 900;
  21 float autocvar_g_vehicle_raptor_speed_up = 1700;
  22 float autocvar_g_vehicle_raptor_speed_down = 1700;
  23 float autocvar_g_vehicle_raptor_friction = 2;
  24
  25 bool autocvar_g_vehicle_raptor_swim = false;
  26
  27 float autocvar_g_vehicle_raptor_cannon_turnspeed = 120;
  28 float autocvar_g_vehicle_raptor_cannon_turnlimit = 20;
  29 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up = 12;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down = 32;
  31
  32 float autocvar_g_vehicle_raptor_cannon_locktarget = 0;
  33 float autocvar_g_vehicle_raptor_cannon_locking_time = 0.2;
  34 float autocvar_g_vehicle_raptor_cannon_locking_releasetime = 0.45;
  35 float autocvar_g_vehicle_raptor_cannon_locked_time = 1;
  36 float autocvar_g_vehicle_raptor_cannon_predicttarget = 1;
  37
  38 float autocvar_g_vehicle_raptor_energy = 100;
  39 float autocvar_g_vehicle_raptor_energy_regen = 25;
  40 float autocvar_g_vehicle_raptor_energy_regen_pause = 0.25;
  41
  42 float autocvar_g_vehicle_raptor_health = 150;
  43 float autocvar_g_vehicle_raptor_health_regen = 0;
  44 float autocvar_g_vehicle_raptor_health_regen_pause = 0;
  45
  46 float autocvar_g_vehicle_raptor_shield = 75;
  47 float autocvar_g_vehicle_raptor_shield_regen = 25;
  48 float autocvar_g_vehicle_raptor_shield_regen_pause = 1.5;
  49
  50 float autocvar_g_vehicle_raptor_bouncefactor = 0.2;
  51 float autocvar_g_vehicle_raptor_bouncestop = 0;
  52 vector autocvar_g_vehicle_raptor_bouncepain = '1 4 1000';
  53
  54 .entity bomb1;
  55 .entity bomb2;
  56
  57 void raptor_land(entity this)
  58 {
  59         float hgt;
  60
  61         hgt = vehicle_altitude(this, 512);
  62         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
  63         this.angles_x *= 0.95;
  64         this.angles_z *= 0.95;
  65
  66         if(hgt < 128 && hgt > 0)
  67                 this.frame = (hgt / 128) * 25;
  68
  69         this.bomb1.gun1.avelocity_y = 90 + ((this.frame / 25) * 2000);
  70         this.bomb1.gun2.avelocity_y = -this.bomb1.gun1.avelocity_y;
  71
  72         if(hgt < 16)
  73         {
  74                 set_movetype(this, MOVETYPE_TOSS);
  75                 setthink(this, vehicles_think);
  76                 this.frame      = 0;
  77         }
  78
  79         this.nextthink  = time;
  80
  81         CSQCMODEL_AUTOUPDATE(this);
  82 }
  83
  84 void raptor_exit(entity this, int eject)
  85 {
  86         entity player = this.owner;
  87         this.owner = NULL;
  88
  89         this.tur_head.exteriormodeltoclient = NULL;
  90
  91         if(!IS_DEAD(this))
  92         {
  93                 setthink(this, raptor_land);
  94                 this.nextthink = time;
  95         }
  96
  97         if(!player)
  98                 return;
  99
 100         makevectors(this.angles);
 101         vector spot;
 102         if(eject)
 103         {
 104                 spot = this.origin + v_forward * 100 + '0 0 64';
 105                 spot = vehicles_findgoodexit(this, spot);
 106                 setorigin(player, spot);
 107                 player.velocity = (v_up + v_forward * 0.25) * 750;
 108                 player.oldvelocity = player.velocity;
 109         }
 110         else
 111         {
 112                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 113                 {
 114                         player.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 115                         player.velocity_z += 200;
 116                         spot = this.origin + v_forward * 32 + '0 0 64';
 117                         spot = vehicles_findgoodexit(this, spot);
 118                 }
 119                 else
 120                 {
 121                         player.velocity = this.velocity * 0.5;
 122                         player.velocity_z += 10;
 123                         spot = this.origin - v_forward * 200 + '0 0 64';
 124                         spot = vehicles_findgoodexit(this, spot);
 125                 }
 126                 player.oldvelocity = player.velocity;
 127                 setorigin(player, spot);
 128         }
 129
 130         antilag_clear(player, CS(player));
 131 }
 132
 133 bool raptor_frame(entity this, float dt)
 134 {
 135         entity vehic = this.vehicle;
 136         return = true;
 137
 138         if(game_stopped)
 139         {
 140                 vehic.solid = SOLID_NOT;
 141                 vehic.takedamage = DAMAGE_NO;
 142                 set_movetype(vehic, MOVETYPE_NONE);
 143                 return;
 144         }
 145
 146         vehicles_frame(vehic, this);
 147
 148         /*
 149         ftmp = vlen(vehic.velocity);
 150         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 151                 ftmp = 1;
 152         else
 153                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 154         */
 155
 156         if(vehic.sound_nexttime < time)
 157         {
 158                 vehic.sound_nexttime = time + 7.955812;
 159                 //sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 160                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 161                 vehic.wait = 0;
 162         }
 163         /*
 164         else if(fabs(ftmp - vehic.wait) > 0.2)
 165         {
 166                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 167                 sound (vehic, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 168                 vehic.wait = ftmp;
 169         }
 170         */
 171
 172         if(IS_DEAD(vehic))
 173         {
 174                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 175                 return;
 176         }
 177         crosshair_trace(this);
 178
 179         //if(time - vehic.lastteleporttime < 1)
 180         //{
 181                 if(vehic.angles_z > 50 || vehic.angles_z < -50)
 182                 {
 183                         if(PHYS_INPUT_BUTTON_JUMP(this))
 184                         {
 185                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 186                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 187                         }
 188                 }
 189         //}
 190
 191         vector vang;
 192         vang = vehic.angles;
 193         vector df = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 194         vang_x *= -1;
 195         df_x *= -1;
 196         if(df_x > 180)  df_x -= 360;
 197         if(df_x < -180) df_x += 360;
 198         if(df_y > 180)  df_y -= 360;
 199         if(df_y < -180) df_y += 360;
 200
 201         float ftmp = shortangle_f(this.v_angle_y - vang_y, vang_y);
 202         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 203         vehic.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 204
 205         // Pitch
 206         ftmp = 0;
 207         if(this.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 208         else if(this.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 209
 210         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 211         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 212         vehic.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 213
 214         vehic.angles_x = anglemods(vehic.angles_x);
 215         vehic.angles_y = anglemods(vehic.angles_y);
 216         vehic.angles_z = anglemods(vehic.angles_z);
 217
 218         if(autocvar_g_vehicle_raptor_movestyle == 1)
 219                 makevectors('0 1 0' * vehic.angles_y);
 220         else
 221                 makevectors(this.v_angle);
 222
 223         df = vehic.velocity * -autocvar_g_vehicle_raptor_friction;
 224
 225         if(this.movement_x != 0)
 226         {
 227                 if(this.movement_x > 0)
 228                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 229                 else if(this.movement_x < 0)
 230                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 231         }
 232
 233         if(this.movement_y != 0)
 234         {
 235                 if(this.movement_y < 0)
 236                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 237                 else if(this.movement_y > 0)
 238                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 239
 240                 vehic.angles_z = bound(-30,vehic.angles_z + (this.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 241         }
 242         else
 243         {
 244                 vehic.angles_z *= 0.95;
 245                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 246                         vehic.angles_z = 0;
 247         }
 248
 249         if(PHYS_INPUT_BUTTON_CROUCH(this))
 250                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 251         else if (PHYS_INPUT_BUTTON_JUMP(this))
 252                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 253
 254         vehic.velocity  += df * dt;
 255         this.velocity = this.movement  = vehic.velocity;
 256         setorigin(this, vehic.origin + '0 0 32');
 257
 258         this.vehicle_weapon2mode = vehic.vehicle_weapon2mode;
 259
 260         vector vf, ad;
 261         // Target lock & predict
 262         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 263         {
 264                 if(vehic.gun1.lock_time < time || IS_DEAD(vehic.gun1.enemy) || STAT(FROZEN, vehic.gun1.enemy))
 265                         vehic.gun1.enemy = NULL;
 266
 267                 if(trace_ent)
 268                 if(trace_ent.move_movetype)
 269                 if(trace_ent.takedamage)
 270                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 271                 {
 272                         if(teamplay)
 273                         {
 274                                 if(trace_ent.team != this.team)
 275                                 {
 276                                         vehic.gun1.enemy = trace_ent;
 277                                         vehic.gun1.lock_time = time + 5;
 278                                 }
 279                         }
 280                         else
 281                         {
 282                                 vehic.gun1.enemy = trace_ent;
 283                                 vehic.gun1.lock_time = time + 0.5;
 284                         }
 285                 }
 286
 287                 if(vehic.gun1.enemy)
 288                 {
 289                         float distance, impact_time;
 290
 291                         vf = real_origin(vehic.gun1.enemy);
 292                         UpdateAuxiliaryXhair(this, vf, '1 0 0', 1);
 293                         vector _vel = vehic.gun1.enemy.velocity;
 294                         if(vehic.gun1.enemy.move_movetype == MOVETYPE_WALK)
 295                                 _vel_z *= 0.1;
 296
 297                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 298                         {
 299                                 ad = vf;
 300                                 distance = vlen(ad - this.origin);
 301                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 302                                 ad = vf + _vel * impact_time;
 303                                 trace_endpos = ad;
 304                         }
 305                         else
 306                                 trace_endpos = vf;
 307                 }
 308         }
 309         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 310         {
 311
 312                 vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_raptor_cannon_locking_time) * dt,
 313                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * dt,
 314                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 315
 316                 if(vehic.lock_target != NULL)
 317                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 318                 if(vehic.lock_strength == 1)
 319                 {
 320                         float i, distance, impact_time;
 321
 322                         vf = real_origin(vehic.lock_target);
 323                         ad = vf;
 324                         for(i = 0; i < 4; ++i)
 325                         {
 326                                 distance = vlen(ad - vehic.origin);
 327                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 328                                 ad = vf + vehic.lock_target.velocity * impact_time;
 329                         }
 330                         trace_endpos = ad;
 331                 }
 332
 333                 if(vehic.lock_target)
 334                 {
 335                         if(vehic.lock_strength == 1)
 336                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 1);
 337                         else if(vehic.lock_strength > 0.5)
 338                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 1);
 339                         else if(vehic.lock_strength < 0.5)
 340                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 1);
 341                 }
 342         }
 343
 344
 345         vehicle_aimturret(vehic, trace_endpos, vehic.gun1, "fire1",
 346                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 347                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 348
 349         vehicle_aimturret(vehic, trace_endpos, vehic.gun2, "fire1",
 350                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 351                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 352
 353         /*
 354         ad = ad * 0.5;
 355         v_forward = vf * 0.5;
 356         traceline(ad, ad + v_forward * max_shot_distance, MOVE_NORMAL, vehic);
 357         UpdateAuxiliaryXhair(this, trace_endpos, '0 1 0', 0);
 358         */
 359
 360         Weapon wep1 = WEP_RAPTOR;
 361         .entity weaponentity = weaponentities[0];
 362         if(!forbidWeaponUse(this))
 363         if(PHYS_INPUT_BUTTON_ATCK(this))
 364         if (wep1.wr_checkammo1(wep1, vehic, weaponentity))
 365         {
 366                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 367         }
 368
 369         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 370                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, dt, true);
 371
 372         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 373                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, dt, false);
 374
 375         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 376                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, dt, false);
 377
 378         Weapon wep2a = WEP_RAPTOR_BOMB;
 379         if(!forbidWeaponUse(this))
 380         if(vehic.vehicle_weapon2mode == RSM_BOMB)
 381         {
 382                 if(time > vehic.lip + autocvar_g_vehicle_raptor_bombs_refire)
 383                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 384                 {
 385                     .entity weaponentity = weaponentities[1];
 386                         wep2a.wr_think(wep2a, vehic, weaponentity, 2);
 387                         vehic.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 388                         vehic.lip   = time;
 389                 }
 390         }
 391         else
 392         {
 393                 Weapon wep2b = WEP_RAPTOR_FLARE;
 394                 if(time > vehic.lip + autocvar_g_vehicle_raptor_flare_refire)
 395                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 396                 {
 397                     .entity weaponentity = weaponentities[1];
 398                         wep2b.wr_think(wep2b, vehic, weaponentity, 2);
 399                         vehic.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 400                         vehic.lip   = time;
 401                 }
 402         }
 403
 404         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 405         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 406         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 407
 408         if(vehic.bomb1.cnt < time)
 409         {
 410                 bool incoming = false;
 411                 IL_EACH(g_projectiles, it.enemy == vehic,
 412                 {
 413                         if(MISSILE_IS_TRACKING(it))
 414                         if(vdist(vehic.origin - it.origin, <, 2 * autocvar_g_vehicle_raptor_flare_range))
 415                         {
 416                                 incoming = true;
 417                                 break;
 418                         }
 419                 });
 420
 421                 if(incoming)
 422                 {
 423                         msg_entity = this;
 424                         soundto(MSG_ONE, vehic, CH_PAIN_SINGLE, SND(VEH_MISSILE_ALARM), VOL_BASE, ATTEN_NONE);
 425                 }
 426
 427                 vehic.bomb1.cnt = time + 1;
 428         }
 429
 430
 431         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 432         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 433         if(vehic.vehicle_flags & VHF_HASSHIELD)
 434                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 435
 436         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 437 }
 438
 439 bool raptor_takeoff(entity this, float dt)
 440 {
 441         entity vehic = this.vehicle;
 442         return = true;
 443
 444         vehic.nextthink = time;
 445         CSQCMODEL_AUTOUPDATE(vehic);
 446         vehic.nextthink = 0; // will this work?
 447
 448         if(vehic.sound_nexttime < time)
 449         {
 450                 vehic.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 451                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 452         }
 453
 454         // Takeoff sequense
 455         if(vehic.frame < 25)
 456         {
 457                 vehic.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / PHYS_INPUT_FRAMETIME);
 458                 vehic.velocity_z = min(vehic.velocity_z * 1.5, 256);
 459                 vehic.bomb1.gun1.avelocity_y = 90 + ((vehic.frame / 25) * 25000);
 460                 vehic.bomb1.gun2.avelocity_y = -vehic.bomb1.gun1.avelocity_y;
 461                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 462
 463                 setorigin(this, vehic.origin + '0 0 32');
 464         }
 465         else
 466                 this.PlayerPhysplug = raptor_frame;
 467
 468         this.vehicle_weapon2mode = vehic.vehicle_weapon2mode;
 469
 470         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 471                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, dt, true);
 472
 473         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 474                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, dt, false);
 475
 476         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 477                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, dt, false);
 478
 479
 480         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 481         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 482         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 483
 484         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 485         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 486         if(vehic.vehicle_flags & VHF_HASSHIELD)
 487                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 488
 489         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 490 }
 491
 492 void raptor_blowup(entity this, entity toucher)
 493 {
 494         this.deadflag   = DEAD_DEAD;
 495         this.vehicle_exit(this, VHEF_NORMAL);
 496         RadiusDamage (this, this.enemy, 250, 15, 250, NULL, NULL, 250, DEATH_VH_RAPT_DEATH.m_id, NULL);
 497
 498         this.alpha                = -1;
 499         set_movetype(this, MOVETYPE_NONE);
 500         this.effects            = EF_NODRAW;
 501         this.colormod      = '0 0 0';
 502         this.avelocity    = '0 0 0';
 503         this.velocity      = '0 0 0';
 504
 505         setorigin(this, this.pos1);
 506         settouch(this, func_null);
 507         this.nextthink = 0;
 508 }
 509
 510 void raptor_diethink(entity this)
 511 {
 512         if(time >= this.wait)
 513         {
 514                 raptor_blowup(this, NULL);
 515                 return;
 516         }
 517
 518         if(random() < 0.05)
 519         {
 520                 sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 521                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 522         }
 523         this.nextthink = time;
 524
 525         CSQCMODEL_AUTOUPDATE(this);
 526 }
 527
 528 // If we dont do this ever now and then, the raptors rotors
 529 // stop working, presumably due to angle overflow. cute.
 530 void raptor_rotor_anglefix(entity this)
 531 {
 532         this.gun1.angles_y = anglemods(this.gun1.angles_y);
 533         this.gun2.angles_y = anglemods(this.gun2.angles_y);
 534         this.nextthink = time + 15;
 535 }
 536
 537 bool raptor_impulse(entity this, int _imp)
 538 {
 539         switch(_imp)
 540         {
 541                 case IMP_weapon_group_1.impulse:
 542                         this.vehicle.vehicle_weapon2mode = RSM_BOMB;
 543                         CSQCVehicleSetup(this, 0);
 544                         return true;
 545                 case IMP_weapon_group_2.impulse:
 546                         this.vehicle.vehicle_weapon2mode = RSM_FLARE;
 547                         CSQCVehicleSetup(this, 0);
 548                         return true;
 549
 550                 case IMP_weapon_next_byid.impulse:
 551                 case IMP_weapon_next_bypriority.impulse:
 552                 case IMP_weapon_next_bygroup.impulse:
 553                         this.vehicle.vehicle_weapon2mode += 1;
 554                         if(this.vehicle.vehicle_weapon2mode > RSM_LAST)
 555                                 this.vehicle.vehicle_weapon2mode = RSM_FIRST;
 556
 557                         CSQCVehicleSetup(this, 0);
 558                         return true;
 559                 case IMP_weapon_last.impulse:
 560                 case IMP_weapon_prev_byid.impulse:
 561                 case IMP_weapon_prev_bypriority.impulse:
 562                 case IMP_weapon_prev_bygroup.impulse:
 563                         this.vehicle.vehicle_weapon2mode -= 1;
 564                         if(this.vehicle.vehicle_weapon2mode < RSM_FIRST)
 565                                 this.vehicle.vehicle_weapon2mode = RSM_LAST;
 566
 567                         CSQCVehicleSetup(this, 0);
 568                         return true;
 569
 570                 /*
 571                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 572                         break;
 573                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 574                         break;
 575                 */
 576         }
 577         return false;
 578 }
 579
 580 spawnfunc(vehicle_raptor)
 581 {
 582         if(!autocvar_g_vehicle_raptor) { delete(this); return; }
 583         if(!vehicle_initialize(this, VEH_RAPTOR, false)) { delete(this); return; }
 584 }
 585
 586 METHOD(Raptor, vr_impact, void(Raptor thisveh, entity instance))
 587 {
 588     if(autocvar_g_vehicle_raptor_bouncepain)
 589         vehicles_impact(instance, autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 590 }
 591 METHOD(Raptor, vr_enter, void(Raptor thisveh, entity instance))
 592 {
 593     instance.vehicle_weapon2mode = RSM_BOMB;
 594     instance.owner.PlayerPhysplug = raptor_takeoff;
 595     set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 596     instance.solid                = SOLID_SLIDEBOX;
 597     instance.owner.vehicle_health = (instance.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 598     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 599     instance.velocity = '0 0 1'; // nudge upwards so takeoff sequence can work
 600     instance.tur_head.exteriormodeltoclient = instance.owner;
 601
 602     instance.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 603     instance.lip   = time;
 604
 605     if(instance.owner.flagcarried)
 606        setorigin(instance.owner.flagcarried, '-20 0 96');
 607
 608     CSQCVehicleSetup(instance.owner, 0);
 609 }
 610 METHOD(Raptor, vr_death, void(Raptor thisveh, entity instance))
 611 {
 612     instance.health                             = 0;
 613     instance.event_damage               = func_null;
 614     instance.solid                              = SOLID_CORPSE;
 615     instance.takedamage                 = DAMAGE_NO;
 616     instance.deadflag                   = DEAD_DYING;
 617     set_movetype(instance, MOVETYPE_BOUNCE);
 618     setthink(instance, raptor_diethink);
 619     instance.nextthink                  = time;
 620     instance.wait                               = time + 5 + (random() * 5);
 621
 622     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (instance.origin, 16), '0 0 0', 1);
 623
 624     instance.velocity_z += 600;
 625
 626     instance.avelocity = '0 0.5 1' * (random() * 400);
 627     instance.avelocity -= '0 0.5 1' * (random() * 400);
 628
 629     instance.colormod = '-0.5 -0.5 -0.5';
 630     settouch(instance, raptor_blowup);
 631 }
 632 METHOD(Raptor, vr_spawn, void(Raptor thisveh, entity instance))
 633 {
 634     if(!instance.gun1)
 635     {
 636         entity spinner;
 637         vector ofs;
 638
 639         //FIXME: Camera is in a bad place in HUD model.
 640         //setorigin(instance.vehicle_viewport, '25 0 5');
 641
 642         instance.vehicles_impulse = raptor_impulse;
 643
 644         instance.frame = 0;
 645
 646         instance.bomb1 = new(raptor_bomb);
 647         instance.bomb2 = new(raptor_bomb);
 648         instance.gun1  = new(raptor_gun);
 649         instance.gun2  = new(raptor_gun);
 650
 651         setmodel(instance.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 652         setmodel(instance.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 653         setmodel(instance.gun1, MDL_VEH_RAPTOR_GUN);
 654         setmodel(instance.gun2, MDL_VEH_RAPTOR_GUN);
 655         setmodel(instance.tur_head, MDL_VEH_RAPTOR_TAIL);
 656
 657         setattachment(instance.bomb1, instance, "bombmount_left");
 658         setattachment(instance.bomb2, instance, "bombmount_right");
 659         setattachment(instance.tur_head, instance,"root");
 660
 661         // FIXMODEL Guns mounts to angled bones
 662         instance.bomb1.angles = instance.angles;
 663         instance.angles = '0 0 0';
 664         // This messes up gun-aim, so work arround it.
 665         //setattachment(instance.gun1, instance, "gunmount_left");
 666         ofs = gettaginfo(instance, gettagindex(instance, "gunmount_left"));
 667         ofs -= instance.origin;
 668         setattachment(instance.gun1, instance, "");
 669         setorigin(instance.gun1, ofs);
 670
 671         //setattachment(instance.gun2, instance, "gunmount_right");
 672         ofs = gettaginfo(instance, gettagindex(instance, "gunmount_right"));
 673         ofs -= instance.origin;
 674         setattachment(instance.gun2, instance, "");
 675         setorigin(instance.gun2, ofs);
 676
 677         instance.angles = instance.bomb1.angles;
 678         instance.bomb1.angles = '0 0 0';
 679
 680         spinner = new(raptor_spinner);
 681         spinner.owner = instance;
 682         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 683         setattachment(spinner, instance, "engine_left");
 684         set_movetype(spinner, MOVETYPE_NOCLIP);
 685         spinner.avelocity = '0 90 0';
 686         instance.bomb1.gun1 = spinner;
 687
 688         spinner = new(raptor_spinner);
 689         spinner.owner = instance;
 690         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 691         setattachment(spinner, instance, "engine_right");
 692         set_movetype(spinner, MOVETYPE_NOCLIP);
 693         spinner.avelocity = '0 -90 0';
 694         instance.bomb1.gun2 = spinner;
 695
 696         // Sigh.
 697         setthink(instance.bomb1, raptor_rotor_anglefix);
 698         instance.bomb1.nextthink = time;
 699
 700         instance.mass                      = 1 ;
 701     }
 702
 703     instance.frame                = 0;
 704     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 705     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 706     set_movetype(instance, MOVETYPE_TOSS);
 707     instance.solid                = SOLID_SLIDEBOX;
 708     instance.vehicle_energy = 1;
 709
 710     if(!autocvar_g_vehicle_raptor_swim)
 711         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 712
 713     instance.PlayerPhysplug = raptor_frame;
 714
 715     instance.bomb1.gun1.avelocity_y = 90;
 716     instance.bomb1.gun2.avelocity_y = -90;
 717
 718     instance.delay = time;
 719
 720     instance.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 721     instance.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 722     instance.damageforcescale = 0.25;
 723     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 724     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 725 }
 726 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 727 {
 728     if(autocvar_g_vehicle_raptor_shield)
 729         instance.vehicle_flags |= VHF_HASSHIELD;
 730
 731     if(autocvar_g_vehicle_raptor_shield_regen)
 732         instance.vehicle_flags |= VHF_SHIELDREGEN;
 733
 734     if(autocvar_g_vehicle_raptor_health_regen)
 735         instance.vehicle_flags |= VHF_HEALTHREGEN;
 736
 737     if(autocvar_g_vehicle_raptor_energy_regen)
 738         instance.vehicle_flags |= VHF_ENERGYREGEN;
 739
 740     instance.vehicle_exit = raptor_exit;
 741     instance.respawntime = autocvar_g_vehicle_raptor_respawntime;
 742     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 743     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 744     instance.max_health = instance.vehicle_health;
 745
 746     if(!autocvar_g_vehicle_raptor_swim)
 747         instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 748 }
 749
 750 #endif
 751 #ifdef CSQC
 752
 753 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 754 {
 755     Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 756                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 757                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 758 }
 759 METHOD(Raptor, vr_crosshair, void(Raptor thisveh, entity player))
 760 {
 761     string crosshair;
 762
 763     switch(weapon2mode)
 764     {
 765         case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 766         case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 767         default:        crosshair = vCROSS_BURST;
 768     }
 769
 770     vector tmpSize = '0 0 0';
 771     if(weapon2mode != RSM_FLARE && !spectatee_status)
 772     {
 773         vector where;
 774
 775         if(!dropmark)
 776         {
 777             dropmark = spawn();
 778             dropmark.owner = player;
 779             dropmark.gravity = 1;
 780         }
 781
 782         float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 783         if(reload2 == 1)
 784         {
 785             setorigin(dropmark, pmove_org);
 786             dropmark.velocity = pmove_vel;
 787             tracetoss(dropmark, player);
 788
 789             where = project_3d_to_2d(trace_endpos);
 790
 791             setorigin(dropmark, trace_endpos);
 792             tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 793
 794             if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 795             {
 796                 where.x -= tmpSize.x * 0.5;
 797                 where.y -= tmpSize.y * 0.5;
 798                 where.z = 0;
 799                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 800                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 801             }
 802             dropmark.cnt = time + 5;
 803         }
 804         else
 805         {
 806             if(dropmark.cnt > time)
 807             {
 808                 where = project_3d_to_2d(dropmark.origin);
 809                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 810
 811                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 812                 {
 813                     where.x -= tmpSize.x * 0.5;
 814                     where.y -= tmpSize.y * 0.5;
 815                     where.z = 0;
 816                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 817                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 818                 }
 819             }
 820         }
 821     }
 822
 823     Vehicles_drawCrosshair(crosshair);
 824 }
 825 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 826 {
 827     AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 828 }
 829
 830 #endif
 831 #endif