qcsrc/common/weapons/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MINE_LAYER,
   4 /* function  */ W_MineLayer,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.75 1 0',
  10 /* model     */ "minelayer",
  11 /* crosshair */ "gfx/crosshairminelayer 0.9",
  12 /* netname   */ "minelayer",
  13 /* fullname  */ _("Mine Layer")
  14 );
  15
  16 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  17 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  18         w_cvar(id, sn, NONE, ammo) \
  19         w_cvar(id, sn, NONE, animtime) \
  20         w_cvar(id, sn, NONE, damage) \
  21         w_cvar(id, sn, NONE, damageforcescale) \
  22         w_cvar(id, sn, NONE, detonatedelay) \
  23         w_cvar(id, sn, NONE, edgedamage) \
  24         w_cvar(id, sn, NONE, force) \
  25         w_cvar(id, sn, NONE, health) \
  26         w_cvar(id, sn, NONE, lifetime) \
  27         w_cvar(id, sn, NONE, lifetime_countdown) \
  28         w_cvar(id, sn, NONE, limit) \
  29         w_cvar(id, sn, NONE, protection) \
  30         w_cvar(id, sn, NONE, proximityradius) \
  31         w_cvar(id, sn, NONE, radius) \
  32         w_cvar(id, sn, NONE, refire) \
  33         w_cvar(id, sn, NONE, remote_damage) \
  34         w_cvar(id, sn, NONE, remote_edgedamage) \
  35         w_cvar(id, sn, NONE, remote_force) \
  36         w_cvar(id, sn, NONE, remote_radius) \
  37         w_cvar(id, sn, NONE, speed) \
  38         w_cvar(id, sn, NONE, time) \
  39         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  40         w_prop(id, sn, float,  reloading_time, reload_time) \
  41         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  42         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  43         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  44         w_prop(id, sn, float,  weaponstart, weaponstart) \
  45         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  46
  47 #ifdef SVQC
  48 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  49 void W_MineLayer_Think (void);
  50 .float minelayer_detonate, mine_explodeanyway;
  51 .float mine_time;
  52 .vector mine_orientation;
  53 #endif
  54 #else
  55 #ifdef SVQC
  56 void spawnfunc_weapon_minelayer() { weapon_defaultspawnfunc(WEP_MINE_LAYER); }
  57
  58 void W_MineLayer_Stick (entity to)
  59 {
  60         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  61
  62         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  63
  64         entity newmine;
  65         newmine = spawn();
  66         newmine.classname = self.classname;
  67
  68         newmine.bot_dodge = self.bot_dodge;
  69         newmine.bot_dodgerating = self.bot_dodgerating;
  70
  71         newmine.owner = self.owner;
  72         newmine.realowner = self.realowner;
  73         setsize(newmine, '-4 -4 -4', '4 4 4');
  74         setorigin(newmine, self.origin);
  75         setmodel(newmine, "models/mine.md3");
  76         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  77
  78         newmine.mine_orientation = -trace_plane_normal;
  79
  80         newmine.takedamage = self.takedamage;
  81         newmine.damageforcescale = self.damageforcescale;
  82         newmine.health = self.health;
  83         newmine.event_damage = self.event_damage;
  84         newmine.spawnshieldtime = self.spawnshieldtime;
  85         newmine.damagedbycontents = TRUE;
  86
  87         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  88         newmine.projectiledeathtype = self.projectiledeathtype;
  89
  90         newmine.mine_time = self.mine_time;
  91
  92         newmine.touch = func_null;
  93         newmine.think = W_MineLayer_Think;
  94         newmine.nextthink = time;
  95         newmine.cnt = self.cnt;
  96         newmine.flags = self.flags;
  97
  98         remove(self);
  99         self = newmine;
 100
 101         if(to)
 102                 SetMovetypeFollow(self, to);
 103 }
 104
 105 void W_MineLayer_Explode()
 106 {
 107         if(other.takedamage == DAMAGE_AIM)
 108                 if(IS_PLAYER(other))
 109                         if(DIFF_TEAM(self.realowner, other))
 110                                 if(other.deadflag == DEAD_NO)
 111                                         if(IsFlying(other))
 112                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 113
 114         self.event_damage = func_null;
 115         self.takedamage = DAMAGE_NO;
 116
 117         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 118
 119         if (self.realowner.weapon == WEP_MINE_LAYER)
 120         {
 121                 entity oldself;
 122                 oldself = self;
 123                 self = self.realowner;
 124                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 125                 {
 126                         self.cnt = WEP_MINE_LAYER;
 127                         ATTACK_FINISHED(self) = time;
 128                         self.switchweapon = w_getbestweapon(self);
 129                 }
 130                 self = oldself;
 131         }
 132         self.realowner.minelayer_mines -= 1;
 133         remove (self);
 134 }
 135
 136 void W_MineLayer_DoRemoteExplode ()
 137 {
 138         self.event_damage = func_null;
 139         self.takedamage = DAMAGE_NO;
 140
 141         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 142                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 143
 144         RadiusDamage (self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 145
 146         if (self.realowner.weapon == WEP_MINE_LAYER)
 147         {
 148                 entity oldself;
 149                 oldself = self;
 150                 self = self.realowner;
 151                 if (!WEP_ACTION(WEP_MINE_LAYER, WR_CHECKAMMO1))
 152                 {
 153                         self.cnt = WEP_MINE_LAYER;
 154                         ATTACK_FINISHED(self) = time;
 155                         self.switchweapon = w_getbestweapon(self);
 156                 }
 157                 self = oldself;
 158         }
 159         self.realowner.minelayer_mines -= 1;
 160         remove (self);
 161 }
 162
 163 void W_MineLayer_RemoteExplode ()
 164 {
 165         if(self.realowner.deadflag == DEAD_NO)
 166                 if((self.spawnshieldtime >= 0)
 167                         ? (time >= self.spawnshieldtime) // timer
 168                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 169                 )
 170                 {
 171                         W_MineLayer_DoRemoteExplode();
 172                 }
 173 }
 174
 175 void W_MineLayer_ProximityExplode ()
 176 {
 177         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 178         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 179         {
 180                 entity head;
 181                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 182                 while(head)
 183                 {
 184                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 185                                 return;
 186                         head = head.chain;
 187                 }
 188         }
 189
 190         self.mine_time = 0;
 191         W_MineLayer_Explode();
 192 }
 193
 194 float W_MineLayer_Count(entity e)
 195 {
 196         float minecount = 0;
 197         entity mine;
 198         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 199                 minecount += 1;
 200
 201         return minecount;
 202 }
 203
 204 void W_MineLayer_Think (void)
 205 {
 206         entity head;
 207
 208         self.nextthink = time;
 209
 210         if(self.movetype == MOVETYPE_FOLLOW)
 211         {
 212                 if(LostMovetypeFollow(self))
 213                 {
 214                         UnsetMovetypeFollow(self);
 215                         self.movetype = MOVETYPE_NONE;
 216                 }
 217         }
 218
 219         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 220         // TODO: replace this mine_trigger.wav sound with a real countdown
 221         if ((time > self.cnt) && (!self.mine_time))
 222         {
 223                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 224                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 225                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 226                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 227         }
 228
 229         // a player's mines shall explode if he disconnects or dies
 230         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 231         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO)
 232         {
 233                 other = world;
 234                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 235                 W_MineLayer_Explode();
 236                 return;
 237         }
 238
 239         // set the mine for detonation when a foe gets close enough
 240         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 241         while(head)
 242         {
 243                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO)
 244                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 245                 if(!self.mine_time)
 246                 {
 247                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 248                         self.mine_time = time + WEP_CVAR(minelayer, time);
 249                 }
 250                 head = head.chain;
 251         }
 252
 253         // explode if it's time to
 254         if(self.mine_time && time >= self.mine_time)
 255         {
 256                 W_MineLayer_ProximityExplode();
 257                 return;
 258         }
 259
 260         // remote detonation
 261         if (self.realowner.weapon == WEP_MINE_LAYER)
 262         if (self.realowner.deadflag == DEAD_NO)
 263         if (self.minelayer_detonate)
 264                 W_MineLayer_RemoteExplode();
 265 }
 266
 267 void W_MineLayer_Touch (void)
 268 {
 269         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 270                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 271
 272         if(WarpZone_Projectile_Touch())
 273         {
 274                 if(wasfreed(self))
 275                         self.realowner.minelayer_mines -= 1;
 276                 return;
 277         }
 278
 279         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 280         {
 281                 // hit a player
 282                 // don't stick
 283         }
 284         else
 285         {
 286                 W_MineLayer_Stick(other);
 287         }
 288 }
 289
 290 void W_MineLayer_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 291 {
 292         if (self.health <= 0)
 293                 return;
 294
 295         float is_from_enemy = (inflictor.realowner != self.realowner);
 296
 297         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 298                 return; // g_projectiles_damage says to halt
 299
 300         self.health = self.health - damage;
 301         self.angles = vectoangles(self.velocity);
 302
 303         if (self.health <= 0)
 304                 W_PrepareExplosionByDamage(attacker, W_MineLayer_Explode);
 305 }
 306
 307 void W_MineLayer_Attack()
 308 {
 309         entity mine;
 310         entity flash;
 311
 312         // scan how many mines we placed, and return if we reached our limit
 313         if(WEP_CVAR(minelayer, limit))
 314         {
 315                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 316                 {
 317                         // the refire delay keeps this message from being spammed
 318                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(WEP_CVAR(minelayer, limit)), " ^7mines at a time\n") );
 319                         play2(self, "weapons/unavailable.wav");
 320                         return;
 321                 }
 322         }
 323
 324         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 325
 326         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 327         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 328
 329         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 330         mine.owner = mine.realowner = self;
 331         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 332                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 333         else
 334                 mine.spawnshieldtime = -1;
 335         mine.classname = "mine";
 336         mine.bot_dodge = TRUE;
 337         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 338
 339         mine.takedamage = DAMAGE_YES;
 340         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 341         mine.health = WEP_CVAR(minelayer, health);
 342         mine.event_damage = W_MineLayer_Damage;
 343         mine.damagedbycontents = TRUE;
 344
 345         mine.movetype = MOVETYPE_TOSS;
 346         PROJECTILE_MAKETRIGGER(mine);
 347         mine.projectiledeathtype = WEP_MINE_LAYER;
 348         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 349
 350         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 351         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 352         mine.angles = vectoangles (mine.velocity);
 353
 354         mine.touch = W_MineLayer_Touch;
 355         mine.think = W_MineLayer_Think;
 356         mine.nextthink = time;
 357         mine.cnt = time + (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 358         mine.flags = FL_PROJECTILE;
 359         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 360
 361         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 362
 363         // muzzle flash for 1st person view
 364         flash = spawn ();
 365         setmodel (flash, "models/flash.md3"); // precision set below
 366         SUB_SetFade (flash, time, 0.1);
 367         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 368         W_AttachToShotorg(flash, '5 0 0');
 369
 370         // common properties
 371
 372         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 373
 374         self.minelayer_mines = W_MineLayer_Count(self);
 375 }
 376
 377 float W_MineLayer_PlacedMines(float detonate)
 378 {
 379         entity mine;
 380         float minfound = 0;
 381
 382         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 383         {
 384                 if(detonate)
 385                 {
 386                         if(!mine.minelayer_detonate)
 387                         {
 388                                 mine.minelayer_detonate = TRUE;
 389                                 minfound = 1;
 390                         }
 391                 }
 392                 else
 393                         minfound = 1;
 394         }
 395         return minfound;
 396 }
 397
 398 float W_MineLayer(float req)
 399 {
 400         entity mine;
 401         float ammo_amount;
 402         switch(req)
 403         {
 404                 case WR_AIM:
 405                 {
 406                         // aim and decide to fire if appropriate
 407                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 408                                 self.BUTTON_ATCK = FALSE;
 409                         else
 410                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), FALSE);
 411                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 412                         {
 413                                 // decide whether to detonate mines
 414                                 entity targetlist, targ;
 415                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 416                                 float selfdamage, teamdamage, enemydamage;
 417                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 418                                 coredamage = WEP_CVAR(minelayer, damage);
 419                                 edgeradius = WEP_CVAR(minelayer, radius);
 420                                 recipricoledgeradius = 1 / edgeradius;
 421                                 selfdamage = 0;
 422                                 teamdamage = 0;
 423                                 enemydamage = 0;
 424                                 targetlist = findchainfloat(bot_attack, TRUE);
 425                                 mine = find(world, classname, "mine");
 426                                 while (mine)
 427                                 {
 428                                         if (mine.realowner != self)
 429                                         {
 430                                                 mine = find(mine, classname, "mine");
 431                                                 continue;
 432                                         }
 433                                         targ = targetlist;
 434                                         while (targ)
 435                                         {
 436                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 437                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 438                                                 // count potential damage according to type of target
 439                                                 if (targ == self)
 440                                                         selfdamage = selfdamage + d;
 441                                                 else if (targ.team == self.team && teamplay)
 442                                                         teamdamage = teamdamage + d;
 443                                                 else if (bot_shouldattack(targ))
 444                                                         enemydamage = enemydamage + d;
 445                                                 targ = targ.chain;
 446                                         }
 447                                         mine = find(mine, classname, "mine");
 448                                 }
 449                                 float desirabledamage;
 450                                 desirabledamage = enemydamage;
 451                                 if (time > self.invincible_finished && time > self.spawnshieldtime)
 452                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 453                                 if (teamplay && self.team)
 454                                         desirabledamage = desirabledamage - teamdamage;
 455
 456                                 mine = find(world, classname, "mine");
 457                                 while (mine)
 458                                 {
 459                                         if (mine.realowner != self)
 460                                         {
 461                                                 mine = find(mine, classname, "mine");
 462                                                 continue;
 463                                         }
 464                                         makevectors(mine.v_angle);
 465                                         targ = targetlist;
 466                                         if (skill > 9) // normal players only do this for the target they are tracking
 467                                         {
 468                                                 targ = targetlist;
 469                                                 while (targ)
 470                                                 {
 471                                                         if (
 472                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 473                                                                 && desirabledamage > 0.1*coredamage
 474                                                         )self.BUTTON_ATCK2 = TRUE;
 475                                                         targ = targ.chain;
 476                                                 }
 477                                         }else{
 478                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 479                                                 //As the distance gets larger, a correct detonation gets near imposible
 480                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 481                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 482                                                         if(IS_PLAYER(self.enemy))
 483                                                                 if(desirabledamage >= 0.1*coredamage)
 484                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 485                                                                                 self.BUTTON_ATCK2 = TRUE;
 486                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 487                                         }
 488
 489                                         mine = find(mine, classname, "mine");
 490                                 }
 491                                 // if we would be doing at X percent of the core damage, detonate it
 492                                 // but don't fire a new shot at the same time!
 493                                 if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 494                                         self.BUTTON_ATCK2 = TRUE;
 495                                 if ((skill > 6.5) && (selfdamage > self.health))
 496                                         self.BUTTON_ATCK2 = FALSE;
 497                                 //if(self.BUTTON_ATCK2 == TRUE)
 498                                 //      dprint(ftos(desirabledamage),"\n");
 499                                 if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 500                         }
 501
 502                         return TRUE;
 503                 }
 504                 case WR_THINK:
 505                 {
 506                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 507                         {
 508                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 509                                 if(!(W_MineLayer_PlacedMines(FALSE) && self.WEP_AMMO(MINE_LAYER) < WEP_CVAR(minelayer, ammo)))
 510                                         WEP_ACTION(self.weapon, WR_RELOAD);
 511                         }
 512                         else if (self.BUTTON_ATCK)
 513                         {
 514                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 515                                 {
 516                                         W_MineLayer_Attack();
 517                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 518                                 }
 519                         }
 520
 521                         if (self.BUTTON_ATCK2)
 522                         {
 523                                 if(W_MineLayer_PlacedMines(TRUE))
 524                                         sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 525                         }
 526
 527                         return TRUE;
 528                 }
 529                 case WR_INIT:
 530                 {
 531                         precache_model ("models/flash.md3");
 532                         precache_model ("models/mine.md3");
 533                         precache_model ("models/weapons/g_minelayer.md3");
 534                         precache_model ("models/weapons/v_minelayer.md3");
 535                         precache_model ("models/weapons/h_minelayer.iqm");
 536                         precache_sound ("weapons/mine_det.wav");
 537                         precache_sound ("weapons/mine_fire.wav");
 538                         precache_sound ("weapons/mine_stick.wav");
 539                         precache_sound ("weapons/mine_trigger.wav");
 540                         MINELAYER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 541                         return TRUE;
 542                 }
 543                 case WR_CHECKAMMO1:
 544                 {
 545                         // don't switch while placing a mine
 546                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 547                         {
 548                                 ammo_amount = self.WEP_AMMO(MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 549                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= WEP_CVAR(minelayer, ammo);
 550                                 return ammo_amount;
 551                         }
 552                         return TRUE;
 553                 }
 554                 case WR_CHECKAMMO2:
 555                 {
 556                         if (W_MineLayer_PlacedMines(FALSE))
 557                                 return TRUE;
 558                         else
 559                                 return FALSE;
 560                 }
 561                 case WR_CONFIG:
 562                 {
 563                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 564                         return TRUE;
 565                 }
 566                 case WR_RESETPLAYER:
 567                 {
 568                         self.minelayer_mines = 0;
 569                         return TRUE;
 570                 }
 571                 case WR_RELOAD:
 572                 {
 573                         W_Reload(WEP_CVAR(minelayer, ammo), "weapons/reload.wav");
 574                         return TRUE;
 575                 }
 576                 case WR_SUICIDEMESSAGE:
 577                 {
 578                         return WEAPON_MINELAYER_SUICIDE;
 579                 }
 580                 case WR_KILLMESSAGE:
 581                 {
 582                         return WEAPON_MINELAYER_MURDER;
 583                 }
 584         }
 585         return TRUE;
 586 }
 587 #endif
 588 #ifdef CSQC
 589 float W_MineLayer(float req)
 590 {
 591         switch(req)
 592         {
 593                 case WR_IMPACTEFFECT:
 594                 {
 595                         vector org2;
 596                         org2 = w_org + w_backoff * 12;
 597                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 598                         if(!w_issilent)
 599                                 sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 600
 601                         return TRUE;
 602                 }
 603                 case WR_INIT:
 604                 {
 605                         precache_sound("weapons/mine_exp.wav");
 606                         return TRUE;
 607                 }
 608                 case WR_ZOOMRETICLE:
 609                 {
 610                         // no weapon specific image for this weapon
 611                         return FALSE;
 612                 }
 613         }
 614         return TRUE;
 615 }
 616 #endif
 617 #endif