qcsrc/common/weapons/w_hagar.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ HAGAR,
   4 /* function  */ W_Hagar,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 8,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '1 1 0.5',
  10 /* modelname */ "hagar",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairhagar 0.8",
  13 /* wepimg    */ "weaponhagar",
  14 /* refname   */ "hagar",
  15 /* wepname   */ _("Hagar")
  16 );
  17
  18 #define HAGAR_SETTINGS(w_cvar,w_prop) HAGAR_SETTINGS_LIST(w_cvar, w_prop, HAGAR, hagar)
  19 #define HAGAR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, ammo) \
  21         w_cvar(id, sn, BOTH, damage) \
  22         w_cvar(id, sn, BOTH, edgedamage) \
  23         w_cvar(id, sn, BOTH, force) \
  24         w_cvar(id, sn, BOTH, radius) \
  25         w_cvar(id, sn, BOTH, refire) \
  26         w_cvar(id, sn, BOTH, speed) \
  27         w_cvar(id, sn, BOTH, spread) \
  28         w_cvar(id, sn, BOTH, damageforcescale) \
  29         w_cvar(id, sn, BOTH, health) \
  30         w_cvar(id, sn, PRI,  lifetime) \
  31         w_cvar(id, sn, SEC,  load) \
  32         w_cvar(id, sn, SEC,  load_max) \
  33         w_cvar(id, sn, SEC,  load_abort) \
  34         w_cvar(id, sn, SEC,  load_animtime) \
  35         w_cvar(id, sn, SEC,  load_hold) \
  36         w_cvar(id, sn, SEC,  load_speed) \
  37         w_cvar(id, sn, SEC,  load_releasedeath) \
  38         w_cvar(id, sn, SEC,  load_spread) \
  39         w_cvar(id, sn, SEC,  load_spread_bias) \
  40         w_cvar(id, sn, SEC,  load_linkexplode) \
  41         w_cvar(id, sn, SEC,  lifetime_min) \
  42         w_cvar(id, sn, SEC,  lifetime_rand) \
  43         w_cvar(id, sn, NONE, secondary) \
  44         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  45         w_prop(id, sn, float,  reloading_time, reload_time) \
  46         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  47         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  48         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  49         w_prop(id, sn, float,  weaponstart, weaponstart) \
  50         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  51         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  52
  53 #ifdef SVQC
  54 HAGAR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  55 #endif
  56 #endif
  57 #ifdef IMPLEMENTATION
  58 #ifdef SVQC
  59 void spawnfunc_weapon_hagar(void) { weapon_defaultspawnfunc(WEP_HAGAR.m_id); }
  60
  61 // NO bounce protection, as bounces are limited!
  62
  63 void W_Hagar_Explode(void)
  64 {
  65         self.event_damage = func_null;
  66         RadiusDamage(self, self.realowner, WEP_CVAR_PRI(hagar, damage), WEP_CVAR_PRI(hagar, edgedamage), WEP_CVAR_PRI(hagar, radius), world, world, WEP_CVAR_PRI(hagar, force), self.projectiledeathtype, other);
  67
  68         remove(self);
  69 }
  70
  71 void W_Hagar_Explode2(void)
  72 {
  73         self.event_damage = func_null;
  74         RadiusDamage(self, self.realowner, WEP_CVAR_SEC(hagar, damage), WEP_CVAR_SEC(hagar, edgedamage), WEP_CVAR_SEC(hagar, radius), world, world, WEP_CVAR_SEC(hagar, force), self.projectiledeathtype, other);
  75
  76         remove(self);
  77 }
  78
  79 void W_Hagar_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83
  84         float is_linkexplode = ( ((inflictor.owner != world) ? (inflictor.owner == self.owner) : true)
  85                 && (inflictor.projectiledeathtype & HITTYPE_SECONDARY)
  86                 && (self.projectiledeathtype & HITTYPE_SECONDARY));
  87
  88         if(is_linkexplode)
  89                 is_linkexplode = (is_linkexplode && WEP_CVAR_SEC(hagar, load_linkexplode));
  90         else
  91                 is_linkexplode = -1; // not secondary load, so continue as normal without exception.
  92
  93         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, is_linkexplode))
  94                 return; // g_projectiles_damage says to halt
  95
  96         self.health = self.health - damage;
  97         self.angles = vectoangles(self.velocity);
  98
  99         if(self.health <= 0)
 100                 W_PrepareExplosionByDamage(attacker, self.think);
 101 }
 102
 103 void W_Hagar_Touch(void)
 104 {
 105         PROJECTILE_TOUCH;
 106         self.use();
 107 }
 108
 109 void W_Hagar_Touch2(void)
 110 {
 111         PROJECTILE_TOUCH;
 112
 113         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
 114                 self.use();
 115         } else {
 116                 self.cnt++;
 117                 Send_Effect("hagar_bounce", self.origin, self.velocity, 1);
 118                 self.angles = vectoangles(self.velocity);
 119                 self.owner = world;
 120                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 121         }
 122 }
 123
 124 void W_Hagar_Attack(void)
 125 {
 126         entity missile;
 127
 128         W_DecreaseAmmo(WEP_CVAR_PRI(hagar, ammo));
 129
 130         W_SetupShot(self, false, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(hagar, damage));
 131
 132         Send_Effect("hagar_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 133
 134         missile = spawn();
 135         missile.owner = missile.realowner = self;
 136         missile.classname = "missile";
 137         missile.bot_dodge = true;
 138         missile.bot_dodgerating = WEP_CVAR_PRI(hagar, damage);
 139
 140         missile.takedamage = DAMAGE_YES;
 141         missile.health = WEP_CVAR_PRI(hagar, health);
 142         missile.damageforcescale = WEP_CVAR_PRI(hagar, damageforcescale);
 143         missile.event_damage = W_Hagar_Damage;
 144         missile.damagedbycontents = true;
 145
 146         missile.touch = W_Hagar_Touch;
 147         missile.use = W_Hagar_Explode;
 148         missile.think = adaptor_think2use_hittype_splash;
 149         missile.nextthink = time + WEP_CVAR_PRI(hagar, lifetime);
 150         PROJECTILE_MAKETRIGGER(missile);
 151         missile.projectiledeathtype = WEP_HAGAR.m_id;
 152         setorigin(missile, w_shotorg);
 153         setsize(missile, '0 0 0', '0 0 0');
 154
 155         missile.movetype = MOVETYPE_FLY;
 156         W_SetupProjVelocity_PRI(missile, hagar);
 157
 158         missile.angles = vectoangles(missile.velocity);
 159         missile.flags = FL_PROJECTILE;
 160         missile.missile_flags = MIF_SPLASH;
 161
 162         CSQCProjectile(missile, true, PROJECTILE_HAGAR, true);
 163
 164         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 165 }
 166
 167 void W_Hagar_Attack2(void)
 168 {
 169         entity missile;
 170
 171         W_DecreaseAmmo(WEP_CVAR_SEC(hagar, ammo));
 172
 173         W_SetupShot(self, false, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hagar, damage));
 174
 175         Send_Effect("hagar_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 176
 177         missile = spawn();
 178         missile.owner = missile.realowner = self;
 179         missile.classname = "missile";
 180         missile.bot_dodge = true;
 181         missile.bot_dodgerating = WEP_CVAR_SEC(hagar, damage);
 182
 183         missile.takedamage = DAMAGE_YES;
 184         missile.health = WEP_CVAR_SEC(hagar, health);
 185         missile.damageforcescale = WEP_CVAR_SEC(hagar, damageforcescale);
 186         missile.event_damage = W_Hagar_Damage;
 187         missile.damagedbycontents = true;
 188
 189         missile.touch = W_Hagar_Touch2;
 190         missile.cnt = 0;
 191         missile.use = W_Hagar_Explode2;
 192         missile.think = adaptor_think2use_hittype_splash;
 193         missile.nextthink = time + WEP_CVAR_SEC(hagar, lifetime_min) + random() * WEP_CVAR_SEC(hagar, lifetime_rand);
 194         PROJECTILE_MAKETRIGGER(missile);
 195         missile.projectiledeathtype = WEP_HAGAR.m_id | HITTYPE_SECONDARY;
 196         setorigin(missile, w_shotorg);
 197         setsize(missile, '0 0 0', '0 0 0');
 198
 199         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 200         W_SetupProjVelocity_SEC(missile, hagar);
 201
 202         missile.angles = vectoangles(missile.velocity);
 203         missile.flags = FL_PROJECTILE;
 204         missile.missile_flags = MIF_SPLASH;
 205
 206         CSQCProjectile(missile, true, PROJECTILE_HAGAR_BOUNCING, true);
 207
 208         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 209 }
 210
 211 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep, hagar_warning;
 212 void W_Hagar_Attack2_Load_Release(void)
 213 {
 214         // time to release the rockets we've loaded
 215
 216         entity missile;
 217         float counter, shots, spread_pershot;
 218         vector s;
 219         vector forward, right, up;
 220
 221         if(!self.hagar_load)
 222                 return;
 223
 224         weapon_prepareattack_do(1, WEP_CVAR_SEC(hagar, refire));
 225
 226         W_SetupShot(self, false, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hagar, damage));
 227         Send_Effect("hagar_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 228
 229         forward = v_forward;
 230         right = v_right;
 231         up = v_up;
 232
 233         shots = self.hagar_load;
 234         missile = world;
 235         for(counter = 0; counter < shots; ++counter)
 236         {
 237                 missile = spawn();
 238                 missile.owner = missile.realowner = self;
 239                 missile.classname = "missile";
 240                 missile.bot_dodge = true;
 241                 missile.bot_dodgerating = WEP_CVAR_SEC(hagar, damage);
 242
 243                 missile.takedamage = DAMAGE_YES;
 244                 missile.health = WEP_CVAR_SEC(hagar, health);
 245                 missile.damageforcescale = WEP_CVAR_SEC(hagar, damageforcescale);
 246                 missile.event_damage = W_Hagar_Damage;
 247                 missile.damagedbycontents = true;
 248
 249                 missile.touch = W_Hagar_Touch; // not bouncy
 250                 missile.use = W_Hagar_Explode2;
 251                 missile.think = adaptor_think2use_hittype_splash;
 252                 missile.nextthink = time + WEP_CVAR_SEC(hagar, lifetime_min) + random() * WEP_CVAR_SEC(hagar, lifetime_rand);
 253                 PROJECTILE_MAKETRIGGER(missile);
 254                 missile.projectiledeathtype = WEP_HAGAR.m_id | HITTYPE_SECONDARY;
 255                 setorigin(missile, w_shotorg);
 256                 setsize(missile, '0 0 0', '0 0 0');
 257                 missile.movetype = MOVETYPE_FLY;
 258                 missile.missile_flags = MIF_SPLASH;
 259
 260                 // per-shot spread calculation: the more shots there are, the less spread is applied (based on the bias cvar)
 261                 spread_pershot = ((shots - 1) / (WEP_CVAR_SEC(hagar, load_max) - 1));
 262                 spread_pershot = (1 - (spread_pershot * WEP_CVAR_SEC(hagar, load_spread_bias)));
 263                 spread_pershot = (WEP_CVAR_SEC(hagar, spread) * spread_pershot * g_weaponspreadfactor);
 264
 265                 // pattern spread calculation
 266                 s = '0 0 0';
 267                 if(counter == 0)
 268                         s = '0 0 0';
 269                 else
 270                 {
 271                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 272                         s.y = v_forward.x;
 273                         s.z = v_forward.y;
 274                 }
 275                 s = s * WEP_CVAR_SEC(hagar, load_spread) * g_weaponspreadfactor;
 276
 277                 W_SetupProjVelocity_Explicit(missile, w_shotdir + right * s.y + up * s.z, v_up, WEP_CVAR_SEC(hagar, speed), 0, 0, spread_pershot, false);
 278
 279                 missile.angles = vectoangles(missile.velocity);
 280                 missile.flags = FL_PROJECTILE;
 281
 282                 CSQCProjectile(missile, true, PROJECTILE_HAGAR, true);
 283
 284                 MUTATOR_CALLHOOK(EditProjectile, self, missile);
 285         }
 286
 287         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hagar, load_animtime), w_ready);
 288         self.hagar_loadstep = time + WEP_CVAR_SEC(hagar, refire) * W_WeaponRateFactor();
 289         self.hagar_load = 0;
 290 }
 291
 292 void W_Hagar_Attack2_Load(void)
 293 {
 294         // loadable hagar secondary attack, must always run each frame
 295
 296         if(time < game_starttime)
 297                 return;
 298
 299         float loaded, enough_ammo;
 300         loaded = self.hagar_load >= WEP_CVAR_SEC(hagar, load_max);
 301
 302         // this is different than WR_CHECKAMMO when it comes to reloading
 303         if(self.items & IT_UNLIMITED_WEAPON_AMMO)
 304                 enough_ammo = true;
 305         else if(autocvar_g_balance_hagar_reload_ammo)
 306                 enough_ammo = self.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_SEC(hagar, ammo);
 307         else
 308                 enough_ammo = self.WEP_AMMO(HAGAR) >= WEP_CVAR_SEC(hagar, ammo);
 309
 310         if(self.BUTTON_ATCK2)
 311         {
 312                 if(self.BUTTON_ATCK && WEP_CVAR_SEC(hagar, load_abort))
 313                 {
 314                         if(self.hagar_load)
 315                         {
 316                                 // if we pressed primary fire while loading, unload all rockets and abort
 317                                 self.weaponentity.state = WS_READY;
 318                                 W_DecreaseAmmo(WEP_CVAR_SEC(hagar, ammo) * self.hagar_load * -1); // give back ammo
 319                                 self.hagar_load = 0;
 320                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 321
 322                                 // pause until we can load rockets again, once we re-press the alt fire button
 323                                 self.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_speed) * W_WeaponRateFactor();
 324
 325                                 // require letting go of the alt fire button before we can load again
 326                                 self.hagar_loadblock = true;
 327                         }
 328                 }
 329                 else
 330                 {
 331                         // check if we can attempt to load another rocket
 332                         if(!loaded && enough_ammo)
 333                         {
 334                                 if(!self.hagar_loadblock && self.hagar_loadstep < time)
 335                                 {
 336                                         W_DecreaseAmmo(WEP_CVAR_SEC(hagar, ammo));
 337                                         self.weaponentity.state = WS_INUSE;
 338                                         self.hagar_load += 1;
 339                                         sound(self, CH_WEAPON_B, "weapons/hagar_load.wav", VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
 340
 341                                         if(self.hagar_load >= WEP_CVAR_SEC(hagar, load_max))
 342                                                 self.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_hold) * W_WeaponRateFactor();
 343                                         else
 344                                                 self.hagar_loadstep = time + WEP_CVAR_SEC(hagar, load_speed) * W_WeaponRateFactor();
 345                                 }
 346                         }
 347                         else if(!self.hagar_loadbeep && self.hagar_load) // prevents the beep from playing each frame
 348                         {
 349                                 // if this is the last rocket we can load, play a beep sound to notify the player
 350                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 351                                 self.hagar_loadbeep = true;
 352                         }
 353                 }
 354         }
 355         else if(self.hagar_loadblock)
 356         {
 357                 // the alt fire button has been released, so re-enable loading if blocked
 358                 self.hagar_loadblock = false;
 359         }
 360
 361         if(self.hagar_load)
 362         {
 363                 // play warning sound if we're about to release
 364                 if((loaded || !enough_ammo) && self.hagar_loadstep - 0.5 < time && WEP_CVAR_SEC(hagar, load_hold) >= 0)
 365                 {
 366                         if(!self.hagar_warning && self.hagar_load) // prevents the beep from playing each frame
 367                         {
 368                                 // we're about to automatically release after holding time, play a beep sound to notify the player
 369                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 370                                 self.hagar_warning = true;
 371                         }
 372                 }
 373
 374                 // release if player let go of button or if they've held it in too long
 375                 if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && WEP_CVAR_SEC(hagar, load_hold) >= 0))
 376                 {
 377                         self.weaponentity.state = WS_READY;
 378                         W_Hagar_Attack2_Load_Release();
 379                 }
 380         }
 381         else
 382         {
 383                 self.hagar_loadbeep = false;
 384                 self.hagar_warning = false;
 385         }
 386
 387         // we aren't checking ammo during an attack, so we must do it here
 388         if(!(WEP_ACTION(self.weapon, WR_CHECKAMMO1) + WEP_ACTION(self.weapon, WR_CHECKAMMO2)))
 389         if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 390         {
 391                 // note: this doesn't force the switch
 392                 W_SwitchToOtherWeapon(self);
 393                 return;
 394         }
 395 }
 396
 397 bool W_Hagar(int req)
 398 {
 399         float ammo_amount;
 400         switch(req)
 401         {
 402                 case WR_AIM:
 403                 {
 404                         if(random()>0.15)
 405                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(hagar, speed), 0, WEP_CVAR_PRI(hagar, lifetime), false);
 406                         else // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 407                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_PRI(hagar, speed), 0, WEP_CVAR_PRI(hagar, lifetime), false);
 408
 409                         return true;
 410                 }
 411                 case WR_THINK:
 412                 {
 413                         float loadable_secondary;
 414                         loadable_secondary = (WEP_CVAR_SEC(hagar, load) && WEP_CVAR(hagar, secondary));
 415
 416                         if(loadable_secondary)
 417                                 W_Hagar_Attack2_Load(); // must always run each frame
 418                         if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(hagar, ammo), WEP_CVAR_SEC(hagar, ammo))) // forced reload
 419                                 WEP_ACTION(self.weapon, WR_RELOAD);
 420                         else if(self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 421                         {
 422                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(hagar, refire)))
 423                                 {
 424                                         W_Hagar_Attack();
 425                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(hagar, refire), w_ready);
 426                                 }
 427                         }
 428                         else if(self.BUTTON_ATCK2 && !loadable_secondary && WEP_CVAR(hagar, secondary))
 429                         {
 430                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(hagar, refire)))
 431                                 {
 432                                         W_Hagar_Attack2();
 433                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hagar, refire), w_ready);
 434                                 }
 435                         }
 436
 437                         return true;
 438                 }
 439                 case WR_GONETHINK:
 440                 {
 441                         // we lost the weapon and want to prepare switching away
 442                         if(self.hagar_load)
 443                         {
 444                                 self.weaponentity.state = WS_READY;
 445                                 W_Hagar_Attack2_Load_Release();
 446                         }
 447
 448                         return true;
 449                 }
 450                 case WR_INIT:
 451                 {
 452                         precache_model("models/weapons/g_hagar.md3");
 453                         precache_model("models/weapons/v_hagar.md3");
 454                         precache_model("models/weapons/h_hagar.iqm");
 455                         precache_sound("weapons/hagar_fire.wav");
 456                         precache_sound("weapons/hagar_load.wav");
 457                         precache_sound("weapons/hagar_beep.wav");
 458                         HAGAR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 459                         return true;
 460                 }
 461                 case WR_SETUP:
 462                 {
 463                         self.hagar_loadblock = false;
 464
 465                         if(self.hagar_load)
 466                         {
 467                                 W_DecreaseAmmo(WEP_CVAR_SEC(hagar, ammo) * self.hagar_load * -1); // give back ammo if necessary
 468                                 self.hagar_load = 0;
 469                         }
 470
 471                         return true;
 472                 }
 473                 case WR_CHECKAMMO1:
 474                 {
 475                         ammo_amount = self.WEP_AMMO(HAGAR) >= WEP_CVAR_PRI(hagar, ammo);
 476                         ammo_amount += self.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_PRI(hagar, ammo);
 477                         return ammo_amount;
 478                 }
 479                 case WR_CHECKAMMO2:
 480                 {
 481                         ammo_amount = self.WEP_AMMO(HAGAR) >= WEP_CVAR_SEC(hagar, ammo);
 482                         ammo_amount += self.(weapon_load[WEP_HAGAR.m_id]) >= WEP_CVAR_SEC(hagar, ammo);
 483                         return ammo_amount;
 484                 }
 485                 case WR_CONFIG:
 486                 {
 487                         HAGAR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 488                         return true;
 489                 }
 490                 case WR_RESETPLAYER:
 491                 {
 492                         self.hagar_load = 0;
 493                         return true;
 494                 }
 495                 case WR_PLAYERDEATH:
 496                 {
 497                         // if we have any rockets loaded when we die, release them
 498                         if(self.hagar_load && WEP_CVAR_SEC(hagar, load_releasedeath))
 499                                 W_Hagar_Attack2_Load_Release();
 500
 501                         return true;
 502                 }
 503                 case WR_RELOAD:
 504                 {
 505                         if(!self.hagar_load) // require releasing loaded rockets first
 506                                 W_Reload(min(WEP_CVAR_PRI(hagar, ammo), WEP_CVAR_SEC(hagar, ammo)), "weapons/reload.wav");
 507
 508                         return true;
 509                 }
 510                 case WR_SUICIDEMESSAGE:
 511                 {
 512                         return WEAPON_HAGAR_SUICIDE;
 513                 }
 514                 case WR_KILLMESSAGE:
 515                 {
 516                         if(w_deathtype & HITTYPE_SECONDARY)
 517                                 return WEAPON_HAGAR_MURDER_BURST;
 518                         else
 519                                 return WEAPON_HAGAR_MURDER_SPRAY;
 520                 }
 521         }
 522         return false;
 523 }
 524 #endif
 525 #ifdef CSQC
 526 bool W_Hagar(int req)
 527 {
 528         switch(req)
 529         {
 530                 case WR_IMPACTEFFECT:
 531                 {
 532                         vector org2;
 533                         org2 = w_org + w_backoff * 6;
 534                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 535                         if(!w_issilent)
 536                         {
 537                                 if(w_random<0.15)
 538                                         sound(self, CH_SHOTS, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 539                                 else if(w_random<0.7)
 540                                         sound(self, CH_SHOTS, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 541                                 else
 542                                         sound(self, CH_SHOTS, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 543                         }
 544
 545                         return true;
 546                 }
 547                 case WR_INIT:
 548                 {
 549                         precache_sound("weapons/hagexp1.wav");
 550                         precache_sound("weapons/hagexp2.wav");
 551                         precache_sound("weapons/hagexp3.wav");
 552                         return true;
 553                 }
 554                 case WR_ZOOMRETICLE:
 555                 {
 556                         // no weapon specific image for this weapon
 557                         return false;
 558                 }
 559         }
 560         return false;
 561 }
 562 #endif
 563 #endif