qcsrc/common/weapons/all.qc

   1 #ifndef WEAPONS_ALL_C
   2 #define WEAPONS_ALL_C
   3
   4 #include "all.qh"
   5
   6 #if defined(CSQC)
   7         #include "../../client/defs.qh"
   8         #include "../constants.qh"
   9         #include "../stats.qh"
  10         #include "../../lib/warpzone/anglestransform.qh"
  11         #include "../../lib/warpzone/common.qh"
  12         #include "../../lib/warpzone/client.qh"
  13         #include "../util.qh"
  14         #include "../../client/autocvars.qh"
  15         #include "../deathtypes/all.qh"
  16         #include "../../lib/csqcmodel/interpolate.qh"
  17         #include "../physics/movetypes/movetypes.qh"
  18         #include "../../client/main.qh"
  19         #include "../../lib/csqcmodel/cl_model.qh"
  20 #elif defined(MENUQC)
  21 #elif defined(SVQC)
  22     #include "../../lib/warpzone/anglestransform.qh"
  23     #include "../../lib/warpzone/common.qh"
  24     #include "../../lib/warpzone/util_server.qh"
  25     #include "../../lib/warpzone/server.qh"
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include "../util.qh"
  30     #include "../monsters/all.qh"
  31     #include "config.qh"
  32     #include "../../server/weapons/csqcprojectile.qh"
  33     #include "../../server/weapons/tracing.qh"
  34     #include "../../server/t_items.qh"
  35     #include "../../server/autocvars.qh"
  36     #include "../../server/constants.qh"
  37     #include "../../server/defs.qh"
  38     #include "../notifications.qh"
  39     #include "../deathtypes/all.qh"
  40     #include "../../server/mutators/all.qh"
  41     #include "../mapinfo.qh"
  42     #include "../../server/command/common.qh"
  43     #include "../../lib/csqcmodel/sv_model.qh"
  44     #include "../../server/portals.qh"
  45     #include "../../server/g_hook.qh"
  46 #endif
  47 #ifndef MENUQC
  48         #include "calculations.qc"
  49 #endif
  50 #ifdef SVQC
  51         #include "config.qc"
  52 #endif
  53 #define IMPLEMENTATION
  54 #include "all.inc"
  55 #undef IMPLEMENTATION
  56
  57 // WEAPON PLUGIN SYSTEM
  58
  59 WepSet _WepSet_FromWeapon(int a)
  60 {
  61         a -= WEP_FIRST;
  62         if (Weapons_MAX > 24)
  63                 if (a >= 24)
  64                 {
  65                         a -= 24;
  66                         if (Weapons_MAX > 48)
  67                                 if (a >= 24)
  68                                 {
  69                                         a -= 24;
  70                                         return '0 0 1' * power2of(a);
  71                                 }
  72                         return '0 1 0' * power2of(a);
  73                 }
  74         return '1 0 0' * power2of(a);
  75 }
  76 #ifdef SVQC
  77         void WriteWepSet(float dst, WepSet w)
  78         {
  79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  81                 else WriteInt24_t(dst, w.x);
  82         }
  83 #endif
  84 #ifdef CSQC
  85         WepSet WepSet_GetFromStat()
  86         {
  87                 return STAT(WEAPONS);
  88         }
  89         WepSet WepSet_GetFromStat_InMap()
  90         {
  91                 return STAT(WEAPONSINMAP);
  92         }
  93         WepSet ReadWepSet()
  94         {
  95                 if (Weapons_MAX > 48) return ReadInt72_t();
  96                 if (Weapons_MAX > 24) return ReadInt48_t();
  97                 return ReadInt24_t() * '1 0 0';
  98         }
  99 #endif
 100
 101 string W_FixWeaponOrder(string order, float complete)
 102 {
 103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 104 }
 105 string W_NameWeaponOrder_MapFunc(string s)
 106 {
 107         int i = stof(s);
 108         if (s == "0" || i)
 109         {
 110                 entity wi = Weapons_from(i);
 111                 if (wi != WEP_Null) return wi.netname;
 112         }
 113         return s;
 114 }
 115
 116 string W_UndeprecateName(string s)
 117 {
 118         switch (s)
 119         {
 120                 case "nex": return "vortex";
 121                 case "rocketlauncher": return "devastator";
 122                 case "laser": return "blaster";
 123                 case "minstanex": return "vaporizer";
 124                 case "grenadelauncher": return "mortar";
 125                 case "uzi": return "machinegun";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, LAMBDA(return ftos(i)));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = Weapons_from(si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = Weapons_from(sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", si), 0)
 164                -
 165                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 166                 sprintf(" %d ", sj), 0)
 167         ;  // low char index first!
 168 }
 169 string W_FixWeaponOrder_BuildImpulseList(string o)
 170 {
 171         int i;
 172         W_FixWeaponOrder_BuildImpulseList_order = o;
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 175         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 176                 world);
 177         o = "";
 178         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 179                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 180         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 181         return substring(o, 1, -1);
 182 }
 183
 184 string W_FixWeaponOrder_AllowIncomplete(string order)
 185 {
 186         return W_FixWeaponOrder(order, 0);
 187 }
 188
 189 string W_FixWeaponOrder_ForceComplete(string order)
 190 {
 191         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 192         return W_FixWeaponOrder(order, 1);
 193 }
 194
 195 void W_RandomWeapons(entity e, float n)
 196 {
 197         int i, j;
 198         WepSet remaining;
 199         WepSet result;
 200         remaining = e.weapons;
 201         result = '0 0 0';
 202         for (i = 0; i < n; ++i)
 203         {
 204                 RandomSelection_Init();
 205                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 206                         if (remaining & WepSet_FromWeapon(Weapons_from(j))) RandomSelection_Add(NULL, j, string_null, 1, 1);
 207                 Weapon w = Weapons_from(RandomSelection_chosen_float);
 208                 result |= WepSet_FromWeapon(w);
 209                 remaining &= ~WepSet_FromWeapon(w);
 210         }
 211         e.weapons = result;
 212 }
 213
 214 string GetAmmoPicture(.int ammotype)
 215 {
 216         switch (ammotype)
 217         {
 218                 case ammo_shells:  return ITEM_Shells.m_icon;
 219                 case ammo_nails:   return ITEM_Bullets.m_icon;
 220                 case ammo_rockets: return ITEM_Rockets.m_icon;
 221                 case ammo_cells:   return ITEM_Cells.m_icon;
 222                 case ammo_plasma:  return ITEM_Plasma.m_icon;
 223                 case ammo_fuel:    return ITEM_JetpackFuel.m_icon;
 224                 default: return "";  // wtf, no ammo type?
 225         }
 226 }
 227
 228 #ifdef CSQC
 229         .int GetAmmoFieldFromNum(int i)
 230         {
 231                 switch (i)
 232                 {
 233                         case 0: return ammo_shells;
 234                         case 1: return ammo_nails;
 235                         case 2: return ammo_rockets;
 236                         case 3: return ammo_cells;
 237                         case 4: return ammo_plasma;
 238                         case 5: return ammo_fuel;
 239                         default: return ammo_none;
 240                 }
 241         }
 242
 243         int GetAmmoStat(.int ammotype)
 244         {
 245                 switch (ammotype)
 246                 {
 247                         case ammo_shells: return STAT_SHELLS;
 248                         case ammo_nails: return STAT_NAILS;
 249                         case ammo_rockets: return STAT_ROCKETS;
 250                         case ammo_cells: return STAT_CELLS;
 251                         case ammo_plasma: return STAT_PLASMA.m_id;
 252                         case ammo_fuel: return STAT_FUEL.m_id;
 253                         default: return -1;
 254                 }
 255         }
 256 #endif
 257
 258 string W_Sound(string w_snd)
 259 {
 260         string output = strcat("weapons/", w_snd);
 261 #ifdef SVQC
 262                 MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 263                 return weapon_sound_output;
 264 #else
 265                 return output;
 266 #endif
 267 }
 268
 269 string W_Model(string w_mdl)
 270 {
 271         string output = strcat("models/weapons/", w_mdl);
 272         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 273         return weapon_model_output;
 274 }
 275
 276 #ifndef MENUQC
 277 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 278 {
 279         switch (algn)
 280         {
 281                 default:
 282                 case 3:
 283                         // right alignment
 284                         break;
 285                 case 4:
 286                         // left
 287                         vecs.y = -vecs.y;
 288                         break;
 289                 case 1:
 290                 case 2:
 291                         // center
 292                         vecs.y = 0;
 293                         vecs.z -= 2;
 294                         break;
 295         }
 296         return vecs;
 297 }
 298
 299 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 300 {
 301 #ifdef SVQC
 302         string s;
 303 #endif
 304         if (visual)
 305         {
 306                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 307         }
 308 #ifdef SVQC
 309         else if (autocvar_g_shootfromeye)
 310         {
 311                 vecs.y = vecs.z = 0;
 312         }
 313         else if (autocvar_g_shootfromcenter)
 314         {
 315                 vecs.y = 0;
 316                 vecs.z -= 2;
 317         }
 318         else if ((s = autocvar_g_shootfromfixedorigin) != "")
 319         {
 320                 vector v = stov(s);
 321                 if (y_is_right) v.y = -v.y;
 322                 if (v.x != 0) vecs.x = v.x;
 323                 vecs.y = v.y;
 324                 vecs.z = v.z;
 325         }
 326 #endif
 327         else  // just do the same as top
 328         {
 329                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 330         }
 331
 332         return vecs;
 333 }
 334
 335 #define shotorg_adjust shotorg_adjust_values
 336
 337 /**
 338  * supported formats:
 339  *
 340  * 1. simple animated model, muzzle flash handling on h_ model:
 341  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 342  *      tags:
 343  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 344  *        shell = casings ejection point (must be on the right hand side of the gun)
 345  *        weapon = attachment for v_tuba.md3
 346  *    v_tuba.md3 - first and third person model
 347  *    g_tuba.md3 - pickup model
 348  *
 349  * 2. simple animated model, muzzle flash handling on v_ model:
 350  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 351  *      tags:
 352  *        weapon = attachment for v_tuba.md3
 353  *    v_tuba.md3 - first and third person model
 354  *      tags:
 355  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 356  *        shell = casings ejection point (must be on the right hand side of the gun)
 357  *    g_tuba.md3 - pickup model
 358  *
 359  * 3. fully animated model, muzzle flash handling on h_ model:
 360  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 361  *      tags:
 362  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 363  *        shell = casings ejection point (must be on the right hand side of the gun)
 364  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 365  *    v_tuba.md3 - third person model
 366  *    g_tuba.md3 - pickup model
 367  *
 368  * 4. fully animated model, muzzle flash handling on v_ model:
 369  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 370  *      tags:
 371  *        shot = muzzle end (shot origin)
 372  *        shell = casings ejection point (must be on the right hand side of the gun)
 373  *    v_tuba.md3 - third person model
 374  *      tags:
 375  *        shot = muzzle end (for muzzle flashes)
 376  *    g_tuba.md3 - pickup model
 377  *
 378  * writes:
 379  *   this.origin, this.angles
 380  *   this.weaponchild
 381  *   this.movedir, this.view_ofs
 382  *   attachment stuff
 383  *   anim stuff
 384  * to free:
 385  *   call again with ""
 386  *   remove the ent
 387  */
 388 void CL_WeaponEntity_SetModel(entity this, string name)
 389 {
 390         if (name == "")
 391         {
 392                 this.model = "";
 393                 if (this.weaponchild) remove(this.weaponchild);
 394                 this.weaponchild = NULL;
 395                 this.movedir = '0 0 0';
 396                 this.spawnorigin = '0 0 0';
 397                 this.oldorigin = '0 0 0';
 398                 this.anim_fire1  = '0 1 0.01';
 399                 this.anim_fire2  = '0 1 0.01';
 400                 this.anim_idle   = '0 1 0.01';
 401                 this.anim_reload = '0 1 0.01';
 402         }
 403         else
 404         {
 405                 // if there is a child entity, hide it until we're sure we use it
 406                 if (this.weaponchild) this.weaponchild.model = "";
 407                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 408                 int v_shot_idx;  // used later
 409                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 410
 411                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 412                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 413                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 414                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 415                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 416                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 417
 418                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 419                 // if we don't, this is a "real" animated model
 420                 string t;
 421                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 422                 {
 423                         if (!this.weaponchild)
 424                         {
 425                                 this.weaponchild = new(weaponchild);
 426                                 make_pure(this.weaponchild);
 427 #ifdef CSQC
 428                                 this.weaponchild.drawmask = MASK_NORMAL;
 429                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 430 #endif
 431                         }
 432                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 433                         setattachment(this.weaponchild, this, t);
 434                 }
 435                 else
 436                 {
 437                         if (this.weaponchild) remove(this.weaponchild);
 438                         this.weaponchild = NULL;
 439                 }
 440
 441                 setorigin(this, '0 0 0');
 442                 this.angles = '0 0 0';
 443                 this.frame = 0;
 444 #ifdef SVQC
 445                 this.viewmodelforclient = NULL;
 446 #else
 447                 this.renderflags &= ~RF_VIEWMODEL;
 448 #endif
 449                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 450                 {
 451                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 452                 }
 453                 else
 454                 {
 455                         int idx;
 456                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 457                         {
 458                                 this.movedir = gettaginfo(this, idx);
 459                         }
 460                         else
 461                         {
 462                                 LOG_WARNINGF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong\n",
 463                                         this.model);
 464                                 this.movedir = '0 0 0';
 465                         }
 466                 }
 467                 {
 468                         int idx = 0;
 469                         // v_ model attached to invisible h_ model
 470                         if (this.weaponchild
 471                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 472                         {
 473                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 474                         }
 475                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 476                         {
 477                                 this.spawnorigin = gettaginfo(this, idx);
 478                         }
 479                         else
 480                         {
 481                                 LOG_WARNINGF("weapon model %s does not support the 'shell' tag, will display casings wrong\n",
 482                                         this.model);
 483                                 this.spawnorigin = this.movedir;
 484                         }
 485                 }
 486                 if (v_shot_idx)
 487                 {
 488                         this.oldorigin = '0 0 0';  // use regular attachment
 489                 }
 490                 else
 491                 {
 492                         int idx;
 493                         if (this.weaponchild)
 494                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 495                         else
 496                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 497                         if (idx)
 498                         {
 499                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 500                         }
 501                         else
 502                         {
 503                                 LOG_WARNINGF(
 504                                         "weapon model %s does not support the 'handle' tag "
 505                                         "and neither does the v_ model support the 'shot' tag, "
 506                                         "will display muzzle flashes TOTALLY wrong\n",
 507                                         this.model);
 508                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 509                         }
 510                 }
 511
 512 #ifdef SVQC
 513                 this.viewmodelforclient = this.owner;
 514 #else
 515                 this.renderflags |= RF_VIEWMODEL;
 516 #endif
 517         }
 518
 519         this.view_ofs = '0 0 0';
 520
 521         if (this.movedir.x >= 0)
 522         {
 523                 int algn = STAT(GUNALIGN, this.owner);
 524                 vector v = this.movedir;
 525                 this.movedir = shotorg_adjust(v, false, false, algn);
 526                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 527         }
 528         int compressed_shotorg = compressShotOrigin(this.movedir);
 529         // make them match perfectly
 530 #ifdef SVQC
 531         this.movedir = decompressShotOrigin(this.owner.stat_shotorg = compressed_shotorg);
 532 #else
 533         this.movedir = decompressShotOrigin(compressed_shotorg);
 534 #endif
 535
 536         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 537
 538         // check if an instant weapon switch occurred
 539         setorigin(this, this.view_ofs);
 540         // reset animstate now
 541         this.wframe = WFRAME_IDLE;
 542         setanim(this, this.anim_idle, true, false, true);
 543 }
 544 #endif
 545
 546 #ifndef MENUQC
 547
 548 REGISTER_NET_TEMP(wframe)
 549 #ifdef CSQC
 550 NET_HANDLE(wframe, bool isNew)
 551 {
 552         vector a;
 553         a.x = ReadCoord();
 554     a.y = ReadCoord();
 555     a.z = ReadCoord();
 556         bool restartanim = ReadByte();
 557         anim_set(viewmodel, a, !restartanim, restartanim, restartanim);
 558         viewmodel.state = ReadByte();
 559         viewmodel.weapon_nextthink = ReadFloat();
 560         viewmodel.alpha = ReadByte() / 255;
 561         switch (viewmodel.state)
 562         {
 563                 case WS_RAISE:
 564                         viewmodel.weapon_switchdelay = activeweapon.switchdelay_raise;
 565                         break;
 566                 case WS_DROP:
 567                         viewmodel.weapon_switchdelay = activeweapon.switchdelay_drop;
 568                         break;
 569         default:
 570             viewmodel.weapon_switchdelay = 0;
 571             break;
 572         }
 573         return true;
 574 }
 575 #endif
 576
 577 #ifdef SVQC
 578 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 579 {
 580         if (!IS_REAL_CLIENT(actor)) return;
 581         int channel = MSG_ONE;
 582         msg_entity = actor;
 583         WriteHeader(channel, wframe);
 584         WriteCoord(channel, a.x);
 585         WriteCoord(channel, a.y);
 586         WriteCoord(channel, a.z);
 587         WriteByte(channel, restartanim);
 588         WriteByte(channel, weaponentity.state);
 589         WriteFloat(channel, weaponentity.weapon_nextthink);
 590         WriteByte(channel, weaponentity.m_alpha * 255);
 591 }
 592 #endif
 593
 594 REGISTER_NET_C2S(w_whereis)
 595 #ifdef SVQC
 596 void Weapon_whereis(Weapon this, entity cl);
 597 NET_HANDLE(w_whereis, bool)
 598 {
 599         Weapon wpn = ReadRegistered(Weapons);
 600         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 601         return true;
 602 }
 603 #else
 604 void w_whereis(Weapon this)
 605 {
 606         int channel = MSG_C2S;
 607         WriteHeader(channel, w_whereis);
 608         WriteRegistered(Weapons, channel, this);
 609 }
 610 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 611 {
 612         switch (request)
 613         {
 614                 case CMD_REQUEST_COMMAND:
 615                 {
 616                         string s = argv(1);
 617                         if (s == "all")
 618                         {
 619                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 620                                 return;
 621                         }
 622                         if (s == "unowned")
 623                         {
 624                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 625                                 return;
 626                         }
 627                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 628                         {
 629                                 w_whereis(it);
 630                                 return;
 631                         });
 632                 }
 633                 default:
 634                 {
 635                         LOG_INFOF("Incorrect parameters for ^2%s^7\n", "weapon_find");
 636                 }
 637                 case CMD_REQUEST_USAGE:
 638                 {
 639                         LOG_INFO("\nUsage:^3 cl_cmd weapon_find weapon\n");
 640                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.\n");
 641                         return;
 642                 }
 643         }
 644 }
 645 #endif
 646
 647
 648 #endif
 649
 650 #endif