qcsrc/common/weapons/all.qh

   1 #ifndef WEAPONS_ALL_H
   2 #define WEAPONS_ALL_H
   3
   4 #include <common/command/all.qh>
   5 #include <common/stats.qh>
   6 #include "config.qh"
   7
   8 // weapon sets
   9 USING(WepSet, vector);
  10 #ifdef SVQC
  11 void WriteWepSet(float dest, WepSet w);
  12 #endif
  13
  14 #ifdef CSQC
  15 WepSet WepSet_GetFromStat();
  16 WepSet WepSet_GetFromStat_InMap();
  17 WepSet ReadWepSet();
  18 #endif
  19
  20 #include "weapon.qh"
  21
  22 #ifndef MENUQC
  23 #include "calculations.qh"
  24 #include <common/models/all.qh>
  25 #endif
  26
  27 #include <common/util.qh>
  28
  29 #ifdef SVQC
  30 #include <server/bot/aim.qh>
  31 #endif
  32
  33 REGISTRY(Weapons, 72) // Increase as needed. Can be up to 72.
  34 #define Weapons_from(i) _Weapons_from(i, WEP_Null)
  35 REGISTER_REGISTRY(Weapons)
  36 STATIC_INIT(WeaponPickup) { FOREACH(Weapons, true, it.m_pickup = NEW(WeaponPickup, it)); }
  37
  38 .WepSet m_wepset;
  39 #define WEPSET(id) (WEP_##id.m_wepset)
  40 #define WepSet_FromWeapon(it) ((it).m_wepset)
  41 WepSet _WepSet_FromWeapon(int i);
  42
  43 GENERIC_COMMAND(dumpweapons, "Dump all weapons into weapons_dump.txt") // WEAPONTODO: make this work with other progs than just server
  44 {
  45     switch(request)
  46     {
  47         case CMD_REQUEST_COMMAND:
  48         {
  49             #ifdef SVQC
  50             wep_config_file = -1;
  51             wep_config_alsoprint = -1;
  52             string filename = argv(1);
  53
  54             if(filename == "")
  55             {
  56                 filename = "weapons_dump.cfg";
  57                 wep_config_alsoprint = false;
  58             }
  59             else if(filename == "-")
  60             {
  61                 filename = "weapons_dump.cfg";
  62                 wep_config_alsoprint = true;
  63             }
  64             wep_config_file = fopen(filename, FILE_WRITE);
  65
  66             if(wep_config_file >= 0)
  67             {
  68                 Dump_Weapon_Settings();
  69                 LOG_INFO(sprintf("Dumping weapons... File located in ^2data/data/%s^7.\n", filename));
  70                 fclose(wep_config_file);
  71                 wep_config_file = -1;
  72                 wep_config_alsoprint = -1;
  73             }
  74             else
  75             {
  76                 LOG_INFO(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
  77             }
  78             #else
  79             LOG_INFO(_("Weapons dump command only works with sv_cmd.\n"));
  80             #endif
  81             return;
  82         }
  83
  84         default:
  85         case CMD_REQUEST_USAGE:
  86         {
  87             LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpweapons [filename]"));
  88             LOG_INFO("  Where 'filename' is the file to write (default is weapons_dump.cfg),\n");
  89             LOG_INFO("  if supplied with '-' output to console as well as default,\n");
  90             LOG_INFO("  if left blank, it will only write to default.\n");
  91             return;
  92         }
  93     }
  94 }
  95
  96 #ifdef SVQC
  97 entity W_PROP_reloader;
  98 float autocvar_w_prop_interval = 5;
  99 .void(Weapon this, int) wr_net;
 100 void W_PROP_reload(int chan, entity to)
 101 {
 102     W_PROP_reloader.nextthink = time + autocvar_w_prop_interval;
 103     msg_entity = to;
 104     FOREACH(Weapons, true, {
 105         it.wr_update(it);
 106         void(Weapon, int) f = it.wr_net;
 107         if (f) f(it, chan);
 108     });
 109 }
 110 void W_PROP_think(entity this)
 111 {
 112     W_PROP_reload(MSG_ALL, NULL);
 113 }
 114 STATIC_INIT_LATE(W_PROP_reloader)
 115 {
 116     entity e = W_PROP_reloader = new_pure(W_PROP_reloader);
 117     setthink(e, W_PROP_think);
 118     W_PROP_think(e);
 119 }
 120 #endif
 121
 122 #define REGISTER_WEAPON(...) EVAL_REGISTER_WEAPON(OVERLOAD(REGISTER_WEAPON, __VA_ARGS__))
 123 #define EVAL_REGISTER_WEAPON(...) __VA_ARGS__
 124 #define REGISTER_WEAPON_2(id, inst) REGISTER(Weapons, WEP, id, m_id, inst)
 125 /** TODO: deprecated - remove */
 126 #define REGISTER_WEAPON_3(id, sname, inst) \
 127     REGISTER_WEAPON_2(id, inst); \
 128     [[alias("WEP_" #id)]] Weapon _wep_##sname
 129
 130 REGISTER_WEAPON(Null, NEW(Weapon));
 131
 132 Weapon Weapons_fromstr(string s)
 133 {
 134     FOREACH(Weapons, it != WEP_Null && it.netname == s, return it);
 135     return NULL;
 136 }
 137
 138
 139 // legacy w_prop mappings
 140 #define X(fld, T) .T fld; .T wepvar_##fld = fld;
 141 X(switchdelay_drop, float)
 142 X(switchdelay_raise, float)
 143 X(weaponreplace, string)
 144 X(weaponstartoverride, float)
 145 X(weaponstart, float)
 146 X(weaponthrowable, float)
 147 X(reload_ammo, float)
 148 .float reloading_ammo = reload_ammo;
 149 X(reload_time, float)
 150 .float reloading_time = reload_time;
 151 #undef X
 152
 153
 154
 155 #define W_PROPS(L, class, prefix) \
 156     L(W_PROP_BEGIN, W_PROP, W_PROP_END, class, prefix) \
 157     L(W_CONFIG_BEGIN, W_CONFIG, W_CONFIG_END, class, prefix) \
 158     L(W_UPDATE_BEGIN, W_UPDATE, W_UPDATE_END, class, prefix) \
 159     L(W_NET_BEGIN, W_NET, W_NET_END, class, prefix) \
 160     /**/ \
 161
 162
 163     #define W_PROP(class, wepname, fld, T, m)       W_PROP_##m(class, fld, T, wepname)
 164     #define W_PROP_NONE(class, fld, T, wepname)     _W_PROP(class, fld, T, wepname)
 165     #define W_PROP_PRI(class, fld, T, wepname)      _W_PROP(class, primary_##fld, T, wepname)
 166     #define W_PROP_SEC(class, fld, T, wepname)      _W_PROP(class, secondary_##fld, T, wepname)
 167     #define W_PROP_BOTH(class, fld, T, wepname) \
 168             W_PROP_PRI(class, fld, T, wepname) \
 169             W_PROP_SEC(class, fld, T, wepname)
 170     #define W_PROP_BEGIN(class)
 171         #define _W_PROP(class, fld, T, wepname) \
 172             /* static */ T _W_PROP_CVAR(wepname, fld); \
 173             ATTRIB(class, wepvar_##fld, T, _W_PROP_CVAR(wepname, fld));
 174         #define _W_PROP_CVAR(wepname, fld) autocvar_g_balance_##wepname##_##fld
 175     #define W_PROP_END()
 176
 177
 178
 179     #define W_CONFIG(class, wepname, fld, T, m)     W_CONFIG_##m(class, fld, T, wepname)
 180     #define W_CONFIG_NONE(class, fld, T, wepname)   _W_CONFIG(class, fld, T, wepname)
 181     #define W_CONFIG_PRI(class, fld, T, wepname)    _W_CONFIG(class, primary_##fld, T, wepname)
 182     #define W_CONFIG_SEC(class, fld, T, wepname)    _W_CONFIG(class, secondary_##fld, T, wepname)
 183     #define W_CONFIG_BOTH(class, fld, T, wepname) \
 184             W_CONFIG_PRI(class, fld, T, wepname) \
 185             W_CONFIG_SEC(class, fld, T, wepname)
 186     #define W_CONFIG_BEGIN(class) METHOD(class, wr_config, void(class this)) {
 187         #ifdef SVQC
 188             #define _W_CONFIG(class, fld, T, wepname) if (#wepname == this.netname) WEP_CONFIG_WRITE_CVARS(wepname, fld, T);
 189         #else
 190             #define _W_CONFIG(class, fld, T, wepname)
 191         #endif
 192     #define W_CONFIG_END() }
 193
 194
 195     #define W_UPDATE(class, wepname, fld, T, m)     W_UPDATE_##m(class, fld, T, wepname)
 196     #define W_UPDATE_NONE(class, fld, T, wepname)   _W_UPDATE(class, fld, T, wepname)
 197     #define W_UPDATE_PRI(class, fld, T, wepname)    _W_UPDATE(class, primary_##fld, T, wepname)
 198     #define W_UPDATE_SEC(class, fld, T, wepname)    _W_UPDATE(class, secondary_##fld, T, wepname)
 199     #define W_UPDATE_BOTH(class, fld, T, wepname) \
 200             W_UPDATE_PRI(class, fld, T, wepname) \
 201             W_UPDATE_SEC(class, fld, T, wepname)
 202     .entity baseline, baseline_target;
 203     #define W_UPDATE_BEGIN(class) \
 204         METHOD(class, wr_update, void(class this)) \
 205         { \
 206             noref entity b = this.baseline; \
 207             if (!b) \
 208             { \
 209                 b = this.baseline = new_pure(baseline); \
 210                 b.baseline_target = this; \
 211             }
 212         #ifdef SVQC
 213             #define _W_UPDATE(class, fld, T, wepname) \
 214                 { \
 215                     T it = _W_PROP_CVAR(wepname, fld); \
 216                     b.wepvar_##fld = this.wepvar_##fld; \
 217                     this.wepvar_##fld = it; \
 218                 }
 219         #else
 220             #define _W_UPDATE(class, fld, T, wepname)
 221         #endif
 222     #define W_UPDATE_END() }
 223
 224
 225     #define W_NET(class, wepname, fld, T, m)     W_NET_##m(class, fld, T, wepname)
 226     #define W_NET_NONE(class, fld, T, wepname)   _W_NET(class, fld, T, wepname)
 227     #define W_NET_PRI(class, fld, T, wepname)    _W_NET(class, primary_##fld, T, wepname)
 228     #define W_NET_SEC(class, fld, T, wepname)    _W_NET(class, secondary_##fld, T, wepname)
 229     #define W_NET_BOTH(class, fld, T, wepname) \
 230             W_NET_PRI(class, fld, T, wepname) \
 231             W_NET_SEC(class, fld, T, wepname)
 232     REGISTER_NET_TEMP(WeaponUpdate)
 233     #if defined(CSQC)
 234         #define W_NET_BEGIN(class) METHOD(class, wr_net, void(class this, int i)) { int n = 0;
 235             #define _W_NET(class, fld, T, wepname) \
 236             { \
 237                 if (++n == i) this.wepvar_##fld = Read_##T(); \
 238             }
 239             .void(Weapon this, int i) wr_net;
 240             NET_HANDLE(WeaponUpdate, bool isnew)
 241             {
 242                 Weapon w = Weapons_from(ReadByte());
 243                 for (int i; (i = ReadByte()); )
 244                 {
 245                     w.wr_net(w, i);
 246                 }
 247                 return true;
 248             }
 249         #define W_NET_END() }
 250     #elif defined(SVQC)
 251         #define W_NET_BEGIN(class) \
 252             METHOD(class, wr_net, void(class this, int chan)) \
 253             { \
 254                 bool commit = false; \
 255                 int i = 0;
 256     #define _W_NET(class, fld, T, wepname) \
 257                 { \
 258                     ++i; \
 259                     T it = this.wepvar_##fld; \
 260                     if (chan == MSG_ONE || it != this.baseline.wepvar_##fld) \
 261                     { \
 262                         if (!commit) { commit = true; WriteHeader(chan, WeaponUpdate); WriteByte(chan, this.m_id); } \
 263                         WriteByte(chan, i); Write_##T(chan, it); \
 264                     } \
 265                 }
 266     #define W_NET_END() \
 267                 if (commit) WriteByte(chan, 0); \
 268             }
 269     #else
 270         #define W_NET_BEGIN(class)
 271             #define _W_NET(class, fld, T, wepname)
 272         #define W_NET_END()
 273     #endif
 274
 275
 276
 277 // read cvars from weapon settings
 278 #define WEP_CVAR(wepname, name) (_wep_##wepname.wepvar_##name)
 279 #define WEP_CVAR_PRI(wepname, name) WEP_CVAR(wepname, primary_##name)
 280 #define WEP_CVAR_SEC(wepname, name) WEP_CVAR(wepname, secondary_##name)
 281 #define WEP_CVAR_BOTH(wepname, isprimary, name) ((isprimary) ? WEP_CVAR_PRI(wepname, name) : WEP_CVAR_SEC(wepname, name))
 282
 283 const int WEP_FIRST = 1;
 284 #define WEP_LAST (Weapons_COUNT - 1)
 285 WepSet WEPSET_ALL;
 286 WepSet WEPSET_SUPERWEAPONS;
 287
 288 #include "all.inc"
 289
 290 // TODO: remove after 0.8.2. Retains impulse number compatibility because 0.8.1 clients don't reload the weapons.cfg
 291 #define WEP_HARDCODED_IMPULSES 20
 292
 293 // TODO: invert after 0.8.2. Will require moving 'best weapon' impulses
 294 #define WEP_IMPULSE_BEGIN 230
 295 #define WEP_IMPULSE_END bound(WEP_IMPULSE_BEGIN, WEP_IMPULSE_BEGIN + (Weapons_COUNT - 1) - 1, 253)
 296
 297 REGISTRY_SORT(Weapons, WEP_HARDCODED_IMPULSES + 1)
 298 REGISTRY_CHECK(Weapons)
 299
 300 STATIC_INIT(register_weapons_done)
 301 {
 302         string inaccessible = "";
 303     FOREACH(Weapons, true, {
 304         WepSet set = it.m_wepset = _WepSet_FromWeapon(it.m_id = i);
 305         WEPSET_ALL |= set;
 306         if ((it.spawnflags) & WEP_FLAG_SUPERWEAPON) WEPSET_SUPERWEAPONS |= set;
 307         it.weapons = set;
 308         if (it == WEP_Null) continue;
 309         int imp = WEP_IMPULSE_BEGIN + it.m_id - 1;
 310         if (imp <= WEP_IMPULSE_END)
 311             localcmd(sprintf("alias weapon_%s \"impulse %d\"\n", it.netname, imp));
 312         else
 313                 inaccessible = strcat(inaccessible, "\n", it.netname);
 314     });
 315     if (inaccessible) LOG_TRACEF("Impulse limit exceeded, weapon(s) will not be directly accessible: %s\n", inaccessible);
 316     #ifdef CSQC
 317     FOREACH(Weapons, true, it.wr_init(it));
 318     #endif
 319     weaponorder_byid = "";
 320     for (int i = Weapons_MAX - 1; i >= 1; --i)
 321         if (Weapons_from(i))
 322             weaponorder_byid = strcat(weaponorder_byid, " ", ftos(i));
 323     weaponorder_byid = strzone(substring(weaponorder_byid, 1, -1));
 324 }
 325
 326 #ifndef MENUQC
 327
 328 .entity weaponchild;
 329 .entity exteriorweaponentity;
 330 vector weaponentity_glowmod(Weapon wep, int c)
 331 {
 332     vector g;
 333     if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 334     return g;
 335 }
 336
 337 //.int weapon; // current weapon
 338 .string weaponname; // name of .weapon
 339
 340 .vector spawnorigin; // for casings
 341
 342 // weapon animation vectors:
 343 .vector anim_fire1;
 344 .vector anim_fire2;
 345 .vector anim_idle;
 346 .vector anim_reload;
 347
 348 // static frame globals
 349
 350 ENUMCLASS(WFRAME)
 351 CASE(WFRAME, DONTCHANGE)
 352 CASE(WFRAME, FIRE1)
 353 CASE(WFRAME, FIRE2)
 354 CASE(WFRAME, IDLE)
 355 CASE(WFRAME, RELOAD)
 356 ENUMCLASS_END(WFRAME)
 357
 358 .WFRAME wframe;
 359
 360 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn);
 361 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim);
 362 #endif
 363
 364 #endif