Simplify clipped circle pictures (e.g. crosshair ring).
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / all.qc
1 #include "all.qh"
2 #ifndef WEAPONS_ALL_C
3 #define WEAPONS_ALL_C
4
5 #if defined(CSQC)
6         #include <client/defs.qh>
7         #include "../constants.qh"
8         #include "../stats.qh"
9         #include <lib/warpzone/anglestransform.qh>
10         #include <lib/warpzone/common.qh>
11         #include <lib/warpzone/client.qh>
12         #include "../util.qh"
13         #include <client/autocvars.qh>
14         #include "../deathtypes/all.qh"
15         #include <lib/csqcmodel/interpolate.qh>
16         #include "../physics/movetypes/movetypes.qh"
17         #include <client/main.qh>
18         #include <lib/csqcmodel/cl_model.qh>
19 #elif defined(MENUQC)
20 #elif defined(SVQC)
21         #include <common/items/_mod.qh>
22     #include <lib/warpzone/anglestransform.qh>
23     #include <lib/warpzone/common.qh>
24     #include <lib/warpzone/util_server.qh>
25     #include <lib/warpzone/server.qh>
26     #include "../constants.qh"
27     #include "../stats.qh"
28     #include "../teams.qh"
29     #include <common/util.qh>
30     #include "../monsters/_mod.qh"
31     #include "config.qh"
32     #include <server/weapons/csqcprojectile.qh>
33     #include <server/weapons/tracing.qh>
34     #include "../t_items.qh"
35     #include <server/autocvars.qh>
36     #include <server/constants.qh>
37     #include <server/defs.qh>
38     #include "../notifications/all.qh"
39     #include "../deathtypes/all.qh"
40     #include <server/mutators/_mod.qh>
41     #include "../mapinfo.qh"
42     #include <server/command/_mod.qh>
43     #include <lib/csqcmodel/sv_model.qh>
44     #include <server/portals.qh>
45     #include <server/g_hook.qh>
46 #endif
47 #ifdef GAMEQC
48         #include "calculations.qc"
49 #endif
50 #ifdef SVQC
51         #include "config.qc"
52 #endif
53
54 #include "weapon/_mod.inc"
55
56
57 // WEAPON PLUGIN SYSTEM
58
59 WepSet _WepSet_FromWeapon(int a)
60 {
61         a -= WEP_FIRST;
62         if (Weapons_MAX > 24)
63                 if (a >= 24)
64                 {
65                         a -= 24;
66                         if (Weapons_MAX > 48)
67                                 if (a >= 24)
68                                 {
69                                         a -= 24;
70                                         return '0 0 1' * (2 ** a);
71                                 }
72                         return '0 1 0' * (2 ** a);
73                 }
74         return '1 0 0' * (2 ** a);
75 }
76 #ifdef SVQC
77         void WriteWepSet(float dst, WepSet w)
78         {
79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
81                 else WriteInt24_t(dst, w.x);
82         }
83 #endif
84 #ifdef CSQC
85         WepSet WepSet_GetFromStat()
86         {
87                 return STAT(WEAPONS);
88         }
89         WepSet WepSet_GetFromStat_InMap()
90         {
91                 return STAT(WEAPONSINMAP);
92         }
93         WepSet ReadWepSet()
94         {
95                 if (Weapons_MAX > 48) return ReadInt72_t();
96                 if (Weapons_MAX > 24) return ReadInt48_t();
97                 return ReadInt24_t() * '1 0 0';
98         }
99 #endif
100
101 string W_FixWeaponOrder(string order, float complete)
102 {
103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
104 }
105 string W_NameWeaponOrder_MapFunc(string s)
106 {
107         int i = stof(s);
108         if (s == "0" || i)
109         {
110                 entity wi = Weapons_from(i);
111                 if (wi != WEP_Null) return wi.netname;
112         }
113         return s;
114 }
115
116 string W_UndeprecateName(string s)
117 {
118         switch (s)
119         {
120                 case "nex": return "vortex";
121                 case "rocketlauncher": return "devastator";
122                 case "laser": return "blaster";
123                 case "minstanex": return "vaporizer";
124                 case "grenadelauncher": return "mortar";
125                 case "uzi": return "machinegun";
126                 case "hmg": return "okhmg";
127                 case "rpc": return "okrpc";
128                 default: return s;
129         }
130 }
131 string W_NameWeaponOrder(string order)
132 {
133         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
134 }
135 string W_NumberWeaponOrder_MapFunc(string s)
136 {
137         if (s == "0" || stof(s)) return s;
138         s = W_UndeprecateName(s);
139         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
140         return s;
141 }
142 string W_NumberWeaponOrder(string order)
143 {
144         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
145 }
146
147 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
148 string W_FixWeaponOrder_BuildImpulseList_order;
149 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
150 {
151         float h;
152         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
153         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
154         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
155 }
156 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
157 {
158         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
159         Weapon e1 = Weapons_from(si);
160         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
161         Weapon e2 = Weapons_from(sj);
162         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
163         if (d != 0) return -d;  // high impulse first!
164         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
165                 sprintf(" %d ", si), 0)
166                -
167                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
168                 sprintf(" %d ", sj), 0)
169         ;  // low char index first!
170 }
171 string W_FixWeaponOrder_BuildImpulseList(string o)
172 {
173         int i;
174         W_FixWeaponOrder_BuildImpulseList_order = o;
175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
176                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
177         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
178                 NULL);
179         o = "";
180         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
181                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
182         W_FixWeaponOrder_BuildImpulseList_order = string_null;
183         return substring(o, 1, -1);
184 }
185
186 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
187 {
188         return W_FixWeaponOrder(order, 0);
189 }
190
191 string W_FixWeaponOrder_ForceComplete(string order)
192 {
193         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
194         return W_FixWeaponOrder(order, 1);
195 }
196
197 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
198 {
199         WepSet result = '0 0 0';
200         for (int j = 0; j < n; ++j)
201         {
202                 RandomSelection_Init();
203                 FOREACH(Weapons, it != WEP_Null, {
204                         if (remaining & (it.m_wepset))
205                                 RandomSelection_AddEnt(it, 1, 1);
206                 });
207                 Weapon w = RandomSelection_chosen_ent;
208                 result |= WepSet_FromWeapon(w);
209                 remaining &= ~WepSet_FromWeapon(w);
210         }
211         return result;
212 }
213
214 string GetAmmoPicture(int ammotype)
215 {
216         switch (ammotype)
217         {
218                 case RES_SHELLS:  return ITEM_Shells.m_icon;
219                 case RES_BULLETS: return ITEM_Bullets.m_icon;
220                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
221                 case RES_CELLS:   return ITEM_Cells.m_icon;
222                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
223                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
224                 default: return "";  // wtf, no ammo type?
225         }
226 }
227
228 #ifdef CSQC
229 int GetAmmoTypeFromNum(int i)
230 {
231         switch (i)
232         {
233                 case 0: return RES_SHELLS;
234                 case 1: return RES_BULLETS;
235                 case 2: return RES_ROCKETS;
236                 case 3: return RES_CELLS;
237                 case 4: return RES_PLASMA;
238                 case 5: return RES_FUEL;
239                 default: return RES_NONE;
240         }
241 }
242
243 int GetAmmoStat(int ammotype)
244 {
245         switch (ammotype)
246         {
247                 case RES_SHELLS: return STAT_SHELLS;
248                 case RES_BULLETS: return STAT_NAILS;
249                 case RES_ROCKETS: return STAT_ROCKETS;
250                 case RES_CELLS: return STAT_CELLS;
251                 case RES_PLASMA: return STAT_PLASMA.m_id;
252                 case RES_FUEL: return STAT_FUEL.m_id;
253                 default: return -1;
254         }
255 }
256 #endif
257
258 string W_Sound(string w_snd)
259 {
260         string output = strcat("weapons/", w_snd);
261         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
262         return M_ARGV(1, string);
263 }
264
265 string W_Model(string w_mdl)
266 {
267         string output = strcat("models/weapons/", w_mdl);
268         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
269         return M_ARGV(1, string);
270 }
271
272 #ifdef GAMEQC
273 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
274 {
275         switch (algn)
276         {
277                 default:
278                 case 3:
279                         // right alignment
280                         break;
281                 case 4:
282                         // left
283                         vecs.y = -vecs.y;
284                         break;
285                 case 1:
286                 case 2:
287                         // center
288                         vecs.y = 0;
289                         vecs.z -= 2;
290                         break;
291         }
292         return vecs;
293 }
294
295 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
296 {
297         string s;
298         if (visual)
299         {
300                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
301         }
302         else if (STAT(SHOOTFROMEYE))
303         {
304                 vecs.y = vecs.z = 0;
305         }
306         else if (STAT(SHOOTFROMCENTER))
307         {
308                 vecs.y = 0;
309                 vecs.z -= 2;
310         }
311         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
312         {
313                 vector v = stov(s);
314                 if (y_is_right) v.y = -v.y;
315                 if (v.x != 0) vecs.x = v.x;
316                 vecs.y = v.y;
317                 vecs.z = v.z;
318         }
319         else  // just do the same as top
320         {
321                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
322         }
323
324         return vecs;
325 }
326
327 #define shotorg_adjust shotorg_adjust_values
328
329 /**
330  * supported formats:
331  *
332  * 1. simple animated model, muzzle flash handling on h_ model:
333  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
334  *      tags:
335  *        shot = muzzle end (shot origin, also used for muzzle flashes)
336  *        shell = casings ejection point (must be on the right hand side of the gun)
337  *        weapon = attachment for v_tuba.md3
338  *    v_tuba.md3 - first and third person model
339  *    g_tuba.md3 - pickup model
340  *
341  * 2. simple animated model, muzzle flash handling on v_ model:
342  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
343  *      tags:
344  *        weapon = attachment for v_tuba.md3
345  *    v_tuba.md3 - first and third person model
346  *      tags:
347  *        shot = muzzle end (shot origin, also used for muzzle flashes)
348  *        shell = casings ejection point (must be on the right hand side of the gun)
349  *    g_tuba.md3 - pickup model
350  *
351  * 3. fully animated model, muzzle flash handling on h_ model:
352  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
353  *      tags:
354  *        shot = muzzle end (shot origin, also used for muzzle flashes)
355  *        shell = casings ejection point (must be on the right hand side of the gun)
356  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
357  *    v_tuba.md3 - third person model
358  *    g_tuba.md3 - pickup model
359  *
360  * 4. fully animated model, muzzle flash handling on v_ model:
361  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
362  *      tags:
363  *        shot = muzzle end (shot origin)
364  *        shell = casings ejection point (must be on the right hand side of the gun)
365  *    v_tuba.md3 - third person model
366  *      tags:
367  *        shot = muzzle end (for muzzle flashes)
368  *    g_tuba.md3 - pickup model
369  *
370  * writes:
371  *   this.origin, this.angles
372  *   this.weaponchild
373  *   this.movedir, this.view_ofs
374  *   attachment stuff
375  *   anim stuff
376  * to free:
377  *   call again with ""
378  *   remove the ent
379  */
380 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
381 {
382         if (name == "")
383         {
384                 vector oldmin = this.mins, oldmax = this.maxs;
385                 setmodel(this, MDL_Null);
386                 setsize(this, oldmin, oldmax);
387                 if (this.weaponchild) delete(this.weaponchild);
388                 this.weaponchild = NULL;
389                 this.movedir = '0 0 0';
390                 this.spawnorigin = '0 0 0';
391                 this.oldorigin = '0 0 0';
392                 this.anim_fire1  = '0 1 0.01';
393                 this.anim_fire2  = '0 1 0.01';
394                 this.anim_idle   = '0 1 0.01';
395                 this.anim_reload = '0 1 0.01';
396         }
397         else
398         {
399                 // if there is a child entity, hide it until we're sure we use it
400                 if (this.weaponchild) this.weaponchild.model = "";
401                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
402                 int v_shot_idx;  // used later
403                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
404
405                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
406                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
407                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
408                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
409                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
410                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
411
412                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
413                 // if we don't, this is a "real" animated model
414                 string t;
415                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
416                 {
417                         if (!this.weaponchild)
418                         {
419                                 this.weaponchild = new(weaponchild);
420 #ifdef CSQC
421                                 this.weaponchild.drawmask = MASK_NORMAL;
422                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
423 #endif
424                         }
425                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
426                         setsize(this.weaponchild, '0 0 0', '0 0 0');
427                         setattachment(this.weaponchild, this, t);
428                 }
429                 else
430                 {
431                         if (this.weaponchild) delete(this.weaponchild);
432                         this.weaponchild = NULL;
433                 }
434
435                 setsize(this, '0 0 0', '0 0 0');
436                 setorigin(this, '0 0 0');
437                 this.angles = '0 0 0';
438                 this.frame = 0;
439 #ifdef SVQC
440                 this.viewmodelforclient = NULL;
441 #else
442                 this.renderflags &= ~RF_VIEWMODEL;
443 #endif
444                 if (v_shot_idx)  // v_ model attached to invisible h_ model
445                 {
446                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
447                 }
448                 else
449                 {
450                         int idx;
451                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
452                         {
453                                 this.movedir = gettaginfo(this, idx);
454                         }
455                         else
456                         {
457                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
458                                         this.model);
459                                 this.movedir = '0 0 0';
460                         }
461                 }
462                 {
463                         int idx = 0;
464                         // v_ model attached to invisible h_ model
465                         if (this.weaponchild
466                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
467                         {
468                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
469                         }
470                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
471                         {
472                                 this.spawnorigin = gettaginfo(this, idx);
473                         }
474                         else
475                         {
476                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
477                                         this.model);
478                                 this.spawnorigin = this.movedir;
479                         }
480                 }
481                 if (v_shot_idx)
482                 {
483                         this.oldorigin = '0 0 0';  // use regular attachment
484                 }
485                 else
486                 {
487                         int idx;
488                         if (this.weaponchild)
489                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
490                         else
491                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
492                         if (idx)
493                         {
494                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
495                         }
496                         else
497                         {
498                                 LOG_WARNF(
499                                         "weapon model %s does not support the 'handle' tag "
500                                         "and neither does the v_ model support the 'shot' tag, "
501                                         "will display muzzle flashes TOTALLY wrong\n",
502                                         this.model);
503                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
504                         }
505                 }
506
507 #ifdef SVQC
508                 this.viewmodelforclient = this.owner;
509 #else
510                 this.renderflags |= RF_VIEWMODEL;
511 #endif
512         }
513
514         this.view_ofs = '0 0 0';
515
516         if (this.movedir.x >= 0)
517         {
518                 //int algn = STAT(GUNALIGN, this.owner);
519                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
520         #ifdef SVQC
521                 this.m_gunalign = algn;
522         #endif
523                 vector v = this.movedir;
524                 this.movedir = shotorg_adjust(v, false, false, algn);
525                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
526         }
527         int compressed_shotorg = compressShotOrigin(this.movedir);
528         // make them match perfectly
529 #ifdef SVQC
530     // null during init
531     if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
532         this.movedir = decompressShotOrigin(compressed_shotorg);
533 #else
534         this.movedir = decompressShotOrigin(compressed_shotorg);
535 #endif
536
537         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
538
539         // check if an instant weapon switch occurred
540         setorigin(this, this.view_ofs);
541         if (!_anim) return;
542         // reset animstate now
543         this.wframe = WFRAME_IDLE;
544         setanim(this, this.anim_idle, true, false, true);
545 }
546 #endif
547
548 #ifdef GAMEQC
549
550 REGISTER_NET_TEMP(wframe)
551 #ifdef CSQC
552 NET_HANDLE(wframe, bool isNew)
553 {
554         vector a = ReadVector();
555     int slot = ReadByte();
556         bool restartanim = ReadByte();
557         entity wepent = viewmodels[slot];
558         if(a.x == wepent.anim_idle_x) // we don't need to enforce idle animation
559                 wepent.animstate_looping = false;
560         else
561                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
562         wepent.state = ReadByte();
563         wepent.weapon_nextthink = ReadFloat();
564         switch (wepent.state)
565         {
566                 case WS_RAISE:
567                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
568                         break;
569                 case WS_DROP:
570                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
571                         break;
572         default:
573             wepent.weapon_switchdelay = 0;
574             break;
575         }
576         return true;
577 }
578 #endif
579
580 #ifdef SVQC
581 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
582 {
583         if (!IS_REAL_CLIENT(actor)) return;
584         int channel = MSG_ONE;
585         msg_entity = actor;
586         WriteHeader(channel, wframe);
587         WriteVector(channel, a);
588         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
589         WriteByte(channel, restartanim);
590         WriteByte(channel, weaponentity.state);
591         WriteFloat(channel, weaponentity.weapon_nextthink);
592 }
593 #endif
594
595 REGISTER_NET_C2S(w_whereis)
596 #ifdef SVQC
597 void Weapon_whereis(Weapon this, entity cl);
598 NET_HANDLE(w_whereis, bool)
599 {
600         Weapon wpn = ReadRegistered(Weapons);
601         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
602         return true;
603 }
604 #else
605 void w_whereis(Weapon this)
606 {
607         int channel = MSG_C2S;
608         WriteHeader(channel, w_whereis);
609         WriteRegistered(Weapons, channel, this);
610 }
611 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
612 {
613         switch (request)
614         {
615                 case CMD_REQUEST_COMMAND:
616                 {
617                         string s = argv(1);
618                         if (s == "all")
619                         {
620                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
621                                 return;
622                         }
623                         if (s == "unowned")
624                         {
625                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
626                                 return;
627                         }
628                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
629                         {
630                                 w_whereis(it);
631                                 return;
632                         });
633                 }
634                 default:
635                 {
636                         LOG_INFOF("Incorrect parameters for ^2%s^7", "weapon_find");
637                 }
638                 case CMD_REQUEST_USAGE:
639                 {
640                         LOG_INFO("Usage:^3 cl_cmd weapon_find weapon");
641                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
642                         return;
643                 }
644         }
645 }
646 #endif
647
648
649 #endif
650
651 #endif