qcsrc/common/weapons/w_mortar.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MORTAR,
   4 /* function  */ W_Mortar,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '1 0 0',
  10 /* modelname */ "gl",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairgrenadelauncher 0.7",
  13 /* wepimg    */ "weapongrenadelauncher",
  14 /* refname   */ "mortar",
  15 /* wepname   */ _("Mortar")
  16 );
  17
  18 #define MORTAR_SETTINGS(w_cvar,w_prop) MORTAR_SETTINGS_LIST(w_cvar, w_prop, MORTAR, mortar)
  19 #define MORTAR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, ammo) \
  21         w_cvar(id, sn, BOTH, animtime) \
  22         w_cvar(id, sn, NONE, bouncefactor) \
  23         w_cvar(id, sn, NONE, bouncestop) \
  24         w_cvar(id, sn, BOTH, damage) \
  25         w_cvar(id, sn, BOTH, damageforcescale) \
  26         w_cvar(id, sn, BOTH, edgedamage) \
  27         w_cvar(id, sn, BOTH, force) \
  28         w_cvar(id, sn, BOTH, health) \
  29         w_cvar(id, sn, BOTH, lifetime) \
  30         w_cvar(id, sn, SEC,  lifetime_bounce) \
  31         w_cvar(id, sn, BOTH, lifetime_stick) \
  32         w_cvar(id, sn, BOTH, radius) \
  33         w_cvar(id, sn, BOTH, refire) \
  34         w_cvar(id, sn, SEC,  remote_detonateprimary) \
  35         w_cvar(id, sn, PRI,  remote_minbouncecnt) \
  36         w_cvar(id, sn, BOTH, speed) \
  37         w_cvar(id, sn, BOTH, speed_up) \
  38         w_cvar(id, sn, BOTH, speed_z) \
  39         w_cvar(id, sn, BOTH, spread) \
  40         w_cvar(id, sn, BOTH, type) \
  41         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  42         w_prop(id, sn, float,  reloading_time, reload_time) \
  43         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  44         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  45         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  46         w_prop(id, sn, float,  weaponstart, weaponstart) \
  47         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  48         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  49
  50 #ifdef SVQC
  51 MORTAR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  52 .float gl_detonate_later;
  53 .float gl_bouncecnt;
  54 #endif
  55 #endif
  56 #ifdef IMPLEMENTATION
  57 #ifdef SVQC
  58
  59 void spawnfunc_weapon_mortar(void) { weapon_defaultspawnfunc(WEP_MORTAR.m_id); }
  60 void spawnfunc_weapon_grenadelauncher(void) { spawnfunc_weapon_mortar(); }
  61
  62 void W_Mortar_Grenade_Explode(void)
  63 {
  64         if(other.takedamage == DAMAGE_AIM)
  65                 if(IS_PLAYER(other))
  66                         if(DIFF_TEAM(self.realowner, other))
  67                                 if(other.deadflag == DEAD_NO)
  68                                         if(IsFlying(other))
  69                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  70
  71         self.event_damage = func_null;
  72         self.takedamage = DAMAGE_NO;
  73
  74         if(self.movetype == MOVETYPE_NONE)
  75                 self.velocity = self.oldvelocity;
  76
  77         RadiusDamage(self, self.realowner, WEP_CVAR_PRI(mortar, damage), WEP_CVAR_PRI(mortar, edgedamage), WEP_CVAR_PRI(mortar, radius), world, world, WEP_CVAR_PRI(mortar, force), self.projectiledeathtype, other);
  78
  79         remove(self);
  80 }
  81
  82 void W_Mortar_Grenade_Explode2(void)
  83 {
  84         if(other.takedamage == DAMAGE_AIM)
  85                 if(IS_PLAYER(other))
  86                         if(DIFF_TEAM(self.realowner, other))
  87                                 if(other.deadflag == DEAD_NO)
  88                                         if(IsFlying(other))
  89                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  90
  91         self.event_damage = func_null;
  92         self.takedamage = DAMAGE_NO;
  93
  94         if(self.movetype == MOVETYPE_NONE)
  95                 self.velocity = self.oldvelocity;
  96
  97         RadiusDamage(self, self.realowner, WEP_CVAR_SEC(mortar, damage), WEP_CVAR_SEC(mortar, edgedamage), WEP_CVAR_SEC(mortar, radius), world, world, WEP_CVAR_SEC(mortar, force), self.projectiledeathtype, other);
  98
  99         remove(self);
 100 }
 101
 102
 103 void W_Mortar_Grenade_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 104 {
 105         if(self.health <= 0)
 106                 return;
 107
 108         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 109                 return; // g_projectiles_damage says to halt
 110
 111         self.health = self.health - damage;
 112
 113         if(self.health <= 0)
 114                 W_PrepareExplosionByDamage(attacker, self.use);
 115 }
 116
 117 void W_Mortar_Grenade_Think1(void)
 118 {
 119         self.nextthink = time;
 120         if(time > self.cnt)
 121         {
 122                 other = world;
 123                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 124                 W_Mortar_Grenade_Explode();
 125                 return;
 126         }
 127         if(self.gl_detonate_later && self.gl_bouncecnt >= WEP_CVAR_PRI(mortar, remote_minbouncecnt))
 128                 W_Mortar_Grenade_Explode();
 129 }
 130
 131 void W_Mortar_Grenade_Touch1(void)
 132 {
 133         PROJECTILE_TOUCH;
 134         if(other.takedamage == DAMAGE_AIM || WEP_CVAR_PRI(mortar, type) == 0) // always explode when hitting a player, or if normal mortar projectile
 135         {
 136                 self.use();
 137         }
 138         else if(WEP_CVAR_PRI(mortar, type) == 1) // bounce
 139         {
 140                 float r;
 141                 r = random() * 6;
 142                 if(r < 1)
 143                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 144                 else if(r < 2)
 145                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 146                 else if(r < 3)
 147                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 148                 else if(r < 4)
 149                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 150                 else if(r < 5)
 151                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 152                 else
 153                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 154                 Send_Effect("hagar_bounce", self.origin, self.velocity, 1);
 155                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 156                 self.gl_bouncecnt += 1;
 157         }
 158         else if(WEP_CVAR_PRI(mortar, type) == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 159         {
 160                 spamsound(self, CH_SHOTS, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 161
 162                 // let it stick whereever it is
 163                 self.oldvelocity = self.velocity;
 164                 self.velocity = '0 0 0';
 165                 self.movetype = MOVETYPE_NONE; // also disables gravity
 166                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 167                 UpdateCSQCProjectile(self);
 168
 169                 // do not respond to any more touches
 170                 self.solid = SOLID_NOT;
 171
 172                 self.nextthink = min(self.nextthink, time + WEP_CVAR_PRI(mortar, lifetime_stick));
 173         }
 174 }
 175
 176 void W_Mortar_Grenade_Touch2(void)
 177 {
 178         PROJECTILE_TOUCH;
 179         if(other.takedamage == DAMAGE_AIM || WEP_CVAR_SEC(mortar, type) == 0) // always explode when hitting a player, or if normal mortar projectile
 180         {
 181                 self.use();
 182         }
 183         else if(WEP_CVAR_SEC(mortar, type) == 1) // bounce
 184         {
 185                 float r;
 186                 r = random() * 6;
 187                 if(r < 1)
 188                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 189                 else if(r < 2)
 190                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 191                 else if(r < 3)
 192                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 193                 else if(r < 4)
 194                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 195                 else if(r < 5)
 196                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 197                 else
 198                         spamsound(self, CH_SHOTS, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 199                 Send_Effect("hagar_bounce", self.origin, self.velocity, 1);
 200                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 201                 self.gl_bouncecnt += 1;
 202
 203                 if(WEP_CVAR_SEC(mortar, lifetime_bounce) && self.gl_bouncecnt == 1)
 204                         self.nextthink = time + WEP_CVAR_SEC(mortar, lifetime_bounce);
 205
 206         }
 207         else if(WEP_CVAR_SEC(mortar, type) == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 208         {
 209                 spamsound(self, CH_SHOTS, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 210
 211                 // let it stick whereever it is
 212                 self.oldvelocity = self.velocity;
 213                 self.velocity = '0 0 0';
 214                 self.movetype = MOVETYPE_NONE; // also disables gravity
 215                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 216                 UpdateCSQCProjectile(self);
 217
 218                 // do not respond to any more touches
 219                 self.solid = SOLID_NOT;
 220
 221                 self.nextthink = min(self.nextthink, time + WEP_CVAR_SEC(mortar, lifetime_stick));
 222         }
 223 }
 224
 225 void W_Mortar_Attack(void)
 226 {
 227         entity gren;
 228
 229         W_DecreaseAmmo(WEP_CVAR_PRI(mortar, ammo));
 230
 231         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, WEP_CVAR_PRI(mortar, damage));
 232         w_shotdir = v_forward; // no TrueAim for grenades please
 233
 234         Send_Effect("grenadelauncher_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 235
 236         gren = spawn();
 237         gren.owner = gren.realowner = self;
 238         gren.classname = "grenade";
 239         gren.bot_dodge = true;
 240         gren.bot_dodgerating = WEP_CVAR_PRI(mortar, damage);
 241         gren.movetype = MOVETYPE_BOUNCE;
 242         gren.bouncefactor = WEP_CVAR(mortar, bouncefactor);
 243         gren.bouncestop = WEP_CVAR(mortar, bouncestop);
 244         PROJECTILE_MAKETRIGGER(gren);
 245         gren.projectiledeathtype = WEP_MORTAR.m_id;
 246         setorigin(gren, w_shotorg);
 247         setsize(gren, '-3 -3 -3', '3 3 3');
 248
 249         gren.cnt = time + WEP_CVAR_PRI(mortar, lifetime);
 250         gren.nextthink = time;
 251         gren.think = W_Mortar_Grenade_Think1;
 252         gren.use = W_Mortar_Grenade_Explode;
 253         gren.touch = W_Mortar_Grenade_Touch1;
 254
 255         gren.takedamage = DAMAGE_YES;
 256         gren.health = WEP_CVAR_PRI(mortar, health);
 257         gren.damageforcescale = WEP_CVAR_PRI(mortar, damageforcescale);
 258         gren.event_damage = W_Mortar_Grenade_Damage;
 259         gren.damagedbycontents = true;
 260         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 261         W_SetupProjVelocity_UP_PRI(gren, mortar);
 262
 263         gren.angles = vectoangles(gren.velocity);
 264         gren.flags = FL_PROJECTILE;
 265
 266         if(WEP_CVAR_PRI(mortar, type) == 0 || WEP_CVAR_PRI(mortar, type) == 2)
 267                 CSQCProjectile(gren, true, PROJECTILE_GRENADE, true);
 268         else
 269                 CSQCProjectile(gren, true, PROJECTILE_GRENADE_BOUNCING, true);
 270
 271         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 272 }
 273
 274 void W_Mortar_Attack2(void)
 275 {
 276         entity gren;
 277
 278         W_DecreaseAmmo(WEP_CVAR_SEC(mortar, ammo));
 279
 280         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(mortar, damage));
 281         w_shotdir = v_forward; // no TrueAim for grenades please
 282
 283         Send_Effect("grenadelauncher_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 284
 285         gren = spawn();
 286         gren.owner = gren.realowner = self;
 287         gren.classname = "grenade";
 288         gren.bot_dodge = true;
 289         gren.bot_dodgerating = WEP_CVAR_SEC(mortar, damage);
 290         gren.movetype = MOVETYPE_BOUNCE;
 291         gren.bouncefactor = WEP_CVAR(mortar, bouncefactor);
 292         gren.bouncestop = WEP_CVAR(mortar, bouncestop);
 293         PROJECTILE_MAKETRIGGER(gren);
 294         gren.projectiledeathtype = WEP_MORTAR.m_id | HITTYPE_SECONDARY;
 295         setorigin(gren, w_shotorg);
 296         setsize(gren, '-3 -3 -3', '3 3 3');
 297
 298         gren.nextthink = time + WEP_CVAR_SEC(mortar, lifetime);
 299         gren.think = adaptor_think2use_hittype_splash;
 300         gren.use = W_Mortar_Grenade_Explode2;
 301         gren.touch = W_Mortar_Grenade_Touch2;
 302
 303         gren.takedamage = DAMAGE_YES;
 304         gren.health = WEP_CVAR_SEC(mortar, health);
 305         gren.damageforcescale = WEP_CVAR_SEC(mortar, damageforcescale);
 306         gren.event_damage = W_Mortar_Grenade_Damage;
 307         gren.damagedbycontents = true;
 308         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 309         W_SetupProjVelocity_UP_SEC(gren, mortar);
 310
 311         gren.angles = vectoangles(gren.velocity);
 312         gren.flags = FL_PROJECTILE;
 313
 314         if(WEP_CVAR_SEC(mortar, type) == 0 || WEP_CVAR_SEC(mortar, type) == 2)
 315                 CSQCProjectile(gren, true, PROJECTILE_GRENADE, true);
 316         else
 317                 CSQCProjectile(gren, true, PROJECTILE_GRENADE_BOUNCING, true);
 318
 319         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 320 }
 321
 322 .float bot_secondary_grenademooth;
 323 bool W_Mortar(int req)
 324 {
 325         entity nade;
 326         float nadefound;
 327         float ammo_amount;
 328         switch(req)
 329         {
 330                 case WR_AIM:
 331                 {
 332                         self.BUTTON_ATCK = false;
 333                         self.BUTTON_ATCK2 = false;
 334                         if(self.bot_secondary_grenademooth == 0) // WEAPONTODO: merge this into using WEP_CVAR_BOTH
 335                         {
 336                                 if(bot_aim(WEP_CVAR_PRI(mortar, speed), WEP_CVAR_PRI(mortar, speed_up), WEP_CVAR_PRI(mortar, lifetime), true))
 337                                 {
 338                                         self.BUTTON_ATCK = true;
 339                                         if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 340                                 }
 341                         }
 342                         else
 343                         {
 344                                 if(bot_aim(WEP_CVAR_SEC(mortar, speed), WEP_CVAR_SEC(mortar, speed_up), WEP_CVAR_SEC(mortar, lifetime), true))
 345                                 {
 346                                         self.BUTTON_ATCK2 = true;
 347                                         if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 348                                 }
 349                         }
 350
 351                         return true;
 352                 }
 353                 /*case WR_CALCINFO:
 354                 {
 355                         wepinfo_pri_refire = max3(sys_frametime, WEP_CVAR_PRI(mortar, refire), WEP_CVAR_PRI(mortar, animtime));
 356                         wepinfo_pri_dps = (WEP_CVAR_PRI(mortar, damage) * (1 / wepinfo_pri_refire));
 357                         wepinfo_pri_speed = (1 / max(1, (10000 / max(1, WEP_CVAR_PRI(mortar, speed)))));
 358
 359                         // for the range calculation, closer to 1 is better
 360                         wepinfo_pri_range_max = 2000 * wepinfo_pri_speed;
 361                         wepinfo_pri_range = wepinfo_pri_speed * WEP_CVAR_PRI(mortar,
 362
 363                         wepinfo_sec_refire = max3(sys_frametime, WEP_CVAR_SEC(mortar, refire), WEP_CVAR_SEC(mortar, animtime));
 364                         wepinfo_sec_dps = (WEP_CVAR_SEC(mortar, damage) * (1 / wepinfo_sec_refire));
 365
 366                         wepinfo_sec_dps = (WEP_CVAR_SEC(mortar, damage) * (1 / max3(sys_frametime, WEP_CVAR_SEC(mortar, refire), WEP_CVAR_SEC(mortar, animtime))));
 367                         wepinfo_ter_dps = 0;
 368                         */
 369                 case WR_THINK:
 370                 {
 371                         if(autocvar_g_balance_mortar_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(mortar, ammo), WEP_CVAR_SEC(mortar, ammo))) // forced reload
 372                                 WEP_ACTION(self.weapon, WR_RELOAD);
 373                         else if(self.BUTTON_ATCK)
 374                         {
 375                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(mortar, refire)))
 376                                 {
 377                                         W_Mortar_Attack();
 378                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(mortar, animtime), w_ready);
 379                                 }
 380                         }
 381                         else if(self.BUTTON_ATCK2)
 382                         {
 383                                 if(WEP_CVAR_SEC(mortar, remote_detonateprimary))
 384                                 {
 385                                         nadefound = 0;
 386                                         for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.realowner == self)
 387                                         {
 388                                                 if(!nade.gl_detonate_later)
 389                                                 {
 390                                                         nade.gl_detonate_later = true;
 391                                                         nadefound = 1;
 392                                                 }
 393                                         }
 394                                         if(nadefound)
 395                                                 sound(self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 396                                 }
 397                                 else if(weapon_prepareattack(1, WEP_CVAR_SEC(mortar, refire)))
 398                                 {
 399                                         W_Mortar_Attack2();
 400                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(mortar, animtime), w_ready);
 401                                 }
 402                         }
 403
 404                         return true;
 405                 }
 406                 case WR_INIT:
 407                 {
 408                         precache_model("models/weapons/g_gl.md3");
 409                         precache_model("models/weapons/v_gl.md3");
 410                         precache_model("models/weapons/h_gl.iqm");
 411                         precache_sound("weapons/grenade_bounce1.wav");
 412                         precache_sound("weapons/grenade_bounce2.wav");
 413                         precache_sound("weapons/grenade_bounce3.wav");
 414                         precache_sound("weapons/grenade_bounce4.wav");
 415                         precache_sound("weapons/grenade_bounce5.wav");
 416                         precache_sound("weapons/grenade_bounce6.wav");
 417                         precache_sound("weapons/grenade_stick.wav");
 418                         precache_sound("weapons/grenade_fire.wav");
 419                         MORTAR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 420                         return true;
 421                 }
 422                 case WR_CHECKAMMO1:
 423                 {
 424                         ammo_amount = self.WEP_AMMO(MORTAR) >= WEP_CVAR_PRI(mortar, ammo);
 425                         ammo_amount += self.(weapon_load[WEP_MORTAR.m_id]) >= WEP_CVAR_PRI(mortar, ammo);
 426                         return ammo_amount;
 427                 }
 428                 case WR_CHECKAMMO2:
 429                 {
 430                         ammo_amount = self.WEP_AMMO(MORTAR) >= WEP_CVAR_SEC(mortar, ammo);
 431                         ammo_amount += self.(weapon_load[WEP_MORTAR.m_id]) >= WEP_CVAR_SEC(mortar, ammo);
 432                         return ammo_amount;
 433                 }
 434                 case WR_CONFIG:
 435                 {
 436                         MORTAR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 437                         return true;
 438                 }
 439                 case WR_RELOAD:
 440                 {
 441                         W_Reload(min(WEP_CVAR_PRI(mortar, ammo), WEP_CVAR_SEC(mortar, ammo)), "weapons/reload.wav"); // WEAPONTODO
 442                         return true;
 443                 }
 444                 case WR_SUICIDEMESSAGE:
 445                 {
 446                         if(w_deathtype & HITTYPE_SECONDARY)
 447                                 return WEAPON_MORTAR_SUICIDE_BOUNCE;
 448                         else
 449                                 return WEAPON_MORTAR_SUICIDE_EXPLODE;
 450                 }
 451                 case WR_KILLMESSAGE:
 452                 {
 453                         if(w_deathtype & HITTYPE_SECONDARY)
 454                                 return WEAPON_MORTAR_MURDER_BOUNCE;
 455                         else
 456                                 return WEAPON_MORTAR_MURDER_EXPLODE;
 457                 }
 458         }
 459         return false;
 460 }
 461 #endif
 462 #ifdef CSQC
 463 bool W_Mortar(int req)
 464 {
 465         switch(req)
 466         {
 467                 case WR_IMPACTEFFECT:
 468                 {
 469                         vector org2;
 470                         org2 = w_org + w_backoff * 12;
 471                         pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 472                         if(!w_issilent)
 473                                 sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 474
 475                         return true;
 476                 }
 477                 case WR_INIT:
 478                 {
 479                         precache_sound("weapons/grenade_impact.wav");
 480                         return true;
 481                 }
 482                 case WR_ZOOMRETICLE:
 483                 {
 484                         // no weapon specific image for this weapon
 485                         return false;
 486                 }
 487         }
 488         return false;
 489 }
 490 #endif
 491 #endif