qcsrc/common/weapons/w_blaster.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ BLASTER,
   4 /* function  */ W_Blaster,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '1 0.5 0.5',
  10 /* modelname */ "laser",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairlaser 0.4",
  13 /* wepimg    */ "weaponlaser",
  14 /* refname   */ "blaster",
  15 /* wepname   */ _("Blaster")
  16 );
  17
  18 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  19 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, animtime) \
  21         w_cvar(id, sn, BOTH, damage) \
  22         w_cvar(id, sn, BOTH, delay) \
  23         w_cvar(id, sn, BOTH, edgedamage) \
  24         w_cvar(id, sn, BOTH, force) \
  25         w_cvar(id, sn, BOTH, lifetime) \
  26         w_cvar(id, sn, BOTH, radius) \
  27         w_cvar(id, sn, BOTH, refire) \
  28         w_cvar(id, sn, BOTH, shotangle) \
  29         w_cvar(id, sn, BOTH, speed) \
  30         w_cvar(id, sn, BOTH, spread) \
  31         w_cvar(id, sn, NONE, secondary) \
  32         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  33         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  34         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  35         w_prop(id, sn, float,  weaponstart, weaponstart) \
  36         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  37         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  38
  39 #ifdef SVQC
  40 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  41 .float blaster_damage;
  42 .float blaster_edgedamage;
  43 .float blaster_radius;
  44 .float blaster_force;
  45 .float blaster_lifetime;
  46 #endif
  47 #else
  48 #ifdef SVQC
  49 void spawnfunc_weapon_blaster(void) { weapon_defaultspawnfunc(WEP_BLASTER); }
  50 void spawnfunc_weapon_laser(void) { spawnfunc_weapon_blaster(); }
  51
  52 void W_Blaster_Touch(void)
  53 {
  54         PROJECTILE_TOUCH;
  55
  56         self.event_damage = func_null;
  57
  58         RadiusDamage(
  59                 self,
  60                 self.realowner,
  61                 self.blaster_damage,
  62                 self.blaster_edgedamage,
  63                 self.blaster_radius,
  64                 world,
  65                 world,
  66                 self.blaster_force,
  67                 self.projectiledeathtype,
  68                 other
  69         );
  70
  71         remove(self);
  72 }
  73
  74 void W_Blaster_Think(void)
  75 {
  76         self.movetype = MOVETYPE_FLY;
  77         self.think = SUB_Remove;
  78         self.nextthink = time + self.blaster_lifetime;
  79         CSQCProjectile(self, TRUE, PROJECTILE_BLASTER, TRUE);
  80 }
  81
  82 void W_Blaster_Attack(
  83         float atk_deathtype,
  84         float atk_shotangle,
  85         float atk_damage,
  86         float atk_edgedamage,
  87         float atk_radius,
  88         float atk_force,
  89         float atk_speed,
  90         float atk_spread,
  91         float atk_delay,
  92         float atk_lifetime)
  93 {
  94         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  95
  96         W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, atk_damage);
  97         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  98
  99         entity missile = spawn();
 100         missile.owner = missile.realowner = self;
 101         missile.classname = "blasterbolt";
 102         missile.bot_dodge = TRUE;
 103         missile.bot_dodgerating = atk_damage;
 104         PROJECTILE_MAKETRIGGER(missile);
 105
 106         missile.blaster_damage = atk_damage;
 107         missile.blaster_edgedamage = atk_edgedamage;
 108         missile.blaster_radius = atk_radius;
 109         missile.blaster_force = atk_force;
 110         missile.blaster_lifetime = atk_lifetime;
 111
 112         setorigin(missile, w_shotorg);
 113         setsize(missile, '0 0 0', '0 0 0');
 114
 115         W_SetupProjVelocity_Explicit(
 116                 missile,
 117                 w_shotdir,
 118                 v_up,
 119                 atk_speed,
 120                 0,
 121                 0,
 122                 atk_spread,
 123                 FALSE
 124         );
 125
 126         missile.angles = vectoangles(missile.velocity);
 127
 128         //missile.glow_color = 250; // 244, 250
 129         //missile.glow_size = 120;
 130
 131         missile.touch = W_Blaster_Touch;
 132         missile.flags = FL_PROJECTILE;
 133         missile.missile_flags = MIF_SPLASH;
 134         missile.projectiledeathtype = atk_deathtype;
 135         missile.think = W_Blaster_Think;
 136         missile.nextthink = time + atk_delay;
 137
 138         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 139
 140         if(time >= missile.nextthink)
 141         {
 142                 entity oldself;
 143                 oldself = self;
 144                 self = missile;
 145                 self.think();
 146                 self = oldself;
 147         }
 148 }
 149 float W_Blaster(float request)
 150 {
 151         switch(request)
 152         {
 153                 case WR_AIM:
 154                 {
 155                         if(WEP_CVAR(blaster, secondary))
 156                         {
 157                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 158                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), FALSE); }
 159                                 else
 160                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 161                         }
 162                         else
 163                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 164
 165                         return TRUE;
 166                 }
 167
 168                 case WR_THINK:
 169                 {
 170                         if(self.BUTTON_ATCK)
 171                         {
 172                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 173                                 {
 174                                         W_Blaster_Attack(
 175                                                 WEP_BLASTER,
 176                                                 WEP_CVAR_PRI(blaster, shotangle),
 177                                                 WEP_CVAR_PRI(blaster, damage),
 178                                                 WEP_CVAR_PRI(blaster, edgedamage),
 179                                                 WEP_CVAR_PRI(blaster, radius),
 180                                                 WEP_CVAR_PRI(blaster, force),
 181                                                 WEP_CVAR_PRI(blaster, speed),
 182                                                 WEP_CVAR_PRI(blaster, spread),
 183                                                 WEP_CVAR_PRI(blaster, delay),
 184                                                 WEP_CVAR_PRI(blaster, lifetime)
 185                                         );
 186                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 187                                 }
 188                         }
 189                         else if(self.BUTTON_ATCK2)
 190                         {
 191                                 switch(WEP_CVAR(blaster, secondary))
 192                                 {
 193                                         case 0: // switch to last used weapon
 194                                         {
 195                                                 if(self.switchweapon == WEP_BLASTER) // don't do this if already switching
 196                                                         W_LastWeapon();
 197                                                 break;
 198                                         }
 199
 200                                         case 1: // normal projectile secondary
 201                                         {
 202                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 203                                                 {
 204                                                         W_Blaster_Attack(
 205                                                                 WEP_BLASTER | HITTYPE_SECONDARY,
 206                                                                 WEP_CVAR_SEC(blaster, shotangle),
 207                                                                 WEP_CVAR_SEC(blaster, damage),
 208                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 209                                                                 WEP_CVAR_SEC(blaster, radius),
 210                                                                 WEP_CVAR_SEC(blaster, force),
 211                                                                 WEP_CVAR_SEC(blaster, speed),
 212                                                                 WEP_CVAR_SEC(blaster, spread),
 213                                                                 WEP_CVAR_SEC(blaster, delay),
 214                                                                 WEP_CVAR_SEC(blaster, lifetime)
 215                                                         );
 216                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 217                                                 }
 218
 219                                                 break;
 220                                         }
 221                                 }
 222                         }
 223                         return TRUE;
 224                 }
 225
 226                 case WR_INIT:
 227                 {
 228                         precache_model("models/weapons/g_laser.md3");
 229                         precache_model("models/weapons/v_laser.md3");
 230                         precache_model("models/weapons/h_laser.iqm");
 231                         precache_sound("weapons/lasergun_fire.wav");
 232                         BLASTER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 233                         return TRUE;
 234                 }
 235
 236                 case WR_SETUP:
 237                 {
 238                         self.ammo_field = ammo_none;
 239                         return TRUE;
 240                 }
 241
 242                 case WR_CHECKAMMO1:
 243                 case WR_CHECKAMMO2:
 244                 {
 245                         return TRUE; // laser has infinite ammo
 246                 }
 247
 248                 case WR_CONFIG:
 249                 {
 250                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 251                         return TRUE;
 252                 }
 253
 254                 case WR_SUICIDEMESSAGE:
 255                 {
 256                         return WEAPON_BLASTER_SUICIDE;
 257                 }
 258
 259                 case WR_KILLMESSAGE:
 260                 {
 261                         return WEAPON_BLASTER_MURDER;
 262                 }
 263         }
 264         return FALSE;
 265 }
 266 #endif
 267 #ifdef CSQC
 268 float W_Blaster(float request)
 269 {
 270         switch(request)
 271         {
 272                 case WR_IMPACTEFFECT:
 273                 {
 274                         vector org2;
 275                         org2 = w_org + w_backoff * 6;
 276                         pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 277                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 278                         return TRUE;
 279                 }
 280
 281                 case WR_INIT:
 282                 {
 283                         precache_sound("weapons/laserimpact.wav");
 284                         return TRUE;
 285                 }
 286                 case WR_ZOOMRETICLE:
 287                 {
 288                         // no weapon specific image for this weapon
 289                         return FALSE;
 290                 }
 291         }
 292         return FALSE;
 293 }
 294 #endif
 295 #endif