qcsrc/common/weapons/all.qc

   1 #ifndef WEAPONS_ALL_C
   2 #define WEAPONS_ALL_C
   3
   4 #include "all.qh"
   5
   6 #if defined(CSQC)
   7         #include "../../client/defs.qh"
   8         #include "../constants.qh"
   9         #include "../stats.qh"
  10         #include "../../lib/warpzone/anglestransform.qh"
  11         #include "../../lib/warpzone/common.qh"
  12         #include "../../lib/warpzone/client.qh"
  13         #include "../util.qh"
  14         #include "../../client/autocvars.qh"
  15         #include "../deathtypes/all.qh"
  16         #include "../../lib/csqcmodel/interpolate.qh"
  17         #include "../movetypes/movetypes.qh"
  18         #include "../../client/main.qh"
  19         #include "../../lib/csqcmodel/cl_model.qh"
  20 #elif defined(MENUQC)
  21 #elif defined(SVQC)
  22     #include "../../lib/warpzone/anglestransform.qh"
  23     #include "../../lib/warpzone/common.qh"
  24     #include "../../lib/warpzone/util_server.qh"
  25     #include "../../lib/warpzone/server.qh"
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include "../util.qh"
  30     #include "../monsters/all.qh"
  31     #include "config.qh"
  32     #include "../../server/weapons/csqcprojectile.qh"
  33     #include "../../server/weapons/tracing.qh"
  34     #include "../../server/t_items.qh"
  35     #include "../../server/autocvars.qh"
  36     #include "../../server/constants.qh"
  37     #include "../../server/defs.qh"
  38     #include "../notifications.qh"
  39     #include "../deathtypes/all.qh"
  40     #include "../../server/mutators/all.qh"
  41     #include "../mapinfo.qh"
  42     #include "../../server/command/common.qh"
  43     #include "../../lib/csqcmodel/sv_model.qh"
  44     #include "../../server/portals.qh"
  45     #include "../../server/g_hook.qh"
  46 #endif
  47 #ifndef MENUQC
  48         #include "calculations.qc"
  49 #endif
  50 #define IMPLEMENTATION
  51 #include "all.inc"
  52 #undef IMPLEMENTATION
  53
  54 // WEAPON PLUGIN SYSTEM
  55
  56 WepSet _WepSet_FromWeapon(int a)
  57 {
  58         a -= WEP_FIRST;
  59         if (Weapons_MAX > 24)
  60                 if (a >= 24)
  61                 {
  62                         a -= 24;
  63                         if (Weapons_MAX > 48)
  64                                 if (a >= 24)
  65                                 {
  66                                         a -= 24;
  67                                         return '0 0 1' * power2of(a);
  68                                 }
  69                         return '0 1 0' * power2of(a);
  70                 }
  71         return '1 0 0' * power2of(a);
  72 }
  73 #ifdef SVQC
  74         void WriteWepSet(float dst, WepSet w)
  75         {
  76                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  77                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  78                 else WriteInt24_t(dst, w.x);
  79         }
  80 #endif
  81 #ifdef CSQC
  82         WepSet WepSet_GetFromStat()
  83         {
  84                 return STAT(WEAPONS);
  85         }
  86         WepSet WepSet_GetFromStat_InMap()
  87         {
  88                 return STAT(WEAPONSINMAP);
  89         }
  90         WepSet ReadWepSet()
  91         {
  92                 if (Weapons_MAX > 48) return ReadInt72_t();
  93                 if (Weapons_MAX > 24) return ReadInt48_t();
  94                 return ReadInt24_t() * '1 0 0';
  95         }
  96 #endif
  97
  98 string W_FixWeaponOrder(string order, float complete)
  99 {
 100         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 101 }
 102 string W_NameWeaponOrder_MapFunc(string s)
 103 {
 104         int i = stof(s);
 105         if (s == "0" || i)
 106         {
 107                 entity wi = Weapons_from(i);
 108                 if (wi != WEP_Null) return wi.netname;
 109         }
 110         return s;
 111 }
 112
 113 string W_UndeprecateName(string s)
 114 {
 115         switch (s)
 116         {
 117                 case "nex": return "vortex";
 118                 case "rocketlauncher": return "devastator";
 119                 case "laser": return "blaster";
 120                 case "minstanex": return "vaporizer";
 121                 case "grenadelauncher": return "mortar";
 122                 case "uzi": return "machinegun";
 123                 default: return s;
 124         }
 125 }
 126 string W_NameWeaponOrder(string order)
 127 {
 128         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 129 }
 130 string W_NumberWeaponOrder_MapFunc(string s)
 131 {
 132         if (s == "0" || stof(s)) return s;
 133         s = W_UndeprecateName(s);
 134         FOREACH(Weapons, it != WEP_Null && it.netname == s, LAMBDA(return ftos(i)));
 135         return s;
 136 }
 137 string W_NumberWeaponOrder(string order)
 138 {
 139         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 140 }
 141
 142 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 143 string W_FixWeaponOrder_BuildImpulseList_order;
 144 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 145 {
 146         float h;
 147         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 148         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 149         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 150 }
 151 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 152 {
 153         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 154         Weapon e1 = Weapons_from(si);
 155         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 156         Weapon e2 = Weapons_from(sj);
 157         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 158         if (d != 0) return -d;  // high impulse first!
 159         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 160                 sprintf(" %d ", si), 0)
 161                -
 162                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", sj), 0)
 164         ;  // low char index first!
 165 }
 166 string W_FixWeaponOrder_BuildImpulseList(string o)
 167 {
 168         int i;
 169         W_FixWeaponOrder_BuildImpulseList_order = o;
 170         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 171                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 172         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 173                 world);
 174         o = "";
 175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 176                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 177         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 178         return substring(o, 1, -1);
 179 }
 180
 181 string W_FixWeaponOrder_AllowIncomplete(string order)
 182 {
 183         return W_FixWeaponOrder(order, 0);
 184 }
 185
 186 string W_FixWeaponOrder_ForceComplete(string order)
 187 {
 188         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 189         return W_FixWeaponOrder(order, 1);
 190 }
 191
 192 void W_RandomWeapons(entity e, float n)
 193 {
 194         int i, j;
 195         WepSet remaining;
 196         WepSet result;
 197         remaining = e.weapons;
 198         result = '0 0 0';
 199         for (i = 0; i < n; ++i)
 200         {
 201                 RandomSelection_Init();
 202                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 203                         if (remaining & WepSet_FromWeapon(Weapons_from(j))) RandomSelection_Add(NULL, j, string_null, 1, 1);
 204                 Weapon w = Weapons_from(RandomSelection_chosen_float);
 205                 result |= WepSet_FromWeapon(w);
 206                 remaining &= ~WepSet_FromWeapon(w);
 207         }
 208         e.weapons = result;
 209 }
 210
 211 string GetAmmoPicture(.int ammotype)
 212 {
 213         switch (ammotype)
 214         {
 215                 case ammo_shells:  return ITEM_Shells.m_icon;
 216                 case ammo_nails:   return ITEM_Bullets.m_icon;
 217                 case ammo_rockets: return ITEM_Rockets.m_icon;
 218                 case ammo_cells:   return ITEM_Cells.m_icon;
 219                 case ammo_plasma:  return ITEM_Plasma.m_icon;
 220                 case ammo_fuel:    return ITEM_JetpackFuel.m_icon;
 221                 default: return "";  // wtf, no ammo type?
 222         }
 223 }
 224
 225 #ifdef CSQC
 226         .int GetAmmoFieldFromNum(int i)
 227         {
 228                 switch (i)
 229                 {
 230                         case 0: return ammo_shells;
 231                         case 1: return ammo_nails;
 232                         case 2: return ammo_rockets;
 233                         case 3: return ammo_cells;
 234                         case 4: return ammo_plasma;
 235                         case 5: return ammo_fuel;
 236                         default: return ammo_none;
 237                 }
 238         }
 239
 240         int GetAmmoStat(.int ammotype)
 241         {
 242                 switch (ammotype)
 243                 {
 244                         case ammo_shells: return STAT_SHELLS;
 245                         case ammo_nails: return STAT_NAILS;
 246                         case ammo_rockets: return STAT_ROCKETS;
 247                         case ammo_cells: return STAT_CELLS;
 248                         case ammo_plasma: return STAT_PLASMA.m_id;
 249                         case ammo_fuel: return STAT_FUEL.m_id;
 250                         default: return -1;
 251                 }
 252         }
 253 #endif
 254
 255 string W_Sound(string w_snd)
 256 {
 257         string output = strcat("weapons/", w_snd);
 258 #ifdef SVQC
 259                 MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 260                 return weapon_sound_output;
 261 #else
 262                 return output;
 263 #endif
 264 }
 265
 266 string W_Model(string w_mdl)
 267 {
 268         string output = strcat("models/weapons/", w_mdl);
 269         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 270         return weapon_model_output;
 271 }
 272
 273 #ifndef MENUQC
 274 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 275 {
 276         switch (algn)
 277         {
 278                 default:
 279                 case 3:
 280                         // right alignment
 281                         break;
 282                 case 4:
 283                         // left
 284                         vecs.y = -vecs.y;
 285                         break;
 286                 case 1:
 287                 case 2:
 288                         // center
 289                         vecs.y = 0;
 290                         vecs.z -= 2;
 291                         break;
 292         }
 293         return vecs;
 294 }
 295
 296 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 297 {
 298 #ifdef SVQC
 299         string s;
 300 #endif
 301         if (visual)
 302         {
 303                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 304         }
 305 #ifdef SVQC
 306         else if (autocvar_g_shootfromeye)
 307         {
 308                 vecs.y = vecs.z = 0;
 309         }
 310         else if (autocvar_g_shootfromcenter)
 311         {
 312                 vecs.y = 0;
 313                 vecs.z -= 2;
 314         }
 315         else if ((s = autocvar_g_shootfromfixedorigin) != "")
 316         {
 317                 vector v = stov(s);
 318                 if (y_is_right) v.y = -v.y;
 319                 if (v.x != 0) vecs.x = v.x;
 320                 vecs.y = v.y;
 321                 vecs.z = v.z;
 322         }
 323 #endif
 324         else  // just do the same as top
 325         {
 326                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 327         }
 328
 329         return vecs;
 330 }
 331
 332 #define shotorg_adjust shotorg_adjust_values
 333
 334 /**
 335  * supported formats:
 336  *
 337  * 1. simple animated model, muzzle flash handling on h_ model:
 338  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 339  *      tags:
 340  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 341  *        shell = casings ejection point (must be on the right hand side of the gun)
 342  *        weapon = attachment for v_tuba.md3
 343  *    v_tuba.md3 - first and third person model
 344  *    g_tuba.md3 - pickup model
 345  *
 346  * 2. simple animated model, muzzle flash handling on v_ model:
 347  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 348  *      tags:
 349  *        weapon = attachment for v_tuba.md3
 350  *    v_tuba.md3 - first and third person model
 351  *      tags:
 352  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 353  *        shell = casings ejection point (must be on the right hand side of the gun)
 354  *    g_tuba.md3 - pickup model
 355  *
 356  * 3. fully animated model, muzzle flash handling on h_ model:
 357  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 358  *      tags:
 359  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 360  *        shell = casings ejection point (must be on the right hand side of the gun)
 361  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 362  *    v_tuba.md3 - third person model
 363  *    g_tuba.md3 - pickup model
 364  *
 365  * 4. fully animated model, muzzle flash handling on v_ model:
 366  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 367  *      tags:
 368  *        shot = muzzle end (shot origin)
 369  *        shell = casings ejection point (must be on the right hand side of the gun)
 370  *    v_tuba.md3 - third person model
 371  *      tags:
 372  *        shot = muzzle end (for muzzle flashes)
 373  *    g_tuba.md3 - pickup model
 374  *
 375  * writes:
 376  *   this.origin, this.angles
 377  *   this.weaponchild
 378  *   this.movedir, this.view_ofs
 379  *   attachment stuff
 380  *   anim stuff
 381  * to free:
 382  *   call again with ""
 383  *   remove the ent
 384  */
 385 void CL_WeaponEntity_SetModel(entity this, string name)
 386 {
 387         if (name == "")
 388         {
 389                 this.model = "";
 390                 if (this.weaponchild) remove(this.weaponchild);
 391                 this.weaponchild = NULL;
 392                 this.movedir = '0 0 0';
 393                 this.spawnorigin = '0 0 0';
 394                 this.oldorigin = '0 0 0';
 395                 this.anim_fire1  = '0 1 0.01';
 396                 this.anim_fire2  = '0 1 0.01';
 397                 this.anim_idle   = '0 1 0.01';
 398                 this.anim_reload = '0 1 0.01';
 399         }
 400         else
 401         {
 402                 // if there is a child entity, hide it until we're sure we use it
 403                 if (this.weaponchild) this.weaponchild.model = "";
 404                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 405                 int v_shot_idx;  // used later
 406                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 407
 408                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 409                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 410                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 411                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 412                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 413                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 414
 415                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 416                 // if we don't, this is a "real" animated model
 417                 string t;
 418                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 419                 {
 420                         if (!this.weaponchild)
 421                         {
 422                                 this.weaponchild = new(weaponchild);
 423                                 make_pure(this.weaponchild);
 424 #ifdef CSQC
 425                                 this.weaponchild.drawmask = MASK_NORMAL;
 426                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 427 #endif
 428                         }
 429                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 430                         setattachment(this.weaponchild, this, t);
 431                 }
 432                 else
 433                 {
 434                         if (this.weaponchild) remove(this.weaponchild);
 435                         this.weaponchild = NULL;
 436                 }
 437
 438                 setorigin(this, '0 0 0');
 439                 this.angles = '0 0 0';
 440                 this.frame = 0;
 441 #ifdef SVQC
 442                 this.viewmodelforclient = NULL;
 443 #else
 444                 this.renderflags &= ~RF_VIEWMODEL;
 445 #endif
 446                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 447                 {
 448                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 449                 }
 450                 else
 451                 {
 452                         int idx;
 453                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 454                         {
 455                                 this.movedir = gettaginfo(this, idx);
 456                         }
 457                         else
 458                         {
 459                                 LOG_WARNINGF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong\n",
 460                                         this.model);
 461                                 this.movedir = '0 0 0';
 462                         }
 463                 }
 464                 {
 465                         int idx = 0;
 466                         // v_ model attached to invisible h_ model
 467                         if (this.weaponchild
 468                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 469                         {
 470                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 471                         }
 472                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 473                         {
 474                                 this.spawnorigin = gettaginfo(this, idx);
 475                         }
 476                         else
 477                         {
 478                                 LOG_WARNINGF("weapon model %s does not support the 'shell' tag, will display casings wrong\n",
 479                                         this.model);
 480                                 this.spawnorigin = this.movedir;
 481                         }
 482                 }
 483                 if (v_shot_idx)
 484                 {
 485                         this.oldorigin = '0 0 0';  // use regular attachment
 486                 }
 487                 else
 488                 {
 489                         int idx;
 490                         if (this.weaponchild)
 491                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 492                         else
 493                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 494                         if (idx)
 495                         {
 496                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 497                         }
 498                         else
 499                         {
 500                                 LOG_WARNINGF(
 501                                         "weapon model %s does not support the 'handle' tag "
 502                                         "and neither does the v_ model support the 'shot' tag, "
 503                                         "will display muzzle flashes TOTALLY wrong\n",
 504                                         this.model);
 505                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 506                         }
 507                 }
 508
 509 #ifdef SVQC
 510                 this.viewmodelforclient = this.owner;
 511 #else
 512                 this.renderflags |= RF_VIEWMODEL;
 513 #endif
 514         }
 515
 516         this.view_ofs = '0 0 0';
 517
 518         if (this.movedir.x >= 0)
 519         {
 520 #ifdef SVQC
 521                 int algn = this.owner.cvar_cl_gunalign;
 522 #else
 523                 int algn = autocvar_cl_gunalign;
 524 #endif
 525                 vector v = this.movedir;
 526                 this.movedir = shotorg_adjust(v, false, false, algn);
 527                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 528         }
 529         int compressed_shotorg = compressShotOrigin(this.movedir);
 530         // make them match perfectly
 531 #ifdef SVQC
 532         this.movedir = decompressShotOrigin(this.owner.stat_shotorg = compressed_shotorg);
 533 #else
 534         this.movedir = decompressShotOrigin(compressed_shotorg);
 535 #endif
 536
 537         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 538
 539         // check if an instant weapon switch occurred
 540         setorigin(this, this.view_ofs);
 541         // reset animstate now
 542         this.wframe = WFRAME_IDLE;
 543         setanim(this, this.anim_idle, true, false, true);
 544 }
 545 #endif
 546
 547 #ifndef MENUQC
 548
 549 REGISTER_NET_TEMP(wframe)
 550 #ifdef CSQC
 551 NET_HANDLE(wframe, bool isNew)
 552 {
 553         vector a;
 554         a.x = ReadCoord();
 555     a.y = ReadCoord();
 556     a.z = ReadCoord();
 557         bool restartanim = ReadByte();
 558         anim_set(viewmodel, a, !restartanim, restartanim, restartanim);
 559         viewmodel.state = ReadByte();
 560         viewmodel.weapon_nextthink = ReadFloat();
 561         viewmodel.alpha = ReadByte() / 255;
 562         switch (viewmodel.state)
 563         {
 564                 case WS_RAISE:
 565                 case WS_DROP:
 566                         viewmodel.weapon_switchdelay = ReadFloat();
 567                         break;
 568         default:
 569             viewmodel.weapon_switchdelay = 0;
 570             break;
 571         }
 572         return true;
 573 }
 574 #endif
 575
 576 #ifdef SVQC
 577 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 578 {
 579         if (!IS_REAL_CLIENT(actor)) return;
 580         int channel = MSG_ONE;
 581         msg_entity = actor;
 582         WriteHeader(channel, wframe);
 583         WriteCoord(channel, a.x);
 584         WriteCoord(channel, a.y);
 585         WriteCoord(channel, a.z);
 586         WriteByte(channel, restartanim);
 587         WriteByte(channel, weaponentity.state);
 588         WriteFloat(channel, weaponentity.weapon_nextthink);
 589         WriteByte(channel, weaponentity.m_alpha * 255);
 590         Weapon w = Weapons_from(actor.weapon);
 591         switch (weaponentity.state)
 592         {
 593                 case WS_RAISE:
 594                         WriteFloat(channel, w.switchdelay_raise);
 595                         break;
 596                 case WS_DROP:
 597                         WriteFloat(channel, w.switchdelay_drop);
 598                         break;
 599         }
 600 }
 601 #endif
 602
 603 #endif
 604
 605 #endif