qcsrc/common/weapons/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ PORTO,
   4 /* function */ W_Porto,
   5 /* ammotype */ ammo_none,
   6 /* impulse  */ 0,
   7 /* flags    */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating   */ 0,
   9 /* color        */ '0.5 0.5 0.5',
  10 /* model    */ "porto" ,
  11 /* crosshair */ "gfx/crosshairporto 0.6",
  12 /* netname  */ "porto",
  13 /* fullname */ _("Port-O-Launch")
  14 );
  15
  16 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  17 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  18         w_cvar(id, sn, BOTH, animtime) \
  19         w_cvar(id, sn, BOTH, lifetime) \
  20         w_cvar(id, sn, BOTH, refire) \
  21         w_cvar(id, sn, BOTH, speed) \
  22         w_cvar(id, sn, NONE, secondary) \
  23         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  24         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  25         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  26         w_prop(id, sn, float,  weaponstart, weaponstart) \
  27         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  28
  29 #ifdef SVQC
  30 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  31 .entity porto_current;
  32 .vector porto_v_angle; // holds "held" view angles
  33 .float porto_v_angle_held;
  34 .vector right_vector;
  35 #endif
  36 #else
  37 #ifdef SVQC
  38 void spawnfunc_weapon_porto (void) { weapon_defaultspawnfunc(WEP_PORTO); }
  39
  40 void W_Porto_Success (void)
  41 {
  42         if(self.realowner == world)
  43         {
  44                 objerror("Cannot succeed successfully: no owner\n");
  45                 return;
  46         }
  47
  48         self.realowner.porto_current = world;
  49         remove(self);
  50 }
  51
  52 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  53 void W_Porto_Fail (float failhard)
  54 {
  55         if(self.realowner == world)
  56         {
  57                 objerror("Cannot fail successfully: no owner\n");
  58                 return;
  59         }
  60
  61         // no portals here!
  62         if(self.cnt < 0)
  63         {
  64                 Portal_ClearWithID(self.realowner, self.portal_id);
  65         }
  66
  67         self.realowner.porto_current = world;
  68
  69         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  70         {
  71                 setsize (self, '-16 -16 0', '16 16 32');
  72                 setorigin(self, self.origin + trace_plane_normal);
  73                 if(move_out_of_solid(self))
  74                 {
  75                         self.flags = FL_ITEM;
  76                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  77                         tracetoss(self, self);
  78                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  79                         {
  80                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  81                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  82                         }
  83                 }
  84         }
  85         remove(self);
  86 }
  87
  88 void W_Porto_Remove (entity p)
  89 {
  90         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  91         {
  92                 entity oldself;
  93                 oldself = self;
  94                 self = p.porto_current;
  95                 W_Porto_Fail(1);
  96                 self = oldself;
  97         }
  98 }
  99
 100 void W_Porto_Think (void)
 101 {
 102         trace_plane_normal = '0 0 0';
 103         if(self.realowner.playerid != self.playerid)
 104                 remove(self);
 105         else
 106                 W_Porto_Fail(0);
 107 }
 108
 109 void W_Porto_Touch (void)
 110 {
 111         vector norm;
 112
 113         // do not use PROJECTILE_TOUCH here
 114         // FIXME but DO handle warpzones!
 115
 116         if(other.classname == "portal")
 117                 return; // handled by the portal
 118
 119         norm = trace_plane_normal;
 120         if(trace_ent.iscreature)
 121         {
 122                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
 123                 if(trace_fraction >= 1)
 124                         return;
 125                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 126                         return;
 127                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 128                         return;
 129         }
 130
 131         if(self.realowner.playerid != self.playerid)
 132         {
 133                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 134                 remove(self);
 135         }
 136         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 137         {
 138                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTEN_NORM);
 139                 // just reflect
 140                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 141                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 142         }
 143         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 144         {
 145                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 146                 W_Porto_Fail(0);
 147                 if(self.cnt < 0)
 148                         Portal_ClearAll_PortalsOnly(self.realowner);
 149         }
 150         else if(self.cnt == 0)
 151         {
 152                 // in-portal only
 153                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 154                 {
 155                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 156                         trace_plane_normal = norm;
 157                         centerprint(self.realowner, "^1In^7-portal created.");
 158                         W_Porto_Success();
 159                 }
 160                 else
 161                 {
 162                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 163                         trace_plane_normal = norm;
 164                         W_Porto_Fail(0);
 165                 }
 166         }
 167         else if(self.cnt == 1)
 168         {
 169                 // out-portal only
 170                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 171                 {
 172                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 173                         trace_plane_normal = norm;
 174                         centerprint(self.realowner, "^4Out^7-portal created.");
 175                         W_Porto_Success();
 176                 }
 177                 else
 178                 {
 179                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 180                         trace_plane_normal = norm;
 181                         W_Porto_Fail(0);
 182                 }
 183         }
 184         else if(self.effects & EF_RED)
 185         {
 186                 self.effects += EF_BLUE - EF_RED;
 187                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 188                 {
 189                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 190                         trace_plane_normal = norm;
 191                         centerprint(self.realowner, "^1In^7-portal created.");
 192                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 193                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 194                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 195                 }
 196                 else
 197                 {
 198                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 199                         trace_plane_normal = norm;
 200                         Portal_ClearAll_PortalsOnly(self.realowner);
 201                         W_Porto_Fail(0);
 202                 }
 203         }
 204         else
 205         {
 206                 if(self.realowner.portal_in.portal_id == self.portal_id)
 207                 {
 208                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 209                         {
 210                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 211                                 trace_plane_normal = norm;
 212                                 centerprint(self.realowner, "^4Out^7-portal created.");
 213                                 W_Porto_Success();
 214                         }
 215                         else
 216                         {
 217                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 218                                 Portal_ClearAll_PortalsOnly(self.realowner);
 219                                 W_Porto_Fail(0);
 220                         }
 221                 }
 222                 else
 223                 {
 224                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 225                         Portal_ClearAll_PortalsOnly(self.realowner);
 226                         W_Porto_Fail(0);
 227                 }
 228         }
 229 }
 230
 231 void W_Porto_Attack (float type)
 232 {
 233         entity gren;
 234
 235         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 236         // always shoot from the eye
 237         w_shotdir = v_forward;
 238         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 239
 240         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 241
 242         gren = spawn ();
 243         gren.cnt = type;
 244         gren.owner = gren.realowner = self;
 245         gren.playerid = self.playerid;
 246         gren.classname = "porto";
 247         gren.bot_dodge = TRUE;
 248         gren.bot_dodgerating = 200;
 249         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 250         PROJECTILE_MAKETRIGGER(gren);
 251         gren.effects = EF_RED;
 252         gren.scale = 4;
 253         setorigin(gren, w_shotorg);
 254         setsize(gren, '0 0 0', '0 0 0');
 255
 256         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 257         gren.think = W_Porto_Think;
 258         gren.touch = W_Porto_Touch;
 259
 260         if(self.items & IT_STRENGTH)
 261                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 262         else
 263                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 264
 265         gren.angles = vectoangles (gren.velocity);
 266         gren.flags = FL_PROJECTILE;
 267
 268         gren.portal_id = time;
 269         self.porto_current = gren;
 270         gren.playerid = self.playerid;
 271         fixedmakevectors(fixedvectoangles(gren.velocity));
 272         gren.right_vector = v_right;
 273
 274         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 275
 276         if(type > 0)
 277                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 278         else
 279                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 280
 281         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 282 }
 283
 284 float w_nexball_weapon(float req); // WEAPONTODO
 285 float W_Porto(float req)
 286 {
 287         //vector v_angle_save;
 288
 289         if (g_nexball) { return w_nexball_weapon(req); }
 290
 291         switch(req)
 292         {
 293                 case WR_AIM:
 294                 {
 295                         self.BUTTON_ATCK = FALSE;
 296                         self.BUTTON_ATCK2 = FALSE;
 297                         if(!WEP_CVAR(porto, secondary))
 298                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), FALSE))
 299                                         self.BUTTON_ATCK = TRUE;
 300
 301                         return TRUE;
 302                 }
 303                 case WR_CONFIG:
 304                 {
 305                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 306                         return TRUE;
 307                 }
 308                 case WR_THINK:
 309                 {
 310                         if(WEP_CVAR(porto, secondary))
 311                         {
 312                                 if (self.BUTTON_ATCK)
 313                                 if (!self.porto_current)
 314                                 if (!self.porto_forbidden)
 315                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 316                                 {
 317                                         W_Porto_Attack(0);
 318                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 319                                 }
 320
 321                                 if (self.BUTTON_ATCK2)
 322                                 if (!self.porto_current)
 323                                 if (!self.porto_forbidden)
 324                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 325                                 {
 326                                         W_Porto_Attack(1);
 327                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 328                                 }
 329                         }
 330                         else
 331                         {
 332                                 if(self.porto_v_angle_held)
 333                                 {
 334                                         if(!self.BUTTON_ATCK2)
 335                                         {
 336                                                 self.porto_v_angle_held = 0;
 337
 338                                                 ClientData_Touch(self);
 339                                         }
 340                                 }
 341                                 else
 342                                 {
 343                                         if(self.BUTTON_ATCK2)
 344                                         {
 345                                                 self.porto_v_angle = self.v_angle;
 346                                                 self.porto_v_angle_held = 1;
 347
 348                                                 ClientData_Touch(self);
 349                                         }
 350                                 }
 351                                 if(self.porto_v_angle_held)
 352                                         makevectors(self.porto_v_angle); // override the previously set angles
 353
 354                                 if (self.BUTTON_ATCK)
 355                                 if (!self.porto_current)
 356                                 if (!self.porto_forbidden)
 357                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 358                                 {
 359                                         W_Porto_Attack(-1);
 360                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 361                                 }
 362                         }
 363
 364                         return TRUE;
 365                 }
 366                 case WR_INIT:
 367                 {
 368                         precache_model ("models/weapons/g_porto.md3");
 369                         precache_model ("models/weapons/v_porto.md3");
 370                         precache_model ("models/weapons/h_porto.iqm");
 371                         precache_model ("models/portal.md3");
 372                         precache_sound ("porto/bounce.wav");
 373                         precache_sound ("porto/create.wav");
 374                         precache_sound ("porto/expire.wav");
 375                         precache_sound ("porto/explode.wav");
 376                         precache_sound ("porto/fire.wav");
 377                         precache_sound ("porto/unsupported.wav");
 378                         PORTO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 379                         return TRUE;
 380                 }
 381                 case WR_SETUP:
 382                 {
 383                         self.ammo_field = ammo_none;
 384                         return TRUE;
 385                 }
 386                 case WR_RESETPLAYER:
 387                 {
 388                         self.porto_current = world;
 389                         return TRUE;
 390                 }
 391         }
 392         return TRUE;
 393 }
 394 #endif
 395 #ifdef CSQC
 396 float W_Porto(float req)
 397 {
 398         switch(req)
 399         {
 400                 case WR_IMPACTEFFECT:
 401                 {
 402                         print("Since when does Porto send DamageInfo?\n");
 403                         return TRUE;
 404                 }
 405                 case WR_INIT:
 406                 {
 407                         // nothing to do
 408                         return TRUE;
 409                 }
 410                 case WR_ZOOMRETICLE:
 411                 {
 412                         // no weapon specific image for this weapon
 413                         return FALSE;
 414                 }
 415         }
 416         return TRUE;
 417 }
 418 #endif
 419 #endif