qcsrc/common/weapons/all.qh

   1 #ifndef WEAPONS_ALL_H
   2 #define WEAPONS_ALL_H
   3
   4 #include "../command/all.qh"
   5 #include "config.qh"
   6
   7 // weapon sets
   8 typedef vector WepSet;
   9 #define WEPSET(id) WepSet_FromWeapon(WEP_##id.m_id)
  10 WepSet WepSet_FromWeapon(int a);
  11 #ifdef SVQC
  12 void WepSet_AddStat();
  13 void WepSet_AddStat_InMap();
  14 void WriteWepSet(float dest, WepSet w);
  15 #endif
  16
  17 #ifdef CSQC
  18 WepSet WepSet_GetFromStat();
  19 WepSet WepSet_GetFromStat_InMap();
  20 WepSet ReadWepSet();
  21 #endif
  22
  23 #include "weapon.qh"
  24
  25 #ifndef MENUQC
  26 #include "calculations.qh"
  27 #include "../models/all.qh"
  28 #endif
  29
  30 #include "../util.qh"
  31
  32 #ifdef SVQC
  33 #include "../../server/bot/aim.qh"
  34 #endif
  35
  36 REGISTRY(Weapons, 72) // Increase as needed. Can be up to 72.
  37 REGISTER_REGISTRY(RegisterWeapons)
  38 STATIC_INIT(WeaponPickup) { FOREACH(Weapons, true, LAMBDA(it.m_pickup = NEW(WeaponPickup, it))); }
  39 entity get_weaponinfo(int id);
  40
  41
  42 GENERIC_COMMAND(dumpweapons, "Dump all weapons into weapons_dump.txt") // WEAPONTODO: make this work with other progs than just server
  43 {
  44     switch(request)
  45     {
  46         case CMD_REQUEST_COMMAND:
  47         {
  48             #ifdef SVQC
  49             wep_config_file = -1;
  50             wep_config_alsoprint = -1;
  51             string filename = argv(1);
  52
  53             if(filename == "")
  54             {
  55                 filename = "weapons_dump.cfg";
  56                 wep_config_alsoprint = false;
  57             }
  58             else if(filename == "-")
  59             {
  60                 filename = "weapons_dump.cfg";
  61                 wep_config_alsoprint = true;
  62             }
  63             wep_config_file = fopen(filename, FILE_WRITE);
  64
  65             if(wep_config_file >= 0)
  66             {
  67                 Dump_Weapon_Settings();
  68                 LOG_INFO(sprintf("Dumping weapons... File located in ^2data/data/%s^7.\n", filename));
  69                 fclose(wep_config_file);
  70                 wep_config_file = -1;
  71                 wep_config_alsoprint = -1;
  72             }
  73             else
  74             {
  75                 LOG_INFO(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
  76             }
  77             #else
  78             LOG_INFO(_("Weapons dump command only works with sv_cmd.\n"));
  79             #endif
  80             return;
  81         }
  82
  83         default:
  84         case CMD_REQUEST_USAGE:
  85         {
  86             LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpweapons [filename]"));
  87             LOG_INFO("  Where 'filename' is the file to write (default is weapons_dump.cfg),\n");
  88             LOG_INFO("  if supplied with '-' output to console as well as default,\n");
  89             LOG_INFO("  if left blank, it will only write to default.\n");
  90             return;
  91         }
  92     }
  93 }
  94
  95 #define REGISTER_WEAPON(id, inst) \
  96     /* WepSet WEPSET_##id; */ \
  97     REGISTER(RegisterWeapons, WEP, Weapons, id, m_id, inst)
  98
  99 // create cvars for weapon settings
 100 #define WEP_ADD_CVAR_NONE(wepname,name) [[last]] float autocvar_g_balance_##wepname##_##name;
 101
 102 #define WEP_ADD_CVAR_PRI(wepname,name) WEP_ADD_CVAR_NONE(wepname, primary_##name)
 103 #define WEP_ADD_CVAR_SEC(wepname,name) WEP_ADD_CVAR_NONE(wepname, secondary_##name)
 104 #define WEP_ADD_CVAR_BOTH(wepname,name) \
 105     WEP_ADD_CVAR_PRI(wepname, name) \
 106     WEP_ADD_CVAR_SEC(wepname, name)
 107
 108 #define WEP_ADD_CVAR(wepid,wepname,mode,name) WEP_ADD_CVAR_##mode(wepname, name)
 109
 110 // create properties for weapon settings
 111 #define WEP_ADD_PROP(wepid,wepname,type,prop,name) \
 112     .type prop; \
 113     [[last]] type autocvar_g_balance_##wepname##_##name;
 114
 115 // read cvars from weapon settings
 116 #define WEP_CVAR(wepname,name) autocvar_g_balance_##wepname##_##name
 117 #define WEP_CVAR_PRI(wepname,name) WEP_CVAR(wepname, primary_##name)
 118 #define WEP_CVAR_SEC(wepname,name) WEP_CVAR(wepname, secondary_##name)
 119 #define WEP_CVAR_BOTH(wepname,isprimary,name) ((isprimary) ? WEP_CVAR_PRI(wepname, name) : WEP_CVAR_SEC(wepname, name))
 120
 121 // set initialization values for weapon settings
 122 #define WEP_SKIP_CVAR(unuseda,unusedb,unusedc,unusedd) /* skip cvars */
 123 #define WEP_SET_PROP(wepid,wepname,type,prop,name) WEP_##wepid.prop = autocvar_g_balance_##wepname##_##name;
 124
 125 const int WEP_FIRST = 1;
 126 #define WEP_LAST (Weapons_COUNT - 1)
 127 WepSet WEPSET_ALL;
 128 WepSet WEPSET_SUPERWEAPONS;
 129
 130 REGISTER_WEAPON(Null, NEW(Weapon));
 131
 132 #include "all.inc"
 133
 134 entity get_weaponinfo(int id)
 135 {
 136     if (id >= WEP_FIRST && id <= WEP_LAST) {
 137         Weapon w = Weapons[id];
 138         if (w) return w;
 139     }
 140     return WEP_Null;
 141 }
 142
 143 // TODO: remove after 0.8.2. Retains impulse number compatibility because 0.8.1 clients don't reload the weapons.cfg
 144 #define WEP_HARDCODED_IMPULSES 22
 145
 146 // TODO: invert after 0.8.2. Will require moving 'best weapon' impulses
 147 #define WEP_IMPULSE_BEGIN 230
 148 #define WEP_IMPULSE_END bound(WEP_IMPULSE_BEGIN, WEP_IMPULSE_BEGIN + (Weapons_COUNT - 1) - 1, 253)
 149
 150 REGISTRY_SORT(Weapons, netname, WEP_HARDCODED_IMPULSES + 1)
 151
 152 STATIC_INIT(register_weapons_done)
 153 {
 154     FOREACH(Weapons, true, LAMBDA(
 155         it.m_id = i;
 156         WepSet set = WepSet_FromWeapon(it.m_id);
 157         WEPSET_ALL |= set;
 158         if ((it.spawnflags) & WEP_FLAG_SUPERWEAPON) WEPSET_SUPERWEAPONS |= set;
 159         it.weapon = it.m_id;
 160         it.weapons = set;
 161         int imp = WEP_IMPULSE_BEGIN + it.m_id - 1;
 162         if (imp <= WEP_IMPULSE_END)
 163             localcmd(sprintf("alias weapon_%s \"impulse %d\"\n", it.netname, imp));
 164         else
 165             LOG_TRACEF(_("Impulse limit exceeded, weapon will not be directly accessible: %s\n"), it.netname);
 166     ));
 167     #ifdef CSQC
 168     FOREACH(Weapons, true, LAMBDA(it.wr_init(it)));
 169     #endif
 170     weaponorder_byid = "";
 171     for (int i = Weapons_MAX - 1; i >= 1; --i)
 172         if (Weapons[i])
 173             weaponorder_byid = strcat(weaponorder_byid, " ", ftos(i));
 174     weaponorder_byid = strzone(substring(weaponorder_byid, 1, strlen(weaponorder_byid) - 1));
 175 }
 176
 177 #ifdef SVQC
 178 void CL_WeaponEntity_SetModel(entity this, int slot, string name);
 179 #endif
 180
 181 #endif