Merge branch 'master' into Mario/vaporizer_damage
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / w_arc.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(
3 /* WEP_##id  */ ARC,
4 /* function  */ W_Arc,
5 /* ammotype  */ ammo_cells,
6 /* impulse   */ 3,
7 /* flags     */ WEP_FLAG_NORMAL,
8 /* rating    */ BOT_PICKUP_RATING_HIGH,
9 /* color     */ '1 1 1',
10 /* modelname */ "arc",
11 /* simplemdl */ "foobar",
12 /* crosshair */ "gfx/crosshairhlac 0.7",
13 /* wepimg    */ "weaponarc",
14 /* refname   */ "arc",
15 /* wepname   */ _("Arc")
16 );
17
18 #define ARC_SETTINGS(w_cvar,w_prop) ARC_SETTINGS_LIST(w_cvar, w_prop, ARC, arc)
19 #define ARC_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
20         w_cvar(id, sn, NONE, beam_ammo) \
21         w_cvar(id, sn, NONE, beam_animtime) \
22         w_cvar(id, sn, NONE, beam_botaimspeed) \
23         w_cvar(id, sn, NONE, beam_botaimlifetime) \
24         w_cvar(id, sn, NONE, beam_damage) \
25         w_cvar(id, sn, NONE, beam_degreespersegment) \
26         w_cvar(id, sn, NONE, beam_distancepersegment) \
27         w_cvar(id, sn, NONE, beam_falloff_halflifedist) \
28         w_cvar(id, sn, NONE, beam_falloff_maxdist) \
29         w_cvar(id, sn, NONE, beam_falloff_mindist) \
30         w_cvar(id, sn, NONE, beam_force) \
31         w_cvar(id, sn, NONE, beam_healing_amax) \
32         w_cvar(id, sn, NONE, beam_healing_aps) \
33         w_cvar(id, sn, NONE, beam_healing_hmax) \
34         w_cvar(id, sn, NONE, beam_healing_hps) \
35         w_cvar(id, sn, NONE, beam_maxangle) \
36         w_cvar(id, sn, NONE, beam_nonplayerdamage) \
37         w_cvar(id, sn, NONE, beam_range) \
38         w_cvar(id, sn, NONE, beam_refire) \
39         w_cvar(id, sn, NONE, beam_returnspeed) \
40         w_cvar(id, sn, NONE, beam_tightness) \
41         w_cvar(id, sn, NONE, burst_ammo) \
42         w_cvar(id, sn, NONE, burst_damage) \
43         w_cvar(id, sn, NONE, burst_healing_aps) \
44         w_cvar(id, sn, NONE, burst_healing_hps) \
45         w_cvar(id, sn, NONE, overheat_max)/* maximum heat before jamming */ \
46         w_cvar(id, sn, NONE, overheat_min)/* minimum heat to wait for cooldown */ \
47         w_cvar(id, sn, NONE, beam_heat)   /* heat increase per second (primary) */ \
48         w_cvar(id, sn, NONE, burst_heat)  /* heat increase per second (secondary) */ \
49         w_cvar(id, sn, NONE, cooldown)    /* heat decrease per second when resting */ \
50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
53         w_prop(id, sn, float,  weaponstart, weaponstart) \
54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
56
57 #ifndef MENUQC
58 const float ARC_MAX_SEGMENTS = 20;
59 vector arc_shotorigin[4];
60 .vector beam_start;
61 .vector beam_dir;
62 .vector beam_wantdir;
63 .int beam_type;
64
65 const int ARC_BT_MISS =        0x00;
66 const int ARC_BT_WALL =        0x01;
67 const int ARC_BT_HEAL =        0x02;
68 const int ARC_BT_HIT =         0x03;
69 const int ARC_BT_BURST_MISS =  0x10;
70 const int ARC_BT_BURST_WALL =  0x11;
71 const int ARC_BT_BURST_HEAL =  0x12;
72 const int ARC_BT_BURST_HIT =   0x13;
73 const int ARC_BT_BURSTMASK =   0x10;
74
75 const int ARC_SF_SETTINGS =    1;
76 const int ARC_SF_START =       2;
77 const int ARC_SF_WANTDIR =     4;
78 const int ARC_SF_BEAMDIR =     8;
79 const int ARC_SF_BEAMTYPE =    16;
80 const int ARC_SF_LOCALMASK =   14;
81 #endif
82 #ifdef SVQC
83 ARC_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
84 .entity arc_beam;
85 .float arc_BUTTON_ATCK_prev; // for better animation control
86 .float beam_prev;
87 .float beam_initialized;
88 .float beam_bursting;
89 .float beam_teleporttime;
90 .float beam_heat; // (beam) amount of heat produced
91 .float arc_overheat; // (dropped arc/player) time during which it's too hot
92 .float arc_cooldown; // (dropped arc/player) cooling speed
93 .float arc_heat_percent; // (player) arc heat in [0,1] (stat)
94 .float arc_smoke_sound;
95 #endif
96 #ifdef CSQC
97 void Ent_ReadArcBeam(float isnew);
98
99 .vector beam_color;
100 .float beam_alpha;
101 .float beam_thickness;
102 .float beam_traileffect;
103 .float beam_hiteffect;
104 .float beam_hitlight[4]; // 0: radius, 123: rgb
105 .float beam_muzzleeffect;
106 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
107 .string beam_image;
108
109 .entity beam_muzzleentity;
110
111 .float beam_degreespersegment;
112 .float beam_distancepersegment;
113 .float beam_usevieworigin;
114 .float beam_initialized;
115 .float beam_maxangle;
116 .float beam_range;
117 .float beam_returnspeed;
118 .float beam_tightness;
119 .vector beam_shotorigin;
120
121 entity Draw_ArcBeam_callback_entity;
122 float Draw_ArcBeam_callback_last_thickness;
123 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
124 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
125 #endif
126 #else
127 #ifdef SVQC
128 void spawnfunc_weapon_arc(void) { weapon_defaultspawnfunc(WEP_ARC); }
129
130 float W_Arc_Beam_Send(entity to, float sf)
131 {
132         WriteByte(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
133
134         // Truncate information when this beam is displayed to the owner client
135         // - The owner client has no use for beam start position or directions,
136         //    it always figures this information out for itself with csqc code.
137         // - Spectating the owner also truncates this information.
138         float drawlocal = ((to == self.owner) || ((to.enemy == self.owner) && IS_SPEC(to)));
139         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
140
141         WriteByte(MSG_ENTITY, sf);
142
143         if(sf & ARC_SF_SETTINGS) // settings information
144         {
145                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
146                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
147                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
148                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
149                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
150                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
151
152                 WriteByte(MSG_ENTITY, drawlocal);
153         }
154         if(sf & ARC_SF_START) // starting location
155         {
156                 WriteCoord(MSG_ENTITY, self.beam_start.x);
157                 WriteCoord(MSG_ENTITY, self.beam_start.y);
158                 WriteCoord(MSG_ENTITY, self.beam_start.z);
159         }
160         if(sf & ARC_SF_WANTDIR) // want/aim direction
161         {
162                 WriteCoord(MSG_ENTITY, self.beam_wantdir.x);
163                 WriteCoord(MSG_ENTITY, self.beam_wantdir.y);
164                 WriteCoord(MSG_ENTITY, self.beam_wantdir.z);
165         }
166         if(sf & ARC_SF_BEAMDIR) // beam direction
167         {
168                 WriteCoord(MSG_ENTITY, self.beam_dir.x);
169                 WriteCoord(MSG_ENTITY, self.beam_dir.y);
170                 WriteCoord(MSG_ENTITY, self.beam_dir.z);
171         }
172         if(sf & ARC_SF_BEAMTYPE) // beam type
173         {
174                 WriteByte(MSG_ENTITY, self.beam_type);
175         }
176
177         return true;
178 }
179
180 void Reset_ArcBeam(entity player, vector forward)
181 {
182         if (!player.arc_beam) {
183                 return;
184         }
185         player.arc_beam.beam_dir = forward;
186         player.arc_beam.beam_teleporttime = time;
187 }
188
189 float Arc_GetHeat_Percent(entity player)
190 {
191         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
192         {
193                 player.arc_overheat = 0;
194                 return 0;
195         }
196
197         if ( player.arc_beam )
198                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
199
200         if ( player.arc_overheat > time )
201         {
202                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
203                         * player.arc_cooldown;
204         }
205
206         return 0;
207 }
208 void Arc_Player_SetHeat(entity player)
209 {
210         player.arc_heat_percent = Arc_GetHeat_Percent(player);
211         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
212 }
213
214 void W_Arc_Beam_Think(void)
215 {
216         if(self != self.owner.arc_beam)
217         {
218                 remove(self);
219                 return;
220         }
221
222
223         float burst = 0;
224         if( self.owner.BUTTON_ATCK2 || self.beam_bursting)
225         {
226                 if(!self.beam_bursting)
227                         self.beam_bursting = true;
228                 burst = ARC_BT_BURSTMASK;
229         }
230
231         if(
232                 !IS_PLAYER(self.owner)
233                 ||
234                 (self.owner.WEP_AMMO(ARC) <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
235                 ||
236                 self.owner.deadflag != DEAD_NO
237                 ||
238                 (!self.owner.BUTTON_ATCK && !burst )
239                 ||
240                 self.owner.frozen
241                 ||
242                 (WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max))
243         )
244         {
245                 if ( WEP_CVAR(arc, cooldown) > 0 )
246                 {
247                         float cooldown_speed = 0;
248                         if ( self.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
249                         {
250                                 cooldown_speed = WEP_CVAR(arc, cooldown);
251                         }
252                         else if ( !burst )
253                         {
254                                 cooldown_speed = self.beam_heat / WEP_CVAR(arc, beam_refire);
255                         }
256
257                         if ( cooldown_speed )
258                         {
259                                 self.owner.arc_overheat = time + self.beam_heat / cooldown_speed;
260                                 self.owner.arc_cooldown = cooldown_speed;
261                         }
262
263                         if ( WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max) )
264                         {
265                                 pointparticles( particleeffectnum("arc_overheat"),
266                                         self.beam_start, self.beam_wantdir, 1 );
267                                 sound(self, CH_WEAPON_A, "weapons/arc_stop.wav", VOL_BASE, ATTN_NORM);
268                         }
269                 }
270
271                 if(self == self.owner.arc_beam) { self.owner.arc_beam = world; }
272                 entity oldself = self;
273                 self = self.owner;
274                 if(!WEP_ACTION(WEP_ARC, WR_CHECKAMMO1) && !WEP_ACTION(WEP_ARC, WR_CHECKAMMO2))
275                 {
276                         // note: this doesn't force the switch
277                         W_SwitchToOtherWeapon(self);
278                 }
279                 self = oldself;
280                 remove(self);
281                 return;
282         }
283
284         // decrease ammo
285         float coefficient = frametime;
286         if(!(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
287         {
288                 float rootammo;
289                 if(burst)
290                         { rootammo = WEP_CVAR(arc, burst_ammo); }
291                 else
292                         { rootammo = WEP_CVAR(arc, beam_ammo); }
293
294                 if(rootammo)
295                 {
296                         coefficient = min(coefficient, self.owner.WEP_AMMO(ARC) / rootammo);
297                         self.owner.WEP_AMMO(ARC) = max(0, self.owner.WEP_AMMO(ARC) - (rootammo * frametime));
298                 }
299         }
300         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
301         self.beam_heat = min( WEP_CVAR(arc, overheat_max), self.beam_heat + heat_speed*frametime );
302
303         makevectors(self.owner.v_angle);
304
305         W_SetupShot_Range(
306                 self.owner,
307                 true,
308                 0,
309                 "",
310                 0,
311                 WEP_CVAR(arc, beam_damage) * coefficient,
312                 WEP_CVAR(arc, beam_range)
313         );
314
315         // After teleport, "lock" the beam until the teleport is confirmed.
316         if (time < self.beam_teleporttime + ANTILAG_LATENCY(self.owner)) {
317                 w_shotdir = self.beam_dir;
318         }
319
320         // network information: shot origin and want/aim direction
321         if(self.beam_start != w_shotorg)
322         {
323                 self.SendFlags |= ARC_SF_START;
324                 self.beam_start = w_shotorg;
325         }
326         if(self.beam_wantdir != w_shotdir)
327         {
328                 self.SendFlags |= ARC_SF_WANTDIR;
329                 self.beam_wantdir = w_shotdir;
330         }
331
332         if(!self.beam_initialized)
333         {
334                 self.beam_dir = w_shotdir;
335                 self.beam_initialized = true;
336         }
337
338         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
339         // idea: blend together self.beam_dir with the inverted direction the player is moving in
340         // might have to make some special accomodation so that it only uses view_right and view_up
341
342         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
343
344         float segments;
345         if(self.beam_dir != w_shotdir)
346         {
347                 // calculate how much we're going to move the end of the beam to the want position
348                 // WEAPONTODO (server and client):
349                 // blendfactor never actually becomes 0 in this situation, which is a problem
350                 // regarding precision... this means that self.beam_dir and w_shotdir approach
351                 // eachother, however they never actually become the same value with this method.
352                 // Perhaps we should do some form of rounding/snapping?
353                 float angle = vlen(w_shotdir - self.beam_dir) * RAD2DEG;
354                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
355                 {
356                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
357                         float blendfactor = bound(
358                                 0,
359                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
360                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
361                         );
362                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
363                 }
364                 else
365                 {
366                         // the radius is not too far yet, no worries :D
367                         float blendfactor = bound(
368                                 0,
369                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
370                                 1
371                         );
372                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
373                 }
374
375                 // network information: beam direction
376                 self.SendFlags |= ARC_SF_BEAMDIR;
377
378                 // calculate how many segments are needed
379                 float max_allowed_segments;
380
381                 if(WEP_CVAR(arc, beam_distancepersegment))
382                 {
383                         max_allowed_segments = min(
384                                 ARC_MAX_SEGMENTS,
385                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
386                         );
387                 }
388                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
389
390                 if(WEP_CVAR(arc, beam_degreespersegment))
391                 {
392                         segments = bound(
393                                 1,
394                                 (
395                                         min(
396                                                 angle,
397                                                 WEP_CVAR(arc, beam_maxangle)
398                                         )
399                                         /
400                                         WEP_CVAR(arc, beam_degreespersegment)
401                                 ),
402                                 max_allowed_segments
403                         );
404                 }
405                 else { segments = 1; }
406         }
407         else { segments = 1; }
408
409         vector beam_endpos = (w_shotorg + (self.beam_dir * WEP_CVAR(arc, beam_range)));
410         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
411
412         float i;
413         float new_beam_type = 0;
414         vector last_origin = w_shotorg;
415         for(i = 1; i <= segments; ++i)
416         {
417                 // WEAPONTODO (client):
418                 // In order to do nice fading and pointing on the starting segment, we must always
419                 // have that drawn as a separate triangle... However, that is difficult to do when
420                 // keeping in mind the above problems and also optimizing the amount of segments
421                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
422
423                 vector new_origin = bezier_quadratic_getpoint(
424                         w_shotorg,
425                         beam_controlpoint,
426                         beam_endpos,
427                         i / segments);
428                 vector new_dir = normalize(new_origin - last_origin);
429
430                 WarpZone_traceline_antilag(
431                         self.owner,
432                         last_origin,
433                         new_origin,
434                         MOVE_NORMAL,
435                         self.owner,
436                         ANTILAG_LATENCY(self.owner)
437                 );
438
439                 // Do all the transforms for warpzones right now, as we already
440                 // "are" in the post-trace system (if we hit a player, that's
441                 // always BEHIND the last passed wz).
442                 last_origin = trace_endpos;
443                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
444                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
445                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
446                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
447
448                 float is_player = (
449                         trace_ent.classname == "player"
450                         ||
451                         trace_ent.classname == "body"
452                         ||
453                         (trace_ent.flags & FL_MONSTER)
454                 );
455
456                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
457                 {
458                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
459                         // NO. trace_endpos should be just fine. If not,
460                         // that's an engine bug that needs proper debugging.
461                         vector hitorigin = trace_endpos;
462
463                         float falloff = ExponentialFalloff(
464                                 WEP_CVAR(arc, beam_falloff_mindist),
465                                 WEP_CVAR(arc, beam_falloff_maxdist),
466                                 WEP_CVAR(arc, beam_falloff_halflifedist),
467                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
468                         );
469
470                         if(is_player && SAME_TEAM(self.owner, trace_ent))
471                         {
472                                 float roothealth, rootarmor;
473                                 if(burst)
474                                 {
475                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
476                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
477                                 }
478                                 else
479                                 {
480                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
481                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
482                                 }
483
484                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
485                                 {
486                                         trace_ent.health = min(
487                                                 trace_ent.health + (roothealth * coefficient),
488                                                 WEP_CVAR(arc, beam_healing_hmax)
489                                         );
490                                 }
491                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
492                                 {
493                                         trace_ent.armorvalue = min(
494                                                 trace_ent.armorvalue + (rootarmor * coefficient),
495                                                 WEP_CVAR(arc, beam_healing_amax)
496                                         );
497                                 }
498
499                                 // stop rot, set visual effect
500                                 if(roothealth || rootarmor)
501                                 {
502                                         trace_ent.pauserothealth_finished = max(
503                                                 trace_ent.pauserothealth_finished,
504                                                 time + autocvar_g_balance_pause_health_rot
505                                         );
506                                         trace_ent.pauserotarmor_finished = max(
507                                                 trace_ent.pauserotarmor_finished,
508                                                 time + autocvar_g_balance_pause_armor_rot
509                                         );
510                                         new_beam_type = ARC_BT_HEAL;
511                                 }
512                         }
513                         else
514                         {
515                                 float rootdamage;
516                                 if(is_player)
517                                 {
518                                         if(burst)
519                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
520                                         else
521                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
522                                 }
523                                 else
524                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
525
526                                 if(accuracy_isgooddamage(self.owner, trace_ent))
527                                 {
528                                         accuracy_add(
529                                                 self.owner,
530                                                 WEP_ARC,
531                                                 0,
532                                                 rootdamage * coefficient * falloff
533                                         );
534                                 }
535
536                                 Damage(
537                                         trace_ent,
538                                         self.owner,
539                                         self.owner,
540                                         rootdamage * coefficient * falloff,
541                                         WEP_ARC,
542                                         hitorigin,
543                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
544                                 );
545
546                                 new_beam_type = ARC_BT_HIT;
547                         }
548                         break;
549                 }
550                 else if(trace_fraction != 1)
551                 {
552                         // we collided with geometry
553                         new_beam_type = ARC_BT_WALL;
554                         break;
555                 }
556         }
557
558         // te_explosion(trace_endpos);
559
560         // if we're bursting, use burst visual effects
561         new_beam_type |= burst;
562
563         // network information: beam type
564         if(new_beam_type != self.beam_type)
565         {
566                 self.SendFlags |= ARC_SF_BEAMTYPE;
567                 self.beam_type = new_beam_type;
568         }
569
570         self.owner.beam_prev = time;
571         self.nextthink = time;
572 }
573
574 void W_Arc_Beam(float burst)
575 {
576
577         // only play fire sound if 1 sec has passed since player let go the fire button
578         if(time - self.beam_prev > 1)
579         {
580                 sound(self, CH_WEAPON_A, "weapons/arc_fire.wav", VOL_BASE, ATTN_NORM);
581         }
582
583         entity beam = self.arc_beam = spawn();
584         beam.classname = "W_Arc_Beam";
585         beam.solid = SOLID_NOT;
586         beam.think = W_Arc_Beam_Think;
587         beam.owner = self;
588         beam.movetype = MOVETYPE_NONE;
589         beam.bot_dodge = true;
590         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
591         beam.beam_bursting = burst;
592         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
593
594         entity oldself = self;
595         self = beam;
596         self.think();
597         self = oldself;
598 }
599
600 void Arc_Smoke()
601 {
602         makevectors(self.v_angle);
603         W_SetupShot_Range(self,true,0,"",0,0,0);
604
605         vector smoke_origin = w_shotorg + self.velocity*frametime;
606         if ( self.arc_overheat > time )
607         {
608                 if ( random() < self.arc_heat_percent )
609                         pointparticles( particleeffectnum("arc_smoke"), smoke_origin, '0 0 0', 1 );
610                 if ( self.BUTTON_ATCK || self.BUTTON_ATCK2 )
611                 {
612                         pointparticles( particleeffectnum("arc_overheat_fire"), smoke_origin, w_shotdir, 1 );
613                         if ( !self.arc_smoke_sound )
614                         {
615                                 self.arc_smoke_sound = 1;
616                                 sound(self, CH_SHOTS_SINGLE, "weapons/arc_loop_overheat.wav", VOL_BASE, ATTN_NORM);
617                         }
618                 }
619         }
620         else if ( self.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
621                         self.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
622         {
623                 if ( random() < (self.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
624                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
625                         pointparticles( particleeffectnum("arc_smoke"), smoke_origin, '0 0 0', 1 );
626         }
627
628         if (  self.arc_smoke_sound && ( self.arc_overheat <= time ||
629                 !( self.BUTTON_ATCK || self.BUTTON_ATCK2 ) ) || self.switchweapon != WEP_ARC )
630         {
631                 self.arc_smoke_sound = 0;
632                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
633         }
634 }
635
636 float W_Arc(float req)
637 {
638         switch(req)
639         {
640                 case WR_AIM:
641                 {
642                         if(WEP_CVAR(arc, beam_botaimspeed))
643                         {
644                                 self.BUTTON_ATCK = bot_aim(
645                                         WEP_CVAR(arc, beam_botaimspeed),
646                                         0,
647                                         WEP_CVAR(arc, beam_botaimlifetime),
648                                         false
649                                 );
650                         }
651                         else
652                         {
653                                 self.BUTTON_ATCK = bot_aim(
654                                         1000000,
655                                         0,
656                                         0.001,
657                                         false
658                                 );
659                         }
660                         return true;
661                 }
662                 case WR_THINK:
663                 {
664                         Arc_Player_SetHeat(self);
665                         Arc_Smoke();
666
667                         if ( self.arc_overheat <= time )
668                         if(self.BUTTON_ATCK || self.BUTTON_ATCK2 || self.arc_beam.beam_bursting )
669                         {
670
671                                 if(self.arc_BUTTON_ATCK_prev)
672                                 {
673                                         #if 0
674                                         if(self.animstate_startframe == self.anim_shoot.x && self.animstate_numframes == self.anim_shoot.y)
675                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
676                                         else
677                                         #endif
678                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
679                                 }
680
681                                 if((!self.arc_beam) || wasfreed(self.arc_beam))
682                                 {
683                                         if(weapon_prepareattack(!!self.BUTTON_ATCK2, 0))
684                                         {
685                                                 W_Arc_Beam(!!self.BUTTON_ATCK2);
686
687                                                 if(!self.arc_BUTTON_ATCK_prev)
688                                                 {
689                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
690                                                         self.arc_BUTTON_ATCK_prev = 1;
691                                                 }
692                                         }
693                                 }
694
695                                 return true;
696                         }
697
698                         if(self.arc_BUTTON_ATCK_prev != 0)
699                         {
700                                 sound(self, CH_WEAPON_A, "weapons/arc_stop.wav", VOL_BASE, ATTN_NORM);
701                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
702                                 ATTACK_FINISHED(self) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor();
703                         }
704                         self.arc_BUTTON_ATCK_prev = 0;
705
706                         #if 0
707                         if(self.BUTTON_ATCK2)
708                         if(weapon_prepareattack(1, autocvar_g_balance_arc_secondary_refire))
709                         {
710                                 W_Arc_Attack2();
711                                 self.arc_count = autocvar_g_balance_arc_secondary_count;
712                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
713                                 self.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor();
714                         }
715                         #endif
716
717                         return true;
718                 }
719                 case WR_INIT:
720                 {
721                         precache_model("models/weapons/g_arc.md3");
722                         precache_model("models/weapons/v_arc.md3");
723                         precache_model("models/weapons/h_arc.iqm");
724                         precache_sound("weapons/arc_fire.wav");
725                         precache_sound("weapons/arc_loop.wav");
726                         precache_sound("weapons/arc_stop.wav");
727                         precache_sound("weapons/arc_loop_overheat.wav");
728                         if(!arc_shotorigin[0])
729                         {
730                                 arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC), false, false, 1);
731                                 arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC), false, false, 2);
732                                 arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC), false, false, 3);
733                                 arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC), false, false, 4);
734                         }
735                         ARC_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
736                         return true;
737                 }
738                 case WR_CHECKAMMO1:
739                 {
740                         return ((!WEP_CVAR(arc, beam_ammo)) || (self.WEP_AMMO(ARC) > 0));
741                 }
742                 case WR_CHECKAMMO2:
743                 {
744                         return WEP_CVAR(arc, overheat_max) > 0 &&
745                                 ((!WEP_CVAR(arc, burst_ammo)) || (self.WEP_AMMO(ARC) > 0));
746                 }
747                 case WR_CONFIG:
748                 {
749                         ARC_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
750                         return true;
751                 }
752                 case WR_KILLMESSAGE:
753                 {
754                         return WEAPON_ARC_MURDER;
755                 }
756                 case WR_DROP:
757                 {
758                         weapon_dropevent_item.arc_overheat = self.arc_overheat;
759                         weapon_dropevent_item.arc_cooldown = self.arc_cooldown;
760                         self.arc_overheat = 0;
761                         self.arc_cooldown = 0;
762                         return true;
763                 }
764                 case WR_PICKUP:
765                 {
766                         if ( !client_hasweapon(self, WEP_ARC, false, false) &&
767                                 weapon_dropevent_item.arc_overheat > time )
768                         {
769                                 self.arc_overheat = weapon_dropevent_item.arc_overheat;
770                                 self.arc_cooldown = weapon_dropevent_item.arc_cooldown;
771                         }
772                         return true;
773                 }
774         }
775         return false;
776 }
777 #endif
778 #ifdef CSQC
779 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
780 {
781         entity beam = Draw_ArcBeam_callback_entity;
782         vector transformed_view_org;
783         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
784
785         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
786         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
787         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
788
789         vector hitorigin;
790
791         // draw segment
792         #if 0
793         if(trace_fraction != 1)
794         {
795                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
796                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
797                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
798         }
799         else
800         {
801                 hitorigin = hit;
802         }
803         #else
804         hitorigin = hit;
805         #endif
806
807         // decide upon thickness
808         float thickness = beam.beam_thickness;
809
810         // draw primary beam render
811         vector top    = hitorigin + (thickdir * thickness);
812         vector bottom = hitorigin - (thickdir * thickness);
813
814         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
815         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
816
817         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
818         R_PolygonVertex(
819                 top,
820                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
821                 beam.beam_color,
822                 beam.beam_alpha
823         );
824         R_PolygonVertex(
825                 last_top,
826                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
827                 beam.beam_color,
828                 beam.beam_alpha
829         );
830         R_PolygonVertex(
831                 last_bottom,
832                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
833                 beam.beam_color,
834                 beam.beam_alpha
835         );
836         R_PolygonVertex(
837                 bottom,
838                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
839                 beam.beam_color,
840                 beam.beam_alpha
841         );
842         R_EndPolygon();
843
844         // draw trailing particles
845         // NOTES:
846         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
847         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
848         if(beam.beam_traileffect)
849         {
850                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
851         }
852
853         // set up for the next
854         Draw_ArcBeam_callback_last_thickness = thickness;
855         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
856         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
857 }
858
859 void Reset_ArcBeam(void)
860 {
861         entity e;
862         for (e = world; (e = findfloat(e, beam_usevieworigin, 1)); ) {
863                 e.beam_initialized = false;
864         }
865         for (e = world; (e = findfloat(e, beam_usevieworigin, 2)); ) {
866                 e.beam_initialized = false;
867         }
868 }
869
870 void Draw_ArcBeam(void)
871 {
872         float dt = time - self.move_time;
873         self.move_time = time;
874         if(dt <= 0) { return; }
875
876         if(!self.beam_usevieworigin)
877         {
878                 InterpolateOrigin_Do();
879         }
880
881         // origin = beam starting origin
882         // v_angle = wanted/aim direction
883         // angles = current direction of beam
884
885         vector start_pos;
886         vector wantdir; //= view_forward;
887         vector beamdir; //= self.beam_dir;
888
889         float segments;
890         if(self.beam_usevieworigin)
891         {
892                 // WEAPONTODO:
893                 // Currently we have to replicate nearly the same method of figuring
894                 // out the shotdir that the server does... Ideally in the future we
895                 // should be able to acquire this from a generalized function built
896                 // into a weapon system for client code.
897
898                 // find where we are aiming
899                 makevectors(warpzone_save_view_angles);
900                 vector forward = v_forward;
901                 vector right = v_right;
902                 vector up = v_up;
903
904                 // decide upon start position
905                 if(self.beam_usevieworigin == 2)
906                         { start_pos = warpzone_save_view_origin; }
907                 else
908                         { start_pos = self.origin; }
909
910                 // trace forward with an estimation
911                 WarpZone_TraceLine(
912                         start_pos,
913                         start_pos + forward * self.beam_range,
914                         MOVE_NOMONSTERS,
915                         self
916                 );
917
918                 // untransform in case our trace went through a warpzone
919                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
920
921                 // un-adjust trueaim if shotend is too close
922                 if(vlen(end_pos - start_pos) < g_trueaim_minrange)
923                         end_pos = start_pos + (forward * g_trueaim_minrange);
924
925                 // move shot origin to the actual gun muzzle origin
926                 vector origin_offset =
927                           right * -self.beam_shotorigin.y
928                         + up * self.beam_shotorigin.z;
929
930                 start_pos = start_pos + origin_offset;
931
932                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
933                 traceline(start_pos, start_pos + forward * self.beam_shotorigin.x, MOVE_NORMAL, self);
934                 start_pos = trace_endpos;
935
936                 // calculate the aim direction now
937                 wantdir = normalize(end_pos - start_pos);
938
939                 if(!self.beam_initialized)
940                 {
941                         self.beam_dir = wantdir;
942                         self.beam_initialized = true;
943                 }
944
945                 if(self.beam_dir != wantdir)
946                 {
947                         // calculate how much we're going to move the end of the beam to the want position
948                         // WEAPONTODO (server and client):
949                         // blendfactor never actually becomes 0 in this situation, which is a problem
950                         // regarding precision... this means that self.beam_dir and w_shotdir approach
951                         // eachother, however they never actually become the same value with this method.
952                         // Perhaps we should do some form of rounding/snapping?
953                         float angle = vlen(wantdir - self.beam_dir) * RAD2DEG;
954                         if(angle && (angle > self.beam_maxangle))
955                         {
956                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
957                                 float blendfactor = bound(
958                                         0,
959                                         (1 - (self.beam_returnspeed * frametime)),
960                                         min(self.beam_maxangle / angle, 1)
961                                 );
962                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
963                         }
964                         else
965                         {
966                                 // the radius is not too far yet, no worries :D
967                                 float blendfactor = bound(
968                                         0,
969                                         (1 - (self.beam_returnspeed * frametime)),
970                                         1
971                                 );
972                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
973                         }
974
975                         // calculate how many segments are needed
976                         float max_allowed_segments;
977
978                         if(self.beam_distancepersegment)
979                         {
980                                 max_allowed_segments = min(
981                                         ARC_MAX_SEGMENTS,
982                                         1 + (vlen(wantdir / self.beam_distancepersegment))
983                                 );
984                         }
985                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
986
987                         if(self.beam_degreespersegment)
988                         {
989                                 segments = bound(
990                                         1,
991                                         (
992                                                 min(
993                                                         angle,
994                                                         self.beam_maxangle
995                                                 )
996                                                 /
997                                                 self.beam_degreespersegment
998                                         ),
999                                         max_allowed_segments
1000                                 );
1001                         }
1002                         else { segments = 1; }
1003                 }
1004                 else { segments = 1; }
1005
1006                 // set the beam direction which the rest of the code will refer to
1007                 beamdir = self.beam_dir;
1008
1009                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
1010                 self.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1011         }
1012         else
1013         {
1014                 // set the values from the provided info from the networked entity
1015                 start_pos = self.origin;
1016                 wantdir = self.v_angle;
1017                 beamdir = self.angles;
1018
1019                 if(beamdir != wantdir)
1020                 {
1021                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1022
1023                         // calculate how many segments are needed
1024                         float max_allowed_segments;
1025
1026                         if(self.beam_distancepersegment)
1027                         {
1028                                 max_allowed_segments = min(
1029                                         ARC_MAX_SEGMENTS,
1030                                         1 + (vlen(wantdir / self.beam_distancepersegment))
1031                                 );
1032                         }
1033                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1034
1035                         if(self.beam_degreespersegment)
1036                         {
1037                                 segments = bound(
1038                                         1,
1039                                         (
1040                                                 min(
1041                                                         angle,
1042                                                         self.beam_maxangle
1043                                                 )
1044                                                 /
1045                                                 self.beam_degreespersegment
1046                                         ),
1047                                         max_allowed_segments
1048                                 );
1049                         }
1050                         else { segments = 1; }
1051                 }
1052                 else { segments = 1; }
1053         }
1054
1055         setorigin(self, start_pos);
1056         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1057
1058         vector beam_endpos = (start_pos + (beamdir * self.beam_range));
1059         vector beam_controlpoint = start_pos + wantdir * (self.beam_range * (1 - self.beam_tightness));
1060
1061         Draw_ArcBeam_callback_entity = self;
1062         Draw_ArcBeam_callback_last_thickness = 0;
1063         Draw_ArcBeam_callback_last_top = start_pos;
1064         Draw_ArcBeam_callback_last_bottom = start_pos;
1065
1066         vector last_origin = start_pos;
1067         vector original_start_pos = start_pos;
1068
1069         float i;
1070         for(i = 1; i <= segments; ++i)
1071         {
1072                 // WEAPONTODO (client):
1073                 // In order to do nice fading and pointing on the starting segment, we must always
1074                 // have that drawn as a separate triangle... However, that is difficult to do when
1075                 // keeping in mind the above problems and also optimizing the amount of segments
1076                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1077
1078                 vector new_origin = bezier_quadratic_getpoint(
1079                         start_pos,
1080                         beam_controlpoint,
1081                         beam_endpos,
1082                         i / segments);
1083
1084                 WarpZone_TraceBox_ThroughZone(
1085                         last_origin,
1086                         '0 0 0',
1087                         '0 0 0',
1088                         new_origin,
1089                         MOVE_NORMAL,
1090                         world,
1091                         world,
1092                         Draw_ArcBeam_callback
1093                 );
1094
1095                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1096                 // system (if we hit a player, that's always BEHIND the last passed wz).
1097                 last_origin = trace_endpos;
1098                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1099                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1100                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1101                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1102                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1103                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1104
1105                 if(trace_fraction < 1) { break; }
1106         }
1107
1108         // visual effects for startpoint and endpoint
1109         if(self.beam_hiteffect)
1110         {
1111                 // FIXME we really should do this on the server so it actually
1112                 // matches gameplay. What this client side stuff is doing is no
1113                 // more than guesswork.
1114                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1115                 pointparticles(
1116                         self.beam_hiteffect,
1117                         last_origin,
1118                         beamdir * -1,
1119                         frametime * 2
1120                 );
1121         }
1122         if(self.beam_hitlight[0])
1123         {
1124                 adddynamiclight(
1125                         last_origin,
1126                         self.beam_hitlight[0],
1127                         vec3(
1128                                 self.beam_hitlight[1],
1129                                 self.beam_hitlight[2],
1130                                 self.beam_hitlight[3]
1131                         )
1132                 );
1133         }
1134         if(self.beam_muzzleeffect)
1135         {
1136                 pointparticles(
1137                         self.beam_muzzleeffect,
1138                         original_start_pos + wantdir * 20,
1139                         wantdir * 1000,
1140                         frametime * 0.1
1141                 );
1142         }
1143         if(self.beam_muzzlelight[0])
1144         {
1145                 adddynamiclight(
1146                         original_start_pos + wantdir * 20,
1147                         self.beam_muzzlelight[0],
1148                         vec3(
1149                                 self.beam_muzzlelight[1],
1150                                 self.beam_muzzlelight[2],
1151                                 self.beam_muzzlelight[3]
1152                         )
1153                 );
1154         }
1155
1156         // cleanup
1157         Draw_ArcBeam_callback_entity = world;
1158         Draw_ArcBeam_callback_last_thickness = 0;
1159         Draw_ArcBeam_callback_last_top = '0 0 0';
1160         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1161 }
1162
1163 void Remove_ArcBeam(void)
1164 {
1165         remove(self.beam_muzzleentity);
1166         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
1167 }
1168
1169 void Ent_ReadArcBeam(float isnew)
1170 {
1171         int sf = ReadByte();
1172         entity flash;
1173
1174         if(isnew)
1175         {
1176                 // calculate shot origin offset from gun alignment
1177                 int gunalign = autocvar_cl_gunalign;
1178                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
1179                         gunalign = 3; // default value
1180                 --gunalign;
1181
1182                 self.beam_shotorigin = arc_shotorigin[gunalign];
1183
1184                 // set other main attributes of the beam
1185                 self.draw = Draw_ArcBeam;
1186                 self.entremove = Remove_ArcBeam;
1187                 self.move_time = time;
1188                 loopsound(self, CH_SHOTS_SINGLE, "weapons/arc_loop.wav", VOL_BASE, ATTEN_NORM);
1189
1190                 flash = spawn();
1191                 flash.owner = self;
1192                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1193                 flash.drawmask = MASK_NORMAL;
1194                 flash.solid = SOLID_NOT;
1195                 flash.avelocity_z = 5000;
1196                 setattachment(flash, self, "");
1197                 setorigin(flash, '0 0 0');
1198
1199                 self.beam_muzzleentity = flash;
1200         }
1201         else
1202         {
1203                 flash = self.beam_muzzleentity;
1204         }
1205
1206         if(sf & ARC_SF_SETTINGS) // settings information
1207         {
1208                 self.beam_degreespersegment = ReadShort();
1209                 self.beam_distancepersegment = ReadShort();
1210                 self.beam_maxangle = ReadShort();
1211                 self.beam_range = ReadCoord();
1212                 self.beam_returnspeed = ReadShort();
1213                 self.beam_tightness = (ReadByte() / 10);
1214
1215                 if(ReadByte())
1216                 {
1217                         if(autocvar_chase_active)
1218                                 { self.beam_usevieworigin = 1; }
1219                         else // use view origin
1220                                 { self.beam_usevieworigin = 2; }
1221                 }
1222                 else
1223                 {
1224                         self.beam_usevieworigin = 0;
1225                 }
1226         }
1227
1228         if(!self.beam_usevieworigin)
1229         {
1230                 // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1231                 self.iflags = IFLAG_ORIGIN;
1232
1233                 InterpolateOrigin_Undo();
1234         }
1235
1236         if(sf & ARC_SF_START) // starting location
1237         {
1238                 self.origin_x = ReadCoord();
1239                 self.origin_y = ReadCoord();
1240                 self.origin_z = ReadCoord();
1241         }
1242         else if(self.beam_usevieworigin) // infer the location from player location
1243         {
1244                 if(self.beam_usevieworigin == 2)
1245                 {
1246                         // use view origin
1247                         self.origin = view_origin;
1248                 }
1249                 else
1250                 {
1251                         // use player origin so that third person display still works
1252                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
1253                 }
1254         }
1255
1256         setorigin(self, self.origin);
1257
1258         if(sf & ARC_SF_WANTDIR) // want/aim direction
1259         {
1260                 self.v_angle_x = ReadCoord();
1261                 self.v_angle_y = ReadCoord();
1262                 self.v_angle_z = ReadCoord();
1263         }
1264
1265         if(sf & ARC_SF_BEAMDIR) // beam direction
1266         {
1267                 self.angles_x = ReadCoord();
1268                 self.angles_y = ReadCoord();
1269                 self.angles_z = ReadCoord();
1270         }
1271
1272         if(sf & ARC_SF_BEAMTYPE) // beam type
1273         {
1274                 self.beam_type = ReadByte();
1275                 switch(self.beam_type)
1276                 {
1277                         case ARC_BT_MISS:
1278                         {
1279                                 self.beam_color = '1 1 1';
1280                                 self.beam_alpha = 0.5;
1281                                 self.beam_thickness = 8;
1282                                 self.beam_traileffect = particleeffectnum("arc_beam");
1283                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1284                                 self.beam_hitlight[0] = 0;
1285                                 self.beam_hitlight[1] = 1;
1286                                 self.beam_hitlight[2] = 1;
1287                                 self.beam_hitlight[3] = 1;
1288                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1289                                 self.beam_muzzlelight[0] = 0;
1290                                 self.beam_muzzlelight[1] = 1;
1291                                 self.beam_muzzlelight[2] = 1;
1292                                 self.beam_muzzlelight[3] = 1;
1293                                 if(self.beam_muzzleeffect >= 0)
1294                                 {
1295                                         setmodel(flash, "models/flash.md3");
1296                                         flash.alpha = self.beam_alpha;
1297                                         flash.colormod = self.beam_color;
1298                                         flash.scale = 0.5;
1299                                 }
1300                                 break;
1301                         }
1302                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1303                         {
1304                                 self.beam_color = '1 1 1';
1305                                 self.beam_alpha = 0.5;
1306                                 self.beam_thickness = 8;
1307                                 self.beam_traileffect = particleeffectnum("arc_beam");
1308                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1309                                 self.beam_hitlight[0] = 0;
1310                                 self.beam_hitlight[1] = 1;
1311                                 self.beam_hitlight[2] = 1;
1312                                 self.beam_hitlight[3] = 1;
1313                                 self.beam_muzzleeffect = -1; // particleeffectnum("grenadelauncher_muzzleflash");
1314                                 self.beam_muzzlelight[0] = 0;
1315                                 self.beam_muzzlelight[1] = 1;
1316                                 self.beam_muzzlelight[2] = 1;
1317                                 self.beam_muzzlelight[3] = 1;
1318                                 self.beam_image = "particles/lgbeam";
1319                                 if(self.beam_muzzleeffect >= 0)
1320                                 {
1321                                         setmodel(flash, "models/flash.md3");
1322                                         flash.alpha = self.beam_alpha;
1323                                         flash.colormod = self.beam_color;
1324                                         flash.scale = 0.5;
1325                                 }
1326                                 break;
1327                         }
1328                         case ARC_BT_HEAL:
1329                         {
1330                                 self.beam_color = '1 1 1';
1331                                 self.beam_alpha = 0.5;
1332                                 self.beam_thickness = 8;
1333                                 self.beam_traileffect = particleeffectnum("arc_beam_heal");
1334                                 self.beam_hiteffect = particleeffectnum("arc_beam_healimpact");
1335                                 self.beam_hitlight[0] = 0;
1336                                 self.beam_hitlight[1] = 1;
1337                                 self.beam_hitlight[2] = 1;
1338                                 self.beam_hitlight[3] = 1;
1339                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1340                                 self.beam_muzzlelight[0] = 0;
1341                                 self.beam_muzzlelight[1] = 1;
1342                                 self.beam_muzzlelight[2] = 1;
1343                                 self.beam_muzzlelight[3] = 1;
1344                                 self.beam_image = "particles/lgbeam";
1345                                 if(self.beam_muzzleeffect >= 0)
1346                                 {
1347                                         setmodel(flash, "models/flash.md3");
1348                                         flash.alpha = self.beam_alpha;
1349                                         flash.colormod = self.beam_color;
1350                                         flash.scale = 0.5;
1351                                 }
1352                                 break;
1353                         }
1354                         case ARC_BT_HIT:
1355                         {
1356                                 self.beam_color = '1 1 1';
1357                                 self.beam_alpha = 0.5;
1358                                 self.beam_thickness = 8;
1359                                 self.beam_traileffect = particleeffectnum("arc_beam");
1360                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1361                                 self.beam_hitlight[0] = 20;
1362                                 self.beam_hitlight[1] = 1;
1363                                 self.beam_hitlight[2] = 0;
1364                                 self.beam_hitlight[3] = 0;
1365                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1366                                 self.beam_muzzlelight[0] = 50;
1367                                 self.beam_muzzlelight[1] = 1;
1368                                 self.beam_muzzlelight[2] = 0;
1369                                 self.beam_muzzlelight[3] = 0;
1370                                 self.beam_image = "particles/lgbeam";
1371                                 if(self.beam_muzzleeffect >= 0)
1372                                 {
1373                                         setmodel(flash, "models/flash.md3");
1374                                         flash.alpha = self.beam_alpha;
1375                                         flash.colormod = self.beam_color;
1376                                         flash.scale = 0.5;
1377                                 }
1378                                 break;
1379                         }
1380                         case ARC_BT_BURST_MISS:
1381                         {
1382                                 self.beam_color = '1 1 1';
1383                                 self.beam_alpha = 0.5;
1384                                 self.beam_thickness = 14;
1385                                 self.beam_traileffect = particleeffectnum("arc_beam");
1386                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1387                                 self.beam_hitlight[0] = 0;
1388                                 self.beam_hitlight[1] = 1;
1389                                 self.beam_hitlight[2] = 1;
1390                                 self.beam_hitlight[3] = 1;
1391                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1392                                 self.beam_muzzlelight[0] = 0;
1393                                 self.beam_muzzlelight[1] = 1;
1394                                 self.beam_muzzlelight[2] = 1;
1395                                 self.beam_muzzlelight[3] = 1;
1396                                 self.beam_image = "particles/lgbeam";
1397                                 if(self.beam_muzzleeffect >= 0)
1398                                 {
1399                                         setmodel(flash, "models/flash.md3");
1400                                         flash.alpha = self.beam_alpha;
1401                                         flash.colormod = self.beam_color;
1402                                         flash.scale = 0.5;
1403                                 }
1404                                 break;
1405                         }
1406                         case ARC_BT_BURST_WALL:
1407                         {
1408                                 self.beam_color = '1 1 1';
1409                                 self.beam_alpha = 0.5;
1410                                 self.beam_thickness = 14;
1411                                 self.beam_traileffect = particleeffectnum("arc_beam");
1412                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1413                                 self.beam_hitlight[0] = 0;
1414                                 self.beam_hitlight[1] = 1;
1415                                 self.beam_hitlight[2] = 1;
1416                                 self.beam_hitlight[3] = 1;
1417                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1418                                 self.beam_muzzlelight[0] = 0;
1419                                 self.beam_muzzlelight[1] = 1;
1420                                 self.beam_muzzlelight[2] = 1;
1421                                 self.beam_muzzlelight[3] = 1;
1422                                 self.beam_image = "particles/lgbeam";
1423                                 if(self.beam_muzzleeffect >= 0)
1424                                 {
1425                                         setmodel(flash, "models/flash.md3");
1426                                         flash.alpha = self.beam_alpha;
1427                                         flash.colormod = self.beam_color;
1428                                         flash.scale = 0.5;
1429                                 }
1430                                 break;
1431                         }
1432                         case ARC_BT_BURST_HEAL:
1433                         {
1434                                 self.beam_color = '1 1 1';
1435                                 self.beam_alpha = 0.5;
1436                                 self.beam_thickness = 14;
1437                                 self.beam_traileffect = particleeffectnum("arc_beam_heal");
1438                                 self.beam_hiteffect = particleeffectnum("healray_impact");
1439                                 self.beam_hitlight[0] = 0;
1440                                 self.beam_hitlight[1] = 1;
1441                                 self.beam_hitlight[2] = 1;
1442                                 self.beam_hitlight[3] = 1;
1443                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1444                                 self.beam_muzzlelight[0] = 0;
1445                                 self.beam_muzzlelight[1] = 1;
1446                                 self.beam_muzzlelight[2] = 1;
1447                                 self.beam_muzzlelight[3] = 1;
1448                                 self.beam_image = "particles/lgbeam";
1449                                 if(self.beam_muzzleeffect >= 0)
1450                                 {
1451                                         setmodel(flash, "models/flash.md3");
1452                                         flash.alpha = self.beam_alpha;
1453                                         flash.colormod = self.beam_color;
1454                                         flash.scale = 0.5;
1455                                 }
1456                                 break;
1457                         }
1458                         case ARC_BT_BURST_HIT:
1459                         {
1460                                 self.beam_color = '1 1 1';
1461                                 self.beam_alpha = 0.5;
1462                                 self.beam_thickness = 14;
1463                                 self.beam_traileffect = particleeffectnum("arc_beam");
1464                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1465                                 self.beam_hitlight[0] = 0;
1466                                 self.beam_hitlight[1] = 1;
1467                                 self.beam_hitlight[2] = 1;
1468                                 self.beam_hitlight[3] = 1;
1469                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1470                                 self.beam_muzzlelight[0] = 0;
1471                                 self.beam_muzzlelight[1] = 1;
1472                                 self.beam_muzzlelight[2] = 1;
1473                                 self.beam_muzzlelight[3] = 1;
1474                                 self.beam_image = "particles/lgbeam";
1475                                 if(self.beam_muzzleeffect >= 0)
1476                                 {
1477                                         setmodel(flash, "models/flash.md3");
1478                                         flash.alpha = self.beam_alpha;
1479                                         flash.colormod = self.beam_color;
1480                                         flash.scale = 0.5;
1481                                 }
1482                                 break;
1483                         }
1484
1485                         // shouldn't be possible, but lets make it colorful if it does :D
1486                         default:
1487                         {
1488                                 self.beam_color = randomvec();
1489                                 self.beam_alpha = 1;
1490                                 self.beam_thickness = 8;
1491                                 self.beam_traileffect = false;
1492                                 self.beam_hiteffect = false;
1493                                 self.beam_hitlight[0] = 0;
1494                                 self.beam_hitlight[1] = 1;
1495                                 self.beam_hitlight[2] = 1;
1496                                 self.beam_hitlight[3] = 1;
1497                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1498                                 self.beam_muzzlelight[0] = 0;
1499                                 self.beam_muzzlelight[1] = 1;
1500                                 self.beam_muzzlelight[2] = 1;
1501                                 self.beam_muzzlelight[3] = 1;
1502                                 self.beam_image = "particles/lgbeam";
1503                                 if(self.beam_muzzleeffect >= 0)
1504                                 {
1505                                         setmodel(flash, "models/flash.md3");
1506                                         flash.alpha = self.beam_alpha;
1507                                         flash.colormod = self.beam_color;
1508                                         flash.scale = 0.5;
1509                                 }
1510                                 break;
1511                         }
1512                 }
1513         }
1514
1515         if(!self.beam_usevieworigin)
1516         {
1517                 InterpolateOrigin_Note();
1518         }
1519 }
1520
1521 float W_Arc(float req)
1522 {
1523         switch(req)
1524         {
1525                 case WR_IMPACTEFFECT:
1526                 {
1527                         // todo
1528                         return true;
1529                 }
1530                 case WR_INIT:
1531                 {
1532                         precache_sound("weapons/arc_loop.wav");
1533                         return true;
1534                 }
1535                 case WR_ZOOMRETICLE:
1536                 {
1537                         // no weapon specific image for this weapon
1538                         return false;
1539                 }
1540         }
1541         return false;
1542 }
1543 #endif
1544 #endif