qcsrc/common/weapons/w_blaster.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ BLASTER,
   4 /* function  */ W_Blaster,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '1 0.5 0.5',
  10 /* modelname */ "laser",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairlaser 0.4",
  13 /* wepimg    */ "weaponlaser",
  14 /* refname   */ "blaster",
  15 /* wepname   */ _("Blaster")
  16 );
  17
  18 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  19 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, animtime) \
  21         w_cvar(id, sn, BOTH, damage) \
  22         w_cvar(id, sn, BOTH, delay) \
  23         w_cvar(id, sn, BOTH, edgedamage) \
  24         w_cvar(id, sn, BOTH, force) \
  25         w_cvar(id, sn, BOTH, force_zscale) \
  26         w_cvar(id, sn, BOTH, lifetime) \
  27         w_cvar(id, sn, BOTH, radius) \
  28         w_cvar(id, sn, BOTH, refire) \
  29         w_cvar(id, sn, BOTH, shotangle) \
  30         w_cvar(id, sn, BOTH, speed) \
  31         w_cvar(id, sn, BOTH, spread) \
  32         w_cvar(id, sn, NONE, secondary) \
  33         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  34         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  35         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  36         w_prop(id, sn, float,  weaponstart, weaponstart) \
  37         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  38         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  39
  40 #ifdef SVQC
  41 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  42 .float blaster_damage;
  43 .float blaster_edgedamage;
  44 .float blaster_radius;
  45 .float blaster_force;
  46 .float blaster_lifetime;
  47 #endif
  48 #else
  49 #ifdef SVQC
  50 void spawnfunc_weapon_blaster(void) { weapon_defaultspawnfunc(WEP_BLASTER); }
  51 void spawnfunc_weapon_laser(void) { spawnfunc_weapon_blaster(); }
  52
  53 void W_Blaster_Touch(void)
  54 {
  55         PROJECTILE_TOUCH;
  56
  57         self.event_damage = func_null;
  58
  59         RadiusDamage(
  60                 self,
  61                 self.realowner,
  62                 self.blaster_damage,
  63                 self.blaster_edgedamage,
  64                 self.blaster_radius,
  65                 world,
  66                 world,
  67                 self.blaster_force,
  68                 self.projectiledeathtype,
  69                 other
  70         );
  71
  72         remove(self);
  73 }
  74
  75 void W_Blaster_Think(void)
  76 {
  77         self.movetype = MOVETYPE_FLY;
  78         self.think = SUB_Remove;
  79         self.nextthink = time + self.blaster_lifetime;
  80         CSQCProjectile(self, true, PROJECTILE_BLASTER, true);
  81 }
  82
  83 void W_Blaster_Attack(
  84         float atk_deathtype,
  85         float atk_shotangle,
  86         float atk_damage,
  87         float atk_edgedamage,
  88         float atk_radius,
  89         float atk_force,
  90         float atk_speed,
  91         float atk_spread,
  92         float atk_delay,
  93         float atk_lifetime)
  94 {
  95         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  96
  97         W_SetupShot_Dir(self, s_forward, false, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, atk_damage);
  98         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  99
 100         entity missile = spawn();
 101         missile.owner = missile.realowner = self;
 102         missile.classname = "blasterbolt";
 103         missile.bot_dodge = true;
 104         missile.bot_dodgerating = atk_damage;
 105         PROJECTILE_MAKETRIGGER(missile);
 106
 107         missile.blaster_damage = atk_damage;
 108         missile.blaster_edgedamage = atk_edgedamage;
 109         missile.blaster_radius = atk_radius;
 110         missile.blaster_force = atk_force;
 111         missile.blaster_lifetime = atk_lifetime;
 112
 113         setorigin(missile, w_shotorg);
 114         setsize(missile, '0 0 0', '0 0 0');
 115
 116         W_SetupProjVelocity_Explicit(
 117                 missile,
 118                 w_shotdir,
 119                 v_up,
 120                 atk_speed,
 121                 0,
 122                 0,
 123                 atk_spread,
 124                 false
 125         );
 126
 127         missile.angles = vectoangles(missile.velocity);
 128
 129         //missile.glow_color = 250; // 244, 250
 130         //missile.glow_size = 120;
 131
 132         missile.touch = W_Blaster_Touch;
 133         missile.flags = FL_PROJECTILE;
 134         missile.missile_flags = MIF_SPLASH;
 135         missile.projectiledeathtype = atk_deathtype;
 136         missile.think = W_Blaster_Think;
 137         missile.nextthink = time + atk_delay;
 138
 139         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 140
 141         if(time >= missile.nextthink)
 142         {
 143                 entity oldself;
 144                 oldself = self;
 145                 self = missile;
 146                 self.think();
 147                 self = oldself;
 148         }
 149 }
 150 float W_Blaster(float request)
 151 {
 152         switch(request)
 153         {
 154                 case WR_AIM:
 155                 {
 156                         if(WEP_CVAR(blaster, secondary))
 157                         {
 158                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 159                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), false); }
 160                                 else
 161                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false); }
 162                         }
 163                         else
 164                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false); }
 165
 166                         return true;
 167                 }
 168
 169                 case WR_THINK:
 170                 {
 171                         if(self.BUTTON_ATCK)
 172                         {
 173                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 174                                 {
 175                                         W_Blaster_Attack(
 176                                                 WEP_BLASTER,
 177                                                 WEP_CVAR_PRI(blaster, shotangle),
 178                                                 WEP_CVAR_PRI(blaster, damage),
 179                                                 WEP_CVAR_PRI(blaster, edgedamage),
 180                                                 WEP_CVAR_PRI(blaster, radius),
 181                                                 WEP_CVAR_PRI(blaster, force),
 182                                                 WEP_CVAR_PRI(blaster, speed),
 183                                                 WEP_CVAR_PRI(blaster, spread),
 184                                                 WEP_CVAR_PRI(blaster, delay),
 185                                                 WEP_CVAR_PRI(blaster, lifetime)
 186                                         );
 187                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 188                                 }
 189                         }
 190                         else if(self.BUTTON_ATCK2)
 191                         {
 192                                 switch(WEP_CVAR(blaster, secondary))
 193                                 {
 194                                         case 0: // switch to last used weapon
 195                                         {
 196                                                 if(self.switchweapon == WEP_BLASTER) // don't do this if already switching
 197                                                         W_LastWeapon();
 198                                                 break;
 199                                         }
 200
 201                                         case 1: // normal projectile secondary
 202                                         {
 203                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 204                                                 {
 205                                                         W_Blaster_Attack(
 206                                                                 WEP_BLASTER | HITTYPE_SECONDARY,
 207                                                                 WEP_CVAR_SEC(blaster, shotangle),
 208                                                                 WEP_CVAR_SEC(blaster, damage),
 209                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 210                                                                 WEP_CVAR_SEC(blaster, radius),
 211                                                                 WEP_CVAR_SEC(blaster, force),
 212                                                                 WEP_CVAR_SEC(blaster, speed),
 213                                                                 WEP_CVAR_SEC(blaster, spread),
 214                                                                 WEP_CVAR_SEC(blaster, delay),
 215                                                                 WEP_CVAR_SEC(blaster, lifetime)
 216                                                         );
 217                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 218                                                 }
 219
 220                                                 break;
 221                                         }
 222                                 }
 223                         }
 224                         return true;
 225                 }
 226
 227                 case WR_INIT:
 228                 {
 229                         precache_model("models/weapons/g_laser.md3");
 230                         precache_model("models/weapons/v_laser.md3");
 231                         precache_model("models/weapons/h_laser.iqm");
 232                         precache_sound("weapons/lasergun_fire.wav");
 233                         BLASTER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 234                         return true;
 235                 }
 236
 237                 case WR_SETUP:
 238                 {
 239                         self.ammo_field = ammo_none;
 240                         return true;
 241                 }
 242
 243                 case WR_CHECKAMMO1:
 244                 case WR_CHECKAMMO2:
 245                 {
 246                         return true; // laser has infinite ammo
 247                 }
 248
 249                 case WR_CONFIG:
 250                 {
 251                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 252                         return true;
 253                 }
 254
 255                 case WR_SUICIDEMESSAGE:
 256                 {
 257                         return WEAPON_BLASTER_SUICIDE;
 258                 }
 259
 260                 case WR_KILLMESSAGE:
 261                 {
 262                         return WEAPON_BLASTER_MURDER;
 263                 }
 264         }
 265         return false;
 266 }
 267 #endif
 268 #ifdef CSQC
 269 float W_Blaster(float request)
 270 {
 271         switch(request)
 272         {
 273                 case WR_IMPACTEFFECT:
 274                 {
 275                         vector org2;
 276                         org2 = w_org + w_backoff * 6;
 277                         pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 278                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 279                         return true;
 280                 }
 281
 282                 case WR_INIT:
 283                 {
 284                         precache_sound("weapons/laserimpact.wav");
 285                         return true;
 286                 }
 287                 case WR_ZOOMRETICLE:
 288                 {
 289                         // no weapon specific image for this weapon
 290                         return false;
 291                 }
 292         }
 293         return false;
 294 }
 295 #endif
 296 #endif