qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MINE_LAYER,
   4 /* function  */ W_MineLayer,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.75 1 0',
  10 /* modelname */ "minelayer",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminelayer 0.9",
  13 /* refname   */ "minelayer",
  14 /* wepname   */ _("Mine Layer")
  15 );
  16
  17 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  18 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  19         w_cvar(id, sn, NONE, ammo) \
  20         w_cvar(id, sn, NONE, animtime) \
  21         w_cvar(id, sn, NONE, damage) \
  22         w_cvar(id, sn, NONE, damageforcescale) \
  23         w_cvar(id, sn, NONE, detonatedelay) \
  24         w_cvar(id, sn, NONE, edgedamage) \
  25         w_cvar(id, sn, NONE, force) \
  26         w_cvar(id, sn, NONE, health) \
  27         w_cvar(id, sn, NONE, lifetime) \
  28         w_cvar(id, sn, NONE, lifetime_countdown) \
  29         w_cvar(id, sn, NONE, limit) \
  30         w_cvar(id, sn, NONE, protection) \
  31         w_cvar(id, sn, NONE, proximityradius) \
  32         w_cvar(id, sn, NONE, radius) \
  33         w_cvar(id, sn, NONE, refire) \
  34         w_cvar(id, sn, NONE, remote_damage) \
  35         w_cvar(id, sn, NONE, remote_edgedamage) \
  36         w_cvar(id, sn, NONE, remote_force) \
  37         w_cvar(id, sn, NONE, remote_radius) \
  38         w_cvar(id, sn, NONE, speed) \
  39         w_cvar(id, sn, NONE, time) \
  40         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  41         w_prop(id, sn, float,  reloading_time, reload_time) \
  42         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  43         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  44         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  45         w_prop(id, sn, float,  weaponstart, weaponstart) \
  46         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  47
  48 #ifdef SVQC
  49 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  50 void W_MineLayer_Think (void);
  51 .float minelayer_detonate, mine_explodeanyway;
  52 .float mine_time;
  53 .vector mine_orientation;
  54 #endif
  55 #else
  56 #ifdef SVQC
  57 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  58
  59 void W_MineLayer_Stick (entity to)
  60 {
  61         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  62
  63         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  64
  65         entity newmine;
  66         newmine = spawn();
  67         newmine.classname = self.classname;
  68
  69         newmine.bot_dodge = self.bot_dodge;
  70         newmine.bot_dodgerating = self.bot_dodgerating;
  71
  72         newmine.owner = self.owner;
  73         newmine.realowner = self.realowner;
  74         setsize(newmine, '-4 -4 -4', '4 4 4');
  75         setorigin(newmine, self.origin);
  76         setmodel(newmine, "models/mine.md3");
  77         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  78
  79         newmine.mine_orientation = -trace_plane_normal;
  80
  81         newmine.takedamage = self.takedamage;
  82         newmine.damageforcescale = self.damageforcescale;
  83         newmine.health = self.health;
  84         newmine.event_damage = self.event_damage;
  85         newmine.spawnshieldtime = self.spawnshieldtime;
  86         newmine.damagedbycontents = TRUE;
  87
  88         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  89         newmine.projectiledeathtype = self.projectiledeathtype;
  90
  91         newmine.mine_time = self.mine_time;
  92
  93         newmine.touch = func_null;
  94         newmine.think = W_MineLayer_Think;
  95         newmine.nextthink = time;
  96         newmine.cnt = self.cnt;
  97         newmine.flags = self.flags;
  98
  99         remove(self);
 100         self = newmine;
 101
 102         if(to)
 103                 SetMovetypeFollow(self, to);
 104 }
 105
 106 void W_MineLayer_Explode()
 107 {
 108         if(other.takedamage == DAMAGE_AIM)
 109                 if(IS_PLAYER(other))
 110                         if(DIFF_TEAM(self.realowner, other))
 111                                 if(other.deadflag == DEAD_NO)
 112                                         if(IsFlying(other))
 113                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 114
 115         self.event_damage = func_null;
 116         self.takedamage = DAMAGE_NO;
 117
 118         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 119
 120         if (self.realowner.weapon == WEP_MINE_LAYER)
 121         {
 122                 entity oldself;
 123                 oldself = self;
 124                 self = self.realowner;
 125                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 126                 {
 127                         self.cnt = WEP_MINE_LAYER;
 128                         ATTACK_FINISHED(self) = time;
 129                         self.switchweapon = w_getbestweapon(self);
 130                 }
 131                 self = oldself;
 132         }
 133         self.realowner.minelayer_mines -= 1;
 134         remove (self);
 135 }
 136
 137 void W_MineLayer_DoRemoteExplode ()
 138 {
 139         self.event_damage = func_null;
 140         self.takedamage = DAMAGE_NO;
 141
 142         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 143                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 144
 145         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 146
 147         if (self.realowner.weapon == WEP_MINE_LAYER)
 148         {
 149                 entity oldself;
 150                 oldself = self;
 151                 self = self.realowner;
 152                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 153                 {
 154                         self.cnt = WEP_MINE_LAYER;
 155                         ATTACK_FINISHED(self) = time;
 156                         self.switchweapon = w_getbestweapon(self);
 157                 }
 158                 self = oldself;
 159         }
 160         self.realowner.minelayer_mines -= 1;
 161         remove (self);
 162 }
 163
 164 void W_MineLayer_RemoteExplode ()
 165 {
 166         if(self.realowner.deadflag == DEAD_NO)
 167                 if((self.spawnshieldtime >= 0)
 168                         ? (time >= self.spawnshieldtime) // timer
 169                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 170                 )
 171                 {
 172                         W_MineLayer_DoRemoteExplode();
 173                 }
 174 }
 175
 176 void W_MineLayer_ProximityExplode ()
 177 {
 178         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 179         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 180         {
 181                 entity head;
 182                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 183                 while(head)
 184                 {
 185                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 186                                 return;
 187                         head = head.chain;
 188                 }
 189         }
 190
 191         self.mine_time = 0;
 192         W_MineLayer_Explode();
 193 }
 194
 195 float W_MineLayer_Count(entity e)
 196 {
 197         float minecount = 0;
 198         entity mine;
 199         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 200                 minecount += 1;
 201
 202         return minecount;
 203 }
 204
 205 void W_MineLayer_Think (void)
 206 {
 207         entity head;
 208
 209         self.nextthink = time;
 210
 211         if(self.movetype == MOVETYPE_FOLLOW)
 212         {
 213                 if(LostMovetypeFollow(self))
 214                 {
 215                         UnsetMovetypeFollow(self);
 216                         self.movetype = MOVETYPE_NONE;
 217                 }
 218         }
 219
 220         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 221         // TODO: replace this mine_trigger.wav sound with a real countdown
 222         if ((time > self.cnt) && (!self.mine_time))
 223         {
 224                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 225                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 226                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 227                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 228         }
 229
 230         // a player's mines shall explode if he disconnects or dies
 231         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 232         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 233         {
 234                 other = world;
 235                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 236                 W_MineLayer_Explode();
 237                 return;
 238         }
 239
 240         // set the mine for detonation when a foe gets close enough
 241         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 242         while(head)
 243         {
 244                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 245                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 246                 if(!self.mine_time)
 247                 {
 248                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 249                         self.mine_time = time + WEP_CVAR(minelayer, time);
 250                 }
 251                 head = head.chain;
 252         }
 253
 254         // explode if it's time to
 255         if(self.mine_time && time >= self.mine_time)
 256         {
 257                 W_MineLayer_ProximityExplode();
 258                 return;
 259         }
 260
 261         // remote detonation
 262         if (self.realowner.weapon == WEP_MINE_LAYER)
 263         if (self.realowner.deadflag == DEAD_NO)
 264         if (self.minelayer_detonate)
 265                 W_MineLayer_RemoteExplode();
 266 }
 267
 268 void W_MineLayer_Touch (void)
 269 {
 270         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 271                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 272
 273         if(WarpZone_Projectile_Touch())
 274         {
 275                 if(wasfreed(self))
 276                         self.realowner.minelayer_mines -= 1;
 277                 return;
 278         }
 279
 280         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 281         {
 282                 // hit a player
 283                 // don't stick
 284         }
 285         else
 286         {
 287                 W_MineLayer_Stick(other);
 288         }
 289 }
 290
 291 void W_MineLayer_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 292 {
 293         if (self.health <= 0)
 294                 return;
 295
 296         float is_from_enemy = (inflictor.realowner != self.realowner);
 297
 298         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 299                 return; // g_projectiles_damage says to halt
 300
 301         self.health = self.health - damage;
 302         self.angles = vectoangles(self.velocity);
 303
 304         if (self.health <= 0)
 305                 W_PrepareExplosionByDamage(attacker, W_MineLayer_Explode);
 306 }
 307
 308 void W_MineLayer_Attack()
 309 {
 310         entity mine;
 311         entity flash;
 312
 313         // scan how many mines we placed, and return if we reached our limit
 314         if(WEP_CVAR(minelayer, limit))
 315         {
 316                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 317                 {
 318                         // the refire delay keeps this message from being spammed
 319                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 320                         play2(self, "weapons/unavailable.wav");
 321                         return;
 322                 }
 323         }
 324
 325         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 326
 327         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 328         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 329
 330         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 331         mine.owner = mine.realowner = self;
 332         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 333                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 334         else
 335                 mine.spawnshieldtime = -1;
 336         mine.classname = "mine";
 337         mine.bot_dodge = TRUE;
 338         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 339
 340         mine.takedamage = DAMAGE_YES;
 341         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 342         mine.health = WEP_CVAR(minelayer, health);
 343         mine.event_damage = W_MineLayer_Damage;
 344         mine.damagedbycontents = TRUE;
 345
 346         mine.movetype = MOVETYPE_TOSS;
 347         PROJECTILE_MAKETRIGGER(mine);
 348         mine.projectiledeathtype = WEP_MINE_LAYER;
 349         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 350
 351         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 352         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 353         mine.angles = vectoangles (mine.velocity);
 354
 355         mine.touch = W_MineLayer_Touch;
 356         mine.think = W_MineLayer_Think;
 357         mine.nextthink = time;
 358         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 359         mine.flags = FL_PROJECTILE;
 360         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 361
 362         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 363
 364         // muzzle flash for 1st person view
 365         flash = spawn ();
 366         setmodel (flash, "models/flash.md3"); // precision set below
 367         SUB_SetFade (flash, time, 0.1);
 368         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 369         W_AttachToShotorg(flash, '5 0 0');
 370
 371         // common properties
 372
 373         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 374
 375         self.minelayer_mines = W_MineLayer_Count(self);
 376 }
 377
 378 float W_MineLayer_PlacedMines(float detonate)
 379 {
 380         entity mine;
 381         float minfound = 0;
 382
 383         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 384         {
 385                 if(detonate)
 386                 {
 387                         if(!mine.minelayer_detonate)
 388                         {
 389                                 mine.minelayer_detonate = TRUE;
 390                                 minfound = 1;
 391                         }
 392                 }
 393                 else
 394                         minfound = 1;
 395         }
 396         return minfound;
 397 }
 398
 399 float W_MineLayer(float req)
 400 {
 401         entity mine;
 402         float ammo_amount;
 403         switch(req)
 404         {
 405                 case WR_AIM:
 406                 {
 407                         // aim and decide to fire if appropriate
 408                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 409                                 self.BUTTON_ATCK = FALSE;
 410                         else
 411                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 412                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 413                         {
 414                                 // decide whether to detonate mines
 415                                 entity targetlist, targ;
 416                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 417                                 float selfdamage, teamdamage, enemydamage;
 418                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 419                                 coredamage = WEP_CVAR(minelayer, damage);
 420                                 edgeradius = WEP_CVAR(minelayer, radius);
 421                                 recipricoledgeradius = 1 / edgeradius;
 422                                 selfdamage = 0;
 423                                 teamdamage = 0;
 424                                 enemydamage = 0;
 425                                 targetlist = findchainfloat(bot_attack, TRUE);
 426                                 mine = find(world, classname, "mine");
 427                                 while (mine)
 428                                 {
 429                                         if (mine.realowner != self)
 430                                         {
 431                                                 mine = find(mine, classname, "mine");
 432                                                 continue;
 433                                         }
 434                                         targ = targetlist;
 435                                         while (targ)
 436                                         {
 437                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 438                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 439                                                 // count potential damage according to type of target
 440                                                 if (targ == self)
 441                                                         selfdamage = selfdamage + d;
 442                                                 else if (targ.team == self.team && teamplay)
 443                                                         teamdamage = teamdamage + d;
 444                                                 else if (bot_shouldattack(targ))
 445                                                         enemydamage = enemydamage + d;
 446                                                 targ = targ.chain;
 447                                         }
 448                                         mine = find(mine, classname, "mine");
 449                                 }
 450                                 float desirabledamage;
 451                                 desirabledamage = enemydamage;
 452                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 453                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 454                                 if (teamplay && self.team)
 455                                         desirabledamage = desirabledamage - teamdamage;
 456
 457                                 mine = find(world, classname, "mine");
 458                                 while (mine)
 459                                 {
 460                                         if (mine.realowner != self)
 461                                         {
 462                                                 mine = find(mine, classname, "mine");
 463                                                 continue;
 464                                         }
 465                                         makevectors(mine.v_angle);
 466                                         targ = targetlist;
 467                                         if (skill > 9) // normal players only do this for the target they are tracking
 468                                         {
 469                                                 targ = targetlist;
 470                                                 while (targ)
 471                                                 {
 472                                                         if (
 473                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 474                                                                 && desirabledamage > 0.1*coredamage
 475                                                         )self.BUTTON_ATCK2 = TRUE;
 476                                                         targ = targ.chain;
 477                                                 }
 478                                         }else{
 479                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 480                                                 //As the distance gets larger, a correct detonation gets near imposible
 481                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 482                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 483                                                         if(IS_PLAYER(self.enemy))
 484                                                                 if(desirabledamage >= 0.1*coredamage)
 485                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 486                                                                                 self.BUTTON_ATCK2 = TRUE;
 487                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 488                                         }
 489
 490                                         mine = find(mine, classname, "mine");
 491                                 }
 492                                 // if we would be doing at X percent of the core damage, detonate it
 493                                 // but don't fire a new shot at the same time!
 494                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 495                                         self.BUTTON_ATCK2 = TRUE;
 496                                 if ((skill > 6.5) && (selfdamage > self.health))
 497                                         self.BUTTON_ATCK2 = FALSE;
 498                                 //if(self.BUTTON_ATCK2 == TRUE)
 499                                 //      dprint(ftos(desirabledamage),"\n");
 500                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 501                         }
 502
 503                         return TRUE;
 504                 }
 505                 case WR_THINK:
 506                 {
 507                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 508                         {
 509                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 510                                 if(!(W_MineLayer_PlacedMines(FALSE) && self.WEP_AMMO(MINE_LAYER) < WEP_CVAR(minelayer, ammo)))
 511                                         WEP_ACTION(self.weapon, WR_RELOAD);
 512                         }
 513                         else if (self.BUTTON_ATCK)
 514                         {
 515                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 516                                 {
 517                                         W_MineLayer_Attack();
 518                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 519                                 }
 520                         }
 521
 522                         if (self.BUTTON_ATCK2)
 523                         {
 524                                 if(W_MineLayer_PlacedMines(TRUE))
 525                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 526                         }
 527
 528                         return TRUE;
 529                 }
 530                 case WR_INIT:
 531                 {
 532                         precache_model ("models/flash.md3");
 533                         precache_model ("models/mine.md3");
 534                         precache_model ("models/weapons/g_minelayer.md3");
 535                         precache_model ("models/weapons/v_minelayer.md3");
 536                         precache_model ("models/weapons/h_minelayer.iqm");
 537                         precache_sound ("weapons/mine_det.wav");
 538                         precache_sound ("weapons/mine_fire.wav");
 539                         precache_sound ("weapons/mine_stick.wav");
 540                         precache_sound ("weapons/mine_trigger.wav");
 541                         MINELAYER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 542                         return TRUE;
 543                 }
 544                 case WR_CHECKAMMO1:
 545                 {
 546                         // don't switch while placing a mine
 547                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 548                         {
 549                                 ammo_amount = self.WEP_AMMO(MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 550                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 551                                 return ammo_amount;
 552                         }
 553                         return TRUE;
 554                 }
 555                 case WR_CHECKAMMO2:
 556                 {
 557                         if (W_MineLayer_PlacedMines(FALSE))
 558                                 return TRUE;
 559                         else
 560                                 return FALSE;
 561                 }
 562                 case WR_CONFIG:
 563                 {
 564                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 565                         return TRUE;
 566                 }
 567                 case WR_RESETPLAYER:
 568                 {
 569                         self.minelayer_mines = 0;
 570                         return TRUE;
 571                 }
 572                 case WR_RELOAD:
 573                 {
 574                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 575                         return TRUE;
 576                 }
 577                 case WR_SUICIDEMESSAGE:
 578                 {
 579                         return WEAPON_MINELAYER_SUICIDE;
 580                 }
 581                 case WR_KILLMESSAGE:
 582                 {
 583                         return WEAPON_MINELAYER_MURDER;
 584                 }
 585         }
 586         return TRUE;
 587 }
 588 #endif
 589 #ifdef CSQC
 590 float W_MineLayer(float req)
 591 {
 592         switch(req)
 593         {
 594                 case WR_IMPACTEFFECT:
 595                 {
 596                         vector org2;
 597                         org2 = w_org + w_backoff * 12;
 598                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 599                         if(!w_issilent)
 600                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 601
 602                         return TRUE;
 603                 }
 604                 case WR_INIT:
 605                 {
 606                         precache_sound("weapons/mine_exp.wav");
 607                         return TRUE;
 608                 }
 609                 case WR_ZOOMRETICLE:
 610                 {
 611                         // no weapon specific image for this weapon
 612                         return FALSE;
 613                 }
 614         }
 615         return TRUE;
 616 }
 617 #endif
 618 #endif