qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* modelname */ "rl",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairrocketlauncher 0.5875",
  13 /* wepimg    */ "weaponrocketlauncher",
  14 /* refname   */ "devastator",
  15 /* wepname   */ _("Devastator")
  16 );
  17
  18 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  19 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, ammo) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, damage) \
  23         w_cvar(id, sn, NONE, damageforcescale) \
  24         w_cvar(id, sn, NONE, detonatedelay) \
  25         w_cvar(id, sn, NONE, edgedamage) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, guidedelay) \
  28         w_cvar(id, sn, NONE, guidegoal) \
  29         w_cvar(id, sn, NONE, guiderate) \
  30         w_cvar(id, sn, NONE, guideratedelay) \
  31         w_cvar(id, sn, NONE, guidestop) \
  32         w_cvar(id, sn, NONE, health) \
  33         w_cvar(id, sn, NONE, lifetime) \
  34         w_cvar(id, sn, NONE, radius) \
  35         w_cvar(id, sn, NONE, refire) \
  36         w_cvar(id, sn, NONE, remote_damage) \
  37         w_cvar(id, sn, NONE, remote_edgedamage) \
  38         w_cvar(id, sn, NONE, remote_force) \
  39         w_cvar(id, sn, NONE, remote_jump_damage) \
  40         w_cvar(id, sn, NONE, remote_jump_radius) \
  41         w_cvar(id, sn, NONE, remote_jump_velocity_z_add) \
  42         w_cvar(id, sn, NONE, remote_jump_velocity_z_max) \
  43         w_cvar(id, sn, NONE, remote_jump_velocity_z_min) \
  44         w_cvar(id, sn, NONE, remote_radius) \
  45         w_cvar(id, sn, NONE, speed) \
  46         w_cvar(id, sn, NONE, speedaccel) \
  47         w_cvar(id, sn, NONE, speedstart) \
  48         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  49         w_prop(id, sn, float,  reloading_time, reload_time) \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifdef SVQC
  58 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  59 .float rl_release;
  60 .float rl_detonate_later;
  61 #endif
  62 #else
  63 #ifdef SVQC
  64 void spawnfunc_weapon_devastator(void) { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  65 void spawnfunc_weapon_rocketlauncher(void) { spawnfunc_weapon_devastator(); }
  66
  67 void W_Devastator_Unregister(void)
  68 {
  69         if(self.realowner && self.realowner.lastrocket == self)
  70         {
  71                 self.realowner.lastrocket = world;
  72                 // self.realowner.rl_release = 1;
  73         }
  74 }
  75
  76 void W_Devastator_Explode(void)
  77 {
  78         W_Devastator_Unregister();
  79
  80         if(other.takedamage == DAMAGE_AIM)
  81                 if(IS_PLAYER(other))
  82                         if(DIFF_TEAM(self.realowner, other))
  83                                 if(other.deadflag == DEAD_NO)
  84                                         if(IsFlying(other))
  85                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  86
  87         self.event_damage = func_null;
  88         self.takedamage = DAMAGE_NO;
  89
  90         RadiusDamage(
  91                 self,
  92                 self.realowner,
  93                 WEP_CVAR(devastator, damage),
  94                 WEP_CVAR(devastator, edgedamage),
  95                 WEP_CVAR(devastator, radius),
  96                 world,
  97                 world,
  98                 WEP_CVAR(devastator, force),
  99                 self.projectiledeathtype,
 100                 other
 101         );
 102
 103         if(self.realowner.weapon == WEP_DEVASTATOR)
 104         {
 105                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 106                 {
 107                         self.realowner.cnt = WEP_DEVASTATOR;
 108                         ATTACK_FINISHED(self.realowner) = time;
 109                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 110                 }
 111         }
 112         remove(self);
 113 }
 114
 115 void W_Devastator_DoRemoteExplode(void)
 116 {
 117         W_Devastator_Unregister();
 118
 119         self.event_damage = func_null;
 120         self.takedamage = DAMAGE_NO;
 121
 122         float handled_as_rocketjump = FALSE;
 123
 124         entity head = WarpZone_FindRadius(
 125                 self.origin,
 126                 WEP_CVAR(devastator, remote_jump_radius),
 127                 FALSE
 128         );
 129
 130         while(head)
 131         {
 132                 if(head.takedamage && (head == self.realowner))
 133                 {
 134                         float distance_to_head = vlen(self.origin - head.WarpZone_findradius_nearest);
 135                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 136                         {
 137                                 // we handled this as a rocketjump :)
 138                                 handled_as_rocketjump = TRUE;
 139
 140                                 // modify velocity
 141                                 head.velocity_x *= 0.9;
 142                                 head.velocity_y *= 0.9;
 143                                 head.velocity_z = bound(
 144                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 145                                         head.velocity_z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 146                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 147                                 );
 148
 149                                 // now do the damage
 150                                 RadiusDamage(
 151                                         self,
 152                                         head,
 153                                         WEP_CVAR(devastator, remote_jump_damage),
 154                                         WEP_CVAR(devastator, remote_jump_damage),
 155                                         WEP_CVAR(devastator, remote_jump_radius),
 156                                         world,
 157                                         head,
 158                                         0,
 159                                         self.projectiledeathtype | HITTYPE_BOUNCE,
 160                                         world
 161                                 );
 162                                 break;
 163                         }
 164                 }
 165                 head = head.chain;
 166         }
 167
 168         RadiusDamage(
 169                 self,
 170                 self.realowner,
 171                 WEP_CVAR(devastator, remote_damage),
 172                 WEP_CVAR(devastator, remote_edgedamage),
 173                 WEP_CVAR(devastator, remote_radius),
 174                 (handled_as_rocketjump ? head : world),
 175                 world,
 176                 WEP_CVAR(devastator, remote_force),
 177                 self.projectiledeathtype | HITTYPE_BOUNCE,
 178                 world
 179         );
 180
 181         if(self.realowner.weapon == WEP_DEVASTATOR)
 182         {
 183                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 184                 {
 185                         self.realowner.cnt = WEP_DEVASTATOR;
 186                         ATTACK_FINISHED(self.realowner) = time;
 187                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 188                 }
 189         }
 190         remove(self);
 191 }
 192
 193 void W_Devastator_RemoteExplode(void)
 194 {
 195         if(self.realowner.deadflag == DEAD_NO)
 196         if(self.realowner.lastrocket)
 197         {
 198                 if((self.spawnshieldtime >= 0)
 199                         ? (time >= self.spawnshieldtime) // timer
 200                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 201                 )
 202                 {
 203                         W_Devastator_DoRemoteExplode();
 204                 }
 205         }
 206 }
 207
 208 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 209 {
 210         if(thisdir * goaldir > maxturn_cos)
 211                 return goaldir;
 212         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 213                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 214         float f, m2;
 215         vector v;
 216         // solve:
 217         //   g = normalize(thisdir + goaldir * X)
 218         //   thisdir * g = maxturn
 219         //
 220         //   gg = thisdir + goaldir * X
 221         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 222         //
 223         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 224         f = thisdir * goaldir;
 225         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 226         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 227         m2 = maxturn_cos * maxturn_cos;
 228         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 229         return normalize(thisdir + goaldir * v_y); // the larger solution!
 230 }
 231 // assume thisdir == -goaldir:
 232 //   f == -1
 233 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 234 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 235 //   x^2 - 2 * x + 1 = 0
 236 //   (x - 1)^2 = 0
 237 //   x = 1
 238 //   normalize(thisdir + goaldir)
 239 //   normalize(0)
 240
 241 void W_Devastator_Think(void)
 242 {
 243         vector desireddir, olddir, newdir, desiredorigin, goal;
 244         float velspeed, f;
 245         self.nextthink = time;
 246         if(time > self.cnt)
 247         {
 248                 other = world;
 249                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 250                 W_Devastator_Explode();
 251                 return;
 252         }
 253
 254         // accelerate
 255         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 256         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 257         if(velspeed > 0)
 258                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 259
 260         // laser guided, or remote detonation
 261         if(self.realowner.weapon == WEP_DEVASTATOR)
 262         {
 263                 if(self == self.realowner.lastrocket)
 264                 if(!self.realowner.rl_release)
 265                 if(!self.BUTTON_ATCK2)
 266                 if(WEP_CVAR(devastator, guiderate))
 267                 if(time > self.pushltime)
 268                 if(self.realowner.deadflag == DEAD_NO)
 269                 {
 270                         f = WEP_CVAR(devastator, guideratedelay);
 271                         if(f)
 272                                 f = bound(0, (time - self.pushltime) / f, 1);
 273                         else
 274                                 f = 1;
 275
 276                         velspeed = vlen(self.velocity);
 277
 278                         makevectors(self.realowner.v_angle);
 279                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 280                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 281                         olddir = normalize(self.velocity);
 282
 283                         // now it gets tricky... we want to move like some curve to approximate the target direction
 284                         // but we are limiting the rate at which we can turn!
 285                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 286                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 287
 288                         self.velocity = newdir * velspeed;
 289                         self.angles = vectoangles(self.velocity);
 290
 291                         if(!self.count)
 292                         {
 293                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 294                                 // TODO add a better sound here
 295                                 sound(self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 296                                 self.count = 1;
 297                         }
 298                 }
 299
 300                 if(self.rl_detonate_later)
 301                         W_Devastator_RemoteExplode();
 302         }
 303
 304         if(self.csqcprojectile_clientanimate == 0)
 305                 UpdateCSQCProjectile(self);
 306 }
 307
 308 void W_Devastator_Touch(void)
 309 {
 310         if(WarpZone_Projectile_Touch())
 311         {
 312                 if(wasfreed(self))
 313                         W_Devastator_Unregister();
 314                 return;
 315         }
 316         W_Devastator_Unregister();
 317         W_Devastator_Explode();
 318 }
 319
 320 void W_Devastator_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 321 {
 322         if(self.health <= 0)
 323                 return;
 324
 325         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 326                 return; // g_projectiles_damage says to halt
 327
 328         self.health = self.health - damage;
 329         self.angles = vectoangles(self.velocity);
 330
 331         if(self.health <= 0)
 332                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 333 }
 334
 335 void W_Devastator_Attack(void)
 336 {
 337         entity missile;
 338         entity flash;
 339
 340         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 341
 342         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 343         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 344
 345         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 346         missile.owner = missile.realowner = self;
 347         self.lastrocket = missile;
 348         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 349                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 350         else
 351                 missile.spawnshieldtime = -1;
 352         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 353         missile.classname = "rocket";
 354         missile.bot_dodge = TRUE;
 355         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 356
 357         missile.takedamage = DAMAGE_YES;
 358         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 359         missile.health = WEP_CVAR(devastator, health);
 360         missile.event_damage = W_Devastator_Damage;
 361         missile.damagedbycontents = TRUE;
 362
 363         missile.movetype = MOVETYPE_FLY;
 364         PROJECTILE_MAKETRIGGER(missile);
 365         missile.projectiledeathtype = WEP_DEVASTATOR;
 366         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 367
 368         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 369         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 370         missile.angles = vectoangles(missile.velocity);
 371
 372         missile.touch = W_Devastator_Touch;
 373         missile.think = W_Devastator_Think;
 374         missile.nextthink = time;
 375         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 376         missile.flags = FL_PROJECTILE;
 377         missile.missile_flags = MIF_SPLASH;
 378
 379         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 380
 381         // muzzle flash for 1st person view
 382         flash = spawn();
 383         setmodel(flash, "models/flash.md3"); // precision set below
 384         SUB_SetFade(flash, time, 0.1);
 385         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 386         W_AttachToShotorg(flash, '5 0 0');
 387
 388         // common properties
 389         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 390 }
 391
 392 float W_Devastator(float req)
 393 {
 394         entity rock;
 395         float rockfound;
 396         float ammo_amount;
 397         switch(req)
 398         {
 399                 #if 0
 400                 case WR_AIM:
 401                 {
 402                         // aim and decide to fire if appropriate
 403                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 404                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 405                         {
 406                                 // decide whether to detonate rockets
 407                                 entity missile, targetlist, targ;
 408                                 targetlist = findchainfloat(bot_attack, TRUE);
 409                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 410                                 {
 411                                         targ = targetlist;
 412                                         while(targ)
 413                                         {
 414                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 415                                                 {
 416                                                         self.BUTTON_ATCK2 = TRUE;
 417                                                         break;
 418                                                 }
 419                                                 targ = targ.chain;
 420                                         }
 421                                 }
 422
 423                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 424                         }
 425
 426                         return TRUE;
 427                 }
 428                 #else
 429                 case WR_AIM:
 430                 {
 431                         // aim and decide to fire if appropriate
 432                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 433                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 434                         {
 435                                 // decide whether to detonate rockets
 436                                 entity missile, targetlist, targ;
 437                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 438                                 float selfdamage, teamdamage, enemydamage;
 439                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 440                                 coredamage = WEP_CVAR(devastator, damage);
 441                                 edgeradius = WEP_CVAR(devastator, radius);
 442                                 recipricoledgeradius = 1 / edgeradius;
 443                                 selfdamage = 0;
 444                                 teamdamage = 0;
 445                                 enemydamage = 0;
 446                                 targetlist = findchainfloat(bot_attack, TRUE);
 447                                 missile = find(world, classname, "rocket");
 448                                 while(missile)
 449                                 {
 450                                         if(missile.realowner != self)
 451                                         {
 452                                                 missile = find(missile, classname, "rocket");
 453                                                 continue;
 454                                         }
 455                                         targ = targetlist;
 456                                         while(targ)
 457                                         {
 458                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 459                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 460                                                 // count potential damage according to type of target
 461                                                 if(targ == self)
 462                                                         selfdamage = selfdamage + d;
 463                                                 else if(targ.team == self.team && teamplay)
 464                                                         teamdamage = teamdamage + d;
 465                                                 else if(bot_shouldattack(targ))
 466                                                         enemydamage = enemydamage + d;
 467                                                 targ = targ.chain;
 468                                         }
 469                                         missile = find(missile, classname, "rocket");
 470                                 }
 471                                 float desirabledamage;
 472                                 desirabledamage = enemydamage;
 473                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 474                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 475                                 if(teamplay && self.team)
 476                                         desirabledamage = desirabledamage - teamdamage;
 477
 478                                 missile = find(world, classname, "rocket");
 479                                 while(missile)
 480                                 {
 481                                         if(missile.realowner != self)
 482                                         {
 483                                                 missile = find(missile, classname, "rocket");
 484                                                 continue;
 485                                         }
 486                                         makevectors(missile.v_angle);
 487                                         targ = targetlist;
 488                                         if(skill > 9) // normal players only do this for the target they are tracking
 489                                         {
 490                                                 targ = targetlist;
 491                                                 while(targ)
 492                                                 {
 493                                                         if(
 494                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 495                                                                 && desirabledamage > 0.1*coredamage
 496                                                         )self.BUTTON_ATCK2 = TRUE;
 497                                                         targ = targ.chain;
 498                                                 }
 499                                         }else{
 500                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 501                                                 //As the distance gets larger, a correct detonation gets near imposible
 502                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 503                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 504                                                         if(IS_PLAYER(self.enemy))
 505                                                                 if(desirabledamage >= 0.1*coredamage)
 506                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 507                                                                                 self.BUTTON_ATCK2 = TRUE;
 508                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 509                                         }
 510
 511                                         missile = find(missile, classname, "rocket");
 512                                 }
 513                                 // if we would be doing at X percent of the core damage, detonate it
 514                                 // but don't fire a new shot at the same time!
 515                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 516                                         self.BUTTON_ATCK2 = TRUE;
 517                                 if((skill > 6.5) && (selfdamage > self.health))
 518                                         self.BUTTON_ATCK2 = FALSE;
 519                                 //if(self.BUTTON_ATCK2 == TRUE)
 520                                 //      dprint(ftos(desirabledamage),"\n");
 521                                 if(self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 522                         }
 523
 524                         return TRUE;
 525                 }
 526                 #endif
 527                 case WR_THINK:
 528                 {
 529                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 530                                 WEP_ACTION(self.weapon, WR_RELOAD);
 531                         else
 532                         {
 533                                 if(self.BUTTON_ATCK)
 534                                 {
 535                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 536                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 537                                         {
 538                                                 W_Devastator_Attack();
 539                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 540                                                 self.rl_release = 0;
 541                                         }
 542                                 }
 543                                 else
 544                                         self.rl_release = 1;
 545
 546                                 if(self.BUTTON_ATCK2)
 547                                 {
 548                                         rockfound = 0;
 549                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 550                                         {
 551                                                 if(!rock.rl_detonate_later)
 552                                                 {
 553                                                         rock.rl_detonate_later = TRUE;
 554                                                         rockfound = 1;
 555                                                 }
 556                                         }
 557                                         if(rockfound)
 558                                                 sound(self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 559                                 }
 560                         }
 561
 562                         return TRUE;
 563                 }
 564                 case WR_INIT:
 565                 {
 566                         //if(autocvar_sv_precacheweapons)
 567                         //{
 568                                 precache_model("models/flash.md3");
 569                                 precache_model("models/weapons/g_rl.md3");
 570                                 precache_model("models/weapons/v_rl.md3");
 571                                 precache_model("models/weapons/h_rl.iqm");
 572                                 precache_sound("weapons/rocket_det.wav");
 573                                 precache_sound("weapons/rocket_fire.wav");
 574                                 precache_sound("weapons/rocket_mode.wav");
 575                         //}
 576                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 577                         return TRUE;
 578                 }
 579                 case WR_SETUP:
 580                 {
 581                         self.rl_release = 1;
 582                         return TRUE;
 583                 }
 584                 case WR_CHECKAMMO1:
 585                 {
 586                         #if 0
 587                         // don't switch while guiding a missile
 588                         if(ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 589                         {
 590                                 ammo_amount = FALSE;
 591                                 if(WEP_CVAR(devastator, reload_ammo))
 592                                 {
 593                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 594                                                 ammo_amount = TRUE;
 595                                 }
 596                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 597                                         ammo_amount = TRUE;
 598                                 return !ammo_amount;
 599                         }
 600                         #endif
 601                         #if 0
 602                         if(self.rl_release == 0)
 603                         {
 604                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 605                                 return TRUE;
 606                         }
 607                         else
 608                         {
 609                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 610                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 611                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 612                                 return ammo_amount;
 613                         }
 614                         #else
 615                         ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 616                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 617                         return ammo_amount;
 618                         #endif
 619                 }
 620                 case WR_CHECKAMMO2:
 621                 {
 622                         return FALSE;
 623                 }
 624                 case WR_CONFIG:
 625                 {
 626                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 627                         return TRUE;
 628                 }
 629                 case WR_RESETPLAYER:
 630                 {
 631                         self.rl_release = 0;
 632                         return TRUE;
 633                 }
 634                 case WR_RELOAD:
 635                 {
 636                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 637                         return TRUE;
 638                 }
 639                 case WR_SUICIDEMESSAGE:
 640                 {
 641                         return WEAPON_DEVASTATOR_SUICIDE;
 642                 }
 643                 case WR_KILLMESSAGE:
 644                 {
 645                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 646                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 647                         else
 648                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 649                 }
 650         }
 651         return FALSE;
 652 }
 653 #endif
 654 #ifdef CSQC
 655 float W_Devastator(float req)
 656 {
 657         switch(req)
 658         {
 659                 case WR_IMPACTEFFECT:
 660                 {
 661                         vector org2;
 662                         org2 = w_org + w_backoff * 12;
 663                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 664                         if(!w_issilent)
 665                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 666
 667                         return TRUE;
 668                 }
 669                 case WR_INIT:
 670                 {
 671                         precache_sound("weapons/rocket_impact.wav");
 672                         return TRUE;
 673                 }
 674                 case WR_ZOOMRETICLE:
 675                 {
 676                         // no weapon specific image for this weapon
 677                         return FALSE;
 678                 }
 679         }
 680         return FALSE;
 681 }
 682 #endif
 683 #endif