qcsrc/common/viewloc.qc

   1 #include "viewloc.qh"
   2 #include "util.qh"
   3
   4 #if defined(CSQC)
   5     #include "../client/defs.qh"
   6     #include "constants.qh"
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9         #include "../server/defs.qh"
  10 #endif
  11
  12 // client movement
  13 void viewloc_PlayerPhysics(entity this)
  14 {
  15         if(this.viewloc)
  16         {
  17                 if(this.viewloc.goalentity == this.viewloc.enemy)
  18                         return; // we can't side-scroll in this case
  19
  20                 vector old_movement = PHYS_CS(this).movement;
  21                 PHYS_CS(this).movement_x = old_movement_y;
  22                 PHYS_CS(this).movement_y = 0;
  23
  24                 vector level_start, level_end;
  25                 level_start = this.viewloc.enemy.origin;
  26                 level_end = this.viewloc.goalentity.origin;
  27                 vector forward = vectoangles(normalize(level_end - level_start));
  28                 vector backward = vectoangles(normalize(level_start - level_end));
  29
  30                 if(this.viewloc.spawnflags & VIEWLOC_FREEAIM)
  31                 {
  32                         if(this.angles_y > 0)
  33                                 PHYS_CS(this).movement_x = -PHYS_CS(this).movement_x;
  34                 }
  35                 else
  36                 {
  37                         if(PHYS_CS(this).movement_x < 0)
  38                                 PHYS_CS(this).movement_x = -PHYS_CS(this).movement_x;
  39
  40                         if(PHYS_CS(this).movement_x < 0) // left
  41                                 this.angles_y = backward.y;
  42                         if(PHYS_CS(this).movement_x > 0) // right
  43                                 this.angles_y = forward.y;
  44                 }
  45
  46                 //if(!PHYS_INPUT_BUTTON_CROUCH(this) && !IS_DUCKED(this))
  47 #ifdef SVQC
  48                         //PHYS_INPUT_BUTTON_CROUCH(this) = (old_movement_x < 0);
  49                         if (old_movement.x < 0)
  50                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
  51 #elif defined(CSQC)
  52                         if (old_movement.x < 0)
  53                         {
  54                                 input_buttons |= BIT(4);
  55                                 this.flags |= FL_DUCKED;
  56                         }
  57                         //else { input_buttons &= ~16; this.flags &= ~FL_DUCKED; }
  58 #endif
  59         }
  60 }
  61
  62 #ifdef CSQC
  63
  64 void viewloc_SetTags(entity this)
  65 {
  66         if(this.viewloc && wasfreed(this.viewloc))
  67                 this.viewloc = NULL;
  68
  69         if(this.viewloc.entnum != this.tag_networkviewloc)
  70         if(this.tag_networkviewloc == 0)
  71                 this.viewloc = NULL;
  72         else
  73                 this.viewloc = findfloat(NULL, entnum, this.tag_networkviewloc);
  74 }
  75
  76 vector CursorToWorldCoord(vector mpos)
  77 {
  78         vector wnear = cs_unproject(vec2(mpos)); // determine the world coordinate for the mouse cursor upon the near clip plane
  79         vector wfar = cs_unproject(vec3(mpos.x, mpos.y, max_shot_distance)); // determine the world coordinate for the mouse cursor upon the far clip plane, with an outrageously large value as a workaround for dp.
  80         traceline(wnear, wfar, MOVE_NOMONSTERS, NULL);
  81         return trace_endpos;
  82 }
  83
  84 vector old_camera_angle = '0 0 0';
  85 bool autocvar_cam_snap_close;
  86 bool autocvar_cam_track;
  87 bool autocvar_cam_snap_hard;
  88 bool autocvar_cam_snap_unlock;
  89 void viewloc_SetViewLocation()
  90 {
  91         entity view = CSQCModel_server2csqc(player_localentnum - 1);
  92         if (!view) return;
  93         //NOTE: the "cam_" cvars sould probably be changed out with a spawnflag or an entity key. I have it like this for my testing -- Player_2
  94         if(view.viewloc && !wasfreed(view.viewloc) && view.viewloc.enemy && view.viewloc.goalentity)
  95         {
  96                 bool have_sidescroll = (view.viewloc.enemy != view.viewloc.goalentity);
  97                 vector position_a = view.viewloc.enemy.origin;
  98                 vector position_b = view.viewloc.goalentity.origin;
  99                 vector camera_angle = '0 0 0';
 100                 vector camera_position;
 101
 102                 /*TODO: have the camera only move when a player moves too much from the center of the camera
 103                  * basically the player would move around in a small "box" in the center of the screen with out changing the camera position or angles */
 104                 camera_position = vec_bounds_in(view.origin, position_a, position_b);
 105
 106
 107                 // a tracking camera follows the player when it leaves the world box
 108                 if (autocvar_cam_track || !have_sidescroll) {
 109                         camera_angle = aim_vec (camera_position, view.origin);
 110                 }
 111
 112                 // hard snap changes the angle as soon as it crosses over the nearest 90 degree mark
 113                 if (autocvar_cam_snap_hard) {
 114                         camera_angle = angle_snap_vec(aim_vec(camera_position, view.origin), 90);
 115                 }
 116
 117                 // tries to avoid snapping unless it *really* needs to
 118                 if (autocvar_cam_snap_close) {
 119                         // like hard snap, but don't snap angles yet.
 120                         camera_angle = aim_vec(camera_position, view.origin);
 121
 122                         /* if the difference between the old and new angle is 60 degrees or more, switch angles.
 123                          * NOTE: bug/feature: this will use non-snaped angles for one frame.
 124                          * doing this resualts in less code, faster code, and a smoother transisition between angles.
 125                          */
 126                         float camera_angle_diff = max(camera_angle.y, old_camera_angle.y) - min(camera_angle.y, old_camera_angle.y);
 127
 128                         if (60 <= camera_angle_diff) { // use new angles
 129                                 old_camera_angle.y = angle_snap_f(camera_angle.y, 90);
 130                         } else { // use old angles
 131                                 camera_angle.y = old_camera_angle.y;
 132                         }
 133                 }
 134
 135                 //unlocking this allows the camera to look up and down. this also allows a top-down view.
 136                 if (!autocvar_cam_snap_unlock) {
 137                         camera_angle.x = 0;
 138                         camera_angle.z = 0;
 139                 }
 140
 141 #if 0
 142                 LOG_TRACE(vtos(camera_position));
 143                 LOG_TRACE(vtos(old_camera_angle));
 144                 LOG_TRACE(vtos(camera_angle));
 145 #endif
 146
 147                 freeze_org = getpropertyvec(VF_ORIGIN);
 148                 freeze_ang = getpropertyvec(VF_ANGLES);
 149                 setproperty(VF_ORIGIN, camera_position);
 150                 setproperty(VF_ANGLES, camera_angle);
 151
 152                 if(spectatee_status)
 153                         return; // if spectating, don't replace angles or inputs!
 154
 155                 if (have_sidescroll) {
 156                         vector view_angle = view.angles;
 157                         if (!(view.viewloc.spawnflags & VIEWLOC_FREEAIM)) {
 158                                 vector avatar_facing_dir;
 159                                 // get the player's forward-facing direction, based on positions a and b
 160                                 if (0 == input_movevalues.y) {
 161                                         avatar_facing_dir = view_angle; // default to the previous values
 162                                 } else if (0 > input_movevalues.y) { // left is forward
 163                                         avatar_facing_dir = vectoangles(normalize(vec_to_max(position_b, position_a) - vec_to_min(position_b, position_a)));
 164                                 } else { // right is forward
 165                                         avatar_facing_dir = vectoangles(normalize(vec_to_min(position_b, position_a) - vec_to_max(position_b, position_a)));
 166                                 }
 167                                 view_angle.y = avatar_facing_dir.y; // snap avatar to look on along the correct axis
 168
 169                                 // if (0 == input_movevalues.x) look straight ahead
 170                                 if (0 > input_movevalues.x) { // look up
 171                                         view_angle.x = 50;
 172                                 } else if (0 < input_movevalues.x) { // look down
 173                                         view_angle.x = -50;
 174                                 }
 175                         } else {
 176                                 vector mpos = CursorToWorldCoord(viewloc_mousepos);
 177                                 mpos.x = view.origin.x; // replace the cursor's x position with the player's
 178                                 view_angle = aim_vec(view.origin, mpos); // get new angles
 179                         }
 180                         view.angles_y = view_angle.y;
 181                         setproperty(VF_CL_VIEWANGLES, view_angle);
 182                 }
 183         }
 184 }
 185
 186 #endif