qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MINE_LAYER,
   4 /* function  */ W_MineLayer,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.75 1 0',
  10 /* modelname */ "minelayer",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminelayer 0.9",
  13 /* wepimg    */ "weaponminelayer",
  14 /* refname   */ "minelayer",
  15 /* wepname   */ _("Mine Layer")
  16 );
  17
  18 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  19 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, ammo) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, damage) \
  23         w_cvar(id, sn, NONE, damageforcescale) \
  24         w_cvar(id, sn, NONE, detonatedelay) \
  25         w_cvar(id, sn, NONE, edgedamage) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, health) \
  28         w_cvar(id, sn, NONE, lifetime) \
  29         w_cvar(id, sn, NONE, lifetime_countdown) \
  30         w_cvar(id, sn, NONE, limit) \
  31         w_cvar(id, sn, NONE, protection) \
  32         w_cvar(id, sn, NONE, proximityradius) \
  33         w_cvar(id, sn, NONE, radius) \
  34         w_cvar(id, sn, NONE, refire) \
  35         w_cvar(id, sn, NONE, remote_damage) \
  36         w_cvar(id, sn, NONE, remote_edgedamage) \
  37         w_cvar(id, sn, NONE, remote_force) \
  38         w_cvar(id, sn, NONE, remote_radius) \
  39         w_cvar(id, sn, NONE, speed) \
  40         w_cvar(id, sn, NONE, time) \
  41         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  42         w_prop(id, sn, float,  reloading_time, reload_time) \
  43         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  44         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  45         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  46         w_prop(id, sn, float,  weaponstart, weaponstart) \
  47         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  48
  49 #ifdef SVQC
  50 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  51 void W_MineLayer_Think (void);
  52 .float minelayer_detonate, mine_explodeanyway;
  53 .float mine_time;
  54 .vector mine_orientation;
  55 #endif
  56 #else
  57 #ifdef SVQC
  58 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  59
  60 void W_MineLayer_Stick (entity to)
  61 {
  62         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  63
  64         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  65
  66         entity newmine;
  67         newmine = spawn();
  68         newmine.classname = self.classname;
  69
  70         newmine.bot_dodge = self.bot_dodge;
  71         newmine.bot_dodgerating = self.bot_dodgerating;
  72
  73         newmine.owner = self.owner;
  74         newmine.realowner = self.realowner;
  75         setsize(newmine, '-4 -4 -4', '4 4 4');
  76         setorigin(newmine, self.origin);
  77         setmodel(newmine, "models/mine.md3");
  78         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  79
  80         newmine.mine_orientation = -trace_plane_normal;
  81
  82         newmine.takedamage = self.takedamage;
  83         newmine.damageforcescale = self.damageforcescale;
  84         newmine.health = self.health;
  85         newmine.event_damage = self.event_damage;
  86         newmine.spawnshieldtime = self.spawnshieldtime;
  87         newmine.damagedbycontents = TRUE;
  88
  89         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  90         newmine.projectiledeathtype = self.projectiledeathtype;
  91
  92         newmine.mine_time = self.mine_time;
  93
  94         newmine.touch = func_null;
  95         newmine.think = W_MineLayer_Think;
  96         newmine.nextthink = time;
  97         newmine.cnt = self.cnt;
  98         newmine.flags = self.flags;
  99
 100         remove(self);
 101         self = newmine;
 102
 103         if(to)
 104                 SetMovetypeFollow(self, to);
 105 }
 106
 107 void W_MineLayer_Explode()
 108 {
 109         if(other.takedamage == DAMAGE_AIM)
 110                 if(IS_PLAYER(other))
 111                         if(DIFF_TEAM(self.realowner, other))
 112                                 if(other.deadflag == DEAD_NO)
 113                                         if(IsFlying(other))
 114                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 115
 116         self.event_damage = func_null;
 117         self.takedamage = DAMAGE_NO;
 118
 119         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 120
 121         if (self.realowner.weapon == WEP_MINE_LAYER)
 122         {
 123                 entity oldself;
 124                 oldself = self;
 125                 self = self.realowner;
 126                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 127                 {
 128                         self.cnt = WEP_MINE_LAYER;
 129                         ATTACK_FINISHED(self) = time;
 130                         self.switchweapon = w_getbestweapon(self);
 131                 }
 132                 self = oldself;
 133         }
 134         self.realowner.minelayer_mines -= 1;
 135         remove (self);
 136 }
 137
 138 void W_MineLayer_DoRemoteExplode ()
 139 {
 140         self.event_damage = func_null;
 141         self.takedamage = DAMAGE_NO;
 142
 143         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 144                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 145
 146         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 147
 148         if (self.realowner.weapon == WEP_MINE_LAYER)
 149         {
 150                 entity oldself;
 151                 oldself = self;
 152                 self = self.realowner;
 153                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 154                 {
 155                         self.cnt = WEP_MINE_LAYER;
 156                         ATTACK_FINISHED(self) = time;
 157                         self.switchweapon = w_getbestweapon(self);
 158                 }
 159                 self = oldself;
 160         }
 161         self.realowner.minelayer_mines -= 1;
 162         remove (self);
 163 }
 164
 165 void W_MineLayer_RemoteExplode ()
 166 {
 167         if(self.realowner.deadflag == DEAD_NO)
 168                 if((self.spawnshieldtime >= 0)
 169                         ? (time >= self.spawnshieldtime) // timer
 170                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 171                 )
 172                 {
 173                         W_MineLayer_DoRemoteExplode();
 174                 }
 175 }
 176
 177 void W_MineLayer_ProximityExplode ()
 178 {
 179         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 180         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 181         {
 182                 entity head;
 183                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 184                 while(head)
 185                 {
 186                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 187                                 return;
 188                         head = head.chain;
 189                 }
 190         }
 191
 192         self.mine_time = 0;
 193         W_MineLayer_Explode();
 194 }
 195
 196 float W_MineLayer_Count(entity e)
 197 {
 198         float minecount = 0;
 199         entity mine;
 200         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 201                 minecount += 1;
 202
 203         return minecount;
 204 }
 205
 206 void W_MineLayer_Think (void)
 207 {
 208         entity head;
 209
 210         self.nextthink = time;
 211
 212         if(self.movetype == MOVETYPE_FOLLOW)
 213         {
 214                 if(LostMovetypeFollow(self))
 215                 {
 216                         UnsetMovetypeFollow(self);
 217                         self.movetype = MOVETYPE_NONE;
 218                 }
 219         }
 220
 221         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 222         // TODO: replace this mine_trigger.wav sound with a real countdown
 223         if ((time > self.cnt) && (!self.mine_time))
 224         {
 225                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 226                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 227                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 228                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 229         }
 230
 231         // a player's mines shall explode if he disconnects or dies
 232         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 233         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 234         {
 235                 other = world;
 236                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 237                 W_MineLayer_Explode();
 238                 return;
 239         }
 240
 241         // set the mine for detonation when a foe gets close enough
 242         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 243         while(head)
 244         {
 245                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 246                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 247                 if(!self.mine_time)
 248                 {
 249                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 250                         self.mine_time = time + WEP_CVAR(minelayer, time);
 251                 }
 252                 head = head.chain;
 253         }
 254
 255         // explode if it's time to
 256         if(self.mine_time && time >= self.mine_time)
 257         {
 258                 W_MineLayer_ProximityExplode();
 259                 return;
 260         }
 261
 262         // remote detonation
 263         if (self.realowner.weapon == WEP_MINE_LAYER)
 264         if (self.realowner.deadflag == DEAD_NO)
 265         if (self.minelayer_detonate)
 266                 W_MineLayer_RemoteExplode();
 267 }
 268
 269 void W_MineLayer_Touch (void)
 270 {
 271         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 272                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 273
 274         if(WarpZone_Projectile_Touch())
 275         {
 276                 if(wasfreed(self))
 277                         self.realowner.minelayer_mines -= 1;
 278                 return;
 279         }
 280
 281         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 282         {
 283                 // hit a player
 284                 // don't stick
 285         }
 286         else
 287         {
 288                 W_MineLayer_Stick(other);
 289         }
 290 }
 291
 292 void W_MineLayer_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 293 {
 294         if (self.health <= 0)
 295                 return;
 296
 297         float is_from_enemy = (inflictor.realowner != self.realowner);
 298
 299         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 300                 return; // g_projectiles_damage says to halt
 301
 302         self.health = self.health - damage;
 303         self.angles = vectoangles(self.velocity);
 304
 305         if (self.health <= 0)
 306                 W_PrepareExplosionByDamage(attacker, W_MineLayer_Explode);
 307 }
 308
 309 void W_MineLayer_Attack()
 310 {
 311         entity mine;
 312         entity flash;
 313
 314         // scan how many mines we placed, and return if we reached our limit
 315         if(WEP_CVAR(minelayer, limit))
 316         {
 317                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 318                 {
 319                         // the refire delay keeps this message from being spammed
 320                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 321                         play2(self, "weapons/unavailable.wav");
 322                         return;
 323                 }
 324         }
 325
 326         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 327
 328         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 329         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 330
 331         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 332         mine.owner = mine.realowner = self;
 333         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 334                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 335         else
 336                 mine.spawnshieldtime = -1;
 337         mine.classname = "mine";
 338         mine.bot_dodge = TRUE;
 339         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 340
 341         mine.takedamage = DAMAGE_YES;
 342         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 343         mine.health = WEP_CVAR(minelayer, health);
 344         mine.event_damage = W_MineLayer_Damage;
 345         mine.damagedbycontents = TRUE;
 346
 347         mine.movetype = MOVETYPE_TOSS;
 348         PROJECTILE_MAKETRIGGER(mine);
 349         mine.projectiledeathtype = WEP_MINE_LAYER;
 350         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 351
 352         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 353         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 354         mine.angles = vectoangles (mine.velocity);
 355
 356         mine.touch = W_MineLayer_Touch;
 357         mine.think = W_MineLayer_Think;
 358         mine.nextthink = time;
 359         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 360         mine.flags = FL_PROJECTILE;
 361         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 362
 363         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 364
 365         // muzzle flash for 1st person view
 366         flash = spawn ();
 367         setmodel (flash, "models/flash.md3"); // precision set below
 368         SUB_SetFade (flash, time, 0.1);
 369         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 370         W_AttachToShotorg(flash, '5 0 0');
 371
 372         // common properties
 373
 374         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 375
 376         self.minelayer_mines = W_MineLayer_Count(self);
 377 }
 378
 379 float W_MineLayer_PlacedMines(float detonate)
 380 {
 381         entity mine;
 382         float minfound = 0;
 383
 384         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 385         {
 386                 if(detonate)
 387                 {
 388                         if(!mine.minelayer_detonate)
 389                         {
 390                                 mine.minelayer_detonate = TRUE;
 391                                 minfound = 1;
 392                         }
 393                 }
 394                 else
 395                         minfound = 1;
 396         }
 397         return minfound;
 398 }
 399
 400 float W_MineLayer(float req)
 401 {
 402         entity mine;
 403         float ammo_amount;
 404         switch(req)
 405         {
 406                 case WR_AIM:
 407                 {
 408                         // aim and decide to fire if appropriate
 409                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 410                                 self.BUTTON_ATCK = FALSE;
 411                         else
 412                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 413                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 414                         {
 415                                 // decide whether to detonate mines
 416                                 entity targetlist, targ;
 417                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 418                                 float selfdamage, teamdamage, enemydamage;
 419                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 420                                 coredamage = WEP_CVAR(minelayer, damage);
 421                                 edgeradius = WEP_CVAR(minelayer, radius);
 422                                 recipricoledgeradius = 1 / edgeradius;
 423                                 selfdamage = 0;
 424                                 teamdamage = 0;
 425                                 enemydamage = 0;
 426                                 targetlist = findchainfloat(bot_attack, TRUE);
 427                                 mine = find(world, classname, "mine");
 428                                 while (mine)
 429                                 {
 430                                         if (mine.realowner != self)
 431                                         {
 432                                                 mine = find(mine, classname, "mine");
 433                                                 continue;
 434                                         }
 435                                         targ = targetlist;
 436                                         while (targ)
 437                                         {
 438                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 439                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 440                                                 // count potential damage according to type of target
 441                                                 if (targ == self)
 442                                                         selfdamage = selfdamage + d;
 443                                                 else if (targ.team == self.team && teamplay)
 444                                                         teamdamage = teamdamage + d;
 445                                                 else if (bot_shouldattack(targ))
 446                                                         enemydamage = enemydamage + d;
 447                                                 targ = targ.chain;
 448                                         }
 449                                         mine = find(mine, classname, "mine");
 450                                 }
 451                                 float desirabledamage;
 452                                 desirabledamage = enemydamage;
 453                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 454                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 455                                 if (teamplay && self.team)
 456                                         desirabledamage = desirabledamage - teamdamage;
 457
 458                                 mine = find(world, classname, "mine");
 459                                 while (mine)
 460                                 {
 461                                         if (mine.realowner != self)
 462                                         {
 463                                                 mine = find(mine, classname, "mine");
 464                                                 continue;
 465                                         }
 466                                         makevectors(mine.v_angle);
 467                                         targ = targetlist;
 468                                         if (skill > 9) // normal players only do this for the target they are tracking
 469                                         {
 470                                                 targ = targetlist;
 471                                                 while (targ)
 472                                                 {
 473                                                         if (
 474                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 475                                                                 && desirabledamage > 0.1*coredamage
 476                                                         )self.BUTTON_ATCK2 = TRUE;
 477                                                         targ = targ.chain;
 478                                                 }
 479                                         }else{
 480                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 481                                                 //As the distance gets larger, a correct detonation gets near imposible
 482                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 483                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 484                                                         if(IS_PLAYER(self.enemy))
 485                                                                 if(desirabledamage >= 0.1*coredamage)
 486                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 487                                                                                 self.BUTTON_ATCK2 = TRUE;
 488                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 489                                         }
 490
 491                                         mine = find(mine, classname, "mine");
 492                                 }
 493                                 // if we would be doing at X percent of the core damage, detonate it
 494                                 // but don't fire a new shot at the same time!
 495                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 496                                         self.BUTTON_ATCK2 = TRUE;
 497                                 if ((skill > 6.5) && (selfdamage > self.health))
 498                                         self.BUTTON_ATCK2 = FALSE;
 499                                 //if(self.BUTTON_ATCK2 == TRUE)
 500                                 //      dprint(ftos(desirabledamage),"\n");
 501                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 502                         }
 503
 504                         return TRUE;
 505                 }
 506                 case WR_THINK:
 507                 {
 508                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 509                         {
 510                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 511                                 if(!(W_MineLayer_PlacedMines(FALSE) && self.WEP_AMMO(MINE_LAYER) < WEP_CVAR(minelayer, ammo)))
 512                                         WEP_ACTION(self.weapon, WR_RELOAD);
 513                         }
 514                         else if (self.BUTTON_ATCK)
 515                         {
 516                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 517                                 {
 518                                         W_MineLayer_Attack();
 519                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 520                                 }
 521                         }
 522
 523                         if (self.BUTTON_ATCK2)
 524                         {
 525                                 if(W_MineLayer_PlacedMines(TRUE))
 526                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 527                         }
 528
 529                         return TRUE;
 530                 }
 531                 case WR_INIT:
 532                 {
 533                         precache_model ("models/flash.md3");
 534                         precache_model ("models/mine.md3");
 535                         precache_model ("models/weapons/g_minelayer.md3");
 536                         precache_model ("models/weapons/v_minelayer.md3");
 537                         precache_model ("models/weapons/h_minelayer.iqm");
 538                         precache_sound ("weapons/mine_det.wav");
 539                         precache_sound ("weapons/mine_fire.wav");
 540                         precache_sound ("weapons/mine_stick.wav");
 541                         precache_sound ("weapons/mine_trigger.wav");
 542                         MINELAYER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 543                         return TRUE;
 544                 }
 545                 case WR_CHECKAMMO1:
 546                 {
 547                         // don't switch while placing a mine
 548                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 549                         {
 550                                 ammo_amount = self.WEP_AMMO(MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 551                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 552                                 return ammo_amount;
 553                         }
 554                         return TRUE;
 555                 }
 556                 case WR_CHECKAMMO2:
 557                 {
 558                         if (W_MineLayer_PlacedMines(FALSE))
 559                                 return TRUE;
 560                         else
 561                                 return FALSE;
 562                 }
 563                 case WR_CONFIG:
 564                 {
 565                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 566                         return TRUE;
 567                 }
 568                 case WR_RESETPLAYER:
 569                 {
 570                         self.minelayer_mines = 0;
 571                         return TRUE;
 572                 }
 573                 case WR_RELOAD:
 574                 {
 575                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 576                         return TRUE;
 577                 }
 578                 case WR_SUICIDEMESSAGE:
 579                 {
 580                         return WEAPON_MINELAYER_SUICIDE;
 581                 }
 582                 case WR_KILLMESSAGE:
 583                 {
 584                         return WEAPON_MINELAYER_MURDER;
 585                 }
 586         }
 587         return TRUE;
 588 }
 589 #endif
 590 #ifdef CSQC
 591 float W_MineLayer(float req)
 592 {
 593         switch(req)
 594         {
 595                 case WR_IMPACTEFFECT:
 596                 {
 597                         vector org2;
 598                         org2 = w_org + w_backoff * 12;
 599                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 600                         if(!w_issilent)
 601                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 602
 603                         return TRUE;
 604                 }
 605                 case WR_INIT:
 606                 {
 607                         precache_sound("weapons/mine_exp.wav");
 608                         return TRUE;
 609                 }
 610                 case WR_ZOOMRETICLE:
 611                 {
 612                         // no weapon specific image for this weapon
 613                         return FALSE;
 614                 }
 615         }
 616         return TRUE;
 617 }
 618 #endif
 619 #endif