qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* modelname */ "rl",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairrocketlauncher 0.7",
  13 /* wepimg    */ "weaponrocketlauncher",
  14 /* refname   */ "devastator",
  15 /* wepname   */ _("Devastator")
  16 );
  17
  18 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  19 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, ammo) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, damage) \
  23         w_cvar(id, sn, NONE, damageforcescale) \
  24         w_cvar(id, sn, NONE, detonatedelay) \
  25         w_cvar(id, sn, NONE, edgedamage) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, guidedelay) \
  28         w_cvar(id, sn, NONE, guidegoal) \
  29         w_cvar(id, sn, NONE, guiderate) \
  30         w_cvar(id, sn, NONE, guideratedelay) \
  31         w_cvar(id, sn, NONE, guidestop) \
  32         w_cvar(id, sn, NONE, health) \
  33         w_cvar(id, sn, NONE, lifetime) \
  34         w_cvar(id, sn, NONE, radius) \
  35         w_cvar(id, sn, NONE, refire) \
  36         w_cvar(id, sn, NONE, remote_damage) \
  37         w_cvar(id, sn, NONE, remote_edgedamage) \
  38         w_cvar(id, sn, NONE, remote_force) \
  39         w_cvar(id, sn, NONE, remote_jump_damage) \
  40         w_cvar(id, sn, NONE, remote_jump_radius) \
  41         w_cvar(id, sn, NONE, remote_jump_velocity_z_add) \
  42         w_cvar(id, sn, NONE, remote_jump_velocity_z_max) \
  43         w_cvar(id, sn, NONE, remote_jump_velocity_z_min) \
  44         w_cvar(id, sn, NONE, remote_radius) \
  45         w_cvar(id, sn, NONE, speed) \
  46         w_cvar(id, sn, NONE, speedaccel) \
  47         w_cvar(id, sn, NONE, speedstart) \
  48         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  49         w_prop(id, sn, float,  reloading_time, reload_time) \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifdef SVQC
  58 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  59 .float rl_release;
  60 .float rl_detonate_later;
  61 #endif
  62 #else
  63 #ifdef SVQC
  64 void spawnfunc_weapon_devastator(void) { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  65 void spawnfunc_weapon_rocketlauncher(void) { spawnfunc_weapon_devastator(); }
  66
  67 void W_Devastator_Unregister(void)
  68 {
  69         if(self.realowner && self.realowner.lastrocket == self)
  70         {
  71                 self.realowner.lastrocket = world;
  72                 // self.realowner.rl_release = 1;
  73         }
  74 }
  75
  76 void W_Devastator_Explode(void)
  77 {
  78         W_Devastator_Unregister();
  79
  80         if(other.takedamage == DAMAGE_AIM)
  81                 if(IS_PLAYER(other))
  82                         if(DIFF_TEAM(self.realowner, other))
  83                                 if(other.deadflag == DEAD_NO)
  84                                         if(IsFlying(other))
  85                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  86
  87         self.event_damage = func_null;
  88         self.takedamage = DAMAGE_NO;
  89
  90         RadiusDamage(
  91                 self,
  92                 self.realowner,
  93                 WEP_CVAR(devastator, damage),
  94                 WEP_CVAR(devastator, edgedamage),
  95                 WEP_CVAR(devastator, radius),
  96                 world,
  97                 world,
  98                 WEP_CVAR(devastator, force),
  99                 self.projectiledeathtype,
 100                 other
 101         );
 102
 103         if(self.realowner.weapon == WEP_DEVASTATOR)
 104         {
 105                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 106                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 107                 {
 108                         self.realowner.cnt = WEP_DEVASTATOR;
 109                         ATTACK_FINISHED(self.realowner) = time;
 110                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 111                 }
 112         }
 113         remove(self);
 114 }
 115
 116 void W_Devastator_DoRemoteExplode(void)
 117 {
 118         W_Devastator_Unregister();
 119
 120         self.event_damage = func_null;
 121         self.takedamage = DAMAGE_NO;
 122
 123         float handled_as_rocketjump = false;
 124
 125         entity head = WarpZone_FindRadius(
 126                 self.origin,
 127                 WEP_CVAR(devastator, remote_jump_radius),
 128                 false
 129         );
 130
 131         while(head)
 132         {
 133                 if(head.takedamage && (head == self.realowner))
 134                 {
 135                         float distance_to_head = vlen(self.origin - head.WarpZone_findradius_nearest);
 136                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 137                         {
 138                                 // we handled this as a rocketjump :)
 139                                 handled_as_rocketjump = true;
 140
 141                                 // modify velocity
 142                                 head.velocity_x *= 0.9;
 143                                 head.velocity_y *= 0.9;
 144                                 head.velocity_z = bound(
 145                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 146                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 147                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 148                                 );
 149
 150                                 // now do the damage
 151                                 RadiusDamage(
 152                                         self,
 153                                         head,
 154                                         WEP_CVAR(devastator, remote_jump_damage),
 155                                         WEP_CVAR(devastator, remote_jump_damage),
 156                                         WEP_CVAR(devastator, remote_jump_radius),
 157                                         world,
 158                                         head,
 159                                         0,
 160                                         self.projectiledeathtype | HITTYPE_BOUNCE,
 161                                         world
 162                                 );
 163                                 break;
 164                         }
 165                 }
 166                 head = head.chain;
 167         }
 168
 169         RadiusDamage(
 170                 self,
 171                 self.realowner,
 172                 WEP_CVAR(devastator, remote_damage),
 173                 WEP_CVAR(devastator, remote_edgedamage),
 174                 WEP_CVAR(devastator, remote_radius),
 175                 (handled_as_rocketjump ? head : world),
 176                 world,
 177                 WEP_CVAR(devastator, remote_force),
 178                 self.projectiledeathtype | HITTYPE_BOUNCE,
 179                 world
 180         );
 181
 182         if(self.realowner.weapon == WEP_DEVASTATOR)
 183         {
 184                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 185                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 186                 {
 187                         self.realowner.cnt = WEP_DEVASTATOR;
 188                         ATTACK_FINISHED(self.realowner) = time;
 189                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 190                 }
 191         }
 192         remove(self);
 193 }
 194
 195 void W_Devastator_RemoteExplode(void)
 196 {
 197         if(self.realowner.deadflag == DEAD_NO)
 198         if(self.realowner.lastrocket)
 199         {
 200                 if((self.spawnshieldtime >= 0)
 201                         ? (time >= self.spawnshieldtime) // timer
 202                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 203                 )
 204                 {
 205                         W_Devastator_DoRemoteExplode();
 206                 }
 207         }
 208 }
 209
 210 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 211 {
 212         if(thisdir * goaldir > maxturn_cos)
 213                 return goaldir;
 214         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 215                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 216         float f, m2;
 217         vector v;
 218         // solve:
 219         //   g = normalize(thisdir + goaldir * X)
 220         //   thisdir * g = maxturn
 221         //
 222         //   gg = thisdir + goaldir * X
 223         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 224         //
 225         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 226         f = thisdir * goaldir;
 227         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 228         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 229         m2 = maxturn_cos * maxturn_cos;
 230         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 231         return normalize(thisdir + goaldir * v.y); // the larger solution!
 232 }
 233 // assume thisdir == -goaldir:
 234 //   f == -1
 235 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 236 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 237 //   x^2 - 2 * x + 1 = 0
 238 //   (x - 1)^2 = 0
 239 //   x = 1
 240 //   normalize(thisdir + goaldir)
 241 //   normalize(0)
 242
 243 void W_Devastator_Think(void)
 244 {
 245         vector desireddir, olddir, newdir, desiredorigin, goal;
 246         float velspeed, f;
 247         self.nextthink = time;
 248         if(time > self.cnt)
 249         {
 250                 other = world;
 251                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 252                 W_Devastator_Explode();
 253                 return;
 254         }
 255
 256         // accelerate
 257         makevectors(self.angles.x * '-1 0 0' + self.angles.y * '0 1 0');
 258         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 259         if(velspeed > 0)
 260                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 261
 262         // laser guided, or remote detonation
 263         if(self.realowner.weapon == WEP_DEVASTATOR)
 264         {
 265                 if(self == self.realowner.lastrocket)
 266                 if(!self.realowner.rl_release)
 267                 if(!self.BUTTON_ATCK2)
 268                 if(WEP_CVAR(devastator, guiderate))
 269                 if(time > self.pushltime)
 270                 if(self.realowner.deadflag == DEAD_NO)
 271                 {
 272                         f = WEP_CVAR(devastator, guideratedelay);
 273                         if(f)
 274                                 f = bound(0, (time - self.pushltime) / f, 1);
 275                         else
 276                                 f = 1;
 277
 278                         velspeed = vlen(self.velocity);
 279
 280                         makevectors(self.realowner.v_angle);
 281                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 282                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 283                         olddir = normalize(self.velocity);
 284
 285                         // now it gets tricky... we want to move like some curve to approximate the target direction
 286                         // but we are limiting the rate at which we can turn!
 287                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 288                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 289
 290                         self.velocity = newdir * velspeed;
 291                         self.angles = vectoangles(self.velocity);
 292
 293                         if(!self.count)
 294                         {
 295                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 296                                 // TODO add a better sound here
 297                                 sound(self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 298                                 self.count = 1;
 299                         }
 300                 }
 301
 302                 if(self.rl_detonate_later)
 303                         W_Devastator_RemoteExplode();
 304         }
 305
 306         if(self.csqcprojectile_clientanimate == 0)
 307                 UpdateCSQCProjectile(self);
 308 }
 309
 310 void W_Devastator_Touch(void)
 311 {
 312         if(WarpZone_Projectile_Touch())
 313         {
 314                 if(wasfreed(self))
 315                         W_Devastator_Unregister();
 316                 return;
 317         }
 318         W_Devastator_Unregister();
 319         W_Devastator_Explode();
 320 }
 321
 322 void W_Devastator_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 323 {
 324         if(self.health <= 0)
 325                 return;
 326
 327         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 328                 return; // g_projectiles_damage says to halt
 329
 330         self.health = self.health - damage;
 331         self.angles = vectoangles(self.velocity);
 332
 333         if(self.health <= 0)
 334                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 335 }
 336
 337 void W_Devastator_Attack(void)
 338 {
 339         entity missile;
 340         entity flash;
 341
 342         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 343
 344         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 345         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 346
 347         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 348         missile.owner = missile.realowner = self;
 349         self.lastrocket = missile;
 350         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 351                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 352         else
 353                 missile.spawnshieldtime = -1;
 354         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 355         missile.classname = "rocket";
 356         missile.bot_dodge = true;
 357         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 358
 359         missile.takedamage = DAMAGE_YES;
 360         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 361         missile.health = WEP_CVAR(devastator, health);
 362         missile.event_damage = W_Devastator_Damage;
 363         missile.damagedbycontents = true;
 364
 365         missile.movetype = MOVETYPE_FLY;
 366         PROJECTILE_MAKETRIGGER(missile);
 367         missile.projectiledeathtype = WEP_DEVASTATOR;
 368         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 369
 370         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 371         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 372         missile.angles = vectoangles(missile.velocity);
 373
 374         missile.touch = W_Devastator_Touch;
 375         missile.think = W_Devastator_Think;
 376         missile.nextthink = time;
 377         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 378         missile.flags = FL_PROJECTILE;
 379         missile.missile_flags = MIF_SPLASH;
 380
 381         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 382
 383         // muzzle flash for 1st person view
 384         flash = spawn();
 385         setmodel(flash, "models/flash.md3"); // precision set below
 386         SUB_SetFade(flash, time, 0.1);
 387         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 388         W_AttachToShotorg(flash, '5 0 0');
 389
 390         // common properties
 391         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 392 }
 393
 394 bool W_Devastator(int req)
 395 {
 396         entity rock;
 397         float rockfound;
 398         float ammo_amount;
 399         switch(req)
 400         {
 401                 #if 0
 402                 case WR_AIM:
 403                 {
 404                         // aim and decide to fire if appropriate
 405                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 406                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 407                         {
 408                                 // decide whether to detonate rockets
 409                                 entity missile, targetlist, targ;
 410                                 targetlist = findchainfloat(bot_attack, true);
 411                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 412                                 {
 413                                         targ = targetlist;
 414                                         while(targ)
 415                                         {
 416                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 417                                                 {
 418                                                         self.BUTTON_ATCK2 = true;
 419                                                         break;
 420                                                 }
 421                                                 targ = targ.chain;
 422                                         }
 423                                 }
 424
 425                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = false;
 426                         }
 427
 428                         return true;
 429                 }
 430                 #else
 431                 case WR_AIM:
 432                 {
 433                         // aim and decide to fire if appropriate
 434                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 435                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 436                         {
 437                                 // decide whether to detonate rockets
 438                                 entity missile, targetlist, targ;
 439                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 440                                 float selfdamage, teamdamage, enemydamage;
 441                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 442                                 coredamage = WEP_CVAR(devastator, damage);
 443                                 edgeradius = WEP_CVAR(devastator, radius);
 444                                 recipricoledgeradius = 1 / edgeradius;
 445                                 selfdamage = 0;
 446                                 teamdamage = 0;
 447                                 enemydamage = 0;
 448                                 targetlist = findchainfloat(bot_attack, true);
 449                                 missile = find(world, classname, "rocket");
 450                                 while(missile)
 451                                 {
 452                                         if(missile.realowner != self)
 453                                         {
 454                                                 missile = find(missile, classname, "rocket");
 455                                                 continue;
 456                                         }
 457                                         targ = targetlist;
 458                                         while(targ)
 459                                         {
 460                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 461                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 462                                                 // count potential damage according to type of target
 463                                                 if(targ == self)
 464                                                         selfdamage = selfdamage + d;
 465                                                 else if(targ.team == self.team && teamplay)
 466                                                         teamdamage = teamdamage + d;
 467                                                 else if(bot_shouldattack(targ))
 468                                                         enemydamage = enemydamage + d;
 469                                                 targ = targ.chain;
 470                                         }
 471                                         missile = find(missile, classname, "rocket");
 472                                 }
 473                                 float desirabledamage;
 474                                 desirabledamage = enemydamage;
 475                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 476                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 477                                 if(teamplay && self.team)
 478                                         desirabledamage = desirabledamage - teamdamage;
 479
 480                                 missile = find(world, classname, "rocket");
 481                                 while(missile)
 482                                 {
 483                                         if(missile.realowner != self)
 484                                         {
 485                                                 missile = find(missile, classname, "rocket");
 486                                                 continue;
 487                                         }
 488                                         makevectors(missile.v_angle);
 489                                         targ = targetlist;
 490                                         if(skill > 9) // normal players only do this for the target they are tracking
 491                                         {
 492                                                 targ = targetlist;
 493                                                 while(targ)
 494                                                 {
 495                                                         if(
 496                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 497                                                                 && desirabledamage > 0.1*coredamage
 498                                                         )self.BUTTON_ATCK2 = true;
 499                                                         targ = targ.chain;
 500                                                 }
 501                                         }else{
 502                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 503                                                 //As the distance gets larger, a correct detonation gets near imposible
 504                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 505                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 506                                                         if(IS_PLAYER(self.enemy))
 507                                                                 if(desirabledamage >= 0.1*coredamage)
 508                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 509                                                                                 self.BUTTON_ATCK2 = true;
 510                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 511                                         }
 512
 513                                         missile = find(missile, classname, "rocket");
 514                                 }
 515                                 // if we would be doing at X percent of the core damage, detonate it
 516                                 // but don't fire a new shot at the same time!
 517                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 518                                         self.BUTTON_ATCK2 = true;
 519                                 if((skill > 6.5) && (selfdamage > self.health))
 520                                         self.BUTTON_ATCK2 = false;
 521                                 //if(self.BUTTON_ATCK2 == true)
 522                                 //      dprint(ftos(desirabledamage),"\n");
 523                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 524                         }
 525
 526                         return true;
 527                 }
 528                 #endif
 529                 case WR_THINK:
 530                 {
 531                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 532                                 WEP_ACTION(self.weapon, WR_RELOAD);
 533                         else
 534                         {
 535                                 if(self.BUTTON_ATCK)
 536                                 {
 537                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 538                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 539                                         {
 540                                                 W_Devastator_Attack();
 541                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 542                                                 self.rl_release = 0;
 543                                         }
 544                                 }
 545                                 else
 546                                         self.rl_release = 1;
 547
 548                                 if(self.BUTTON_ATCK2)
 549                                 if(self.switchweapon == WEP_DEVASTATOR)
 550                                 {
 551                                         rockfound = 0;
 552                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 553                                         {
 554                                                 if(!rock.rl_detonate_later)
 555                                                 {
 556                                                         rock.rl_detonate_later = true;
 557                                                         rockfound = 1;
 558                                                 }
 559                                         }
 560                                         if(rockfound)
 561                                                 sound(self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 562                                 }
 563                         }
 564
 565                         return true;
 566                 }
 567                 case WR_INIT:
 568                 {
 569                         //if(autocvar_sv_precacheweapons)
 570                         //{
 571                                 precache_model("models/flash.md3");
 572                                 precache_model("models/weapons/g_rl.md3");
 573                                 precache_model("models/weapons/v_rl.md3");
 574                                 precache_model("models/weapons/h_rl.iqm");
 575                                 precache_sound("weapons/rocket_det.wav");
 576                                 precache_sound("weapons/rocket_fire.wav");
 577                                 precache_sound("weapons/rocket_mode.wav");
 578                         //}
 579                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 580                         return true;
 581                 }
 582                 case WR_SETUP:
 583                 {
 584                         self.rl_release = 1;
 585                         return true;
 586                 }
 587                 case WR_CHECKAMMO1:
 588                 {
 589                         #if 0
 590                         // don't switch while guiding a missile
 591                         if(ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 592                         {
 593                                 ammo_amount = false;
 594                                 if(WEP_CVAR(devastator, reload_ammo))
 595                                 {
 596                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 597                                                 ammo_amount = true;
 598                                 }
 599                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 600                                         ammo_amount = true;
 601                                 return !ammo_amount;
 602                         }
 603                         #endif
 604                         #if 0
 605                         if(self.rl_release == 0)
 606                         {
 607                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 608                                 return true;
 609                         }
 610                         else
 611                         {
 612                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 613                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 614                                 printf("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 615                                 return ammo_amount;
 616                         }
 617                         #else
 618                         ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 619                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR]) >= WEP_CVAR(devastator, ammo);
 620                         return ammo_amount;
 621                         #endif
 622                 }
 623                 case WR_CHECKAMMO2:
 624                 {
 625                         return false;
 626                 }
 627                 case WR_CONFIG:
 628                 {
 629                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 630                         return true;
 631                 }
 632                 case WR_RESETPLAYER:
 633                 {
 634                         self.rl_release = 0;
 635                         return true;
 636                 }
 637                 case WR_RELOAD:
 638                 {
 639                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 640                         return true;
 641                 }
 642                 case WR_SUICIDEMESSAGE:
 643                 {
 644                         return WEAPON_DEVASTATOR_SUICIDE;
 645                 }
 646                 case WR_KILLMESSAGE:
 647                 {
 648                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 649                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 650                         else
 651                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 652                 }
 653         }
 654         return false;
 655 }
 656 #endif
 657 #ifdef CSQC
 658 bool W_Devastator(int req)
 659 {
 660         switch(req)
 661         {
 662                 case WR_IMPACTEFFECT:
 663                 {
 664                         vector org2;
 665                         org2 = w_org + w_backoff * 12;
 666                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 667                         if(!w_issilent)
 668                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 669
 670                         return true;
 671                 }
 672                 case WR_INIT:
 673                 {
 674                         precache_sound("weapons/rocket_impact.wav");
 675                         return true;
 676                 }
 677                 case WR_ZOOMRETICLE:
 678                 {
 679                         // no weapon specific image for this weapon
 680                         return false;
 681                 }
 682         }
 683         return false;
 684 }
 685 #endif
 686 #endif