qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/defs.qh>
   7         #include "../constants.qh"
   8         #include "../stats.qh"
   9         #include <lib/warpzone/anglestransform.qh>
  10         #include <lib/warpzone/common.qh>
  11         #include <lib/warpzone/client.qh>
  12         #include "../util.qh"
  13         #include <client/autocvars.qh>
  14         #include "../deathtypes/all.qh"
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include "../physics/movetypes/movetypes.qh"
  17         #include <client/main.qh>
  18         #include <lib/csqcmodel/cl_model.qh>
  19 #elif defined(MENUQC)
  20 #elif defined(SVQC)
  21         #include <common/items/_mod.qh>
  22     #include <lib/warpzone/anglestransform.qh>
  23     #include <lib/warpzone/common.qh>
  24     #include <lib/warpzone/util_server.qh>
  25     #include <lib/warpzone/server.qh>
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include <common/util.qh>
  30     #include "../monsters/_mod.qh"
  31     #include "config.qh"
  32     #include <server/weapons/csqcprojectile.qh>
  33     #include <server/weapons/tracing.qh>
  34     #include "../t_items.qh"
  35     #include <server/autocvars.qh>
  36     #include <server/constants.qh>
  37     #include <server/defs.qh>
  38     #include "../notifications/all.qh"
  39     #include "../deathtypes/all.qh"
  40     #include <server/mutators/_mod.qh>
  41     #include "../mapinfo.qh"
  42     #include <server/command/_mod.qh>
  43     #include <lib/csqcmodel/sv_model.qh>
  44     #include <server/portals.qh>
  45     #include <server/g_hook.qh>
  46 #endif
  47 #ifdef GAMEQC
  48         #include "calculations.qc"
  49 #endif
  50 #ifdef SVQC
  51         #include "config.qc"
  52 #endif
  53
  54 #include "weapon/_mod.inc"
  55
  56
  57 // WEAPON PLUGIN SYSTEM
  58
  59 WepSet _WepSet_FromWeapon(int a)
  60 {
  61         a -= WEP_FIRST;
  62         if (Weapons_MAX > 24)
  63                 if (a >= 24)
  64                 {
  65                         a -= 24;
  66                         if (Weapons_MAX > 48)
  67                                 if (a >= 24)
  68                                 {
  69                                         a -= 24;
  70                                         return '0 0 1' * (2 ** a);
  71                                 }
  72                         return '0 1 0' * (2 ** a);
  73                 }
  74         return '1 0 0' * (2 ** a);
  75 }
  76 #ifdef SVQC
  77         void WriteWepSet(float dst, WepSet w)
  78         {
  79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  81                 else WriteInt24_t(dst, w.x);
  82         }
  83 #endif
  84 #ifdef CSQC
  85         WepSet WepSet_GetFromStat()
  86         {
  87                 return STAT(WEAPONS);
  88         }
  89         WepSet WepSet_GetFromStat_InMap()
  90         {
  91                 return STAT(WEAPONSINMAP);
  92         }
  93         WepSet ReadWepSet()
  94         {
  95                 if (Weapons_MAX > 48) return ReadInt72_t();
  96                 if (Weapons_MAX > 24) return ReadInt48_t();
  97                 return ReadInt24_t() * '1 0 0';
  98         }
  99 #endif
 100
 101 string W_FixWeaponOrder(string order, float complete)
 102 {
 103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 104 }
 105 string W_NameWeaponOrder_MapFunc(string s)
 106 {
 107         int i = stof(s);
 108         if (s == "0" || i)
 109         {
 110                 entity wi = Weapons_from(i);
 111                 if (wi != WEP_Null) return wi.netname;
 112         }
 113         return s;
 114 }
 115
 116 string W_UndeprecateName(string s)
 117 {
 118         switch (s)
 119         {
 120                 case "nex": return "vortex";
 121                 case "rocketlauncher": return "devastator";
 122                 case "laser": return "blaster";
 123                 case "minstanex": return "vaporizer";
 124                 case "grenadelauncher": return "mortar";
 125                 case "uzi": return "machinegun";
 126                 case "hmg": return "okhmg";
 127                 case "rpc": return "okrpc";
 128                 default: return s;
 129         }
 130 }
 131 string W_NameWeaponOrder(string order)
 132 {
 133         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 134 }
 135 string W_NumberWeaponOrder_MapFunc(string s)
 136 {
 137         if (s == "0" || stof(s)) return s;
 138         s = W_UndeprecateName(s);
 139         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 140         return s;
 141 }
 142 string W_NumberWeaponOrder(string order)
 143 {
 144         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 145 }
 146
 147 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 148 string W_FixWeaponOrder_BuildImpulseList_order;
 149 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 150 {
 151         float h;
 152         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 153         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 154         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 155 }
 156 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 157 {
 158         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 159         Weapon e1 = Weapons_from(si);
 160         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 161         Weapon e2 = Weapons_from(sj);
 162         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 163         if (d != 0) return -d;  // high impulse first!
 164         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 165                 sprintf(" %d ", si), 0)
 166                -
 167                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 168                 sprintf(" %d ", sj), 0)
 169         ;  // low char index first!
 170 }
 171 string W_FixWeaponOrder_BuildImpulseList(string o)
 172 {
 173         int i;
 174         W_FixWeaponOrder_BuildImpulseList_order = o;
 175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 176                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 177         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 178                 NULL);
 179         o = "";
 180         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 181                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 182         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 183         return substring(o, 1, -1);
 184 }
 185
 186 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 187 {
 188         return W_FixWeaponOrder(order, 0);
 189 }
 190
 191 string W_FixWeaponOrder_ForceComplete(string order)
 192 {
 193         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 194         return W_FixWeaponOrder(order, 1);
 195 }
 196
 197 void W_RandomWeapons(entity e, int n)
 198 {
 199         WepSet remaining = e.weapons;
 200         WepSet result = '0 0 0';
 201         for (int j = 0; j < n; ++j)
 202         {
 203                 RandomSelection_Init();
 204                 FOREACH(Weapons, it != WEP_Null, {
 205                         if (remaining & (it.m_wepset))
 206                                 RandomSelection_AddEnt(it, 1, 1);
 207                 });
 208                 Weapon w = RandomSelection_chosen_ent;
 209                 result |= WepSet_FromWeapon(w);
 210                 remaining &= ~WepSet_FromWeapon(w);
 211         }
 212         e.weapons = result;
 213 }
 214
 215 string GetAmmoPicture(int ammotype)
 216 {
 217         switch (ammotype)
 218         {
 219                 case RESOURCE_SHELLS:  return ITEM_Shells.m_icon;
 220                 case RESOURCE_BULLETS: return ITEM_Bullets.m_icon;
 221                 case RESOURCE_ROCKETS: return ITEM_Rockets.m_icon;
 222                 case RESOURCE_CELLS:   return ITEM_Cells.m_icon;
 223                 case RESOURCE_PLASMA:  return ITEM_Plasma.m_icon;
 224                 case RESOURCE_FUEL:    return ITEM_JetpackFuel.m_icon;
 225                 default: return "";  // wtf, no ammo type?
 226         }
 227 }
 228
 229 #ifdef CSQC
 230 int GetAmmoTypeFromNum(int i)
 231 {
 232         switch (i)
 233         {
 234                 case 0: return RESOURCE_SHELLS;
 235                 case 1: return RESOURCE_BULLETS;
 236                 case 2: return RESOURCE_ROCKETS;
 237                 case 3: return RESOURCE_CELLS;
 238                 case 4: return RESOURCE_PLASMA;
 239                 case 5: return RESOURCE_FUEL;
 240                 default: return RESOURCE_NONE;
 241         }
 242 }
 243
 244 int GetAmmoStat(int ammotype)
 245 {
 246         switch (ammotype)
 247         {
 248                 case RESOURCE_SHELLS: return STAT_SHELLS;
 249                 case RESOURCE_BULLETS: return STAT_NAILS;
 250                 case RESOURCE_ROCKETS: return STAT_ROCKETS;
 251                 case RESOURCE_CELLS: return STAT_CELLS;
 252                 case RESOURCE_PLASMA: return STAT_PLASMA.m_id;
 253                 case RESOURCE_FUEL: return STAT_FUEL.m_id;
 254                 default: return -1;
 255         }
 256 }
 257 #endif
 258
 259 string W_Sound(string w_snd)
 260 {
 261         string output = strcat("weapons/", w_snd);
 262         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 263         return M_ARGV(1, string);
 264 }
 265
 266 string W_Model(string w_mdl)
 267 {
 268         string output = strcat("models/weapons/", w_mdl);
 269         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 270         return M_ARGV(1, string);
 271 }
 272
 273 #ifdef GAMEQC
 274 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 275 {
 276         switch (algn)
 277         {
 278                 default:
 279                 case 3:
 280                         // right alignment
 281                         break;
 282                 case 4:
 283                         // left
 284                         vecs.y = -vecs.y;
 285                         break;
 286                 case 1:
 287                 case 2:
 288                         // center
 289                         vecs.y = 0;
 290                         vecs.z -= 2;
 291                         break;
 292         }
 293         return vecs;
 294 }
 295
 296 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 297 {
 298         string s;
 299         if (visual)
 300         {
 301                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 302         }
 303         else if (STAT(SHOOTFROMEYE))
 304         {
 305                 vecs.y = vecs.z = 0;
 306         }
 307         else if (STAT(SHOOTFROMCENTER))
 308         {
 309                 vecs.y = 0;
 310                 vecs.z -= 2;
 311         }
 312         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 313         {
 314                 vector v = stov(s);
 315                 if (y_is_right) v.y = -v.y;
 316                 if (v.x != 0) vecs.x = v.x;
 317                 vecs.y = v.y;
 318                 vecs.z = v.z;
 319         }
 320         else  // just do the same as top
 321         {
 322                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 323         }
 324
 325         return vecs;
 326 }
 327
 328 #define shotorg_adjust shotorg_adjust_values
 329
 330 /**
 331  * supported formats:
 332  *
 333  * 1. simple animated model, muzzle flash handling on h_ model:
 334  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 335  *      tags:
 336  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 337  *        shell = casings ejection point (must be on the right hand side of the gun)
 338  *        weapon = attachment for v_tuba.md3
 339  *    v_tuba.md3 - first and third person model
 340  *    g_tuba.md3 - pickup model
 341  *
 342  * 2. simple animated model, muzzle flash handling on v_ model:
 343  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 344  *      tags:
 345  *        weapon = attachment for v_tuba.md3
 346  *    v_tuba.md3 - first and third person model
 347  *      tags:
 348  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 349  *        shell = casings ejection point (must be on the right hand side of the gun)
 350  *    g_tuba.md3 - pickup model
 351  *
 352  * 3. fully animated model, muzzle flash handling on h_ model:
 353  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 354  *      tags:
 355  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 356  *        shell = casings ejection point (must be on the right hand side of the gun)
 357  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 358  *    v_tuba.md3 - third person model
 359  *    g_tuba.md3 - pickup model
 360  *
 361  * 4. fully animated model, muzzle flash handling on v_ model:
 362  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 363  *      tags:
 364  *        shot = muzzle end (shot origin)
 365  *        shell = casings ejection point (must be on the right hand side of the gun)
 366  *    v_tuba.md3 - third person model
 367  *      tags:
 368  *        shot = muzzle end (for muzzle flashes)
 369  *    g_tuba.md3 - pickup model
 370  *
 371  * writes:
 372  *   this.origin, this.angles
 373  *   this.weaponchild
 374  *   this.movedir, this.view_ofs
 375  *   attachment stuff
 376  *   anim stuff
 377  * to free:
 378  *   call again with ""
 379  *   remove the ent
 380  */
 381 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 382 {
 383         if (name == "")
 384         {
 385                 vector oldmin = this.mins, oldmax = this.maxs;
 386                 setmodel(this, MDL_Null);
 387                 setsize(this, oldmin, oldmax);
 388                 if (this.weaponchild) delete(this.weaponchild);
 389                 this.weaponchild = NULL;
 390                 this.movedir = '0 0 0';
 391                 this.spawnorigin = '0 0 0';
 392                 this.oldorigin = '0 0 0';
 393                 this.anim_fire1  = '0 1 0.01';
 394                 this.anim_fire2  = '0 1 0.01';
 395                 this.anim_idle   = '0 1 0.01';
 396                 this.anim_reload = '0 1 0.01';
 397         }
 398         else
 399         {
 400                 // if there is a child entity, hide it until we're sure we use it
 401                 if (this.weaponchild) this.weaponchild.model = "";
 402                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 403                 int v_shot_idx;  // used later
 404                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 405
 406                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 407                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 408                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 409                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 410                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 411                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 412
 413                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 414                 // if we don't, this is a "real" animated model
 415                 string t;
 416                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 417                 {
 418                         if (!this.weaponchild)
 419                         {
 420                                 this.weaponchild = new(weaponchild);
 421 #ifdef CSQC
 422                                 this.weaponchild.drawmask = MASK_NORMAL;
 423                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 424 #endif
 425                         }
 426                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 427                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 428                         setattachment(this.weaponchild, this, t);
 429                 }
 430                 else
 431                 {
 432                         if (this.weaponchild) delete(this.weaponchild);
 433                         this.weaponchild = NULL;
 434                 }
 435
 436                 setsize(this, '0 0 0', '0 0 0');
 437                 setorigin(this, '0 0 0');
 438                 this.angles = '0 0 0';
 439                 this.frame = 0;
 440 #ifdef SVQC
 441                 this.viewmodelforclient = NULL;
 442 #else
 443                 this.renderflags &= ~RF_VIEWMODEL;
 444 #endif
 445                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 446                 {
 447                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 448                 }
 449                 else
 450                 {
 451                         int idx;
 452                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 453                         {
 454                                 this.movedir = gettaginfo(this, idx);
 455                         }
 456                         else
 457                         {
 458                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 459                                         this.model);
 460                                 this.movedir = '0 0 0';
 461                         }
 462                 }
 463                 {
 464                         int idx = 0;
 465                         // v_ model attached to invisible h_ model
 466                         if (this.weaponchild
 467                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 468                         {
 469                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 470                         }
 471                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 472                         {
 473                                 this.spawnorigin = gettaginfo(this, idx);
 474                         }
 475                         else
 476                         {
 477                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 478                                         this.model);
 479                                 this.spawnorigin = this.movedir;
 480                         }
 481                 }
 482                 if (v_shot_idx)
 483                 {
 484                         this.oldorigin = '0 0 0';  // use regular attachment
 485                 }
 486                 else
 487                 {
 488                         int idx;
 489                         if (this.weaponchild)
 490                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 491                         else
 492                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 493                         if (idx)
 494                         {
 495                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 496                         }
 497                         else
 498                         {
 499                                 LOG_WARNF(
 500                                         "weapon model %s does not support the 'handle' tag "
 501                                         "and neither does the v_ model support the 'shot' tag, "
 502                                         "will display muzzle flashes TOTALLY wrong\n",
 503                                         this.model);
 504                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 505                         }
 506                 }
 507
 508 #ifdef SVQC
 509                 this.viewmodelforclient = this.owner;
 510 #else
 511                 this.renderflags |= RF_VIEWMODEL;
 512 #endif
 513         }
 514
 515         this.view_ofs = '0 0 0';
 516
 517         if (this.movedir.x >= 0)
 518         {
 519                 //int algn = STAT(GUNALIGN, this.owner);
 520                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 521         #ifdef SVQC
 522                 this.m_gunalign = algn;
 523         #endif
 524                 vector v = this.movedir;
 525                 this.movedir = shotorg_adjust(v, false, false, algn);
 526                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 527         }
 528         int compressed_shotorg = compressShotOrigin(this.movedir);
 529         // make them match perfectly
 530 #ifdef SVQC
 531     // null during init
 532     if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 533         this.movedir = decompressShotOrigin(compressed_shotorg);
 534 #else
 535         this.movedir = decompressShotOrigin(compressed_shotorg);
 536 #endif
 537
 538         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 539
 540         // check if an instant weapon switch occurred
 541         setorigin(this, this.view_ofs);
 542         if (!_anim) return;
 543         // reset animstate now
 544         this.wframe = WFRAME_IDLE;
 545         setanim(this, this.anim_idle, true, false, true);
 546 }
 547 #endif
 548
 549 #ifdef GAMEQC
 550
 551 REGISTER_NET_TEMP(wframe)
 552 #ifdef CSQC
 553 NET_HANDLE(wframe, bool isNew)
 554 {
 555         vector a = ReadVector();
 556     int slot = ReadByte();
 557         bool restartanim = ReadByte();
 558         entity wepent = viewmodels[slot];
 559         if(a.x == wepent.anim_idle_x) // we don't need to enforce idle animation
 560                 wepent.animstate_looping = false;
 561         else
 562                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 563         wepent.state = ReadByte();
 564         wepent.weapon_nextthink = ReadFloat();
 565         switch (wepent.state)
 566         {
 567                 case WS_RAISE:
 568                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 569                         break;
 570                 case WS_DROP:
 571                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 572                         break;
 573         default:
 574             wepent.weapon_switchdelay = 0;
 575             break;
 576         }
 577         return true;
 578 }
 579 #endif
 580
 581 #ifdef SVQC
 582 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 583 {
 584         if (!IS_REAL_CLIENT(actor)) return;
 585         int channel = MSG_ONE;
 586         msg_entity = actor;
 587         WriteHeader(channel, wframe);
 588         WriteVector(channel, a);
 589         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 590         WriteByte(channel, restartanim);
 591         WriteByte(channel, weaponentity.state);
 592         WriteFloat(channel, weaponentity.weapon_nextthink);
 593 }
 594 #endif
 595
 596 REGISTER_NET_C2S(w_whereis)
 597 #ifdef SVQC
 598 void Weapon_whereis(Weapon this, entity cl);
 599 NET_HANDLE(w_whereis, bool)
 600 {
 601         Weapon wpn = ReadRegistered(Weapons);
 602         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 603         return true;
 604 }
 605 #else
 606 void w_whereis(Weapon this)
 607 {
 608         int channel = MSG_C2S;
 609         WriteHeader(channel, w_whereis);
 610         WriteRegistered(Weapons, channel, this);
 611 }
 612 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 613 {
 614         switch (request)
 615         {
 616                 case CMD_REQUEST_COMMAND:
 617                 {
 618                         string s = argv(1);
 619                         if (s == "all")
 620                         {
 621                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 622                                 return;
 623                         }
 624                         if (s == "unowned")
 625                         {
 626                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 627                                 return;
 628                         }
 629                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 630                         {
 631                                 w_whereis(it);
 632                                 return;
 633                         });
 634                 }
 635                 default:
 636                 {
 637                         LOG_INFOF("Incorrect parameters for ^2%s^7", "weapon_find");
 638                 }
 639                 case CMD_REQUEST_USAGE:
 640                 {
 641                         LOG_INFO("Usage:^3 cl_cmd weapon_find weapon");
 642                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 643                         return;
 644                 }
 645         }
 646 }
 647 #endif
 648
 649
 650 #endif
 651
 652 #endif