qcsrc/common/viewloc.qc

   1 #include "viewloc.qh"
   2 #include "util.qh"
   3
   4 #if defined(CSQC)
   5     #include <client/main.qh>
   6     #include "constants.qh"
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9         #include <common/weapons/_all.qh>
  10         #include <common/stats.qh>
  11 #endif
  12
  13 // client movement
  14 void viewloc_PlayerPhysics(entity this)
  15 {
  16         if(this.viewloc)
  17         {
  18                 if(this.viewloc.goalentity == this.viewloc.enemy)
  19                         return; // we can't side-scroll in this case
  20
  21                 vector old_movement = PHYS_CS(this).movement;
  22                 PHYS_CS(this).movement_x = old_movement_y;
  23                 if((this.viewloc.spawnflags & VIEWLOC_FREEMOVE) && !this.ladder_entity)
  24                         PHYS_CS(this).movement_y = old_movement_x;
  25                 else
  26                         PHYS_CS(this).movement_y = 0;
  27
  28                 vector level_start, level_end;
  29                 level_start = this.viewloc.enemy.origin;
  30                 level_end = this.viewloc.goalentity.origin;
  31                 vector forward = vectoangles(normalize(level_end - level_start));
  32                 vector backward = vectoangles(normalize(level_start - level_end));
  33
  34                 if((this.viewloc.spawnflags & VIEWLOC_FREEMOVE) && this.angles_y < 0 && !this.ladder_entity)
  35                         PHYS_CS(this).movement_y = -PHYS_CS(this).movement_y;
  36
  37                 if(this.viewloc.spawnflags & VIEWLOC_FREEAIM)
  38                 {
  39                         if(this.angles_y > 0)
  40                                 PHYS_CS(this).movement_x = -PHYS_CS(this).movement_x;
  41                 }
  42                 else
  43                 {
  44                         if(PHYS_CS(this).movement_x < 0)
  45                                 PHYS_CS(this).movement_x = -PHYS_CS(this).movement_x;
  46
  47                         if(PHYS_CS(this).movement_x < 0) // left
  48                                 this.angles_y = backward.y;
  49                         if(PHYS_CS(this).movement_x > 0) // right
  50                                 this.angles_y = forward.y;
  51                 }
  52         #if 0
  53                 //if(!PHYS_INPUT_BUTTON_CROUCH(this) && !IS_DUCKED(this))
  54                 if(!(this.viewloc.spawnflags & VIEWLOC_FREEMOVE))
  55                 {
  56 #ifdef SVQC
  57                         //PHYS_INPUT_BUTTON_CROUCH(this) = (old_movement_x < 0);
  58                         if (old_movement.x < 0)
  59                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
  60 #elif defined(CSQC)
  61                         if (old_movement.x < 0)
  62                         {
  63                                 input_buttons |= BIT(4);
  64                                 this.flags |= FL_DUCKED;
  65                         }
  66                         //else { input_buttons &= ~16; this.flags &= ~FL_DUCKED; }
  67 #endif
  68                 }
  69         #endif
  70         }
  71 }
  72
  73 #ifdef CSQC
  74
  75 void viewloc_SetTags(entity this)
  76 {
  77         if(this.viewloc && wasfreed(this.viewloc))
  78                 this.viewloc = NULL;
  79
  80         if(this.viewloc.entnum != this.tag_networkviewloc)
  81         {
  82                 if(this.tag_networkviewloc == 0)
  83                         this.viewloc = NULL;
  84                 else
  85                         this.viewloc = findfloat(NULL, entnum, this.tag_networkviewloc);
  86         }
  87 }
  88
  89 vector CursorToWorldCoord(vector mpos)
  90 {
  91         vector wnear = cs_unproject(vec2(mpos)); // determine the world coordinate for the mouse cursor upon the near clip plane
  92         vector wfar = cs_unproject(vec3(mpos.x, mpos.y, max_shot_distance)); // determine the world coordinate for the mouse cursor upon the far clip plane, with an outrageously large value as a workaround for dp.
  93         traceline(wnear, wfar, MOVE_NOMONSTERS, NULL);
  94         return trace_endpos;
  95 }
  96
  97 vector old_camera_angle = '0 0 0';
  98 void viewloc_SetViewLocation()
  99 {
 100         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 101         if (!view) return;
 102         entity viewloc_ent = view.viewloc;
 103         if(viewloc_ent && !wasfreed(viewloc_ent) && viewloc_ent.enemy && viewloc_ent.goalentity)
 104         {
 105                 bool have_sidescroll = (viewloc_ent.enemy != viewloc_ent.goalentity);
 106                 vector position_a = viewloc_ent.enemy.origin;
 107                 vector position_b = viewloc_ent.goalentity.origin;
 108                 vector camera_angle = '0 0 0';
 109                 vector camera_position;
 110
 111                 /*TODO: have the camera only move when a player moves too much from the center of the camera
 112                  * basically the player would move around in a small "box" in the center of the screen with out changing the camera position or angles */
 113                 camera_position = vec_bounds_in(view.origin, position_a, position_b);
 114
 115                 // use camera's angle when possible
 116                 if (!(viewloc_ent.spawnflags & VIEWLOC_CAM_NOANGLE)) {
 117                         camera_angle = viewloc_ent.enemy.movedir;
 118                 }
 119
 120                 // a tracking camera follows the player when it leaves the world box
 121                 if ((viewloc_ent.spawnflags & VIEWLOC_CAM_TRACK) || !have_sidescroll) {
 122                         camera_angle = aim_vec (camera_position, view.origin);
 123                 }
 124
 125                 // hard snap changes the angle as soon as it crosses over the nearest 90 degree mark
 126                 if (viewloc_ent.spawnflags & VIEWLOC_CAM_SNAP_HARD) {
 127                         camera_angle = angle_snap_vec(aim_vec(camera_position, view.origin), 90);
 128                 }
 129
 130                 // tries to avoid snapping unless it *really* needs to
 131                 if (viewloc_ent.spawnflags & VIEWLOC_CAM_SNAP_CLOSE) {
 132                         // like hard snap, but don't snap angles yet.
 133                         camera_angle = aim_vec(camera_position, view.origin);
 134
 135                         /* if the difference between the old and new angle is 60 degrees or more, switch angles.
 136                          * NOTE: bug/feature: this will use non-snaped angles for one frame.
 137                          * doing this results in less code, faster code, and a smoother transisition between angles.
 138                          */
 139                         float camera_angle_diff = max(camera_angle.y, old_camera_angle.y) - min(camera_angle.y, old_camera_angle.y);
 140
 141                         if (60 <= camera_angle_diff) { // use new angles
 142                                 old_camera_angle.y = angle_snap_f(camera_angle.y, 90);
 143                         } else { // use old angles
 144                                 camera_angle.y = old_camera_angle.y;
 145                         }
 146                 }
 147
 148                 //unlocking this allows the camera to look up and down. this also allows a top-down view.
 149                 if (!(viewloc_ent.spawnflags & VIEWLOC_CAM_SNAP_UNLOCK)) {
 150                         camera_angle.x = 0;
 151                         camera_angle.z = 0;
 152                 }
 153
 154 #if 0
 155                 LOG_TRACE(vtos(camera_position));
 156                 LOG_TRACE(vtos(old_camera_angle));
 157                 LOG_TRACE(vtos(camera_angle));
 158 #endif
 159
 160                 freeze_org = getpropertyvec(VF_ORIGIN);
 161                 freeze_ang = getpropertyvec(VF_ANGLES);
 162                 setproperty(VF_ORIGIN, camera_position);
 163                 setproperty(VF_ANGLES, camera_angle);
 164
 165                 if(spectatee_status)
 166                         return; // if spectating, don't replace angles or inputs!
 167
 168                 if (have_sidescroll) {
 169                         vector view_angle = view.angles;
 170                         if (!(viewloc_ent.spawnflags & VIEWLOC_FREEAIM)) {
 171                                 vector avatar_facing_dir;
 172                                 // get the player's forward-facing direction, based on positions a and b
 173                                 if (0 == input_movevalues.y) {
 174                                         avatar_facing_dir = view_angle; // default to the previous values
 175                                 } else if (0 > input_movevalues.y) { // left is forward
 176                                         avatar_facing_dir = vectoangles(normalize(vec_to_max(position_b, position_a) - vec_to_min(position_b, position_a)));
 177                                 } else { // right is forward
 178                                         avatar_facing_dir = vectoangles(normalize(vec_to_min(position_b, position_a) - vec_to_max(position_b, position_a)));
 179                                 }
 180                                 view_angle.y = avatar_facing_dir.y; // snap avatar to look on along the correct axis
 181
 182                                 // if (0 == input_movevalues.x) look straight ahead
 183                                 if (!(viewloc_ent.spawnflags & VIEWLOC_FREEMOVE)) {
 184                                         if (0 > input_movevalues.x) { // look up
 185                                                 view_angle.x = 50;
 186                                         } else if (0 < input_movevalues.x) { // look down
 187                                                 view_angle.x = -50;
 188                                         }
 189                                 }
 190                         } else {
 191                                 vector mpos = CursorToWorldCoord(viewloc_mousepos);
 192                                 mpos.x = view.origin.x; // replace the cursor's x position with the player's
 193                                 view_angle = aim_vec(view.origin + view.view_ofs, mpos); // get new angles
 194                         }
 195                         view.angles_y = view_angle.y;
 196                         setproperty(VF_CL_VIEWANGLES, view_angle);
 197                 }
 198         }
 199 }
 200
 201 STATIC_INIT_LATE(viewloc_cursor)
 202 {
 203         // fix the mouse position on init so it isn't in the corner
 204         viewloc_mousepos = '0.5 0 0' * autocvar_vid_conwidth + '0 0.5 0' * autocvar_vid_conheight;
 205 }
 206
 207 #endif