qcsrc/common/weapons/w_porto.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ PORTO,
   4 /* function  */ W_Porto,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 0,
   7 /* flags     */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating    */ 0,
   9 /* color     */ '0.5 0.5 0.5',
  10 /* modelname */ "porto",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairporto 0.6",
  13 /* wepimg    */ "weaponporto",
  14 /* refname   */ "porto",
  15 /* wepname   */ _("Port-O-Launch")
  16 );
  17
  18 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  19 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, animtime) \
  21         w_cvar(id, sn, BOTH, lifetime) \
  22         w_cvar(id, sn, BOTH, refire) \
  23         w_cvar(id, sn, BOTH, speed) \
  24         w_cvar(id, sn, NONE, secondary) \
  25         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  26         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  27         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  28         w_prop(id, sn, float,  weaponstart, weaponstart) \
  29         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  30         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  31
  32 #ifdef SVQC
  33 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  34 .entity porto_current;
  35 .vector porto_v_angle; // holds "held" view angles
  36 .float porto_v_angle_held;
  37 .vector right_vector;
  38 #endif
  39 #endif
  40 #ifdef IMPLEMENTATION
  41 #ifdef SVQC
  42 #include "../triggers/trigger/jumppads.qh"
  43
  44 void spawnfunc_weapon_porto(void) { weapon_defaultspawnfunc(WEP_PORTO.m_id); }
  45
  46 void W_Porto_Success(void)
  47 {
  48         if(self.realowner == world)
  49         {
  50                 objerror("Cannot succeed successfully: no owner\n");
  51                 return;
  52         }
  53
  54         self.realowner.porto_current = world;
  55         remove(self);
  56 }
  57
  58 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  59 void W_Porto_Fail(float failhard)
  60 {
  61         if(self.realowner == world)
  62         {
  63                 objerror("Cannot fail successfully: no owner\n");
  64                 return;
  65         }
  66
  67         // no portals here!
  68         if(self.cnt < 0)
  69         {
  70                 Portal_ClearWithID(self.realowner, self.portal_id);
  71         }
  72
  73         self.realowner.porto_current = world;
  74
  75         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  76         {
  77                 setsize(self, '-16 -16 0', '16 16 32');
  78                 setorigin(self, self.origin + trace_plane_normal);
  79                 if(move_out_of_solid(self))
  80                 {
  81                         self.flags = FL_ITEM;
  82                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  83                         tracetoss(self, self);
  84                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  85                         {
  86                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO.m_id, 0, self.origin, self.velocity);
  87                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_FAILED);
  88                         }
  89                 }
  90         }
  91         remove(self);
  92 }
  93
  94 void W_Porto_Remove(entity p)
  95 {
  96         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  97         {
  98                 entity oldself;
  99                 oldself = self;
 100                 self = p.porto_current;
 101                 W_Porto_Fail(1);
 102                 self = oldself;
 103         }
 104 }
 105
 106 void W_Porto_Think(void)
 107 {
 108         trace_plane_normal = '0 0 0';
 109         if(self.realowner.playerid != self.playerid)
 110                 remove(self);
 111         else
 112                 W_Porto_Fail(0);
 113 }
 114
 115 void W_Porto_Touch(void)
 116 {
 117         vector norm;
 118
 119         // do not use PROJECTILE_TOUCH here
 120         // FIXME but DO handle warpzones!
 121
 122         if(other.classname == "portal")
 123                 return; // handled by the portal
 124
 125         norm = trace_plane_normal;
 126         if(trace_ent.iscreature)
 127         {
 128                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN.z, MOVE_WORLDONLY, self);
 129                 if(trace_fraction >= 1)
 130                         return;
 131                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 132                         return;
 133                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 134                         return;
 135         }
 136
 137         if(self.realowner.playerid != self.playerid)
 138         {
 139                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 140                 remove(self);
 141         }
 142         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 143         {
 144                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTEN_NORM);
 145                 // just reflect
 146                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 147                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 148         }
 149         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 150         {
 151                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 152                 W_Porto_Fail(0);
 153                 if(self.cnt < 0)
 154                         Portal_ClearAll_PortalsOnly(self.realowner);
 155         }
 156         else if(self.cnt == 0)
 157         {
 158                 // in-portal only
 159                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 160                 {
 161                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 162                         trace_plane_normal = norm;
 163                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 164                         W_Porto_Success();
 165                 }
 166                 else
 167                 {
 168                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 169                         trace_plane_normal = norm;
 170                         W_Porto_Fail(0);
 171                 }
 172         }
 173         else if(self.cnt == 1)
 174         {
 175                 // out-portal only
 176                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 177                 {
 178                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 179                         trace_plane_normal = norm;
 180                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 181                         W_Porto_Success();
 182                 }
 183                 else
 184                 {
 185                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 186                         trace_plane_normal = norm;
 187                         W_Porto_Fail(0);
 188                 }
 189         }
 190         else if(self.effects & EF_RED)
 191         {
 192                 self.effects += EF_BLUE - EF_RED;
 193                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 194                 {
 195                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 196                         trace_plane_normal = norm;
 197                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 198                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 199                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 200                         CSQCProjectile(self, true, PROJECTILE_PORTO_BLUE, true); // change type
 201                 }
 202                 else
 203                 {
 204                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 205                         trace_plane_normal = norm;
 206                         Portal_ClearAll_PortalsOnly(self.realowner);
 207                         W_Porto_Fail(0);
 208                 }
 209         }
 210         else
 211         {
 212                 if(self.realowner.portal_in.portal_id == self.portal_id)
 213                 {
 214                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 215                         {
 216                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 217                                 trace_plane_normal = norm;
 218                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 219                                 W_Porto_Success();
 220                         }
 221                         else
 222                         {
 223                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 224                                 Portal_ClearAll_PortalsOnly(self.realowner);
 225                                 W_Porto_Fail(0);
 226                         }
 227                 }
 228                 else
 229                 {
 230                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 231                         Portal_ClearAll_PortalsOnly(self.realowner);
 232                         W_Porto_Fail(0);
 233                 }
 234         }
 235 }
 236
 237 void W_Porto_Attack(float type)
 238 {
 239         entity gren;
 240
 241         W_SetupShot(self, false, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 242         // always shoot from the eye
 243         w_shotdir = v_forward;
 244         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 245
 246         //Send_Effect("grenadelauncher_muzzleflash", w_shotorg, w_shotdir * 1000, 1);
 247
 248         gren = spawn();
 249         gren.cnt = type;
 250         gren.owner = gren.realowner = self;
 251         gren.playerid = self.playerid;
 252         gren.classname = "porto";
 253         gren.bot_dodge = true;
 254         gren.bot_dodgerating = 200;
 255         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 256         PROJECTILE_MAKETRIGGER(gren);
 257         gren.effects = EF_RED;
 258         gren.scale = 4;
 259         setorigin(gren, w_shotorg);
 260         setsize(gren, '0 0 0', '0 0 0');
 261
 262         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 263         gren.think = W_Porto_Think;
 264         gren.touch = W_Porto_Touch;
 265
 266         if(self.items & ITEM_Strength.m_itemid)
 267                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 268         else
 269                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 270
 271         gren.angles = vectoangles(gren.velocity);
 272         gren.flags = FL_PROJECTILE;
 273
 274         gren.portal_id = time;
 275         self.porto_current = gren;
 276         gren.playerid = self.playerid;
 277         fixedmakevectors(fixedvectoangles(gren.velocity));
 278         gren.right_vector = v_right;
 279
 280         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 281
 282         if(type > 0)
 283                 CSQCProjectile(gren, true, PROJECTILE_PORTO_BLUE, true);
 284         else
 285                 CSQCProjectile(gren, true, PROJECTILE_PORTO_RED, true);
 286
 287         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 288 }
 289
 290 bool w_nexball_weapon(int req); // WEAPONTODO
 291 bool W_Porto(int req)
 292 {
 293         //vector v_angle_save;
 294
 295         if(g_nexball) { return w_nexball_weapon(req); }
 296
 297         switch(req)
 298         {
 299                 case WR_AIM:
 300                 {
 301                         self.BUTTON_ATCK = false;
 302                         self.BUTTON_ATCK2 = false;
 303                         if(!WEP_CVAR(porto, secondary))
 304                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), false))
 305                                         self.BUTTON_ATCK = true;
 306
 307                         return true;
 308                 }
 309                 case WR_CONFIG:
 310                 {
 311                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 312                         return true;
 313                 }
 314                 case WR_THINK:
 315                 {
 316                         if(WEP_CVAR(porto, secondary))
 317                         {
 318                                 if(self.BUTTON_ATCK)
 319                                 if(!self.porto_current)
 320                                 if(!self.porto_forbidden)
 321                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 322                                 {
 323                                         W_Porto_Attack(0);
 324                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 325                                 }
 326
 327                                 if(self.BUTTON_ATCK2)
 328                                 if(!self.porto_current)
 329                                 if(!self.porto_forbidden)
 330                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 331                                 {
 332                                         W_Porto_Attack(1);
 333                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 334                                 }
 335                         }
 336                         else
 337                         {
 338                                 if(self.porto_v_angle_held)
 339                                 {
 340                                         if(!self.BUTTON_ATCK2)
 341                                         {
 342                                                 self.porto_v_angle_held = 0;
 343
 344                                                 ClientData_Touch(self);
 345                                         }
 346                                 }
 347                                 else
 348                                 {
 349                                         if(self.BUTTON_ATCK2)
 350                                         {
 351                                                 self.porto_v_angle = self.v_angle;
 352                                                 self.porto_v_angle_held = 1;
 353
 354                                                 ClientData_Touch(self);
 355                                         }
 356                                 }
 357                                 if(self.porto_v_angle_held)
 358                                         makevectors(self.porto_v_angle); // override the previously set angles
 359
 360                                 if(self.BUTTON_ATCK)
 361                                 if(!self.porto_current)
 362                                 if(!self.porto_forbidden)
 363                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 364                                 {
 365                                         W_Porto_Attack(-1);
 366                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 367                                 }
 368                         }
 369
 370                         return true;
 371                 }
 372                 case WR_INIT:
 373                 {
 374                         precache_model("models/weapons/g_porto.md3");
 375                         precache_model("models/weapons/v_porto.md3");
 376                         precache_model("models/weapons/h_porto.iqm");
 377                         precache_model("models/portal.md3");
 378                         precache_sound("porto/bounce.wav");
 379                         precache_sound("porto/create.wav");
 380                         precache_sound("porto/expire.wav");
 381                         precache_sound("porto/explode.wav");
 382                         precache_sound("porto/fire.wav");
 383                         precache_sound("porto/unsupported.wav");
 384                         PORTO_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 385                         return true;
 386                 }
 387                 case WR_SETUP:
 388                 {
 389                         self.ammo_field = ammo_none;
 390                         return true;
 391                 }
 392                 case WR_RESETPLAYER:
 393                 {
 394                         self.porto_current = world;
 395                         return true;
 396                 }
 397         }
 398         return false;
 399 }
 400 #endif
 401 #ifdef CSQC
 402 bool W_Porto(int req)
 403 {
 404         switch(req)
 405         {
 406                 case WR_IMPACTEFFECT:
 407                 {
 408                         print("Since when does Porto send DamageInfo?\n");
 409                         return true;
 410                 }
 411                 case WR_INIT:
 412                 {
 413                         // nothing to do
 414                         return true;
 415                 }
 416                 case WR_ZOOMRETICLE:
 417                 {
 418                         // no weapon specific image for this weapon
 419                         return false;
 420                 }
 421         }
 422         return false;
 423 }
 424 #endif
 425 #endif