Don't perform trueaim tracing on the client side when drawing muzzle flashes, accurat...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / all.qc
1 #include "all.qh"
2 #ifndef WEAPONS_ALL_C
3 #define WEAPONS_ALL_C
4
5 #if defined(CSQC)
6         #include <client/defs.qh>
7         #include "../constants.qh"
8         #include "../stats.qh"
9         #include <lib/warpzone/anglestransform.qh>
10         #include <lib/warpzone/common.qh>
11         #include <lib/warpzone/client.qh>
12         #include "../util.qh"
13         #include <client/autocvars.qh>
14         #include "../deathtypes/all.qh"
15         #include <lib/csqcmodel/interpolate.qh>
16         #include "../physics/movetypes/movetypes.qh"
17         #include <client/main.qh>
18         #include <lib/csqcmodel/cl_model.qh>
19 #elif defined(MENUQC)
20 #elif defined(SVQC)
21         #include <common/items/_mod.qh>
22     #include <lib/warpzone/anglestransform.qh>
23     #include <lib/warpzone/common.qh>
24     #include <lib/warpzone/util_server.qh>
25     #include <lib/warpzone/server.qh>
26     #include "../constants.qh"
27     #include "../stats.qh"
28     #include "../teams.qh"
29     #include <common/util.qh>
30     #include "../monsters/_mod.qh"
31     #include "config.qh"
32     #include <server/weapons/csqcprojectile.qh>
33     #include <server/weapons/tracing.qh>
34     #include "../t_items.qh"
35     #include <server/autocvars.qh>
36     #include <server/constants.qh>
37     #include <server/defs.qh>
38     #include "../notifications/all.qh"
39     #include "../deathtypes/all.qh"
40     #include <server/mutators/_mod.qh>
41     #include "../mapinfo.qh"
42     #include <server/command/_mod.qh>
43     #include <lib/csqcmodel/sv_model.qh>
44     #include <server/portals.qh>
45     #include <server/g_hook.qh>
46 #endif
47 #ifdef GAMEQC
48         #include "calculations.qc"
49 #endif
50 #ifdef SVQC
51         #include "config.qc"
52 #endif
53
54 #include "weapon/_mod.inc"
55
56
57 // WEAPON PLUGIN SYSTEM
58
59 WepSet _WepSet_FromWeapon(int a)
60 {
61         a -= WEP_FIRST;
62         if (REGISTRY_MAX(Weapons) > 24)
63                 if (a >= 24)
64                 {
65                         a -= 24;
66                         if (REGISTRY_MAX(Weapons) > 48)
67                                 if (a >= 24)
68                                 {
69                                         a -= 24;
70                                         return '0 0 1' * (2 ** a);
71                                 }
72                         return '0 1 0' * (2 ** a);
73                 }
74         return '1 0 0' * (2 ** a);
75 }
76 #ifdef SVQC
77         void WriteWepSet(float dst, WepSet w)
78         {
79                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
80                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
81                 else WriteInt24_t(dst, w.x);
82         }
83 #endif
84 #ifdef CSQC
85         WepSet WepSet_GetFromStat()
86         {
87                 return STAT(WEAPONS);
88         }
89         WepSet WepSet_GetFromStat_InMap()
90         {
91                 return STAT(WEAPONSINMAP);
92         }
93         WepSet ReadWepSet()
94         {
95                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
96                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
97                 return ReadInt24_t() * '1 0 0';
98         }
99 #endif
100
101 string W_FixWeaponOrder(string order, float complete)
102 {
103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
104 }
105 string W_NameWeaponOrder_MapFunc(string s)
106 {
107         int i = stof(s);
108         if (s == "0" || i)
109         {
110                 entity wi = REGISTRY_GET(Weapons, i);
111                 if (wi != WEP_Null) return wi.netname;
112         }
113         return s;
114 }
115
116 string W_UndeprecateName(string s)
117 {
118         switch (s)
119         {
120                 case "nex": return "vortex";
121                 case "rocketlauncher": return "devastator";
122                 case "laser": return "blaster";
123                 case "minstanex": return "vaporizer";
124                 case "grenadelauncher": return "mortar";
125                 case "uzi": return "machinegun";
126                 case "hmg": return "okhmg";
127                 case "rpc": return "okrpc";
128                 default: return s;
129         }
130 }
131 string W_NameWeaponOrder(string order)
132 {
133         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
134 }
135 string W_NumberWeaponOrder_MapFunc(string s)
136 {
137         if (s == "0" || stof(s)) return s;
138         s = W_UndeprecateName(s);
139         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
140         return s;
141 }
142 string W_NumberWeaponOrder(string order)
143 {
144         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
145 }
146
147 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
148 string W_FixWeaponOrder_BuildImpulseList_order;
149 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
150 {
151         float h;
152         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
153         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
154         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
155 }
156 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
157 {
158         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
159         Weapon e1 = REGISTRY_GET(Weapons, si);
160         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
161         Weapon e2 = REGISTRY_GET(Weapons, sj);
162         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
163         if (d != 0) return -d;  // high impulse first!
164         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
165                 sprintf(" %d ", si), 0)
166                -
167                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
168                 sprintf(" %d ", sj), 0)
169         ;  // low char index first!
170 }
171 string W_FixWeaponOrder_BuildImpulseList(string o)
172 {
173         int i;
174         W_FixWeaponOrder_BuildImpulseList_order = o;
175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
176                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
177         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
178                 NULL);
179         o = "";
180         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
181                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
182         W_FixWeaponOrder_BuildImpulseList_order = string_null;
183         return substring(o, 1, -1);
184 }
185
186 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
187 {
188         return W_FixWeaponOrder(order, 0);
189 }
190
191 string W_FixWeaponOrder_ForceComplete(string order)
192 {
193         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
194         return W_FixWeaponOrder(order, 1);
195 }
196
197 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
198 {
199         WepSet result = '0 0 0';
200         for (int j = 0; j < n; ++j)
201         {
202                 RandomSelection_Init();
203                 FOREACH(Weapons, it != WEP_Null, {
204                         if (remaining & (it.m_wepset))
205                                 RandomSelection_AddEnt(it, 1, 1);
206                 });
207                 Weapon w = RandomSelection_chosen_ent;
208                 result |= WepSet_FromWeapon(w);
209                 remaining &= ~WepSet_FromWeapon(w);
210         }
211         return result;
212 }
213
214 string GetAmmoPicture(int ammotype)
215 {
216         switch (ammotype)
217         {
218                 case RES_SHELLS:  return ITEM_Shells.m_icon;
219                 case RES_BULLETS: return ITEM_Bullets.m_icon;
220                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
221                 case RES_CELLS:   return ITEM_Cells.m_icon;
222                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
223                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
224                 default: return "";  // wtf, no ammo type?
225         }
226 }
227
228 string GetAmmoName(int ammotype)
229 {
230         switch (ammotype)
231         {
232                 case RES_SHELLS:  return ITEM_Shells.m_name;
233                 case RES_BULLETS: return ITEM_Bullets.m_name;
234                 case RES_ROCKETS: return ITEM_Rockets.m_name;
235                 case RES_CELLS:   return ITEM_Cells.m_name;
236                 case RES_PLASMA:  return ITEM_Plasma.m_name;
237                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
238                 default:          return "batteries";
239         }
240 }
241
242 #ifdef CSQC
243 int GetAmmoTypeFromNum(int i)
244 {
245         switch (i)
246         {
247                 case 0: return RES_SHELLS;
248                 case 1: return RES_BULLETS;
249                 case 2: return RES_ROCKETS;
250                 case 3: return RES_CELLS;
251                 case 4: return RES_PLASMA;
252                 case 5: return RES_FUEL;
253                 default: return RES_NONE;
254         }
255 }
256
257 int GetAmmoStat(int ammotype)
258 {
259         switch (ammotype)
260         {
261                 case RES_SHELLS: return STAT_SHELLS;
262                 case RES_BULLETS: return STAT_NAILS;
263                 case RES_ROCKETS: return STAT_ROCKETS;
264                 case RES_CELLS: return STAT_CELLS;
265                 case RES_PLASMA: return STAT_PLASMA.m_id;
266                 case RES_FUEL: return STAT_FUEL.m_id;
267                 default: return -1;
268         }
269 }
270 #endif
271
272 string W_Sound(string w_snd)
273 {
274         string output = strcat("weapons/", w_snd);
275         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
276         return M_ARGV(1, string);
277 }
278
279 string W_Model(string w_mdl)
280 {
281         string output = strcat("models/weapons/", w_mdl);
282         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
283         return M_ARGV(1, string);
284 }
285
286 #ifdef GAMEQC
287 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
288 {
289         switch (algn)
290         {
291                 default:
292                 case 3:
293                         // right alignment
294                         break;
295                 case 4:
296                         // left
297                         vecs.y = -vecs.y;
298                         break;
299                 case 1:
300                 case 2:
301                         // center
302                         vecs.y = 0;
303                         vecs.z -= 2;
304                         break;
305         }
306         return vecs;
307 }
308
309 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
310 {
311         string s;
312         if (visual)
313         {
314                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
315         }
316         else if (STAT(SHOOTFROMEYE))
317         {
318                 vecs.y = vecs.z = 0;
319         }
320         else if (STAT(SHOOTFROMCENTER))
321         {
322                 vecs.y = 0;
323                 vecs.z -= 2;
324         }
325         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
326         {
327                 vector v = stov(s);
328                 if (y_is_right) v.y = -v.y;
329                 if (v.x != 0) vecs.x = v.x;
330                 vecs.y = v.y;
331                 vecs.z = v.z;
332         }
333         else  // just do the same as top
334         {
335                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
336         }
337
338         return vecs;
339 }
340
341 #define shotorg_adjust shotorg_adjust_values
342
343 /**
344  * supported formats:
345  *
346  * 1. simple animated model, muzzle flash handling on h_ model:
347  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
348  *      tags:
349  *        shot = muzzle end (shot origin, also used for muzzle flashes)
350  *        shell = casings ejection point (must be on the right hand side of the gun)
351  *        weapon = attachment for v_tuba.md3
352  *    v_tuba.md3 - first and third person model
353  *    g_tuba.md3 - pickup model
354  *
355  * 2. simple animated model, muzzle flash handling on v_ model:
356  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
357  *      tags:
358  *        weapon = attachment for v_tuba.md3
359  *    v_tuba.md3 - first and third person model
360  *      tags:
361  *        shot = muzzle end (shot origin, also used for muzzle flashes)
362  *        shell = casings ejection point (must be on the right hand side of the gun)
363  *    g_tuba.md3 - pickup model
364  *
365  * 3. fully animated model, muzzle flash handling on h_ model:
366  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
367  *      tags:
368  *        shot = muzzle end (shot origin, also used for muzzle flashes)
369  *        shell = casings ejection point (must be on the right hand side of the gun)
370  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
371  *    v_tuba.md3 - third person model
372  *    g_tuba.md3 - pickup model
373  *
374  * 4. fully animated model, muzzle flash handling on v_ model:
375  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
376  *      tags:
377  *        shot = muzzle end (shot origin)
378  *        shell = casings ejection point (must be on the right hand side of the gun)
379  *    v_tuba.md3 - third person model
380  *      tags:
381  *        shot = muzzle end (for muzzle flashes)
382  *    g_tuba.md3 - pickup model
383  *
384  * writes:
385  *   this.origin, this.angles
386  *   this.weaponchild
387  *   this.movedir, this.view_ofs, this.movedir_aligned
388  *   attachment stuff
389  *   anim stuff
390  * to free:
391  *   call again with ""
392  *   remove the ent
393  */
394 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
395 {
396         if (name == "")
397         {
398                 vector oldmin = this.mins, oldmax = this.maxs;
399                 setmodel(this, MDL_Null);
400                 setsize(this, oldmin, oldmax);
401                 if (this.weaponchild) delete(this.weaponchild);
402                 this.weaponchild = NULL;
403                 this.movedir = '0 0 0';
404                 this.spawnorigin = '0 0 0';
405                 this.oldorigin = '0 0 0';
406                 this.anim_fire1  = '0 1 0.01';
407                 this.anim_fire2  = '0 1 0.01';
408                 this.anim_idle   = '0 1 0.01';
409                 this.anim_reload = '0 1 0.01';
410         }
411         else
412         {
413                 // if there is a child entity, hide it until we're sure we use it
414                 if (this.weaponchild) this.weaponchild.model = "";
415                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
416                 int v_shot_idx;  // used later
417                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
418
419                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
420                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
421                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
422                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
423                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
424                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
425
426                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
427                 // if we don't, this is a "real" animated model
428                 string t;
429                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
430                 {
431                         if (!this.weaponchild)
432                         {
433                                 this.weaponchild = new(weaponchild);
434 #ifdef CSQC
435                                 this.weaponchild.drawmask = MASK_NORMAL;
436                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
437 #endif
438                         }
439                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
440                         setsize(this.weaponchild, '0 0 0', '0 0 0');
441                         setattachment(this.weaponchild, this, t);
442                 }
443                 else
444                 {
445                         if (this.weaponchild) delete(this.weaponchild);
446                         this.weaponchild = NULL;
447                 }
448
449                 setsize(this, '0 0 0', '0 0 0');
450                 setorigin(this, '0 0 0');
451                 this.angles = '0 0 0';
452                 this.frame = 0;
453 #ifdef SVQC
454                 this.viewmodelforclient = NULL;
455 #else
456                 this.renderflags &= ~RF_VIEWMODEL;
457 #endif
458                 if (v_shot_idx)  // v_ model attached to invisible h_ model
459                 {
460                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
461                 }
462                 else
463                 {
464                         int idx;
465                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
466                         {
467                                 this.movedir = gettaginfo(this, idx);
468                         }
469                         else
470                         {
471                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
472                                         this.model);
473                                 this.movedir = '0 0 0';
474                         }
475                 }
476                 {
477                         int idx = 0;
478                         // v_ model attached to invisible h_ model
479                         if (this.weaponchild
480                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
481                         {
482                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
483                         }
484                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
485                         {
486                                 this.spawnorigin = gettaginfo(this, idx);
487                         }
488                         else
489                         {
490                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
491                                         this.model);
492                                 this.spawnorigin = this.movedir;
493                         }
494                 }
495                 if (v_shot_idx)
496                 {
497                         this.oldorigin = '0 0 0';  // use regular attachment
498                 }
499                 else
500                 {
501                         int idx;
502                         if (this.weaponchild)
503                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
504                         else
505                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
506                         if (idx)
507                         {
508                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
509                         }
510                         else
511                         {
512                                 LOG_WARNF(
513                                         "weapon model %s does not support the 'handle' tag "
514                                         "and neither does the v_ model support the 'shot' tag, "
515                                         "will display muzzle flashes TOTALLY wrong\n",
516                                         this.model);
517                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
518                         }
519                 }
520
521 #ifdef SVQC
522                 this.viewmodelforclient = this.owner;
523 #else
524                 this.renderflags |= RF_VIEWMODEL;
525 #endif
526         }
527
528         this.view_ofs = '0 0 0';
529         this.movedir_aligned = this.movedir;
530
531         if (this.movedir.x >= 0)
532         {
533                 //int algn = STAT(GUNALIGN, this.owner);
534                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
535         #ifdef SVQC
536                 this.m_gunalign = algn;
537         #endif
538                 vector v = this.movedir;
539                 this.movedir = shotorg_adjust(v, false, false, algn);
540                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
541                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
542         }
543         int compressed_shotorg = compressShotOrigin(this.movedir);
544         // make them match perfectly
545 #ifdef SVQC
546     // null during init
547     if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
548         this.movedir = decompressShotOrigin(compressed_shotorg);
549 #else
550         this.movedir = decompressShotOrigin(compressed_shotorg);
551 #endif
552
553         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
554
555         // check if an instant weapon switch occurred
556         setorigin(this, this.view_ofs);
557         if (!_anim) return;
558         // reset animstate now
559         this.wframe = WFRAME_IDLE;
560         setanim(this, this.anim_idle, true, false, true);
561 }
562 #endif
563
564 #ifdef GAMEQC
565
566 REGISTER_NET_TEMP(wframe)
567 #ifdef CSQC
568 NET_HANDLE(wframe, bool isNew)
569 {
570         int fr = ReadByte();
571         float t = ReadFloat();
572     int slot = ReadByte();
573         bool restartanim = ReadByte();
574         entity wepent = viewmodels[slot];
575         if(fr == WFRAME_IDLE)
576                 wepent.animstate_looping = false; // we don't need to enforce idle animation
577         else
578         {
579                 vector a = '0 0 0';
580                 switch(fr)
581                 {
582                         default:
583                         case WFRAME_IDLE: a = wepent.anim_idle; break;
584                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
585                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
586                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
587                 }
588                 a.z *= t;
589                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
590         }
591         wepent.state = ReadByte();
592         wepent.weapon_nextthink = ReadFloat();
593         switch (wepent.state)
594         {
595                 case WS_RAISE:
596                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
597                         break;
598                 case WS_DROP:
599                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
600                         break;
601         default:
602             wepent.weapon_switchdelay = 0;
603             break;
604         }
605         return true;
606 }
607 #endif
608
609 #ifdef SVQC
610 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
611 {
612         if (!IS_REAL_CLIENT(actor)) return;
613         int channel = MSG_ONE;
614         msg_entity = actor;
615         WriteHeader(channel, wframe);
616         WriteByte(channel, wepframe);
617         WriteFloat(channel, attackrate);
618         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
619         WriteByte(channel, restartanim);
620         WriteByte(channel, weaponentity.state);
621         WriteFloat(channel, weaponentity.weapon_nextthink);
622 }
623 #endif
624
625 REGISTER_NET_C2S(w_whereis)
626 #ifdef SVQC
627 void Weapon_whereis(Weapon this, entity cl);
628 NET_HANDLE(w_whereis, bool)
629 {
630         Weapon wpn = ReadRegistered(Weapons);
631         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
632         return true;
633 }
634 #else
635 void w_whereis(Weapon this)
636 {
637         int channel = MSG_C2S;
638         WriteHeader(channel, w_whereis);
639         WriteRegistered(Weapons, channel, this);
640 }
641 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
642 {
643         switch (request)
644         {
645                 case CMD_REQUEST_COMMAND:
646                 {
647                         string s = argv(1);
648                         if (s == "all")
649                         {
650                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
651                                 return;
652                         }
653                         if (s == "unowned")
654                         {
655                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
656                                 return;
657                         }
658                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
659                         {
660                                 w_whereis(it);
661                                 return;
662                         });
663                 }
664                 default:
665                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
666                 case CMD_REQUEST_USAGE:
667                 {
668                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
669                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
670                         return;
671                 }
672         }
673 }
674 #endif
675
676 #ifdef SVQC
677 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
678 {
679         flash.owner = actor;
680         flash.angles_z = random() * 360;
681
682         entity view = actor.(weaponentity);
683         entity exterior = actor.exteriorweaponentity;
684
685         if (view.oldorigin.x > 0)
686         {
687                 setattachment(flash, exterior, "");
688                 setorigin(flash, view.oldorigin + offset);
689         }
690         else
691         {
692                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
693                 else setattachment(flash, exterior, "tag_shot");
694                 setorigin(flash, offset);
695         }
696 }
697 #elif defined(CSQC)
698 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
699 {
700         flash.owner = wepent;
701         flash.angles_z = random() * 360;
702
703         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
704         else setattachment(flash, wepent, "tag_shot");
705         setorigin(flash, offset);
706 }
707 #endif
708
709 void W_MuzzleFlash_Model_Think(entity this)
710 {
711         this.frame += 2;
712         this.scale *= 0.5;
713         this.alpha -= 0.25;
714         this.nextthink = time + 0.05;
715
716         if(this.alpha <= 0)
717         {
718                 setthink(this, SUB_Remove);
719                 this.nextthink = time;
720                 this.realowner.muzzle_flash = NULL;
721                 return;
722         }
723 }
724
725 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
726 {
727         if(wepent.muzzle_flash == NULL)
728                 wepent.muzzle_flash = spawn();
729
730         entity flash = wepent.muzzle_flash;
731         setmodel(flash, muzzlemodel); // precision set below
732
733         flash.scale = 0.75;
734         setthink(flash, W_MuzzleFlash_Model_Think);
735         flash.nextthink = time + 0.02;
736         flash.frame = 2;
737         flash.alpha = 0.75;
738         flash.angles_z = random() * 180;
739         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
740         flash.owner = flash.realowner = wepent;
741
742 #ifdef CSQC
743         flash.drawmask = MASK_NORMAL;
744 #endif
745 }
746
747 REGISTER_NET_TEMP(w_muzzleflash)
748
749 #ifdef SVQC
750 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
751 {
752         // don't show an exterior muzzle effect for the off-hand
753         if(weaponslot(weaponentity) == 0)
754         {
755                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
756
757                 if(thiswep.m_muzzlemodel != MDL_Null)
758                 {
759                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
760                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
761                 }
762         }
763
764         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
765         {
766                 if(!IS_REAL_CLIENT(it))
767                         continue;
768                 int channel = MSG_ONE;
769                 msg_entity = it;
770                 WriteHeader(channel, w_muzzleflash);
771                 WriteByte(channel, thiswep.m_id);
772                 WriteByte(channel, weaponslot(weaponentity));
773                 WriteVector(channel, shotorg);
774         });
775 }
776 #elif defined(CSQC)
777 NET_HANDLE(w_muzzleflash, bool isNew)
778 {
779         return = true;
780         int weapon_id = ReadByte();
781     int slot = ReadByte();
782     vector sv_shotorg = ReadVector();
783
784         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
785     vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
786         vector forward, right, up;
787         MAKE_VECTORS(viewangles, forward, right, up);
788
789         if(autocvar_chase_active)
790         {
791                 // in third person mode, show the muzzle flash from the server side weapon position
792                 // we don't have a view model to reference in this case
793                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
794                 return;
795         }
796     if(!autocvar_r_drawviewmodel) return;
797
798         entity wepent = viewmodels[slot];
799         // get the local player entity to calculate shot origin
800         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
801         if(!rlplayer)
802                 rlplayer = csqcplayer; // fall back to the global
803
804         vector md = wepent.movedir_aligned;
805         vector vecs = ((md.x > 0) ? md : '0 0 0');
806         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
807         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
808
809         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
810
811         if(thiswep.m_muzzlemodel != MDL_Null)
812         {
813                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
814                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
815         }
816 }
817 #endif
818
819
820 #endif
821
822 #endif